[bug#44457] [PATCH]: gnu: Add hunspell-dict-it-it.

[bug#44457] [PATCH]: gnu: Add hunspell-dict-it-it.

[paul]

[-- Attachment #1: Type: text/plain, Size: 588 bytes --]

Dear Guixers,

as discussed here [0] and [1], I'm sending a patch to add a new 
hunspell.scm file to store hunspell dictionaries and an Italian 
dictionary. I tried to make my implementation reusable by other 
languages by defining a function that produces dictionary packages.

If there is consensus I can move other hunspell dictionaries to the new 
file and/or convert them to use the new function.

Thank you for your review.

Cheers,

Giacomo


[0]: https://issues.guix.gnu.org/42474

[1]: https://lists.nongnu.org/archive/html/guix-devel/2020-11/msg00000.html


[-- Attachment #2: 0001-gnu-Add-hunspell-dict-it-it.patch --]
[-- Type: text/x-patch, Size: 4623 bytes --]

From e5db7d7e9c66fa105966fe88d18a40d8075b9f61 Mon Sep 17 00:00:00 2001
From: Giacomo Leidi <goodoldpaul@autistici.org>
Date: Thu, 5 Nov 2020 02:04:20 +0100
Subject: [PATCH] gnu: Add hunspell-dict-it-it.

* gnu/packages/hunspell.scm: New file;
(hunspell-dictionary): New variable;
(hunspell-dict-it-it): New variable.
* gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
---
 gnu/local.mk              |  1 +
 gnu/packages/hunspell.scm | 81 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)
 create mode 100644 gnu/packages/hunspell.scm

diff --git a/gnu/local.mk b/gnu/local.mk
index 2a994bd3b9..510687e714 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -273,6 +273,7 @@ GNU_SYSTEM_MODULES =				\
   %D%/packages/heads.scm			\
   %D%/packages/hexedit.scm			\
   %D%/packages/hugs.scm				\
+  %D%/packages/hunspell.scm				\
   %D%/packages/hurd.scm				\
   %D%/packages/hyperledger.scm			\
   %D%/packages/i2p.scm				\
diff --git a/gnu/packages/hunspell.scm b/gnu/packages/hunspell.scm
new file mode 100644
index 0000000000..1340ecee7b
--- /dev/null
+++ b/gnu/packages/hunspell.scm
@@ -0,0 +1,81 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2020 Giacomo Leidi <goodoldpaul@autistici.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu packages hunspell)
+  #:use-module (guix build-system gnu)
+  #:use-module (guix download)
+  #:use-module (guix git-download)
+  #:use-module ((guix licenses) #:prefix license:)
+  #:use-module (guix packages)
+  #:use-module (ice-9 match)
+  #:use-module (gnu packages libreoffice))
+
+(define* (hunspell-dictionary dict-name full-name #:key home-page license)
+  (package
+    (name (string-append
+           "hunspell-dict-"
+           ;; Downcase and replace underscore in package names
+           ;; to follow Guix naming conventions.
+           (string-map (match-lambda
+                         (#\_ #\-)
+                         (chr chr))
+                       (string-downcase dict-name))))
+    (version (package-version libreoffice))
+    (source
+     (origin
+       (method git-fetch)
+       (uri (git-reference
+             (url (string-append "https://anongit.freedesktop.org/git/"
+                                 "libreoffice/dictionaries.git/"))
+             (commit
+              (string-append "libreoffice-" version))))
+       (file-name (git-file-name "libreoffice-dictionaries" version))
+       (sha256
+        (base32 "0vvxnjpm1322ahf9q8bqs1yhkn7krglw8c6yazcf7a3jljykd9k9"))))
+    (build-system gnu-build-system)
+    (arguments
+     `(#:phases
+       (modify-phases %standard-phases
+         (delete 'configure)
+         (delete 'build)
+         (replace 'install              ;no install target
+           (lambda* (#:key outputs #:allow-other-keys)
+             (let* ((out (assoc-ref outputs "out"))
+                    (hunspell (string-append out "/share/hunspell/"))
+                    (myspell (string-append out "/share/myspell")))
+               (for-each
+                (lambda (ext)
+                  (install-file (string-append ,dict-name "/" ,dict-name ext)
+                                hunspell))
+                '(".aff" ".dic"))
+               (symlink hunspell myspell)
+               #t))))
+       #:tests? #f))                    ; no tests
+    (synopsis
+     (string-append "Hunspell dictionary for " full-name " (" dict-name ")"))
+    (description "This package provides a dictionary for the Hunspell
+spell-checking library.")
+    (license license)
+    (home-page home-page)))
+
+(define-public hunspell-dict-it-it
+  (let ((home-page "https://libreitalia.org/")
+        (license license:gpl3))
+    (hunspell-dictionary "it_IT" "Italian"
+                         #:home-page home-page
+                         #:license license)))
-- 
2.29.1

[bug#44457] [PATCH]: gnu: Add hunspell-dict-it-it.

[Jonathan Brielmaier]

> Subject: [PATCH] gnu: Add hunspell-dict-it-it.

In theory you could it split into two commits: one for the
hunspell-dictionary function and the other for the italian dict. But I
think it's okay so.

> +    (build-system gnu-build-system)
> +    (arguments

Maybe it would be an idea to (build-system trivial-build-system) instead?

> +(define-public hunspell-dict-it-it

If there is only one language version like with Italian, I think it
would be nicer to have it name `hunspell-dict-it`. But I guess it makes
the code a bit more complicated.

> +  (let ((home-page "https://libreitalia.org/")
> +        (license license:gpl3))
> +    (hunspell-dictionary "it_IT" "Italian"
> +                         #:home-page home-page
> +                         #:license license)))

For me the let feels a bit useless...

hunspell-dict-it-it builds and installs fine. It works in LibreOffice
just fine!

~Jonathan

[bug#44457] [PATCH]: gnu: Add hunspell-dict-it-it.

[paul]

[-- Attachment #1: Type: text/plain, Size: 481 bytes --]

Hi Jonathan,

I'm attaching an updated patch.

I changed the build system to trivial and removed the useless let (I 
must admit I forgot it there). About the variable naming, technically 
there is also it_CH: the Italian spoke in a region of Switzerland. In 
the Libreoffice repository there's still no dedicated dictionary but it 
could be uploaded in the future, so I'd keep the variable naming. What 
do you think?

Thank you for your review,

Cheers

Giacomo


[-- Attachment #2: 0001-gnu-Add-hunspell-dict-it-it.patch --]
[-- Type: text/x-patch, Size: 4678 bytes --]

From 17a476dd234fa4a128eb90ccc8ac9a565045bfa1 Mon Sep 17 00:00:00 2001
From: Giacomo Leidi <goodoldpaul@autistici.org>
Date: Thu, 5 Nov 2020 02:04:20 +0100
Subject: [PATCH] gnu: Add hunspell-dict-it-it.

* gnu/packages/hunspell.scm: New file;
(hunspell-dictionary): New variable;
(hunspell-dict-it-it): New variable.
* gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
---
 gnu/local.mk              |  1 +
 gnu/packages/hunspell.scm | 80 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)
 create mode 100644 gnu/packages/hunspell.scm

diff --git a/gnu/local.mk b/gnu/local.mk
index 2a994bd3b9..510687e714 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -273,6 +273,7 @@ GNU_SYSTEM_MODULES =				\
   %D%/packages/heads.scm			\
   %D%/packages/hexedit.scm			\
   %D%/packages/hugs.scm				\
+  %D%/packages/hunspell.scm				\
   %D%/packages/hurd.scm				\
   %D%/packages/hyperledger.scm			\
   %D%/packages/i2p.scm				\
diff --git a/gnu/packages/hunspell.scm b/gnu/packages/hunspell.scm
new file mode 100644
index 0000000000..ac46dd2104
--- /dev/null
+++ b/gnu/packages/hunspell.scm
@@ -0,0 +1,80 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2020 Giacomo Leidi <goodoldpaul@autistici.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu packages hunspell)
+  #:use-module (guix build-system trivial)
+  #:use-module (guix download)
+  #:use-module (guix git-download)
+  #:use-module ((guix licenses) #:prefix license:)
+  #:use-module (guix packages)
+  #:use-module (ice-9 match)
+  #:use-module (gnu packages libreoffice))
+
+(define* (hunspell-dictionary dict-name full-name #:key home-page license)
+  (package
+    (name (string-append
+           "hunspell-dict-"
+           ;; Downcase and replace underscore in package names
+           ;; to follow Guix naming conventions.
+           (string-map (match-lambda
+                         (#\_ #\-)
+                         (chr chr))
+                       (string-downcase dict-name))))
+    (version (package-version libreoffice))
+    (source
+     (origin
+       (method git-fetch)
+       (uri (git-reference
+             (url (string-append "https://anongit.freedesktop.org/git/"
+                                 "libreoffice/dictionaries.git/"))
+             (commit
+              (string-append "libreoffice-" version))))
+       (file-name (git-file-name "libreoffice-dictionaries" version))
+       (sha256
+        (base32 "0vvxnjpm1322ahf9q8bqs1yhkn7krglw8c6yazcf7a3jljykd9k9"))))
+    (build-system trivial-build-system)
+    (native-inputs
+     `(("source" ,source)))
+    (arguments
+     `(#:modules ((guix build utils))
+       #:builder (begin
+                   (use-modules (guix build utils))
+                   (let* ((dictionary
+                           (string-append (assoc-ref %build-inputs "source")
+                                          "/" ,dict-name
+                                          "/" ,dict-name))
+                          (hunspell (string-append %output "/share/hunspell/"))
+                          (myspell (string-append %output "/share/myspell")))
+                     (for-each
+                      (lambda (ext)
+                        (install-file (string-append dictionary ext)
+                                      hunspell))
+                      '(".aff" ".dic"))
+                     (symlink hunspell myspell)
+                     #t))))
+    (synopsis
+     (string-append "Hunspell dictionary for " full-name " (" dict-name ")"))
+    (description "This package provides a dictionary for the Hunspell
+spell-checking library.")
+    (license license)
+    (home-page home-page)))
+
+(define-public hunspell-dict-it-it
+  (hunspell-dictionary "it_IT" "Italian"
+                       #:home-page "https://libreitalia.org/"
+                       #:license license:gpl3))
-- 
2.29.1

[bug#44457] [PATCH] gnu: Add hunspell-dict-it-it.

[paul]

Hi,

I'm leaving here a friendly ping :). Thank you for your time.

Cheers,

Giacomo

[bug#44457] [PATCH]: gnu: Add hunspell-dict-it-it.

[Ludovic Courtès]

Hi!

paul <goodoldpaul@autistici.org> skribis:

> From 17a476dd234fa4a128eb90ccc8ac9a565045bfa1 Mon Sep 17 00:00:00 2001
> From: Giacomo Leidi <goodoldpaul@autistici.org>
> Date: Thu, 5 Nov 2020 02:04:20 +0100
> Subject: [PATCH] gnu: Add hunspell-dict-it-it.
>
> * gnu/packages/hunspell.scm: New file;
> (hunspell-dictionary): New variable;
> (hunspell-dict-it-it): New variable.
> * gnu/local.mk (GNU_SYSTEM_MODULES): Add it.

I’m picking up this patch as it seems to have fallen through the
cracks.  :-)

Overall it LGTM; a couple of comments below.

Apparently this is different from the Hunspell dictionaries made from
Aspell word lists that appear in (gnu packages aspell), right?

Should we name the packages differently to avoid collisions with the
existing ‘hunspell-dict-*’ packages?

[...]

> +    (synopsis
> +     (string-append "Hunspell dictionary for " full-name " (" dict-name ")"))

This is recommended against as this prevents i18n:

  https://guix.gnu.org/manual/en/html_node/Synopses-and-Descriptions.html

You can work around it by writing the string in full, as in:

  (define-public hunspell-dict-it-it
    (let ((synopsis identity))
      (hunspell-dictionary "it_IT" "Italian"
                           #:synopsis (synopsis "Hunspell dictionary for Italian")
                           #:home-page "https://libreitalia.org/"
                           #:license license:gpl3)))


> +                       #:license license:gpl3))

It wondered whether this might be ‘gpl3+’, but
<https://cgit.freedesktop.org/libreoffice/dictionaries/tree/it_IT/README_it_IT.txt>
confirms that this is “version 3 only”; all good!  :-)

Could you send an updated patch?

Thanks,
Ludo’.

[bug#44457] [PATCH]: gnu: Add hunspell-dict-it-it.

[paul]

[-- Attachment #1: Type: text/plain, Size: 2178 bytes --]

Hi Ludo’ !

On 12/23/20 5:29 PM, Ludovic Courtès wrote:
> Hi!
>
> paul <goodoldpaul@autistici.org> skribis:
>
>>  From 17a476dd234fa4a128eb90ccc8ac9a565045bfa1 Mon Sep 17 00:00:00 2001
>> From: Giacomo Leidi <goodoldpaul@autistici.org>
>> Date: Thu, 5 Nov 2020 02:04:20 +0100
>> Subject: [PATCH] gnu: Add hunspell-dict-it-it.
>>
>> * gnu/packages/hunspell.scm: New file;
>> (hunspell-dictionary): New variable;
>> (hunspell-dict-it-it): New variable.
>> * gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
> I’m picking up this patch as it seems to have fallen through the
> cracks.  :-)
Definitely not a problem but still thanks a lot :)
>
> Overall it LGTM; a couple of comments below.
>
> Apparently this is different from the Hunspell dictionaries made from
> Aspell word lists that appear in (gnu packages aspell), right?
>
> Should we name the packages differently to avoid collisions with the
> existing ‘hunspell-dict-*’ packages?

We definitely can but if I understood correctly they are generated from 
STOW wordlists [0] which seems to contain only variants of the English 
language.

Since also the Libreoffice repository contains some of those variants, I 
was wondering, to achieve better consistency with future dictionaries, 
if it's worth either

- to migrate the duplicates to use (hunspell-dictionary) from (gnu 
packages hunspell)

- or just to use STOW for the English language and its variants and 
Libreoffice dictionaries for all the supported languages

I believe either way we should be able to avoid collisions, but maybe I 
should just rename this one dictionary and, after we reach consensus, we 
can always decide to change it back. What do you think?

Should I move this discussion to guix-devel?

>> +    (synopsis
>> +     (string-append "Hunspell dictionary for " full-name " (" dict-name ")"))
> This is recommended against as this prevents i18n:
>
>    https://guix.gnu.org/manual/en/html_node/Synopses-and-Descriptions.html

I apologize about this, I attached an updated patch.


Thank you for your time,

Cheers


Giacomo


[0]: http://wordlist.aspell.net/scowl-readme/


[-- Attachment #2: 0001-gnu-Add-hunspell-dict-it-it.patch --]
[-- Type: text/x-patch, Size: 4738 bytes --]

From be2124a82d8c2902a2031e4c6d89100b9fa42168 Mon Sep 17 00:00:00 2001
From: Giacomo Leidi <goodoldpaul@autistici.org>
Date: Thu, 5 Nov 2020 02:04:20 +0100
Subject: [PATCH] gnu: Add hunspell-dict-it-it.

* gnu/packages/hunspell.scm: New file;
(hunspell-dictionary): New variable;
(hunspell-dict-it-it): New variable.
* gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
---
 gnu/local.mk              |  1 +
 gnu/packages/hunspell.scm | 81 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)
 create mode 100644 gnu/packages/hunspell.scm

diff --git a/gnu/local.mk b/gnu/local.mk
index 2f267e8aee..025fe88f36 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -277,6 +277,7 @@ GNU_SYSTEM_MODULES =				\
   %D%/packages/heads.scm			\
   %D%/packages/hexedit.scm			\
   %D%/packages/hugs.scm				\
+  %D%/packages/hunspell.scm				\
   %D%/packages/hurd.scm				\
   %D%/packages/hyperledger.scm			\
   %D%/packages/i2p.scm				\
diff --git a/gnu/packages/hunspell.scm b/gnu/packages/hunspell.scm
new file mode 100644
index 0000000000..e36c1b6cc9
--- /dev/null
+++ b/gnu/packages/hunspell.scm
@@ -0,0 +1,81 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2020 Giacomo Leidi <goodoldpaul@autistici.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu packages hunspell)
+  #:use-module (guix build-system trivial)
+  #:use-module (guix download)
+  #:use-module (guix git-download)
+  #:use-module ((guix licenses) #:prefix license:)
+  #:use-module (guix packages)
+  #:use-module (ice-9 match)
+  #:use-module (gnu packages libreoffice))
+
+(define* (hunspell-dictionary dict-name full-name #:key synopsis home-page license)
+  (package
+    (name (string-append
+           "hunspell-dict-"
+           ;; Downcase and replace underscore in package names
+           ;; to follow Guix naming conventions.
+           (string-map (match-lambda
+                         (#\_ #\-)
+                         (chr chr))
+                       (string-downcase dict-name))))
+    (version (package-version libreoffice))
+    (source
+     (origin
+       (method git-fetch)
+       (uri (git-reference
+             (url (string-append "https://anongit.freedesktop.org/git/"
+                                 "libreoffice/dictionaries.git/"))
+             (commit
+              (string-append "libreoffice-" version))))
+       (file-name (git-file-name "libreoffice-dictionaries" version))
+       (sha256
+        (base32 "0vvxnjpm1322ahf9q8bqs1yhkn7krglw8c6yazcf7a3jljykd9k9"))))
+    (build-system trivial-build-system)
+    (native-inputs
+     `(("source" ,source)))
+    (arguments
+     `(#:modules ((guix build utils))
+       #:builder (begin
+                   (use-modules (guix build utils))
+                   (let* ((dictionary
+                           (string-append (assoc-ref %build-inputs "source")
+                                          "/" ,dict-name
+                                          "/" ,dict-name))
+                          (hunspell (string-append %output "/share/hunspell/"))
+                          (myspell (string-append %output "/share/myspell")))
+                     (for-each
+                      (lambda (ext)
+                        (install-file (string-append dictionary ext)
+                                      hunspell))
+                      '(".aff" ".dic"))
+                     (symlink hunspell myspell)
+                     #t))))
+    (synopsis synopsis)
+    (description "This package provides a dictionary for the Hunspell
+spell-checking library.")
+    (license license)
+    (home-page home-page)))
+
+(define-public hunspell-dict-it-it
+  (let ((synopsis identity))
+    (hunspell-dictionary "it_IT" "Italian"
+                         #:synopsis (synopsis "Hunspell dictionary for Italian")
+                         #:home-page "https://libreitalia.org/"
+                         #:license license:gpl3)))
-- 
2.29.2

bug#44457: [PATCH]: gnu: Add hunspell-dict-it-it.

[Ludovic Courtès]

Hi,

paul <goodoldpaul@autistici.org> skribis:

> We definitely can but if I understood correctly they are generated
> from STOW wordlists [0] which seems to contain only variants of the
> English language.

Oh right.

> Since also the Libreoffice repository contains some of those variants,
> I was wondering, to achieve better consistency with future
> dictionaries, if it's worth either
>
> - to migrate the duplicates to use (hunspell-dictionary) from (gnu
>   packages hunspell)
>
> - or just to use STOW for the English language and its variants and
>   Libreoffice dictionaries for all the supported languages
>
> I believe either way we should be able to avoid collisions, but maybe
> I should just rename this one dictionary and, after we reach
> consensus, we can always decide to change it back. What do you think?

I think it’s fine this way, I hadn’t realized that the hunspell-dict-*
from aspell.scm were English only.

Now, I just noticed that libreoffice.scm also :-) comes with
huspell-dict-* packages, which are built from yet other sources (primary
sources it seems, rather than LibreOffice).

I’ve applied this patch, but perhaps we should now move those
dictionaries from libreoffice.scm to hunspell.scm?

Thanks!

Ludo’.