[PATCH 0/7] Port notmuch-show's x/X bindings to notmuch-tree

[PATCH 0/7] Port notmuch-show's x/X bindings to notmuch-tree

[William Casarin]

These patches bring notmuch-tree more in line with the user experience
of notmuch-show by adding the x/X bindings.

id:20191113225752.26502-1-jb55@jb55.com is also recommended, it adds a
bind for opening a thread in notmuch-tree mode.

William Casarin (7):
  emacs/tree: return true if a thread was found in next-thread
  emacs/tree: add notmuch-tree-goto-matching-message
  emacs/tree: add notmuch-tree-matching-message
  emacs/tree: add kill-both prefix argument to notmuch-tree-quit
  emacs/tree: add notmuch-tree-archive-message-than-next-or-exit
  emacs/tree: add notmuch-tree-archive-thread-then-exit
  emacs/tree: add x/X bindings

 emacs/notmuch-tree.el | 72 +++++++++++++++++++++++++++++++------------
 1 file changed, 52 insertions(+), 20 deletions(-)


base-commit: 7ad7cfbff232431377562271901ee00202bf0bd0
-- 
2.23.0

[PATCH 1/7] emacs/tree: return true if a thread was found in next-thread

[William Casarin]

This will allow us to pop back to parent buffers when there are no
more threads to jump to.

Signed-off-by: William Casarin <jb55@jb55.com>
---
 emacs/notmuch-tree.el | 8 ++++++--
 1 file changed, 6 insertions(+), 2 deletions(-)

diff --git a/emacs/notmuch-tree.el b/emacs/notmuch-tree.el
index c00315e8..4bc05160 100644
--- a/emacs/notmuch-tree.el
+++ b/emacs/notmuch-tree.el
@@ -620,10 +620,14 @@ message will be \"unarchived\", i.e. the tag changes in
   (notmuch-tree-thread-top))
 
 (defun notmuch-tree-next-thread ()
+  "Get the next thread in the current tree. Returns t if a thread was
+found or nil if not."
   (interactive)
   (forward-line 1)
-  (while (not (or (notmuch-tree-get-prop :first) (eobp)))
-    (forward-line 1)))
+  (let (end)
+    (while (not (or (notmuch-tree-get-prop :first) (setq end (eobp))))
+      (forward-line 1))
+    (not end)))
 
 (defun notmuch-tree-thread-mapcar (function)
   "Iterate through all messages in the current thread
-- 
2.23.0

[PATCH 2/7] emacs/tree: add notmuch-tree-goto-matching-message

[William Casarin]

This function captures some common logic when jumping to matching
messages in notmuch-tree mode.

We also add a new return value (t or nil), that indicates if there was
a next matching message in the thread to show.

Signed-off-by: William Casarin <jb55@jb55.com>
---
 emacs/notmuch-tree.el | 17 +++++++++++++----
 1 file changed, 13 insertions(+), 4 deletions(-)

diff --git a/emacs/notmuch-tree.el b/emacs/notmuch-tree.el
index 4bc05160..9f2d87b5 100644
--- a/emacs/notmuch-tree.el
+++ b/emacs/notmuch-tree.el
@@ -577,12 +577,22 @@ message will be \"unarchived\", i.e. the tag changes in
   (when (window-live-p notmuch-tree-message-window)
     (notmuch-tree-show-message-in)))
 
+(defun notmuch-tree-goto-matching-message (&optional prev)
+  "Move to the next or previous matching message.
+
+Returns t if there was a next matching message in the thread to show,
+nil otherwise."
+  (let (last)
+    (while (and (not (setq last (if prev (bobp) (eobp))))
+                (not (notmuch-tree-get-match)))
+      (forward-line (if prev -1 nil)))
+    (not last)))
+
 (defun notmuch-tree-prev-matching-message ()
   "Move to previous matching message."
   (interactive)
   (forward-line -1)
-  (while (and (not (bobp)) (not (notmuch-tree-get-match)))
-    (forward-line -1))
+  (notmuch-tree-goto-matching-message t)
   (when (window-live-p notmuch-tree-message-window)
     (notmuch-tree-show-message-in)))
 
@@ -590,8 +600,7 @@ message will be \"unarchived\", i.e. the tag changes in
   "Move to next matching message."
   (interactive)
   (forward-line)
-  (while (and (not (eobp)) (not (notmuch-tree-get-match)))
-    (forward-line))
+  (notmuch-tree-goto-matching-message)
   (when (window-live-p notmuch-tree-message-window)
     (notmuch-tree-show-message-in)))
 
-- 
2.23.0

[PATCH 3/7] emacs/tree: add notmuch-tree-matching-message

[William Casarin]

This functions removes some duplicate logic between
notmuch-tree-{next,prev}-matching-message

We do this because we will be adding some additional logic similar to
the notmuch-show-next-open-message function, and it will help if this
logic is all in one place.

Signed-off-by: William Casarin <jb55@jb55.com>
---
 emacs/notmuch-tree.el | 18 ++++++++++--------
 1 file changed, 10 insertions(+), 8 deletions(-)

diff --git a/emacs/notmuch-tree.el b/emacs/notmuch-tree.el
index 9f2d87b5..b9173790 100644
--- a/emacs/notmuch-tree.el
+++ b/emacs/notmuch-tree.el
@@ -588,21 +588,23 @@ nil otherwise."
       (forward-line (if prev -1 nil)))
     (not last)))
 
+(defun notmuch-tree-matching-message (&optional prev)
+  "Move to the next or previous matching message"
+  (interactive "P")
+  (forward-line (if prev -1 nil))
+  (notmuch-tree-goto-matching-message prev)
+  (when (window-live-p notmuch-tree-message-window)
+    (notmuch-tree-show-message-in)))
+
 (defun notmuch-tree-prev-matching-message ()
   "Move to previous matching message."
   (interactive)
-  (forward-line -1)
-  (notmuch-tree-goto-matching-message t)
-  (when (window-live-p notmuch-tree-message-window)
-    (notmuch-tree-show-message-in)))
+  (notmuch-tree-matching-message t))
 
 (defun notmuch-tree-next-matching-message ()
   "Move to next matching message."
   (interactive)
-  (forward-line)
-  (notmuch-tree-goto-matching-message)
-  (when (window-live-p notmuch-tree-message-window)
-    (notmuch-tree-show-message-in)))
+  (notmuch-tree-matching-message))
 
 (defun notmuch-tree-refresh-view ()
   "Refresh view."
-- 
2.23.0

[PATCH 4/7] emacs/tree: add kill-both prefix argument to notmuch-tree-quit

[William Casarin]

This allows us to close both windows at the same time.

Signed-off-by: William Casarin <jb55@jb55.com>
---
 emacs/notmuch-tree.el | 6 +++---
 1 file changed, 3 insertions(+), 3 deletions(-)

diff --git a/emacs/notmuch-tree.el b/emacs/notmuch-tree.el
index b9173790..367b10c4 100644
--- a/emacs/notmuch-tree.el
+++ b/emacs/notmuch-tree.el
@@ -530,10 +530,10 @@ Shows in split pane or whole window according to value of
   (when (notmuch-tree-scroll-message-window)
     (notmuch-tree-next-matching-message)))
 
-(defun notmuch-tree-quit ()
+(defun notmuch-tree-quit (&optional kill-both)
   "Close the split view or exit tree."
-  (interactive)
-  (unless (notmuch-tree-close-message-window)
+  (interactive "P")
+  (when (or (not (notmuch-tree-close-message-window)) kill-both)
     (kill-buffer (current-buffer))))
 
 (defun notmuch-tree-close-message-window ()
-- 
2.23.0

[PATCH 5/7] emacs/tree: add notmuch-tree-archive-message-than-next-or-exit

[William Casarin]

This is the notmuch-tree version of
notmuch-show-archive-message-than-next-or-exit.

Signed-off-by: William Casarin <jb55@jb55.com>
---
 emacs/notmuch-tree.el | 30 ++++++++++++++++++++----------
 1 file changed, 20 insertions(+), 10 deletions(-)

diff --git a/emacs/notmuch-tree.el b/emacs/notmuch-tree.el
index 367b10c4..fd6f9f83 100644
--- a/emacs/notmuch-tree.el
+++ b/emacs/notmuch-tree.el
@@ -563,6 +563,15 @@ message will be \"unarchived\", i.e. the tag changes in
   (notmuch-tree-archive-message unarchive)
   (notmuch-tree-next-matching-message))
 
+(defun notmuch-tree-archive-message-then-next-or-exit ()
+  "Archive current message, then show next open message in current thread.
+
+If at the last open message in the current thread, then exit back
+to search results."
+  (interactive)
+  (notmuch-tree-archive-message)
+  (notmuch-tree-next-matching-message t))
+
 (defun notmuch-tree-next-message ()
   "Move to next message."
   (interactive)
@@ -588,23 +597,24 @@ nil otherwise."
       (forward-line (if prev -1 nil)))
     (not last)))
 
-(defun notmuch-tree-matching-message (&optional prev)
+(defun notmuch-tree-matching-message (&optional prev pop-at-end)
   "Move to the next or previous matching message"
   (interactive "P")
   (forward-line (if prev -1 nil))
-  (notmuch-tree-goto-matching-message prev)
-  (when (window-live-p notmuch-tree-message-window)
-    (notmuch-tree-show-message-in)))
+  (if (and pop-at-end (not (notmuch-tree-goto-matching-message prev)))
+      (notmuch-tree-quit pop-at-end)
+    (when (window-live-p notmuch-tree-message-window)
+      (notmuch-tree-show-message-in))))
 
-(defun notmuch-tree-prev-matching-message ()
+(defun notmuch-tree-prev-matching-message (&optional pop-at-end)
   "Move to previous matching message."
-  (interactive)
-  (notmuch-tree-matching-message t))
+  (interactive "P")
+  (notmuch-tree-matching-message t pop-at-end))
 
-(defun notmuch-tree-next-matching-message ()
+(defun notmuch-tree-next-matching-message (&optional pop-at-end)
   "Move to next matching message."
-  (interactive)
-  (notmuch-tree-matching-message))
+  (interactive "P")
+  (notmuch-tree-matching-message nil pop-at-end))
 
 (defun notmuch-tree-refresh-view ()
   "Refresh view."
-- 
2.23.0

Re: [PATCH 5/7] emacs/tree: add notmuch-tree-archive-message-than-next-or-exit

[William Casarin]

William Casarin <jb55@jb55.com> writes:

> This is the notmuch-tree version of
> notmuch-show-archive-message-than-next-or-exit.
>
> Signed-off-by: William Casarin <jb55@jb55.com>
> ---
>  emacs/notmuch-tree.el | 30 ++++++++++++++++++++----------
>  1 file changed, 20 insertions(+), 10 deletions(-)
>
> diff --git a/emacs/notmuch-tree.el b/emacs/notmuch-tree.el
> index 367b10c4..fd6f9f83 100644
> --- a/emacs/notmuch-tree.el
> +++ b/emacs/notmuch-tree.el
> @@ -563,6 +563,15 @@ message will be \"unarchived\", i.e. the tag changes in
>    (notmuch-tree-archive-message unarchive)
>    (notmuch-tree-next-matching-message))
>  
> +(defun notmuch-tree-archive-message-then-next-or-exit ()
> +  "Archive current message, then show next open message in current thread.
> +
> +If at the last open message in the current thread, then exit back
> +to search results."
> +  (interactive)
> +  (notmuch-tree-archive-message)
> +  (notmuch-tree-next-matching-message t))
> +
>  (defun notmuch-tree-next-message ()
>    "Move to next message."
>    (interactive)
> @@ -588,23 +597,24 @@ nil otherwise."
>        (forward-line (if prev -1 nil)))
>      (not last)))
>  
> -(defun notmuch-tree-matching-message (&optional prev)
> +(defun notmuch-tree-matching-message (&optional prev pop-at-end)
>    "Move to the next or previous matching message"
>    (interactive "P")
>    (forward-line (if prev -1 nil))
> -  (notmuch-tree-goto-matching-message prev)
> -  (when (window-live-p notmuch-tree-message-window)
> -    (notmuch-tree-show-message-in)))
> +  (if (and pop-at-end (not (notmuch-tree-goto-matching-message prev)))

bah, this should be

  (if (and (not (notmuch-tree-goto-matching-message prev)) pop-at-end)

since short-circuit evaulation prevents the goto-matching-message from
getting called.

I'll push out a v2 later if this gets enough Concept ACKs.

> +      (notmuch-tree-quit pop-at-end)
> +    (when (window-live-p notmuch-tree-message-window)
> +      (notmuch-tree-show-message-in))))
>  
> -(defun notmuch-tree-prev-matching-message ()
> +(defun notmuch-tree-prev-matching-message (&optional pop-at-end)
>    "Move to previous matching message."
> -  (interactive)
> -  (notmuch-tree-matching-message t))
> +  (interactive "P")
> +  (notmuch-tree-matching-message t pop-at-end))
>  
> -(defun notmuch-tree-next-matching-message ()
> +(defun notmuch-tree-next-matching-message (&optional pop-at-end)
>    "Move to next matching message."
> -  (interactive)
> -  (notmuch-tree-matching-message))
> +  (interactive "P")
> +  (notmuch-tree-matching-message nil pop-at-end))
>  
>  (defun notmuch-tree-refresh-view ()
>    "Refresh view."
> -- 
> 2.23.0

Re: [PATCH 5/7] emacs/tree: add notmuch-tree-archive-message-than-next-or-exit

[David Edmondson]

On Sunday, 2019-11-17 at 15:17:58 -08, William Casarin wrote:

> I'll push out a v2 later if this gets enough Concept ACKs.

The changes make sense to me in principle, but I don't use
notmuch-tree. It would be good if someone who does could try them and
comment.

dme.
-- 
I do believe it's Madame Joy.

Re: [PATCH 5/7] emacs/tree: add notmuch-tree-archive-message-than-next-or-exit

[William Casarin]

David Edmondson <dme@dme.org> writes:

> On Sunday, 2019-11-17 at 15:17:58 -08, William Casarin wrote:
>
>> I'll push out a v2 later if this gets enough Concept ACKs.
>
> The changes make sense to me in principle, but I don't use
> notmuch-tree. It would be good if someone who does could try them and
> comment.

I didn't either but I realized it's quite nice for viewing long threaded
discussions. The main  reason I never used it before  was because of the
different keybinds and missing functionality. My goal is to try to bring
as many  things over  as possible  so that  notmuch-show users  can feel
comfortable in notmuch-tree.

x/X was the  big one for me. The  only else perhaps is a  button to quit
both windows at the same time. I  added this functionality in one of the
patches (prefix argument to notmuch-tree-quit) so we just need a keybind
for it now.

If anyone  is interested in  trying this  out I've pushed  these patches
plus the M-RET binding to my github:

    git fetch https://github.com/jb55/notmuch tree-improvements

Cheers,
Will

-- 
https://jb55.com

[PATCH 6/7] emacs/tree: add notmuch-tree-archive-thread-then-exit

[William Casarin]

This is the notmuch-tree version of
notmuch-show-archive-thread-then-exit

Signed-off-by: William Casarin <jb55@jb55.com>
---
 emacs/notmuch-tree.el | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/emacs/notmuch-tree.el b/emacs/notmuch-tree.el
index fd6f9f83..b8844b64 100644
--- a/emacs/notmuch-tree.el
+++ b/emacs/notmuch-tree.el
@@ -563,6 +563,12 @@ message will be \"unarchived\", i.e. the tag changes in
   (notmuch-tree-archive-message unarchive)
   (notmuch-tree-next-matching-message))
 
+(defun notmuch-tree-archive-thread-then-exit ()
+  "Archive all messages in the current buffer, then exit notmuch-tree."
+  (interactive)
+  (notmuch-tree-archive-thread)
+  (notmuch-tree-quit t))
+
 (defun notmuch-tree-archive-message-then-next-or-exit ()
   "Archive current message, then show next open message in current thread.
 
-- 
2.23.0

[PATCH 7/7] emacs/tree: add x/X bindings

[William Casarin]

Add x and X binds to notmuch-tree for functionally that we have in
notmuch-show.

The notmuch-tree-quit binding is somewhat redundant, since it is
handled by notmuch-bury-or-kill-this-buffer which is bound to q.

Signed-off-by: William Casarin <jb55@jb55.com>
---
 emacs/notmuch-tree.el | 3 ++-
 1 file changed, 2 insertions(+), 1 deletion(-)

diff --git a/emacs/notmuch-tree.el b/emacs/notmuch-tree.el
index b8844b64..d3a54bcb 100644
--- a/emacs/notmuch-tree.el
+++ b/emacs/notmuch-tree.el
@@ -277,7 +277,8 @@ FUNC."
     ;; The main tree view bindings
     (define-key map (kbd "RET") 'notmuch-tree-show-message)
     (define-key map [mouse-1] 'notmuch-tree-show-message)
-    (define-key map "x" 'notmuch-tree-quit)
+    (define-key map "x" 'notmuch-tree-archive-message-then-next-or-exit)
+    (define-key map "X" 'notmuch-tree-archive-thread-then-exit)
     (define-key map "A" 'notmuch-tree-archive-thread)
     (define-key map "a" 'notmuch-tree-archive-message-then-next)
     (define-key map "z" 'notmuch-tree-to-tree)
-- 
2.23.0

Re: [PATCH 0/7] Port notmuch-show's x/X bindings to notmuch-tree

[Teemu Likonen]

[-- Attachment #1: Type: text/plain, Size: 628 bytes --]

William Casarin [2019-11-17T14:29:22-08] wrote:

> These patches bring notmuch-tree more in line with the user experience
> of notmuch-show by adding the x/X bindings.

I have not tested the patch set yet but I think it is very good idea to
add x/X keybindings to make tree view work similarly to show view.
Perhaps I will try the patch set later. Would you mind sending a fixed
version of "PATCH 5/7" (see id:87mucuay8p.fsf@jb55.com)?

-- 
///  OpenPGP key: 4E1055DC84E9DFF613D78557719D69D324539450
//  https://keys.openpgp.org/search?q=tlikonen@iki.fi
/  https://keybase.io/tlikonen  https://github.com/tlikonen

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 694 bytes --]

Re: [PATCH 0/7] Port notmuch-show's x/X bindings to notmuch-tree

[Teemu Likonen]

[-- Attachment #1: Type: text/plain, Size: 1042 bytes --]

Teemu Likonen [2019-11-20T10:10:43+02] wrote:

> William Casarin [2019-11-17T14:29:22-08] wrote:
>> These patches bring notmuch-tree more in line with the user experience
>> of notmuch-show by adding the x/X bindings.
>
> I have not tested the patch set yet but I think it is very good idea
> to add x/X keybindings to make tree view work similarly to show view.

Now I have been using the patch set some days and it works as expected.
Usually I open a thread with M-TAB (notmuch-tree-from-search-thread) and
if I then find thread uninteresting I hit "X"
(notmuch-tree-archive-thread-then-exit) and continue browsing the thread
list.

I'm quite experienced with Emacs Lisp (and Common Lisp) but I don't know
Notmuch Emacs code to give educated comments on this patch set's code.
From user's side it works and I support this feature. Thanks!

-- 
///  OpenPGP key: 4E1055DC84E9DFF613D78557719D69D324539450
//  https://keys.openpgp.org/search?q=tlikonen@iki.fi
/  https://keybase.io/tlikonen  https://github.com/tlikonen

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 694 bytes --]

[PATCH 1/7] emacs/tree: return true if a thread was found in next-thread

[William Casarin]

This will allow us to pop back to parent buffers when there are no
more threads to jump to.

Signed-off-by: William Casarin <jb55@jb55.com>
---

 This is as rebased version of id:20191228150124.20630-1-jb55@jb55.com
 as requested in id:87v9mg3gut.fsf@tethera.net 

 emacs/notmuch-tree.el | 5 ++++-
 1 file changed, 4 insertions(+), 1 deletion(-)

diff --git a/emacs/notmuch-tree.el b/emacs/notmuch-tree.el
index 9a83292c..1bcf6cf9 100644
--- a/emacs/notmuch-tree.el
+++ b/emacs/notmuch-tree.el
@@ -679,10 +679,13 @@ message will be \"unarchived\", i.e. the tag changes in
   (notmuch-tree-thread-top))
 
 (defun notmuch-tree-next-thread ()
+  "Get the next thread in the current tree. Returns t if a thread was
+found or nil if not."
   (interactive)
   (forward-line 1)
   (while (not (or (notmuch-tree-get-prop :first) (eobp)))
-    (forward-line 1)))
+    (forward-line 1))
+  (not (eobp)))
 
 (defun notmuch-tree-thread-mapcar (function)
   "Iterate through all messages in the current thread
-- 
2.25.1

[PATCH 5/7] emacs/tree: add notmuch-tree-archive-message-than-next-or-exit

[William Casarin]

This is the notmuch-tree version of
notmuch-show-archive-message-than-next-or-exit.

Signed-off-by: William Casarin <jb55@jb55.com>
---
 emacs/notmuch-tree.el | 30 ++++++++++++++++++++----------
 1 file changed, 20 insertions(+), 10 deletions(-)

diff --git a/emacs/notmuch-tree.el b/emacs/notmuch-tree.el
index b405e9e3..02bdd1ee 100644
--- a/emacs/notmuch-tree.el
+++ b/emacs/notmuch-tree.el
@@ -617,6 +617,15 @@ message will be \"unarchived\", i.e. the tag changes in
   (notmuch-tree-archive-message unarchive)
   (notmuch-tree-next-matching-message))
 
+(defun notmuch-tree-archive-message-then-next-or-exit ()
+  "Archive current message, then show next open message in current thread.
+
+If at the last open message in the current thread, then exit back
+to search results."
+  (interactive)
+  (notmuch-tree-archive-message)
+  (notmuch-tree-next-matching-message t))
+
 (defun notmuch-tree-next-message ()
   "Move to next message."
   (interactive)
@@ -643,23 +652,24 @@ nil otherwise."
       (forward-line dir))
     (not (funcall eobfn))))
 
-(defun notmuch-tree-matching-message (&optional prev)
+(defun notmuch-tree-matching-message (&optional prev pop-at-end)
   "Move to the next or previous matching message"
   (interactive "P")
   (forward-line (if prev -1 nil))
-  (notmuch-tree-goto-matching-message prev)
-  (when (window-live-p notmuch-tree-message-window)
-    (notmuch-tree-show-message-in)))
+  (if (and (not (notmuch-tree-goto-matching-message prev)) pop-at-end)
+      (notmuch-tree-quit pop-at-end)
+    (when (window-live-p notmuch-tree-message-window)
+      (notmuch-tree-show-message-in))))
 
-(defun notmuch-tree-prev-matching-message ()
+(defun notmuch-tree-prev-matching-message (&optional pop-at-end)
   "Move to previous matching message."
-  (interactive)
-  (notmuch-tree-matching-message t))
+  (interactive "P")
+  (notmuch-tree-matching-message t pop-at-end))
 
-(defun notmuch-tree-next-matching-message ()
+(defun notmuch-tree-next-matching-message (&optional pop-at-end)
   "Move to next matching message."
-  (interactive)
-  (notmuch-tree-matching-message))
+  (interactive "P")
+  (notmuch-tree-matching-message nil pop-at-end))
 
 (defun notmuch-tree-refresh-view (&optional view)
   "Refresh view."
-- 
2.25.1