unofficial mirror of guix-patches@gnu.org 
 help / color / mirror / code / Atom feed
* [bug#64510] [PATCH v1] gnu: Add simtrace-1
@ 2023-07-07 14:09 Denis 'GNUtoo' Carikli
  2023-10-05 10:12 ` Christopher Baines
                   ` (2 more replies)
  0 siblings, 3 replies; 9+ messages in thread
From: Denis 'GNUtoo' Carikli @ 2023-07-07 14:09 UTC (permalink / raw)
  To: 64510; +Cc: Denis 'GNUtoo' Carikli

* gnu/packages/telephony.scm (simtrace-1): New variable.

Signed-off-by: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
---
 gnu/packages/telephony.scm | 72 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)

diff --git a/gnu/packages/telephony.scm b/gnu/packages/telephony.scm
index aa65c4eaad..b00a2971c7 100644
--- a/gnu/packages/telephony.scm
+++ b/gnu/packages/telephony.scm
@@ -87,6 +87,7 @@ (define-module (gnu packages telephony)
   #:use-module (gnu packages security-token)
   #:use-module (gnu packages serialization)
   #:use-module (gnu packages speech)
+  #:use-module (gnu packages tex)
   #:use-module (gnu packages tls)
   #:use-module (gnu packages upnp)
   #:use-module (gnu packages video)
@@ -989,6 +990,77 @@ (define-public libosmocore
     (home-page "https://osmocom.org/projects/libosmocore/wiki/Libosmocore")
     (license license:gpl2+)))
 
+(define-public simtrace-1
+  (package
+    (name "simtrace-1")
+    (version "1.5")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://gitea.osmocom.org/sim-card/simtrace")
+                    (commit (string-append "v" version))))
+              (sha256
+               (base32
+                "03wjdavp7fbr7jzzhqx6di9v87yvfi19i3kpn798vlpbw7iwkjry"))))
+    (arguments
+     (list #:tests? #f ;no tests
+           #:make-flags #~(list (string-append "CC="
+                                               #$(cc-for-target))
+                                (string-append "DESTDIR="
+                                               #$output))
+           #:phases #~(modify-phases %standard-phases
+                        (add-after 'unpack 'chdir
+                          (lambda _
+                            (chdir "host")))
+                        (add-after 'chdir 'fix-makefile
+                          (lambda _
+                            (substitute* "Makefile"
+                              (("/usr")
+                               ""))))
+                        (delete 'configure)
+                        (add-after 'build 'build-usermanual
+                          (lambda* (#:key inputs native-inputs
+                                    #:allow-other-keys)
+                            (substitute* "../docs/usermanual.xml"
+                              (("http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd")
+                               (string-append (assoc-ref inputs "docbook-xml")
+                                              "/xml/dtd/docbook/docbookx.dtd")))
+                            ;; At the beginning of the document, a table is
+                            ;; constructed with the build time in it. This
+                            ;; comes from '\newcommand{\DBKdate}{\today}' in
+                            ;; share/dblatex/latex/contrib/db2latex/db2latex.sty
+                            ;; in /gnu/store/[...]-dblatex-[...]. We used the
+                            ;; commit time for the date instead.
+                            (invoke (which "faketime") "2019-10-01"
+                                    (which "dblatex") "../docs/usermanual.xml")))
+                        (add-after 'build-usermanual 'install-usermanual
+                          (lambda _
+                            (install-file "../docs/usermanual.pdf"
+                                          (string-append #$output
+                                           "/share/doc/simtrace-1/"))))
+                        (add-after 'install 'install-man
+                          (lambda _
+                            (install-file "simtrace.1"
+                                          (string-append #$output "/man/man1/")))))))
+    (build-system gnu-build-system)
+    (native-inputs (list dblatex docbook-xml-4.2 libfaketime pkg-config
+                         texlive))
+    (inputs (list libosmocore libusb lksctp-tools talloc))
+    (synopsis
+     "Sniff the communication between phones and SIM cards with SIMtrace 1")
+    (description
+     "This contains the simtrace utility.
+It is compatible with the SIMtrace 1 hardware that contains an Atmel AT91SAM7S
+micro-controller.  It is not compatible with the SIMtrace 2 hardware that uses
+an Atmel ATSAM3S micro-controller instead.  The simtrace utility can display
+the SIM PDUs directly and/or send them to a given IP address to enable users
+to view SIM PDUs in Wireshark.  It also contains a complete user manual for
+the SIMtrace 1 hardware.")
+    (home-page "https://osmocom.org/projects/simtrace/wiki/SIMtrace")
+    ;; The utility is GPLv2-only according to the source files headers, and the
+    ;; manual is under the cc-by-sa 3.0
+    (license (list license:gpl2 license:cc-by-sa3.0))))
+
 (define-public xgoldmon
   ;; There are no releases nor tags.
   (let ((revision "1")

base-commit: 961ffca1c75141cbb351d143b22b673638e9659d
-- 
2.40.1





^ permalink raw reply related	[flat|nested] 9+ messages in thread
end of thread, other threads:[~2024-01-24  0:06 UTC | newest]

Thread overview: 9+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2023-07-07 14:09 [bug#64510] [PATCH v1] gnu: Add simtrace-1 Denis 'GNUtoo' Carikli
2023-10-05 10:12 ` Christopher Baines
2023-10-06 12:53   ` Denis 'GNUtoo' Carikli
2023-10-06 13:07     ` Denis 'GNUtoo' Carikli
2023-10-06 16:16 ` [bug#64510] [PATCH v2] " Denis 'GNUtoo' Carikli
2023-10-11 17:16   ` [bug#64510] [PATCH v1] " Ludovic Courtès
2023-10-11 17:19   ` Ludovic Courtès
2024-01-12  5:47 ` [bug#64510] [PATCH v3] " Denis 'GNUtoo' Carikli
2024-01-24  0:05   ` Denis 'GNUtoo' Carikli

Code repositories for project(s) associated with this public inbox

	https://git.savannah.gnu.org/cgit/guix.git

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).