[PATCH] gnu: Add Red Eclipse.

[PATCH] gnu: Add Red Eclipse.

[Kei Yamashita]

With much help from others on IRC, this patch works! If necessary
or preferable, please suggest changes to make this patch more
maintainable in the long run.

Re: [PATCH] gnu: Add Red Eclipse.

[Florian Paul Schmidt]

[-- Attachment #1.1: Type: text/plain, Size: 300 bytes --]

On 23.04.2016 08:20, Kei Yamashita wrote:
> With much help from others on IRC, this patch works! If necessary
> or preferable, please suggest changes to make this patch more
> maintainable in the long run.
> 

Hi,

I think you forgot to attach the patch :)

Flo


-- 
https://fps.io


[-- Attachment #2: OpenPGP digital signature --]
[-- Type: application/pgp-signature, Size: 473 bytes --]

Re: [PATCH] gnu: Add Red Eclipse.

[Kei Yamashita]

[-- Attachment #1: Type: text/plain, Size: 430 bytes --]

Huh. The email client did report an SMTP error...

On Sat, 23 Apr 2016 09:18:32 +0200
Florian Paul Schmidt <mista.tapas@gmx.net> wrote:

> On 23.04.2016 08:20, Kei Yamashita wrote:
> > With much help from others on IRC, this patch works! If necessary
> > or preferable, please suggest changes to make this patch more
> > maintainable in the long run.
> >   
> 
> Hi,
> 
> I think you forgot to attach the patch :)
> 
> Flo
> 
> 


[-- Attachment #2: 0001-gnu-Add-Red-Eclipse.patch --]
[-- Type: application/octet-stream, Size: 9583 bytes --]

From 3d9bcdd7c48e1477231e16c7ee581aedad231690 Mon Sep 17 00:00:00 2001
From: Kei Yamashita <kei@openmailbox.org>
Date: Sat, 23 Apr 2016 01:58:55 -0400
Subject: [PATCH] gnu: Add Red Eclipse.

* gnu/packages/games.scm (redeclipse): New variable.
---
 gnu/packages/games.scm | 143 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 143 insertions(+)

diff --git a/gnu/packages/games.scm b/gnu/packages/games.scm
index c514671..7590fdc 100644
--- a/gnu/packages/games.scm
+++ b/gnu/packages/games.scm
@@ -18,6 +18,7 @@
 ;;; Copyright © 2016 Manolis Fragkiskos Ragkousis <manolis837@gmail.com>
 ;;; Copyright © 2016 Nils Gillmann <niasterisk@grrlz.net>
 ;;; Copyright © 2016 Albin Söderqvist <albin@fripost.org>
+;;; Copyright © 2016 Kei Yamashita <kei@openmailbox.org>
 ;;;
 ;;; This file is part of GNU Guix.
 ;;;
@@ -35,6 +36,7 @@
 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
 
 (define-module (gnu packages games)
+  #:use-module (ice-9 match)
   #:use-module ((guix licenses) #:prefix license:)
   #:use-module (guix utils)
   #:use-module (guix packages)
@@ -2094,3 +2096,144 @@ is attributed to Albert Einstein.")
 the chat server psyced with the specific config located at
 http://lavachat.symlynx.com/unix/")
     (license license:gpl2+)))
+
+(define-public redeclipse
+  (let ((data-sources
+         '(("acerspyro" "0gxxr6nbac918b49x1cp72nw951hqm5m4iyi2shb1612ly384w8q")
+           ("actors" "1jq9q82m6nx07nwpb5cnpdcwa33jrcgg0j2yir8zk6zpnxdmp0il")
+           ("appleflap" "1cn41c6xs68l88rmphqh4rlsh6h04xnkkvklxdpqpvvr4zlsmi85")
+           ("blendbrush" "0wjbgnniirl9arv274m8mpdqbbq7d09g0pq1z9dl56sazmbk5yy0")
+           ("caustics" "0gxv1pqhi6c27mqi9mwqyfnzv9rq5sva1vgxhb9ljh231rmkdc15")
+           ("crosshairs" "0vlyhd10mly2qnjpwvss9ani7dg3v2njpf7457ilx7fk9a3hlbkk")
+           ("elyvisions" "0s0l77rd9fd09imvj05pwcz4bqrn3j8qsw8prv5pi5bqa50mbn19")
+           ("fonts" "0apn8j9lf43nmnidq1f0azhrr1n896g7si4djbix1bwll6ild0mq")
+           ("freezurbern" "0y60s3g8v8bl2m6pk2yr9fzl67ymv821x6l2f9hszzydlcjwlscn")
+           ("john" "1lmwn0r7qpyac2qrnkv9llhsbyzqpgr27hxq2qn1rfbq12fja0ld")
+           ("jojo" "0sh3ricqlqw868a0mz2n9iw7lhp650pysd2wkcdizhcmw2hlayx9")
+           ("jwin" "1r459jhxx64j3vdw886ypkm6zg0yg6cr2qark54i1zdskjhp762k")
+           ("luckystrike" "08xq87crcz0jq45q1g6p8h4xrm1bcqzd019zp7n0f9c3p9j6al91")
+           ("maps" "1f0hqh8mbd4nzqi4hja4k5f380nszhx8igajg5ini4p9cp39x9vi")
+           ("mayhem" "1hn9jp64aiz8k6p2nxyg82h2nc8fadgghzhrm26y7i4bz9xwxacm")
+           ("mikeplus64" "1kj2zznxykgm3f1h1fvd8xzim5f292lyh96l2gj5km1nynzjmaap")
+           ("misc" "1phmzjs5rmika3568b7jb6ywbsi40r711rhg8cbsflllcp7hdidf")
+           ("nobiax" "08in9c24m2pq7x371q10ny4q3l1l3zb8m029iypy2lx9gr99i7hm")
+           ("particles" "0wcd3s6vhrjknffnfqrcpkcqk1r01f1fiz6q7n4srhpdv3i4d6vm")
+           ("philipk" "1s0kmap8iv5sddanrhycblskj3ywvz9xg2m11f6vnfy108palkga")
+           ("projectiles" "0xdhrs9rsncd1f88s5igdbfksli7h0irg5jdbj6p2a3rgdzb3gnj")
+           ("props" "1sbh3a94pmzic78bil0dvdh4fd8s6gh52f77jdram3w0gwv79x3r")
+           ("skyboxes" "0hy95a6ps0fk4cq8j6pjipk8rnsjna9bm0ly2l373gbshlfg6zgi")
+           ("sounds" "1pnyd7acm19sj1k1cy9hq3n3dnzzaiak7j5f0h7fikiybq5rdk7b")
+           ("textures" "0gxfnc4xm0kp3pd7lhd4yy1dqq00g727h21l64nyiw2b2d6n1755")
+           ("torley" "1cri5mf8ls8mvpn1x1p9hacyg9ibilaiz07gqv2hl2q8ww5xc1s6")
+           ("trak" "0xyk5z59kn9ym9n5fdcrwhqig6gjcjgnrgi9rqbbai713w9vpsbq")
+           ("ulukai" "0ziv9c4inmza40mas1w9dp048y6f646x00bs7kqv33hd1snbg3v3")
+           ("unnamed" "0hm291k9azilnp0m04zhm52vml1rhxk1z4l74v66spbikr6s2zdx")
+           ("vanities" "1qbc2v67kdrlvq10miw3dfmg3j9w9bq1hgqrzjcbph0l4gra1ndw")
+           ("vegetation" "13928yw0wflcj620cmp8rqwplaw8508f3j4zi32vxida1ksz6xn0")
+           ("weapons" "1ghn6nfcnd5lyl8dnj22csldvf9hrb32wjzpab4sjjz3iyv0zmr3")
+           ("wicked" "0q9badvg6ix5rhl05s83kw2v6a49jpnbkqk4ls89qahaddfagi8g"))))
+    (package
+      (name "redeclipse")
+      (version "1.5.3")
+      (source (origin
+                (method url-fetch)
+                (uri (string-append "https://github.com/red-eclipse/base"
+                                    "/archive/v" version ".tar.gz"))
+                (file-name (string-append name "-" version))
+                (sha256
+                 (base32
+                  "1y0jv5lz69zisiw8sd5z9a9v21zc83by1sx9b7dly78ngif4gc4l"))))
+      (build-system gnu-build-system)
+      (arguments
+       `(#:tests? #f ; no check target
+         #:make-flags (list "CC=gcc" "-Csrc"
+                            (string-append "INSTDIR="
+                                           (assoc-ref %outputs "out") "/bin"))
+         #:phases (modify-phases %standard-phases
+                    (add-after 'unpack 'unpack-data
+                      (lambda* (#:key inputs #:allow-other-keys)
+                        (delete-file-recursively "data")
+                        (mkdir "data")
+                        (for-each (lambda (name)
+                                   (system* "tar" "-xvf"
+                                            (assoc-ref inputs name)
+                                            "-Cdata"
+                                            "--transform"
+                                            (string-append "s/"
+                                                           name "-1.5.3/"
+                                                           name "/")))
+                        (list ,@(map car data-sources)))))
+                    (delete 'configure) ; no configure script
+                    (add-after 'set-paths 'set-sdl-paths
+                      (lambda* (#:key inputs #:allow-other-keys)
+                        (setenv "CPATH"
+                                (string-append (assoc-ref inputs "sdl-union")
+                                               "/include/SDL"))))
+                    (add-after 'install 'copy-data
+                      (lambda* (#:key inputs #:allow-other-keys)
+                        (copy-recursively "config" (string-append
+                                                    %output
+                                                    "/config"))
+                        (copy-recursively "data" (string-append
+                                                  %output
+                                                  "/data"))))
+                    (add-after
+                        'copy-data 'wrap-program
+                      (lambda* (#:key inputs outputs #:allow-other-keys)
+                        (let* ((out (assoc-ref outputs "out"))
+                               (bin (string-append out "/bin")))
+                          (with-directory-excursion bin
+                            (rename-file "redeclipse_linux"
+                                         ".redeclipse_linux-real")
+                            (rename-file "redeclipse_server_linux"
+                                         ".redeclipse_server_linux-real")
+                            (call-with-output-file "redeclipse_linux"
+                              (lambda (port)
+                                (format port "#!~a/bin/sh
+# Run the thing from its home, otherwise it just bails out.
+cd \"~a\"
+exec -a \"$0\" ~a/.redeclipse_linux-real~%"
+                                        (assoc-ref inputs "bash") ;implicit input
+                                        (string-append out)
+                                        (string-append bin))))
+                            (call-with-output-file "redeclipse_server_linux"
+                              (lambda (port)
+                                (format port "#!~a/bin/sh
+# Run the thing from its home, otherwise it just bails out.
+cd \"~a\"
+exec -a \"$0\" ~a/.redeclipse_server_linux-real~%"
+                                        (assoc-ref inputs "bash") ;implicit input
+                                        (string-append out)
+                                        (string-append bin))))
+                            (chmod "redeclipse_linux" #o555)
+                            (chmod "redeclipse_server_linux" #o555))))))))
+      (native-inputs `(("pkg-config" ,pkg-config)))
+      (inputs
+       `(("curl" ,curl)
+         ("glu" ,glu)
+         ("sdl-union" ,(sdl-union))
+         ;; Create origin records for the many separate data packages.
+         ,@(map (match-lambda
+                  ((name hash)
+                   (list name
+                         (origin
+                           (method url-fetch)
+                           (uri (string-append "https://github.com/red-eclipse/"
+                                               name "/archive/v" version ".tar.gz"))
+                           (sha256 (base32 hash))
+                           (file-name (string-append name "-" version ".tar.gz"))))))
+                data-sources)))
+      (home-page "http://redeclipse.net/")
+      (synopsis "Arena shooter derived from the Cube 2 engine")
+      (description
+       "Red Eclipse is an open-source arena shooter, created from the Cube2
+engine.  Offering an innovative parkour system and distinct but all potent
+weapons, Red Eclipse provides fast paced and accessible gameplay.")
+
+      ;; License information available in detail at the following link:
+      ;; http://redeclipse.net/wiki/License
+      (license (list license:expat
+                     license:zlib
+                     license:cc-by-sa3.0
+                     license:cc-by3.0
+                     license:cc0)))))
-- 
2.7.4

Re: [PATCH] gnu: Add Red Eclipse.

[Alex Kost]

Kei Yamashita (2016-04-23 14:46 +0300) wrote:

Thanks, this is very impressive work!!  I don't have any significant
notes, so if there will be no other comments, I'm going to fix them and
commit this patch.

[...]
> +(define-public redeclipse
> +  (let ((data-sources
> +         '(("acerspyro" "0gxxr6nbac918b49x1cp72nw951hqm5m4iyi2shb1612ly384w8q")
> +           ("actors" "1jq9q82m6nx07nwpb5cnpdcwa33jrcgg0j2yir8zk6zpnxdmp0il")
> +           ("appleflap" "1cn41c6xs68l88rmphqh4rlsh6h04xnkkvklxdpqpvvr4zlsmi85")
> +           ("blendbrush" "0wjbgnniirl9arv274m8mpdqbbq7d09g0pq1z9dl56sazmbk5yy0")
> +           ("caustics" "0gxv1pqhi6c27mqi9mwqyfnzv9rq5sva1vgxhb9ljh231rmkdc15")
> +           ("crosshairs" "0vlyhd10mly2qnjpwvss9ani7dg3v2njpf7457ilx7fk9a3hlbkk")
> +           ("elyvisions" "0s0l77rd9fd09imvj05pwcz4bqrn3j8qsw8prv5pi5bqa50mbn19")
> +           ("fonts" "0apn8j9lf43nmnidq1f0azhrr1n896g7si4djbix1bwll6ild0mq")
> +           ("freezurbern" "0y60s3g8v8bl2m6pk2yr9fzl67ymv821x6l2f9hszzydlcjwlscn")
> +           ("john" "1lmwn0r7qpyac2qrnkv9llhsbyzqpgr27hxq2qn1rfbq12fja0ld")
> +           ("jojo" "0sh3ricqlqw868a0mz2n9iw7lhp650pysd2wkcdizhcmw2hlayx9")
> +           ("jwin" "1r459jhxx64j3vdw886ypkm6zg0yg6cr2qark54i1zdskjhp762k")
> +           ("luckystrike" "08xq87crcz0jq45q1g6p8h4xrm1bcqzd019zp7n0f9c3p9j6al91")
> +           ("maps" "1f0hqh8mbd4nzqi4hja4k5f380nszhx8igajg5ini4p9cp39x9vi")
> +           ("mayhem" "1hn9jp64aiz8k6p2nxyg82h2nc8fadgghzhrm26y7i4bz9xwxacm")
> +           ("mikeplus64" "1kj2zznxykgm3f1h1fvd8xzim5f292lyh96l2gj5km1nynzjmaap")
> +           ("misc" "1phmzjs5rmika3568b7jb6ywbsi40r711rhg8cbsflllcp7hdidf")
> +           ("nobiax" "08in9c24m2pq7x371q10ny4q3l1l3zb8m029iypy2lx9gr99i7hm")
> +           ("particles" "0wcd3s6vhrjknffnfqrcpkcqk1r01f1fiz6q7n4srhpdv3i4d6vm")
> +           ("philipk" "1s0kmap8iv5sddanrhycblskj3ywvz9xg2m11f6vnfy108palkga")
> +           ("projectiles" "0xdhrs9rsncd1f88s5igdbfksli7h0irg5jdbj6p2a3rgdzb3gnj")
> +           ("props" "1sbh3a94pmzic78bil0dvdh4fd8s6gh52f77jdram3w0gwv79x3r")
> +           ("skyboxes" "0hy95a6ps0fk4cq8j6pjipk8rnsjna9bm0ly2l373gbshlfg6zgi")
> +           ("sounds" "1pnyd7acm19sj1k1cy9hq3n3dnzzaiak7j5f0h7fikiybq5rdk7b")
> +           ("textures" "0gxfnc4xm0kp3pd7lhd4yy1dqq00g727h21l64nyiw2b2d6n1755")
> +           ("torley" "1cri5mf8ls8mvpn1x1p9hacyg9ibilaiz07gqv2hl2q8ww5xc1s6")
> +           ("trak" "0xyk5z59kn9ym9n5fdcrwhqig6gjcjgnrgi9rqbbai713w9vpsbq")
> +           ("ulukai" "0ziv9c4inmza40mas1w9dp048y6f646x00bs7kqv33hd1snbg3v3")
> +           ("unnamed" "0hm291k9azilnp0m04zhm52vml1rhxk1z4l74v66spbikr6s2zdx")
> +           ("vanities" "1qbc2v67kdrlvq10miw3dfmg3j9w9bq1hgqrzjcbph0l4gra1ndw")
> +           ("vegetation" "13928yw0wflcj620cmp8rqwplaw8508f3j4zi32vxida1ksz6xn0")
> +           ("weapons" "1ghn6nfcnd5lyl8dnj22csldvf9hrb32wjzpab4sjjz3iyv0zmr3")
> +           ("wicked" "0q9badvg6ix5rhl05s83kw2v6a49jpnbkqk4ls89qahaddfagi8g"))))
> +    (package
> +      (name "redeclipse")

I would name the package "red-eclipse", but it probably doesn't matter.

> +      (version "1.5.3")
> +      (source (origin
> +                (method url-fetch)
> +                (uri (string-append "https://github.com/red-eclipse/base"
> +                                    "/archive/v" version ".tar.gz"))
> +                (file-name (string-append name "-" version))
                                                             ^^^^^^
                   (file-name (string-append name "-" version ".tar.gz"))

> +                (sha256
> +                 (base32
> +                  "1y0jv5lz69zisiw8sd5z9a9v21zc83by1sx9b7dly78ngif4gc4l"))))
> +      (build-system gnu-build-system)
> +      (arguments
> +       `(#:tests? #f ; no check target
> +         #:make-flags (list "CC=gcc" "-Csrc"
> +                            (string-append "INSTDIR="
> +                                           (assoc-ref %outputs "out") "/bin"))
> +         #:phases (modify-phases %standard-phases
> +                    (add-after 'unpack 'unpack-data
> +                      (lambda* (#:key inputs #:allow-other-keys)
> +                        (delete-file-recursively "data")
> +                        (mkdir "data")
> +                        (for-each (lambda (name)
> +                                   (system* "tar" "-xvf"
> +                                            (assoc-ref inputs name)
> +                                            "-Cdata"
> +                                            "--transform"
> +                                            (string-append "s/"
> +                                                           name "-1.5.3/"
> +                                                           name "/")))
> +                        (list ,@(map car data-sources)))))

This (for-each ...) is not properly indented.

> +                    (delete 'configure) ; no configure script
> +                    (add-after 'set-paths 'set-sdl-paths
> +                      (lambda* (#:key inputs #:allow-other-keys)
> +                        (setenv "CPATH"
> +                                (string-append (assoc-ref inputs "sdl-union")
> +                                               "/include/SDL"))))
> +                    (add-after 'install 'copy-data
> +                      (lambda* (#:key inputs #:allow-other-keys)
> +                        (copy-recursively "config" (string-append
> +                                                    %output
> +                                                    "/config"))
> +                        (copy-recursively "data" (string-append
> +                                                  %output
> +                                                  "/data"))))
> +                    (add-after
> +                        'copy-data 'wrap-program

It is more good-looking to move this line to the previous one.

> +                      (lambda* (#:key inputs outputs #:allow-other-keys)
> +                        (let* ((out (assoc-ref outputs "out"))
> +                               (bin (string-append out "/bin")))
> +                          (with-directory-excursion bin
> +                            (rename-file "redeclipse_linux"
> +                                         ".redeclipse_linux-real")
> +                            (rename-file "redeclipse_server_linux"
> +                                         ".redeclipse_server_linux-real")
> +                            (call-with-output-file "redeclipse_linux"
> +                              (lambda (port)
> +                                (format port "#!~a/bin/sh
> +# Run the thing from its home, otherwise it just bails out.
> +cd \"~a\"
> +exec -a \"$0\" ~a/.redeclipse_linux-real~%"
> +                                        (assoc-ref inputs "bash") ;implicit input
> +                                        (string-append out)
> +                                        (string-append bin))))
> +                            (call-with-output-file "redeclipse_server_linux"
> +                              (lambda (port)
> +                                (format port "#!~a/bin/sh
> +# Run the thing from its home, otherwise it just bails out.
> +cd \"~a\"
> +exec -a \"$0\" ~a/.redeclipse_server_linux-real~%"
> +                                        (assoc-ref inputs "bash") ;implicit input
> +                                        (string-append out)
> +                                        (string-append bin))))
> +                            (chmod "redeclipse_linux" #o555)
> +                            (chmod "redeclipse_server_linux" #o555))))))))
> +      (native-inputs `(("pkg-config" ,pkg-config)))
> +      (inputs
> +       `(("curl" ,curl)
> +         ("glu" ,glu)
> +         ("sdl-union" ,(sdl-union))
> +         ;; Create origin records for the many separate data packages.
> +         ,@(map (match-lambda
> +                  ((name hash)
> +                   (list name
> +                         (origin
> +                           (method url-fetch)
> +                           (uri (string-append "https://github.com/red-eclipse/"
> +                                               name "/archive/v" version ".tar.gz"))
> +                           (sha256 (base32 hash))
> +                           (file-name (string-append name "-" version ".tar.gz"))))))
> +                data-sources)))


I'm afraid this is not reliable.  I mean that all these data sources
have the same "v1.5.3" tags.  I doubt that once there will be a new
release of the base repository, they also will tag all the data repos to
the new version.

I think it's OK to do it like this for now, but if the mentioned problem
will happen after the next release, we'll have to change this method
(probably by making private "red-eclipse-<NAME>" packages for all data
NAMEs).

> +      (home-page "http://redeclipse.net/")
> +      (synopsis "Arena shooter derived from the Cube 2 engine")
> +      (description
> +       "Red Eclipse is an open-source arena shooter, created from the Cube2
> +engine.  Offering an innovative parkour system and distinct but all potent
> +weapons, Red Eclipse provides fast paced and accessible gameplay.")
> +
> +      ;; License information available in detail at the following link:
> +      ;; http://redeclipse.net/wiki/License
> +      (license (list license:expat
> +                     license:zlib
> +                     license:cc-by-sa3.0
> +                     license:cc-by3.0
> +                     license:cc0)))))

-- 
Alex

Re: [PATCH] gnu: Add Red Eclipse.

[Ludovic Courtès]

Alex Kost <alezost@gmail.com> skribis:


[...]

>> +         ;; Create origin records for the many separate data packages.
>> +         ,@(map (match-lambda
>> +                  ((name hash)
>> +                   (list name
>> +                         (origin
>> +                           (method url-fetch)
>> +                           (uri (string-append "https://github.com/red-eclipse/"
>> +                                               name "/archive/v" version ".tar.gz"))
>> +                           (sha256 (base32 hash))
>> +                           (file-name (string-append name "-" version ".tar.gz"))))))
>> +                data-sources)))
>
>
> I'm afraid this is not reliable.  I mean that all these data sources
> have the same "v1.5.3" tags.  I doubt that once there will be a new
> release of the base repository, they also will tag all the data repos to
> the new version.
>
> I think it's OK to do it like this for now, but if the mentioned problem
> will happen after the next release, we'll have to change this method
> (probably by making private "red-eclipse-<NAME>" packages for all data
> NAMEs).

Yeah I think it’s OK.  We can always adjust it when a new release comes
out.

>> +       "Red Eclipse is an open-source arena shooter, created from the Cube2

s/open-source//

>> +      ;; License information available in detail at the following link:
>> +      ;; http://redeclipse.net/wiki/License
>> +      (license (list license:expat
>> +                     license:zlib
>> +                     license:cc-by-sa3.0
>> +                     license:cc-by3.0
>> +                     license:cc0)))))

Would be worth mentioning that it’s a combination of all these licenses,
IIUC.

Looks like we’re there modulo this and the minor indentation issue?

Would you like to apply it with these changes, Alex?

Thank you all!

Ludo’.

Re: [PATCH] gnu: Add Red Eclipse.

[Alex Kost]

Ludovic Courtès (2016-04-27 15:14 +0300) wrote:

>>> +       "Red Eclipse is an open-source arena shooter, created from the Cube2
>
> s/open-source//

Oops, I didn't notice this, thanks!

>>> +      ;; License information available in detail at the following link:
>>> +      ;; http://redeclipse.net/wiki/License
>>> +      (license (list license:expat
>>> +                     license:zlib
>>> +                     license:cc-by-sa3.0
>>> +                     license:cc-by3.0
>>> +                     license:cc0)))))
>
> Would be worth mentioning that it’s a combination of all these licenses,
> IIUC.
>
> Looks like we’re there modulo this and the minor indentation issue?
>
> Would you like to apply it with these changes, Alex?

Adjusted and applied.  Thanks again, Kei!

I forgot to mention that if a build phase succeeds, it should return #t
(although anything but #f also works), so I added #t to the ends of
the phases.

-- 
Alex

Re: [PATCH] gnu: Add Red Eclipse.

[Andreas Enge]

On Tue, Apr 26, 2016 at 01:22:33PM +0300, Alex Kost wrote:
> > +      (name "redeclipse")
> I would name the package "red-eclipse", but it probably doesn't matter.

That would be in line with our package naming guidelines: replace everything
that is not [A-Za-z0-9] by a '-'. Do you think we could still rename the
package?

Andreas

Re: [PATCH] gnu: Add Red Eclipse.

[Kei Yamashita]

[-- Attachment #1.1: Type: text/plain, Size: 496 bytes --]

On Mon, 2 May 2016 12:38:37 +0200
Andreas Enge <andreas@enge.fr> wrote:

> On Tue, Apr 26, 2016 at 01:22:33PM +0300, Alex Kost wrote:
> > > +      (name "redeclipse")  
> > I would name the package "red-eclipse", but it probably doesn't
> > matter.  
> 
> That would be in line with our package naming guidelines: replace
> everything that is not [A-Za-z0-9] by a '-'. Do you think we could
> still rename the package?
> 
> Andreas
> 

Here's a patch if anyone wants to apply it.

[-- Attachment #1.2: 0001-gnu-Rename-redeclipse-package-to-match-naming-specif.patch --]
[-- Type: application/octet-stream, Size: 929 bytes --]

From 1a78f4bb97d2697a3e202a21c3d222b30c136ac4 Mon Sep 17 00:00:00 2001
From: Kei Yamashita <kei@openmailbox.org>
Date: Tue, 3 May 2016 12:04:38 -0400
Subject: [PATCH] gnu: Rename redeclipse package to match naming specification.

* gnu/packages/games.scm (redeclipse): Rename to...
(red-eclipse): ...this.
---
 gnu/packages/games.scm | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/gnu/packages/games.scm b/gnu/packages/games.scm
index 34998ce..52a7f9b 100644
--- a/gnu/packages/games.scm
+++ b/gnu/packages/games.scm
@@ -2133,7 +2133,7 @@ http://lavachat.symlynx.com/unix/")
            ("weapons"     "1ghn6nfcnd5lyl8dnj22csldvf9hrb32wjzpab4sjjz3iyv0zmr3")
            ("wicked"      "0q9badvg6ix5rhl05s83kw2v6a49jpnbkqk4ls89qahaddfagi8g"))))
     (package
-      (name "redeclipse")
+      (name "red-eclipse")
       (version "1.5.3")
       (source (origin
                 (method url-fetch)
-- 
2.7.4


[-- Attachment #2: OpenPGP digital signature --]
[-- Type: application/pgp-signature, Size: 473 bytes --]

Re: [PATCH] gnu: Add Red Eclipse.

[Andreas Enge]

On Tue, May 03, 2016 at 12:10:22PM -0400, Kei Yamashita wrote:
> Here's a patch if anyone wants to apply it.

Thanks a lot, I just pushed.

Andreas

Re: [PATCH] gnu: Add Red Eclipse.

[Alex Kost]

> From 1a78f4bb97d2697a3e202a21c3d222b30c136ac4 Mon Sep 17 00:00:00 2001
> From: Kei Yamashita <kei@openmailbox.org>
> Date: Tue, 3 May 2016 12:04:38 -0400
> Subject: [PATCH] gnu: Rename redeclipse package to match naming specification.
>
> * gnu/packages/games.scm (redeclipse): Rename to...
> (red-eclipse): ...this.
> ---
>  gnu/packages/games.scm | 2 +-
>  1 file changed, 1 insertion(+), 1 deletion(-)
>
> diff --git a/gnu/packages/games.scm b/gnu/packages/games.scm
> index 34998ce..52a7f9b 100644
> --- a/gnu/packages/games.scm
> +++ b/gnu/packages/games.scm
> @@ -2133,7 +2133,7 @@ http://lavachat.symlynx.com/unix/")
>             ("weapons"     "1ghn6nfcnd5lyl8dnj22csldvf9hrb32wjzpab4sjjz3iyv0zmr3")
>             ("wicked"      "0q9badvg6ix5rhl05s83kw2v6a49jpnbkqk4ls89qahaddfagi8g"))))
>      (package
> -      (name "redeclipse")
> +      (name "red-eclipse")
>        (version "1.5.3")
>        (source (origin
>                  (method url-fetch)

Only the package name is renamed here.  I think it would be more
consistent to rename the variable as well.

-- 
Alex

Re: [PATCH] gnu: Add Red Eclipse.

[Alex Kost]

Andreas Enge (2016-05-02 13:38 +0300) wrote:

> On Tue, Apr 26, 2016 at 01:22:33PM +0300, Alex Kost wrote:
>> > +      (name "redeclipse")
>> I would name the package "red-eclipse", but it probably doesn't matter.
>
> That would be in line with our package naming guidelines: replace everything
> that is not [A-Za-z0-9] by a '-'. Do you think we could still rename the
> package?

Probably; you are the master of guidelines, so I trust your judge :-)
OTOH we also have such packages as 'accountsservice', 'recordmydesktop',
'randomjungle', 'rubberband' and others.  Should they also be renamed to
'accounts-service', 'record-my-desktop', 'random-jungle', 'rubber-band',
etc.?

-- 
Alex

Re: [PATCH] gnu: Add Red Eclipse.

[Andreas Enge]

On Tue, May 03, 2016 at 10:08:52PM +0300, Alex Kost wrote:
> Only the package name is renamed here.  I think it would be more
> consistent to rename the variable as well.

My apologies, indeed. I will push an additional patch.

On Tue, May 03, 2016 at 10:09:40PM +0300, Alex Kost wrote:
> Probably; you are the master of guidelines, so I trust your judge :-)
> OTOH we also have such packages as 'accountsservice', 'recordmydesktop',
> 'randomjungle', 'rubberband' and others.  Should they also be renamed to
> 'accounts-service', 'record-my-desktop', 'random-jungle', 'rubber-band',

It depends; I just noticed for red-eclipse since you brought up the question.
Now I just checked accountsservice:
              (uri (string-append "https://www.freedesktop.org/software/"
                                  name "/" name "-" version ".tar.xz"))
    (description
     "The AccountService project provides a set of D-Bus interfaces for querying
It looks as if this should remain accountservice, since there is no space
in the project name.
The same holds for recordmydesktop.

For randomjungle, the tarball does not contain a space, the description does;
then it is up to us to make a decision on what the project name is. The
tarball name is always fine.
The same holds for rubber band.

It might also be more awkward to modify names of packages that are already
there for some time.

Andreas

Re: [PATCH] gnu: Add Red Eclipse.

[Albin]

Den 2016-05-03 kl. 21:09, skrev Alex Kost:
> Andreas Enge (2016-05-02 13:38 +0300) wrote:
> 
>> On Tue, Apr 26, 2016 at 01:22:33PM +0300, Alex Kost wrote:
>>>> +      (name "redeclipse")
>>> I would name the package "red-eclipse", but it probably doesn't matter.
>>
>> That would be in line with our package naming guidelines: replace everything
>> that is not [A-Za-z0-9] by a '-'. Do you think we could still rename the
>> package?
> 
> Probably; you are the master of guidelines, so I trust your judge :-)
> OTOH we also have such packages as 'accountsservice', 'recordmydesktop',
> 'randomjungle', 'rubberband' and others.  Should they also be renamed to
> 'accounts-service', 'record-my-desktop', 'random-jungle', 'rubber-band',
> etc.?
> 

I just installed 'red-eclipse' from a git checkout and then the link to
the binary was named 'redeclipse_linux' and not 'red-eclipse' as I had
expected.

Albin

Re: [PATCH] gnu: Add Red Eclipse.

[Andreas Enge]

On Tue, May 03, 2016 at 09:24:46PM +0200, Albin wrote:
> I just installed 'red-eclipse' from a git checkout and then the link to
> the binary was named 'redeclipse_linux' and not 'red-eclipse' as I had
> expected.

Well, this happens; we usually do not modify binary names from upstream.
For instance, the libreoffice binary is called "soffice" (I wonder who
still remembers why, a question of age and nationality, probably...).

Andreas

Re: [PATCH] gnu: Add Red Eclipse.

[Alex Kost]

Albin (2016-05-03 22:24 +0300) wrote:

> Den 2016-05-03 kl. 21:09, skrev Alex Kost:
>> Andreas Enge (2016-05-02 13:38 +0300) wrote:
>> 
>>> On Tue, Apr 26, 2016 at 01:22:33PM +0300, Alex Kost wrote:
>>>>> +      (name "redeclipse")
>>>> I would name the package "red-eclipse", but it probably doesn't matter.
>>>
>>> That would be in line with our package naming guidelines: replace everything
>>> that is not [A-Za-z0-9] by a '-'. Do you think we could still rename the
>>> package?
>> 
>> Probably; you are the master of guidelines, so I trust your judge :-)
>> OTOH we also have such packages as 'accountsservice', 'recordmydesktop',
>> 'randomjungle', 'rubberband' and others.  Should they also be renamed to
>> 'accounts-service', 'record-my-desktop', 'random-jungle', 'rubber-band',
>> etc.?
>> 
>
> I just installed 'red-eclipse' from a git checkout and then the link to
> the binary was named 'redeclipse_linux' and not 'red-eclipse' as I had
> expected.

First time I tried it, I expected just "redeclipse", but the upstream
doesn't provide this name for some reason, and as Andreas pointed we
don't modify the upstream choice without a good reason (although I think
it would be good to make a symlink here).  For example, we don't have
"cc" binary, or you can't do "loadkeys colemak" because we don't make
"colemak" link (the upstream calls this layout "en-latin9").

-- 
Alex

Re: [PATCH] gnu: Add Red Eclipse.

[Alex Kost]

Andreas Enge (2016-05-03 22:23 +0300) wrote:

> On Tue, May 03, 2016 at 10:08:52PM +0300, Alex Kost wrote:
>> Only the package name is renamed here.  I think it would be more
>> consistent to rename the variable as well.
>
> My apologies, indeed. I will push an additional patch.

I see, thanks!

> On Tue, May 03, 2016 at 10:09:40PM +0300, Alex Kost wrote:
>> Probably; you are the master of guidelines, so I trust your judge :-)
>> OTOH we also have such packages as 'accountsservice', 'recordmydesktop',
>> 'randomjungle', 'rubberband' and others.  Should they also be renamed to
>> 'accounts-service', 'record-my-desktop', 'random-jungle', 'rubber-band',
>
> It depends; I just noticed for red-eclipse since you brought up the question.
> Now I just checked accountsservice:
>               (uri (string-append "https://www.freedesktop.org/software/"
>                                   name "/" name "-" version ".tar.xz"))
>     (description
>      "The AccountService project provides a set of D-Bus interfaces for querying
> It looks as if this should remain accountservice, since there is no space
> in the project name.
> The same holds for recordmydesktop.

OK, got it.

> For randomjungle, the tarball does not contain a space, the description does;
> then it is up to us to make a decision on what the project name is. The
> tarball name is always fine.
> The same holds for rubber band.
>
> It might also be more awkward to modify names of packages that are already
> there for some time.

I agree, thanks for clarifying.

-- 
Alex