Re: reverting CJK input methods

[Kenichi Handa <handa@m17n.org>]

In article <20040429.150303.42778779.wl@gnu.org>, Werner LEMBERG <wl@gnu.org> writes:

> Computers are much faster today, with much more memory.  Ken'ichi-san,
> what do you think about activating the decode maps for all CJK quail
> input methods, and adding a function like `show-input-method-input'
> which yields the current input method's input string for the current
> character.

It's a good idea.  But, as computers are much faster, I
think we can find a key for a specific character by looking
up the quail map.  Please evaluate the attached code,
activate some input method, input some character, go to that
character, and do M-x quail-find-key RET.

If that is too slow, another way is to generate the decode
map on demand.

---
Ken'ichi HANDA
handa@m17n.org

(defun quail-find-key (char map key)
  (when (consp map)
    (let ((translation (car map)))
      (cond ((integerp translation)
	     (if (= translation char)
		 (throw 'tag key)))
	    ((stringp translation)
	     (if (string-match (string char) translation)
		 (throw 'tag key)))
	    ((vectorp translation)
	     (dotimes (i (length translation))
	       (let ((target (aref translation i)))
		 (if (integerp target)
		     (if (= target char)
			 (throw 'tag key))
		   (if (and (= (length target) 1)
			    (= (aref target 0) char))
		       (throw 'tag key))))))
	    ((consp translation)
	     (setq translation (cdr translation))
	     (dotimes (i (length translation))
	       (let ((target (aref translation i)))
		 (if (integerp target)
		     (if (= target char)
			 (throw 'tag key))
		   (if (and (= (length target) 1)
			    (= (aref target 0) char))
		       (throw 'tag key)))))))))
  (dolist (elt (cdr map))
    (quail-find-key char (cdr elt) (cons (car elt) key))))

(defun quail-show-key ()
  (interactive)
  (let* ((char (following-char))
	 (key (catch 'tag
		(quail-find-key char (quail-map) nil))))
    (if key
	(message "%c can be input by typing \"%s\""
		 char (apply 'string (nreverse key)))
      (message "%c can't be input by the current input method" char))))