Re: Name of buffers created by project-shell

[Dmitry Gutov <dgutov@yandex.ru>]

[-- Attachment #1: Type: text/plain, Size: 1377 bytes --]

On 15.03.2021 02:41, Dmitry Gutov wrote:
>> I think there's a problem even without using C-u:
>>
>> `project-shell' from a buffer whose associated project root path is
>> /src/project1 creates a buffer named *shell*.
>>
>> Then `project-shell' from a buffer whose associated project root path is
>> /src/project2 creates a buffer named *shell*<project2> (I am using the
>> default `post-forward-angle-brackets' for `uniquify-buffer-name-style').
>>
>> But the uniquify rationalize mecanism doesn't rename the first buffer to
>> *shell*<project1> which happens to be the case for buffers visiting
>> files...
> 
> Yup, that's another bug. It should also how up for vc-dir buffers too.

Actually, it didn't occur for vc-dir buffers. So it's arguably a bug in 
my code.

Attaching the updated patch which fixes that particular problem, though 
I'm a little more suspicious of some of uniquify's choices now.

In particular, this code depends on list-buffers-directory being set to 
a value in particular format which is very non-obvious from this 
variable's docstring.

And to have uniquify work similarly with buffers created by M-x shell 
and M-x eshell as well, these commands need similar changes (we can't 
really depend on them in project.el because it's an ELPA Core package), 
as well as shell-mode and eshell-mode being listed in 
uniquify-list-buffers-directory-modes.

[-- Attachment #2: uniquify-project-shell.diff --]
[-- Type: text/x-patch, Size: 3579 bytes --]

diff --git a/lisp/progmodes/project.el b/lisp/progmodes/project.el
index b6a886f731..5b1c92ec9d 100644
--- a/lisp/progmodes/project.el
+++ b/lisp/progmodes/project.el
@@ -895,6 +895,22 @@ project-vc-dir
   (interactive)
   (vc-dir (project-root (project-current t))))
 
+(defvar-local project--origin-project-root nil)
+
+(defun project--find-existing-buffer (mode root)
+  (seq-find
+   (lambda (buf)
+     (and
+      (buffer-live-p buf)
+      (provided-mode-derived-p
+       (buffer-local-value 'major-mode buf)
+       mode)
+      (equal (buffer-local-value
+              'project--origin-project-root
+              buf)
+             root)))
+   (buffer-list)))
+
 ;;;###autoload
 (defun project-shell ()
   "Start an inferior shell in the current project's root directory.
@@ -904,15 +920,16 @@ project-shell
 if one already exists."
   (interactive)
   (let* ((default-directory (project-root (project-current t)))
-         (default-project-shell-name
-           (concat "*" (file-name-nondirectory
-                        (directory-file-name
-                         (file-name-directory default-directory)))
-                   "-shell*"))
-         (shell-buffer (get-buffer default-project-shell-name)))
-    (if (and shell-buffer (not current-prefix-arg))
-        (pop-to-buffer-same-window shell-buffer)
-      (shell (generate-new-buffer-name default-project-shell-name)))))
+         (existing-buffer (unless current-prefix-arg
+                            (project--find-existing-buffer 'shell-mode
+                                                           default-directory))))
+    (if existing-buffer
+        (pop-to-buffer-same-window existing-buffer)
+      (let* ((uniquify-list-buffers-directory-modes
+              (cons 'shell-mode uniquify-list-buffers-directory-modes)))
+        (shell (create-file-buffer (expand-file-name "*shell*")))
+        (setq list-buffers-directory (expand-file-name "*shell*" default-directory))
+        (setq project--origin-project-root default-directory)))))
 
 ;;;###autoload
 (defun project-eshell ()
@@ -922,17 +939,22 @@ project-eshell
 With \\[universal-argument] prefix arg, create a new Eshell buffer even
 if one already exists."
   (interactive)
+  (require 'eshell)
   (defvar eshell-buffer-name)
   (let* ((default-directory (project-root (project-current t)))
-         (eshell-buffer-name
-          (concat "*" (file-name-nondirectory
-                       (directory-file-name
-                        (file-name-directory default-directory)))
-                  "-eshell*"))
-         (eshell-buffer (get-buffer eshell-buffer-name)))
-    (if (and eshell-buffer (not current-prefix-arg))
-        (pop-to-buffer-same-window eshell-buffer)
-      (eshell t))))
+         (existing-buffer (unless current-prefix-arg
+                            (project--find-existing-buffer 'eshell-mode
+                                                           default-directory))))
+    (if existing-buffer
+        (pop-to-buffer-same-window existing-buffer)
+      (let* ((uniquify-list-buffers-directory-modes
+              (cons 'eshell-mode uniquify-list-buffers-directory-modes))
+             (buf (create-file-buffer (expand-file-name eshell-buffer-name))))
+        (pop-to-buffer-same-window buf)
+        (unless (derived-mode-p 'eshell-mode)
+          (eshell-mode))
+        (setq list-buffers-directory (expand-file-name eshell-buffer-name default-directory))
+        (setq project--origin-project-root default-directory)))))
 
 ;;;###autoload
 (defun project-async-shell-command ()