[bug#41567] [PATCH] gnu: Add mspdebug.

[bug#41567] [PATCH] gnu: Add mspdebug.

[Morgan.J.Smith]

From: Morgan Smith <Morgan.J.Smith@outlook.com>

* gnu/packages/mspdebug.scm (mspdebug): New variable.
---
 gnu/packages/mspdebug.scm | 44 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 gnu/packages/mspdebug.scm

diff --git a/gnu/packages/mspdebug.scm b/gnu/packages/mspdebug.scm
new file mode 100644
index 0000000000..fcabcae472
--- /dev/null
+++ b/gnu/packages/mspdebug.scm
@@ -0,0 +1,44 @@
+;;; Copyright © 2020 Morgan Smith <Morgan.J.Smith@outlook.com>
+
+(define-module (gnu packages mspdebug)
+  #:use-module (guix packages)
+  #:use-module (guix git-download)
+  #:use-module (guix build-system gnu)
+  #:use-module (guix licenses)
+  #:use-module (gnu packages libusb)
+  #:use-module (gnu packages readline))
+
+
+(define-public mspdebug
+  (package
+    (name "mspdebug")
+    (version "0.25")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://github.com/dlbeer/mspdebug.git")
+                    (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32 "0prgwb5vx6fd4bj12ss1bbb6axj2kjyriyjxqrzd58s5jyyy8d3c"))))
+    (build-system gnu-build-system)
+    (arguments
+     `(#:phases (modify-phases %standard-phases (delete 'configure) (delete 'check))
+       #:make-flags
+       (let ((target ,(%current-target-system)))
+         (list (string-append "CC=" (if target
+                                        (string-append target "-gcc")
+                                        "gcc"))
+               "INSTALL=install"
+               (string-append "PREFIX=" %output)))))
+    (inputs
+     `(("libusb-compat" ,libusb-compat)
+       ("readline" ,readline)))
+    (synopsis "Free debugger for use with MSP430 MCUs")
+    (description "MspDebug supports FET430UIF, eZ430, RF2500 and Olimex
+MSP430-JTAG-TINY programmers, as well as many other compatible
+devices.  It can be used as a proxy for gdb or as an independent
+debugger with support for programming, disassembly and reverse
+engineering.")
+    (home-page "https://github.com/dlbeer/mspdebug")
+    (license gpl2)))
-- 
2.26.2

[bug#41567] [PATCH] gnu: Add mspdebug.

[Marius Bakke]

[-- Attachment #1: Type: text/plain, Size: 2140 bytes --]

Morgan.J.Smith@outlook.com writes:

> From: Morgan Smith <Morgan.J.Smith@outlook.com>
>
> * gnu/packages/mspdebug.scm (mspdebug): New variable.

Can you move this package to gnu/packages/debug.scm instead of adding a
new module?

[...]

> +(define-public mspdebug
> +  (package
> +    (name "mspdebug")
> +    (version "0.25")
> +    (source (origin
> +              (method git-fetch)
> +              (uri (git-reference
> +                    (url "https://github.com/dlbeer/mspdebug.git")
> +                    (commit (string-append "v" version))))
> +              (file-name (git-file-name name version))
> +              (sha256
> +               (base32 "0prgwb5vx6fd4bj12ss1bbb6axj2kjyriyjxqrzd58s5jyyy8d3c"))))
> +    (build-system gnu-build-system)
> +    (arguments
> +     `(#:phases (modify-phases %standard-phases (delete 'configure) (delete 'check))
> +       #:make-flags
> +       (let ((target ,(%current-target-system)))
> +         (list (string-append "CC=" (if target
> +                                        (string-append target "-gcc")
> +                                        "gcc"))

Since very recently, you can now use:

  (string-append "CC=" ,(cc-for-target))

instead of the let binding and conditional.

> +               "INSTALL=install"
> +               (string-append "PREFIX=" %output)))))
> +    (inputs
> +     `(("libusb-compat" ,libusb-compat)
> +       ("readline" ,readline)))
> +    (synopsis "Free debugger for use with MSP430 MCUs")

No need to mention free here, since everything in Guix is free
software.  The GitHub tagline is pretty good:

  Debugging tool for MSP430 MCUs

> +    (description "MspDebug supports FET430UIF, eZ430, RF2500 and Olimex
> +MSP430-JTAG-TINY programmers, as well as many other compatible
> +devices.  It can be used as a proxy for gdb or as an independent
> +debugger with support for programming, disassembly and reverse
> +engineering.")
> +    (home-page "https://github.com/dlbeer/mspdebug")
> +    (license gpl2)))

This should be 'gpl2+', since the source files say "GPL 2 or any later
version".

Can you send an updated patch?  Thanks in advance!

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 487 bytes --]

[bug#41567] [PATCH] gnu: Add mspdebug.

[Tobias Geerinckx-Rice via Guix-patches via]

[-- Attachment #1: Type: text/plain, Size: 563 bytes --]

Morgan,

Morgan.J.Smith@outlook.com 写道：
> +     `(#:phases (modify-phases %standard-phases (delete 
> 'configure) (delete 'check))

Try to keep lines within 80 characters.  Have you heard of our 
lord & saviour ‘guix lint’?  It's nitpicking like this, automated.

There's a more ‘declarative’ way to disable tests.  Add a short 
note why:

  `(#:tests? #f                         ; no test suite
    #:phases
    (modify-phases %standard-phases
      (delete 'configure)))             ; no configure script

Kind regards,

T G-R

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 227 bytes --]

[bug#41567] [PATCH] gnu: Add mspdebug.

[Morgan.J.Smith]

From: Morgan Smith <Morgan.J.Smith@outlook.com>

* gnu/packages/debug.scm (mspdebug): New variable.
---
 gnu/packages/debug.scm | 36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

diff --git a/gnu/packages/debug.scm b/gnu/packages/debug.scm
index 4a264427c2..18cc2894a7 100644
--- a/gnu/packages/debug.scm
+++ b/gnu/packages/debug.scm
@@ -5,6 +5,7 @@
 ;;; Copyright © 2018, 2019 Rutger Helling <rhelling@mykolab.com>
 ;;; Copyright © 2019 Pkill -9 <pkill9@runbox.com>
 ;;; Copyright © 2020 Vincent Legoll <vincent.legoll@gmail.com>
+;;; Copyright © 2020 Morgan Smith <Morgan.J.Smith@outlook.com>
 ;;;
 ;;; This file is part of GNU Guix.
 ;;;
@@ -56,6 +57,7 @@
   #:use-module (gnu packages serialization)
   #:use-module (gnu packages virtualization)
   #:use-module (gnu packages xdisorg)
+  #:use-module (gnu packages libusb)
   #:use-module (ice-9 match)
   #:use-module (srfi srfi-1))
 
@@ -596,3 +598,37 @@ GDB with very efficient reverse-execution, which in combination with standard
 GDB/x86 features like hardware data watchpoints, makes debugging much more
 fun.")
     (license license:expat)))
+
+(define-public mspdebug
+  (package
+    (name "mspdebug")
+    (version "0.25")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://github.com/dlbeer/mspdebug.git")
+                    (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32 "0prgwb5vx6fd4bj12ss1bbb6axj2kjyriyjxqrzd58s5jyyy8d3c"))))
+    (build-system gnu-build-system)
+    (arguments
+     `(#:tests? #f                         ; no test suite
+       #:phases
+       (modify-phases %standard-phases
+         (delete 'configure))              ; no configure script
+       #:make-flags
+       (list (string-append "CC=" ,(cc-for-target))
+             "INSTALL=install"
+             (string-append "PREFIX=" %output))))
+  (inputs
+     `(("libusb-compat" ,libusb-compat)
+       ("readline" ,readline)))
+    (synopsis "Debugging tool for MSP430 MCUs")
+    (description "MspDebug supports FET430UIF, eZ430, RF2500 and Olimex
+MSP430-JTAG-TINY programmers, as well as many other compatible
+devices.  It can be used as a proxy for gdb or as an independent
+debugger with support for programming, disassembly and reverse
+engineering.")
+    (home-page "https://github.com/dlbeer/mspdebug")
+    (license license:gpl2+)))
-- 
2.26.2

bug#41567: [PATCH] gnu: Add mspdebug.

[Marius Bakke]

[-- Attachment #1: Type: text/plain, Size: 159 bytes --]

Morgan.J.Smith@outlook.com writes:

> From: Morgan Smith <Morgan.J.Smith@outlook.com>
>
> * gnu/packages/debug.scm (mspdebug): New variable.

Applied, thanks!

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 487 bytes --]