[bug#30002] [PATCH 1/2] gnu: Add darkstat.

[bug#30002] [PATCH 1/2] gnu: Add darkstat.

[宋文武]

* gnu/packages/monitoring.scm (darkstat): New variable.
---
 gnu/packages/monitoring.scm | 34 ++++++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)

diff --git a/gnu/packages/monitoring.scm b/gnu/packages/monitoring.scm
index c136265c5..f178232cc 100644
--- a/gnu/packages/monitoring.scm
+++ b/gnu/packages/monitoring.scm
@@ -1,5 +1,6 @@
 ;;; GNU Guix --- Functional package management for GNU
 ;;; Copyright © 2016 Ludovic Courtès <ludo@gnu.org>
+;;; Copyright © 2018 Sou Bunnbu <iyzsong@member.fsf.org>
 ;;;
 ;;; This file is part of GNU Guix.
 ;;;
@@ -22,6 +23,7 @@
   #:use-module ((guix licenses) #:prefix license:)
   #:use-module (guix build-system perl)
   #:use-module (guix build-system gnu)
+  #:use-module (gnu packages admin)
   #:use-module (gnu packages base)
   #:use-module (gnu packages compression)
   #:use-module (gnu packages gd)
@@ -122,3 +124,35 @@ etc. via a Web interface.  Features include:
   notification and problem history, log file, etc.
 @end itemize\n")
     (license license:gpl2)))
+
+(define-public darkstat
+  (package
+    (name "darkstat")
+    (version "3.0.719")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "https://unix4lyfe.org/darkstat/darkstat-"
+                                  version ".tar.bz2"))
+              (sha256
+               (base32
+                "1mzddlim6dhd7jhr4smh0n2fa511nvyjhlx76b03vx7phnar1bxf"))))
+    (build-system gnu-build-system)
+    (arguments '(#:tests? #f))          ; no tests
+    (inputs
+     `(("libpcap" ,libpcap)
+       ("zlib" ,zlib)))
+    (home-page "https://unix4lyfe.org/darkstat/")
+    (synopsis "Network statistics gatherer")
+    (description
+     "@command{darkstat} is a packet sniffer that runs as a background process,
+gathers all sorts of statistics about network usage, and serves them over
+HTTP.  Features:
+
+@itemize
+@item Traffic graphs, reports per host, shows ports for each host.
+@item Embedded web-server with deflate compression.
+@item Asynchronous reverse DNS resolution using a child process.
+@item Small.  Portable.  Single-threaded.  Efficient.
+@item Supports IPv6.
+@end itemize")
+    (license license:gpl2)))
-- 
2.13.3

[bug#30003] [PATCH 2/2] gnu: services: Add darkstat service.

[宋文武]

* gnu/services/monitoring.scm: New file.
* gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
* doc/guix.texi (Monitoring Services): Document it.
---
 doc/guix.texi               | 42 +++++++++++++++++++++
 gnu/local.mk                |  1 +
 gnu/services/monitoring.scm | 91 +++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 134 insertions(+)
 create mode 100644 gnu/services/monitoring.scm

diff --git a/doc/guix.texi b/doc/guix.texi
index 1d1f30f00..f9dec3082 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -14697,6 +14697,48 @@ the 2nd element of the pair is the password.
 @end deftp
 
 
+@subsubheading Darkstat Service
+@cindex darkstat
+@command{darkstat} is a packet sniffer that captures network traffic,
+calculates statistics about usage, and serves reports over HTTP.
+
+@defvar {Scheme Variable} darkstat-service-type
+This is the service type for the
+@uref{https://unix4lyfe.org/darkstat/, darkstat}
+service,  its value must be a @code{darkstat-configuration} record as in
+this example:
+
+@example
+(service darkstat-service-type
+  (darkstat-configuration
+    (interface "eth0")))
+@end example
+@end defvar
+
+@deftp {Data Type} darkstat-configuration
+Data type representing the configuration of @command{darkstat}.
+
+@table @asis
+@item @code{package} (default: @code{darstat})
+The darkstat package to use.
+
+@item @code{interface}
+Capture traffic on the specified network interface.
+
+@item @code{port} (default: @code{"667"})
+Bind the web interface to the specified port.
+
+@item @code{bindaddr} (default: @code{"127.0.0.1"})
+Bind the web interface to the specified address.
+
+@item @code{base} (default: @code{"/"})
+Specify the path of the base URL.  This can be useful if
+@command{darkstat} is accessed via a reverse proxy.
+
+@end table
+@end deftp
+
+
 @node Kerberos Services
 @subsubsection Kerberos Services
 @cindex Kerberos
diff --git a/gnu/local.mk b/gnu/local.mk
index 679c119a5..62fcd2cd4 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -460,6 +460,7 @@ GNU_SYSTEM_MODULES =				\
   %D%/services/mail.scm				\
   %D%/services/mcron.scm			\
   %D%/services/messaging.scm			\
+  %D%/services/monitoring.scm			\
   %D%/services/networking.scm			\
   %D%/services/nfs.scm			\
   %D%/services/shepherd.scm			\
diff --git a/gnu/services/monitoring.scm b/gnu/services/monitoring.scm
new file mode 100644
index 000000000..438d66596
--- /dev/null
+++ b/gnu/services/monitoring.scm
@@ -0,0 +1,91 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2018 Sou Bunnbu <iyzsong@member.fsf.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu services monitoring)
+  #:use-module (gnu services)
+  #:use-module (gnu services shepherd)
+  #:use-module (gnu packages admin)
+  #:use-module (gnu packages monitoring)
+  #:use-module (gnu system shadow)
+  #:use-module (guix gexp)
+  #:use-module (guix records)
+  #:use-module (ice-9 match)
+  #:export (darkstat-configuration
+            darkstat-service-type))
+
+\f
+;;;
+;;; darkstat
+;;;
+
+(define-record-type* <darkstat-configuration>
+  darkstat-configuration make-darkstat-configuration darkstat-configuration?
+  (package   darkstat-configuration-package
+             (default darkstat))
+  (interface darkstat-configuration-interface)
+  (port      darkstat-configuration-port
+             (default "667"))
+  (bindaddr  darkstat-configuration-bindaddr
+             (default "127.0.0.1"))
+  (base      darkstat-configuration-base
+             (default "/")))
+
+(define %darkstat-accounts
+  (list (user-account
+         (name "darkstat")
+         (group "darkstat")
+         (system? #t)
+         (comment "darkstat daemon user")
+         (home-directory "/var/lib/darkstat")
+         (shell (file-append shadow "/sbin/nologin")))
+        (user-group
+         (name "darkstat")
+         (system? #t))))
+
+(define darkstat-shepherd-service
+  (match-lambda
+    (($ <darkstat-configuration>
+        package interface port bindaddr base)
+     (shepherd-service
+      (documentation "Network statistics gatherer.")
+      (provision '(darkstat))
+      (requirement '(networking))
+      (start #~(make-forkexec-constructor
+                (list #$(file-append package "/sbin/darkstat")
+                      "-i" #$interface
+                      "-p" #$port
+                      "-b" #$bindaddr
+                      "--base" #$base
+                      "--syslog" "--no-daemon"
+                      "--chroot" "/var/lib/darkstat"
+                      "--user" "darkstat"
+                      "--import" "darkstat.db"
+                      "--export" "darkstat.db")))
+      (stop #~(make-kill-destructor))))))
+
+(define darkstat-service-type
+  (service-type
+   (name 'darkstat)
+   (description
+    "Run @command{darkstat} to serve network traffic statictics reports over
+HTTP.")
+   (extensions
+    (list (service-extension account-service-type
+                             (const %darkstat-accounts))
+          (service-extension shepherd-root-service-type
+                             (compose list darkstat-shepherd-service))))))
-- 
2.13.3

[bug#30002] [PATCH 1/2] gnu: Add darkstat.

[Ludovic Courtès]

宋文武 <iyzsong@member.fsf.org> skribis:

> * gnu/packages/monitoring.scm (darkstat): New variable.

LGTM, thanks!

Ludo'.

[bug#30003] [PATCH 2/2] gnu: services: Add darkstat service.

[Ludovic Courtès]

Hello,

宋文武 <iyzsong@member.fsf.org> skribis:

> * gnu/services/monitoring.scm: New file.
> * gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
> * doc/guix.texi (Monitoring Services): Document it.

Nice!

I only have minor suggestions:

> +@subsubheading Darkstat Service
> +@cindex darkstat
> +@command{darkstat} is a packet sniffer that captures network traffic,

I think you can remove @command since you’re referring to the software,
not to the command.

> +@example
> +(service darkstat-service-type
> +  (darkstat-configuration
> +    (interface "eth0")))

This should be aligned to the right.  Also perhaps s/eth0/eno1/ to match
common names.

> +@item @code{package} (default: @code{darstat})
                                          ^
Typo.

> +@item @code{bindaddr} (default: @code{"127.0.0.1"})

I’d prefer “address” or “listen-address” or “bind-address” (likewise in
the code.)

Otherwise LGTM, thank you!

Ludo’.

bug#30003: [PATCH 2/2] gnu: services: Add darkstat service.

[宋文武]

ludo@gnu.org (Ludovic Courtès) writes:

> Hello,
>
> 宋文武 <iyzsong@member.fsf.org> skribis:
>
>> * gnu/services/monitoring.scm: New file.
>> * gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
>> * doc/guix.texi (Monitoring Services): Document it.
>
> Nice!
>
> I only have minor suggestions:
>
>> +@subsubheading Darkstat Service
>> +@cindex darkstat
>> +@command{darkstat} is a packet sniffer that captures network traffic,
>
> I think you can remove @command since you’re referring to the software,
> not to the command.
>
>> +@example
>> +(service darkstat-service-type
>> +  (darkstat-configuration
>> +    (interface "eth0")))
>
> This should be aligned to the right.  Also perhaps s/eth0/eno1/ to match
> common names.
>
>> +@item @code{package} (default: @code{darstat})
>                                           ^
> Typo.
>
>> +@item @code{bindaddr} (default: @code{"127.0.0.1"})
>
> I’d prefer “address” or “listen-address” or “bind-address” (likewise in
> the code.)
>
> Otherwise LGTM, thank you!

Done, thanks for the review!

bug#30002: [PATCH 1/2] gnu: Add darkstat.

[宋文武]

ludo@gnu.org (Ludovic Courtès) writes:

> 宋文武 <iyzsong@member.fsf.org> skribis:
>
>> * gnu/packages/monitoring.scm (darkstat): New variable.
>
> LGTM, thanks!
>

Pushed, thank you!