[bug#63814] [PATCH 0/6] gnu: Add le-biniou.

[bug#63814] [PATCH 0/6] gnu: Add le-biniou.

[Antero Mejr via Guix-patches via]

This patch set adds the Le Biniou audio visualizer and dependencies.

Antero Mejr (6):
  gnu: Add subunit.
  gnu: Add orcania.
  gnu: Add yder.
  gnu: Add ulfius.
  gnu: Add le-biniou-data.
  gnu: Add le-biniou.

 gnu/packages/check.scm |  33 ++++++++++
 gnu/packages/music.scm |  76 +++++++++++++++++++++++
 gnu/packages/web.scm   | 133 +++++++++++++++++++++++++++++++++++++++++
 3 files changed, 242 insertions(+)

-- 
2.39.2

[bug#63814] [PATCH 1/6] gnu: Add subunit.

[Antero Mejr via Guix-patches via]

* gnu/packages/check.scm (subunit): New variable.
---
 gnu/packages/check.scm | 33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)

diff --git a/gnu/packages/check.scm b/gnu/packages/check.scm
index 87728fefa3..4acac531c2 100644
--- a/gnu/packages/check.scm
+++ b/gnu/packages/check.scm
@@ -3554,3 +3554,36 @@ (define-public guile-proba
 to run test collections, and a library that includes a test runner and
 helpers for writing tests.")
     (license license:public-domain)))
+
+(define-public subunit
+  (package
+    (name "subunit")
+    (version "1.4.2")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://github.com/testing-cabal/subunit")
+                    (commit version)))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "16n1zxwnmhb7vzixngvmm5zzk4q5jaqqjwyr6pr6w0ys60b7xja3"))))
+    (build-system gnu-build-system)
+    (native-inputs (list autoconf
+                         automake
+                         check
+                         cppunit
+                         libtool
+                         pkg-config
+                         python-fixtures
+                         python-hypothesis
+                         python-testscenarios))
+    (inputs (list perl python))
+    (propagated-inputs (list python-testtools))
+    (home-page "https://github.com/testing-cabal/subunit")
+    (synopsis "Test reporting and control protocol")
+    (description
+     "Subunit is a streaming protocol for test results.  Subunit comes with
+command line filters to process a subunit stream and language bindings for
+Python, C, C++ and shell.  Bindings are easy to write for other languages.")
+    (license (list license:asl2.0 license:bsd-3)))) ;user can pick
-- 
2.39.2

[bug#63814] [PATCH 2/6] gnu: Add orcania.

[Antero Mejr via Guix-patches via]

* gnu/packages/web.scm (orcania): New variable.
---
 gnu/packages/web.scm | 37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

diff --git a/gnu/packages/web.scm b/gnu/packages/web.scm
index 3af4aa0b8d..e47abdb1bc 100644
--- a/gnu/packages/web.scm
+++ b/gnu/packages/web.scm
@@ -8794,6 +8794,43 @@ (define-public archivebox
     (home-page "https://archivebox.io/")
     (license license:expat)))
 
+(define-public orcania
+  (package
+    (name "orcania")
+    (version "2.3.2")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://github.com/babelouest/orcania")
+                    (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "0dhczbhwvf3f9mj38qm46j10rpr77yz1np68mabfw8zcfwhr0pn4"))))
+    (build-system cmake-build-system)
+    (arguments
+     (list #:configure-flags #~(list "-DBUILD_ORCANIA_TESTING=ON"
+                                     "-DBUILD_ORCANIA_DOCUMENTATION=ON")
+           #:phases #~(modify-phases %standard-phases
+                        (add-after 'build 'build-doc
+                          (lambda _
+                            (invoke "make" "doc")))
+                        (add-after 'install 'install-doc
+                          (lambda _
+                            (let ((doc (string-append #$output
+                                                      "/share/doc/orcania")))
+                              (mkdir-p doc)
+                              (copy-recursively "../source/doc/html" doc)))))))
+    (native-inputs (list check doxygen subunit))
+    (home-page "https://babelouest.github.io/orcania/")
+    (synopsis "Collection of C functions for Ulfius")
+    (description
+     "Orcania is a library with functions that can be shared among C programs.
+It is intended to provide low-level functionalities for the Ulfius and Yder
+libraries.")
+    (license license:lgpl2.1)))
+
+
 ;;;
 ;;; Avoid adding new packages to the end of this file. To reduce the chances
 ;;; of a merge conflict, place them above by existing packages with similar
-- 
2.39.2

[bug#63814] [PATCH 3/6] gnu: Add yder.

[Antero Mejr via Guix-patches via]

* gnu/packages/web.scm (yder): New variable.
---
 gnu/packages/web.scm | 37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

diff --git a/gnu/packages/web.scm b/gnu/packages/web.scm
index e47abdb1bc..bc066b6a71 100644
--- a/gnu/packages/web.scm
+++ b/gnu/packages/web.scm
@@ -8830,6 +8830,43 @@ (define-public orcania
 libraries.")
     (license license:lgpl2.1)))
 
+(define-public yder
+  (package
+    (name "yder")
+    (version "1.4.19")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://github.com/babelouest/yder")
+                    (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "02jgrqby39ykfdhc7z0bh3x5aqisqybz6lnvn7msh9wqbj5zvzi8"))))
+    (build-system cmake-build-system)
+    (arguments
+     (list #:configure-flags #~(list "-DWITH_JOURNALD=OFF"
+                                     "-DBUILD_YDER_TESTING=ON"
+                                     "-DBUILD_YDER_DOCUMENTATION=ON")
+           #:phases #~(modify-phases %standard-phases
+                        (add-after 'build 'build-doc
+                          (lambda _
+                            (invoke "make" "doc")))
+                        (add-after 'install 'install-doc
+                          (lambda _
+                            (let ((doc (string-append #$output
+                                                      "/share/doc/yder")))
+                              (mkdir-p doc)
+                              (copy-recursively "../source/doc/html" doc)))))))
+    (native-inputs (list check doxygen subunit))
+    (inputs (list orcania))
+    (home-page "https://babelouest.github.io/yder/")
+    (synopsis "Logging library for C applications")
+    (description
+     "Yder is a logging library written in C.  It can log messages to the
+console, a file, syslog, journald, or a callback function.")
+    (license license:lgpl2.1)))
+
 
 ;;;
 ;;; Avoid adding new packages to the end of this file. To reduce the chances
-- 
2.39.2

[bug#63814] [PATCH 4/6] gnu: Add ulfius.

[Antero Mejr via Guix-patches via]

* gnu/packages/web.scm (ulfius): New variable.
---
 gnu/packages/web.scm | 59 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

diff --git a/gnu/packages/web.scm b/gnu/packages/web.scm
index bc066b6a71..65434f2dae 100644
--- a/gnu/packages/web.scm
+++ b/gnu/packages/web.scm
@@ -8867,6 +8867,65 @@ (define-public yder
 console, a file, syslog, journald, or a callback function.")
     (license license:lgpl2.1)))
 
+(define-public ulfius
+  (package
+    (name "ulfius")
+    (version "2.7.13")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://github.com/babelouest/ulfius")
+                    (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "1dfwdpqmqki63dddi53bfv6jd0kzv8gh2w1lxsv6mzk3sxl6qakf"))))
+    (build-system cmake-build-system)
+    (arguments
+     (list #:configure-flags #~(list "-DBUILD_ULFIUS_TESTING=ON"
+                                     "-DBUILD_ULFIUS_DOCUMENTATION=ON")
+           #:phases #~(modify-phases %standard-phases
+                        (add-after 'build 'build-doc
+                          (lambda _
+                            (invoke "make" "doc")))
+                        (replace 'check
+                          (lambda* (#:key tests? parallel-tests? #:allow-other-keys)
+                            (when tests?
+                              (let ((job-count (number->string
+                                                (or (and parallel-tests?
+                                                         (parallel-job-count))
+                                                    1))))
+                                ;; Skip failing tests that try to start a server.
+                                (invoke "ctest" "--output-on-failure"
+                                        "-j" job-count "-E"
+                                        "(core|framework|example_callbacks)")))))
+                        (add-after 'install 'install-doc
+                          (lambda _
+                            (let ((doc (string-append #$output
+                                                      "/share/doc/ulfius")))
+                              (mkdir-p doc)
+                              (copy-recursively "../source/doc/html" doc)))))))
+    (native-inputs (list check doxygen subunit))
+    (inputs (list zlib))
+    (propagated-inputs ;for libulfius.pc
+     (list curl
+           gnutls
+           jansson
+           libgcrypt
+           libmicrohttpd
+           orcania
+           yder))
+    (home-page "https://babelouest.github.io/ulfius/")
+    (synopsis "HTTP Framework for REST Applications in C")
+    (description
+     "Ulfius is a HTTP Framework library for REST Applications written in C.
+It is based on GNU libmicrohttpd for the backend web server, Jansson for the
+JSON manipulation library, and libcurl for the http/smtp client API.  It can
+be used to facilitate creation of web applications in C programs with a small
+memory footprint, as in embedded systems applications.  It can create
+webservices in HTTP or HTTPS mode, stream data, or implement server
+websockets.")
+    (license license:lgpl2.1)))
 
 ;;;
 ;;; Avoid adding new packages to the end of this file. To reduce the chances
-- 
2.39.2

[bug#63814] [PATCH 5/6] gnu: Add le-biniou-data.

[Antero Mejr via Guix-patches via]

* gnu/packages/music.scm (le-biniou-data): New variable.
---
 gnu/packages/music.scm | 21 +++++++++++++++++++++
 1 file changed, 21 insertions(+)

diff --git a/gnu/packages/music.scm b/gnu/packages/music.scm
index 7e4a7d1169..c29ce996a0 100644
--- a/gnu/packages/music.scm
+++ b/gnu/packages/music.scm
@@ -7321,6 +7321,27 @@ (define-public samplebrain
 realtime.")
     (license license:gpl2+)))
 
+(define-public le-biniou-data
+  (package
+    (name "le-biniou-data")
+    (version "3.66.0")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://gitlab.com/lebiniou/lebiniou-data")
+                    (commit (string-append "version-" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "1s8dax6ryfqz7aqq8rj5ipxddshp5mjdvj0mn9kk1zzr55hvkfb7"))))
+    (build-system gnu-build-system)
+    (native-inputs (list autoconf automake libtool))
+    (home-page "https://biniou.net/")
+    (synopsis "Data files for use with Le Biniou")
+    (description
+     "This package contains data files for use with Le Biniou.")
+    (license license:gpl2+)))
+
 ;;;
 ;;; Avoid adding new packages to the end of this file. To reduce the chances
 ;;; of a merge conflict, place them above by existing packages with similar
-- 
2.39.2

[bug#63814] [PATCH 6/6] gnu: Add le-biniou.

[Antero Mejr via Guix-patches via]

* gnu/packages/music.scm (le-biniou): New variable.
---
 gnu/packages/music.scm | 55 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/gnu/packages/music.scm b/gnu/packages/music.scm
index c29ce996a0..8f6df1e3f7 100644
--- a/gnu/packages/music.scm
+++ b/gnu/packages/music.scm
@@ -7342,6 +7342,61 @@ (define-public le-biniou-data
      "This package contains data files for use with Le Biniou.")
     (license license:gpl2+)))
 
+(define-public le-biniou
+  (package
+    (name "le-biniou")
+    (version "3.66.0")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://gitlab.com/lebiniou/lebiniou")
+                    (commit (string-append "version-" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "1fvf944i703yd17kkxgja2xyyznb30p006piclz1rmgkhijp0lcp"))))
+    (build-system gnu-build-system)
+    (arguments
+     (list #:configure-flags #~(list (string-append "LDFLAGS=-Wl,-rpath="
+                                                    #$output "/lib")
+                                     (string-append
+                                      "LEBINIOU_DATADIR="
+                                      #$(this-package-input "le-biniou-data")))
+           #:phases #~(modify-phases %standard-phases
+                        (add-after 'unpack 'patch
+                          (lambda _
+                            (substitute* "src/bulfius_vui.c"
+                              (("xdg-open")
+                               (string-append
+                                #$(this-package-input "xdg-utils")
+                                "/bin/xdg-open"))))))))
+    (native-inputs (list autoconf
+                         automake
+                         libtool
+                         perl ;for pod2man
+                         pkg-config))
+    (inputs (list alsa-lib
+                  curl
+                  ffmpeg
+                  fftw
+                  glib
+                  imagemagick
+                  jack-1
+                  jansson
+                  le-biniou-data
+                  libcaca
+                  libsndfile
+                  pulseaudio
+                  sdl2
+                  ulfius
+                  xdg-utils))
+    (home-page "https://biniou.net/")
+    (synopsis "Audio visualization and VJing tool")
+    (description
+     "Le Biniou is a music visualization & VJing tool.  It creates live
+visuals based on audio performances or existing tracks.")
+    (license license:gpl2+)))
+
 ;;;
 ;;; Avoid adding new packages to the end of this file. To reduce the chances
 ;;; of a merge conflict, place them above by existing packages with similar
-- 
2.39.2

bug#63814: [PATCH 0/6] gnu: Add le-biniou.

[Ludovic Courtès]

Hi Antero,

Antero Mejr <antero@mailbox.org> skribis:

>   gnu: Add subunit.
>   gnu: Add orcania.
>   gnu: Add yder.
>   gnu: Add ulfius.
>   gnu: Add le-biniou-data.
>   gnu: Add le-biniou.

All green:

  https://qa.guix.gnu.org/issue/63814

Finally applied, thanks!

Ludo’.