* [PATCH 1/4] import: gnu: Propagate the key-download argument.
@ 2015-01-08 21:45 Eric Bavier
2015-01-08 21:45 ` [PATCH 2/4] import: Factorize utility functions Eric Bavier
` (3 more replies)
0 siblings, 4 replies; 8+ messages in thread
From: Eric Bavier @ 2015-01-08 21:45 UTC (permalink / raw)
To: guix-devel
* guix/import/gnu.scm (gnu->guix-package): Pass the key-download
argument on to gnu-package->sexp.
---
guix/import/gnu.scm | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/guix/import/gnu.scm b/guix/import/gnu.scm
index 1947f48..b5f67bd 100644
--- a/guix/import/gnu.scm
+++ b/guix/import/gnu.scm
@@ -102,7 +102,7 @@ details.)"
(let ((version (gnu-release-version release)))
(match (find-packages (regexp-quote name))
((info . _)
- (gnu-package->sexp info release))
+ (gnu-package->sexp info release #:key-download key-download))
(()
(raise (condition
(&message
--
1.7.9.5
^ permalink raw reply related [flat|nested] 8+ messages in thread
* [PATCH 2/4] import: Factorize utility functions.
2015-01-08 21:45 [PATCH 1/4] import: gnu: Propagate the key-download argument Eric Bavier
@ 2015-01-08 21:45 ` Eric Bavier
2015-01-09 13:36 ` Ludovic Courtès
2015-01-08 21:45 ` [PATCH 3/4] tests: import: Factorize utility function Eric Bavier
` (2 subsequent siblings)
3 siblings, 1 reply; 8+ messages in thread
From: Eric Bavier @ 2015-01-08 21:45 UTC (permalink / raw)
To: guix-devel
* guix/import/pypi.scm (hash-table->alist, flatten, assoc-ref*,
url-fetch, json-fetch): Pull functions from here and...
* guix/import/gnu.scm (file-sha256): here out into...
* guix/import/utils.scm: Here, and...
* guix/import/json.scm: Here. New file.
* Makefile.am (MODULE)[guile-json]: Add it.
* tests/pypi.scm (pypi->guix-package): Update mock module reference.
---
Makefile.am | 1 +
guix/import/gnu.scm | 7 ++-----
guix/import/json.scm | 32 +++++++++++++++++++++++++++++
guix/import/pypi.scm | 47 +-----------------------------------------
guix/import/utils.scm | 54 ++++++++++++++++++++++++++++++++++++++++++++++++-
tests/pypi.scm | 2 +-
6 files changed, 90 insertions(+), 53 deletions(-)
create mode 100644 guix/import/json.scm
diff --git a/Makefile.am b/Makefile.am
index bc0b952..c2bb176 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -174,6 +174,7 @@ SCM_TESTS = \
if HAVE_GUILE_JSON
MODULES += \
+ guix/import/json.scm \
guix/import/pypi.scm \
guix/scripts/import/pypi.scm
diff --git a/guix/import/gnu.scm b/guix/import/gnu.scm
index b5f67bd..81f3f45 100644
--- a/guix/import/gnu.scm
+++ b/guix/import/gnu.scm
@@ -1,4 +1,4 @@
-;;; GNU Guix --- Functional package management for GNU
+;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2014 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
@@ -18,6 +18,7 @@
(define-module (guix import gnu)
#:use-module (guix gnu-maintenance)
+ #:use-module (guix import utils)
#:use-module (guix utils)
#:use-module (guix store)
#:use-module (guix hash)
@@ -38,10 +39,6 @@
;;;
;;; Code:
-(define (file-sha256 file)
- "Return the SHA256 hash of FILE as a bytevector."
- (call-with-input-file file port-sha256))
-
(define (qualified-url url)
"Return a fully-qualified URL based on URL."
(if (string-prefix? "/" url)
diff --git a/guix/import/json.scm b/guix/import/json.scm
new file mode 100644
index 0000000..c3092a5
--- /dev/null
+++ b/guix/import/json.scm
@@ -0,0 +1,32 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2014 David Thompson <davet@gnu.org>
+;;; Copyright © 2015 Eric Bavier <bavier@member.fsf.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix import json)
+ #:use-module (json)
+ #:use-module (guix utils)
+ #:use-module (guix import utils)
+ #:export (json-fetch))
+
+(define (json-fetch url)
+ "Return an alist representation of the JSON resource URL, or #f on failure."
+ (call-with-temporary-output-file
+ (lambda (temp port)
+ (and (url-fetch url temp)
+ (hash-table->alist
+ (call-with-input-file temp json->scm))))))
diff --git a/guix/import/pypi.scm b/guix/import/pypi.scm
index 88f4a8e..8567cad 100644
--- a/guix/import/pypi.scm
+++ b/guix/import/pypi.scm
@@ -27,40 +27,15 @@
#:use-module (web uri)
#:use-module (guix utils)
#:use-module (guix import utils)
+ #:use-module (guix import json)
#:use-module (guix base32)
#:use-module (guix hash)
#:use-module (guix packages)
#:use-module (guix licenses)
#:use-module (guix build-system python)
- #:use-module ((guix build download) #:prefix build:)
#:use-module (gnu packages python)
#:export (pypi->guix-package))
-(define (hash-table->alist table)
- "Return an alist represenation of TABLE."
- (map (match-lambda
- ((key . (lst ...))
- (cons key
- (map (lambda (x)
- (if (hash-table? x)
- (hash-table->alist x)
- x))
- lst)))
- ((key . (? hash-table? table))
- (cons key (hash-table->alist table)))
- (pair pair))
- (hash-map->list cons table)))
-
-(define (flatten lst)
- "Return a list that recursively concatenates all sub-lists of LIST."
- (fold-right
- (match-lambda*
- (((sub-list ...) memo)
- (append (flatten sub-list) memo))
- ((elem memo)
- (cons elem memo)))
- '() lst))
-
(define (join lst delimiter)
"Return a list that contains the elements of LST, each separated by
DELIMETER."
@@ -71,13 +46,6 @@ DELIMETER."
((elem . rest)
(cons* elem delimiter (join rest delimiter)))))
-(define (assoc-ref* alist key . rest)
- "Return the value for KEY from ALIST. For each additional key specified,
-recursively apply the procedure to the sub-list."
- (if (null? rest)
- (assoc-ref alist key)
- (apply assoc-ref* (assoc-ref alist key) rest)))
-
(define string->license
(match-lambda
("GNU LGPL" lgpl2.0)
@@ -88,19 +56,6 @@ recursively apply the procedure to the sub-list."
("Apache License, Version 2.0" asl2.0)
(_ #f)))
-(define (url-fetch url file-name)
- "Save the contents of URL to FILE-NAME. Return #f on failure."
- (parameterize ((current-output-port (current-error-port)))
- (build:url-fetch url file-name)))
-
-(define (json-fetch url)
- "Return an alist representation of the JSON resource URL, or #f on failure."
- (call-with-temporary-output-file
- (lambda (temp port)
- (and (url-fetch url temp)
- (hash-table->alist
- (call-with-input-file temp json->scm))))))
-
(define (pypi-fetch name)
"Return an alist representation of the PyPI metadata for the package NAME,
or #f on failure."
diff --git a/guix/import/utils.scm b/guix/import/utils.scm
index 062cfc5..c3d4c4f 100644
--- a/guix/import/utils.scm
+++ b/guix/import/utils.scm
@@ -20,7 +20,18 @@
#:use-module (ice-9 match)
#:use-module (ice-9 regex)
#:use-module (srfi srfi-1)
- #:export (factorize-uri))
+ #:use-module (guix hash)
+ #:use-module (guix utils)
+ #:use-module ((guix build download) #:prefix build:)
+ #:export (factorize-uri
+
+ hash-table->alist
+ flatten
+ assoc-ref*
+
+ url-fetch
+
+ file-sha256))
(define (factorize-uri uri version)
"Factorize URI, a package tarball URI as a string, such that any occurrences
@@ -49,3 +60,44 @@ of the string VERSION is replaced by the symbol 'version."
result))))
'()
indices))))))
+
+(define (hash-table->alist table)
+ "Return an alist represenation of TABLE."
+ (map (match-lambda
+ ((key . (lst ...))
+ (cons key
+ (map (lambda (x)
+ (if (hash-table? x)
+ (hash-table->alist x)
+ x))
+ lst)))
+ ((key . (? hash-table? table))
+ (cons key (hash-table->alist table)))
+ (pair pair))
+ (hash-map->list cons table)))
+
+(define (flatten lst)
+ "Return a list that recursively concatenates all sub-lists of LST."
+ (fold-right
+ (match-lambda*
+ (((sub-list ...) memo)
+ (append (flatten sub-list) memo))
+ ((elem memo)
+ (cons elem memo)))
+ '() lst))
+
+(define (assoc-ref* alist key . rest)
+ "Return the value for KEY from ALIST. For each additional key specified,
+recursively apply the procedure to the sub-list."
+ (if (null? rest)
+ (assoc-ref alist key)
+ (apply assoc-ref* (assoc-ref alist key) rest)))
+
+(define (url-fetch url file-name)
+ "Save the contents of URL to FILE-NAME. Return #f on failure."
+ (parameterize ((current-output-port (current-error-port)))
+ (build:url-fetch url file-name)))
+
+(define (file-sha256 file)
+ "Return the SHA256 hash of FILE as a bytevector."
+ (call-with-input-file file port-sha256))
diff --git a/tests/pypi.scm b/tests/pypi.scm
index 124c512..53c34d9 100644
--- a/tests/pypi.scm
+++ b/tests/pypi.scm
@@ -60,7 +60,7 @@
(test-assert "pypi->guix-package"
;; Replace network resources with sample data.
- (mock ((guix import pypi) url-fetch
+ (mock ((guix import utils) url-fetch
(lambda (url file-name)
(with-output-to-file file-name
(lambda ()
--
1.7.9.5
^ permalink raw reply related [flat|nested] 8+ messages in thread
* [PATCH 3/4] tests: import: Factorize utility function.
2015-01-08 21:45 [PATCH 1/4] import: gnu: Propagate the key-download argument Eric Bavier
2015-01-08 21:45 ` [PATCH 2/4] import: Factorize utility functions Eric Bavier
@ 2015-01-08 21:45 ` Eric Bavier
2015-01-09 13:37 ` Ludovic Courtès
2015-01-08 21:45 ` [PATCH 4/4] import: Add CPAN importer Eric Bavier
2015-01-09 13:31 ` [PATCH 1/4] import: gnu: Propagate the key-download argument Ludovic Courtès
3 siblings, 1 reply; 8+ messages in thread
From: Eric Bavier @ 2015-01-08 21:45 UTC (permalink / raw)
To: guix-devel
* tests/pypi.scm (mock): Move this...
* guix/tests.scm: to here.
---
guix/tests.scm | 11 +++++++++++
tests/pypi.scm | 9 +--------
2 files changed, 12 insertions(+), 8 deletions(-)
diff --git a/guix/tests.scm b/guix/tests.scm
index 0226799..e63cded 100644
--- a/guix/tests.scm
+++ b/guix/tests.scm
@@ -27,6 +27,7 @@
#:export (open-connection-for-tests
random-text
random-bytevector
+ mock
with-derivation-narinfo))
;;; Commentary:
@@ -69,6 +70,16 @@
(loop (1+ i)))
bv))))
+(define-syntax-rule (mock (module proc replacement) body ...)
+ "Within BODY, replace the definition of PROC from MODULE with the definition
+given by REPLACEMENT."
+ (let* ((m (resolve-module 'module))
+ (original (module-ref m 'proc)))
+ (dynamic-wind
+ (lambda () (module-set! m 'proc replacement))
+ (lambda () body ...)
+ (lambda () (module-set! m 'proc original)))))
+
\f
;;;
;;; Narinfo files, as used by the substituter.
diff --git a/tests/pypi.scm b/tests/pypi.scm
index 53c34d9..45cf7ca 100644
--- a/tests/pypi.scm
+++ b/tests/pypi.scm
@@ -20,17 +20,10 @@
#:use-module (guix import pypi)
#:use-module (guix base32)
#:use-module (guix hash)
+ #:use-module (guix tests)
#:use-module (srfi srfi-64)
#:use-module (ice-9 match))
-(define-syntax-rule (mock (module proc replacement) body ...)
- (let* ((m (resolve-module 'module))
- (original (module-ref m 'proc)))
- (dynamic-wind
- (lambda () (module-set! m 'proc replacement))
- (lambda () body ...)
- (lambda () (module-set! m 'proc original)))))
-
(define test-json
"{
\"info\": {
--
1.7.9.5
^ permalink raw reply related [flat|nested] 8+ messages in thread
* [PATCH 4/4] import: Add CPAN importer.
2015-01-08 21:45 [PATCH 1/4] import: gnu: Propagate the key-download argument Eric Bavier
2015-01-08 21:45 ` [PATCH 2/4] import: Factorize utility functions Eric Bavier
2015-01-08 21:45 ` [PATCH 3/4] tests: import: Factorize utility function Eric Bavier
@ 2015-01-08 21:45 ` Eric Bavier
2015-01-09 13:41 ` Ludovic Courtès
2015-01-09 13:31 ` [PATCH 1/4] import: gnu: Propagate the key-download argument Ludovic Courtès
3 siblings, 1 reply; 8+ messages in thread
From: Eric Bavier @ 2015-01-08 21:45 UTC (permalink / raw)
To: guix-devel
* guix/import/cpan.scm, guix/scripts/import/cpan.scm, tests/cpan.scm:
New files.
* Makefile.am (MODULE)[guile-json]: Add them.
* guix/scripts/import.scm (importers): Add cpan.
* doc/guix.texi (Requirements): Mention `guix import cpan` as a user
of guile-json.
(Invoking guix import): Document new `guix import cpan` command.
---
Makefile.am | 8 ++-
doc/guix.texi | 24 +++++--
guix/import/cpan.scm | 160 ++++++++++++++++++++++++++++++++++++++++++
guix/scripts/import.scm | 2 +-
guix/scripts/import/cpan.scm | 91 ++++++++++++++++++++++++
tests/cpan.scm | 107 ++++++++++++++++++++++++++++
6 files changed, 385 insertions(+), 7 deletions(-)
create mode 100644 guix/import/cpan.scm
create mode 100644 guix/scripts/import/cpan.scm
create mode 100644 tests/cpan.scm
diff --git a/Makefile.am b/Makefile.am
index c2bb176..5ee7434 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -176,9 +176,13 @@ if HAVE_GUILE_JSON
MODULES += \
guix/import/json.scm \
guix/import/pypi.scm \
- guix/scripts/import/pypi.scm
+ guix/scripts/import/pypi.scm \
+ guix/import/cpan.scm \
+ guix/scripts/import/cpan.scm
-SCM_TESTS += tests/pypi.scm
+SCM_TESTS += \
+ tests/pypi.scm \
+ tests/cpan.scm
endif
diff --git a/doc/guix.texi b/doc/guix.texi
index 0073785..4d90d98 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -258,10 +258,10 @@ interest primarily for developers and not for casual users.
@item
Installing @uref{http://gnutls.org/, GnuTLS-Guile} will
allow you to access @code{https} URLs with the @command{guix download}
-command (@pxref{Invoking guix download}) and the @command{guix import
-pypi} command. This is primarily of interest to developers.
-@xref{Guile Preparations, how to install the GnuTLS bindings for Guile,,
-gnutls-guile, GnuTLS-Guile}.
+command (@pxref{Invoking guix download}), the @command{guix import pypi}
+command, and the @command{guix import cpan} command. This is primarily
+of interest to developers. @xref{Guile Preparations, how to install the
+GnuTLS bindings for Guile,, gnutls-guile, GnuTLS-Guile}.
@end itemize
Unless @code{--disable-daemon} was passed to @command{configure}, the
@@ -2958,6 +2958,22 @@ package:
guix import pypi itsdangerous
@end example
+@item cpan
+@cindex cpan
+Import meta-data from @uref{https://www.metacpan.org/, MetaCPAN}.
+Information is taken from the JSON-formatted meta-data provided through
+@uref{https://api.metacpan.org/, MetaCPAN's API} and includes most
+relevant information. License information should be checked closely.
+Package dependencies are included but may in some cases needlessly
+include core Perl modules.
+
+The command command below imports meta-data for the @code{Acme::Boolean}
+Perl module:
+
+@example
+guix import cpan Acme::Boolean
+@end example
+
@item nix
Import meta-data from a local copy of the source of the
@uref{http://nixos.org/nixpkgs/, Nixpkgs distribution}@footnote{This
diff --git a/guix/import/cpan.scm b/guix/import/cpan.scm
new file mode 100644
index 0000000..be9dc27
--- /dev/null
+++ b/guix/import/cpan.scm
@@ -0,0 +1,160 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2014 Eric Bavier <bavier@member.fsf.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix import cpan)
+ #:use-module (ice-9 match)
+ #:use-module (ice-9 regex)
+ #:use-module (srfi srfi-1)
+ #:use-module (json)
+ #:use-module (guix store)
+ #:use-module (guix base32)
+ #:use-module ((guix download) #:select (download-to-store))
+ #:use-module (guix import utils)
+ #:use-module (guix import json)
+ #:export (cpan->guix-package))
+
+(define string->license
+ (match-lambda
+ ;; List of valid values from https://metacpan.org/pod/CPAN::Meta::Spec.
+ ;; Some licenses are excluded based on their absense from (guix licenses).
+ ("agpl_3" 'agpl3)
+ ;; apache_1_1
+ ("apache_2_0" 'asl2.0)
+ ;; artistic_1_0
+ ;; artistic_2_0
+ ("bsd" 'bsd-3)
+ ("freebsd" 'bsd-2)
+ ;; gfdl_1_2
+ ("gfdl_1_3" 'fdl1.3+)
+ ("gpl_1" 'gpl1)
+ ("gpl_2" 'gpl2)
+ ("gpl_3" 'gpl3)
+ ("lgpl_2_1" 'lgpl2.1)
+ ("lgpl_3_0" 'lgpl3)
+ ("mit" 'x11)
+ ;; mozilla_1_0
+ ("mozilla_1_1" 'mpl1.1)
+ ("openssl" 'openssl)
+ ("perl_5" 'gpl1+) ;and Artistic 1
+ ("qpl_1_0" 'qpl)
+ ;; ssleay
+ ;; sun
+ ("zlib" 'zlib)
+ ((x) (string->license x))
+ ((lst ...) `(list ,@(map string->license lst)))
+ (_ #f)))
+
+(define (module->name module)
+ "Transform a 'module' name into a 'release' name"
+ (regexp-substitute/global #f "::" module 'pre "-" 'post))
+
+(define (cpan-fetch module)
+ "Return an alist representation of the CPAN metadata for the perl module NAME,
+or #f on failure. NAME should be e.g. \"Test::Script\""
+ ;; This API always returns the latest release of the module.
+ (json-fetch (string-append "http://api.metacpan.org/release/"
+ ;; XXX: The 'release' api requires the "release"
+ ;; name of the package. This substitution seems
+ ;; reasonably consistent across packages.
+ (module->name module))))
+
+(define (cpan-home name)
+ (string-append "http://search.cpan.org/dist/" name))
+
+(define (cpan-package->sexp package)
+ "Return the `package' s-expression for a python package with the given NAME,
+VERSION, SOURCE-URL, HOME-PAGE, SYNOPSIS, DESCRIPTION, and LICENSE."
+ (define name
+ (assoc-ref package "distribution"))
+
+ (define (guix-name name)
+ (if (string-prefix? "perl-" name)
+ (string-downcase name)
+ (string-append "perl-" (string-downcase name))))
+
+ (define version
+ (assoc-ref package "version"))
+
+ (define (convert-inputs phases)
+ ;; Convert phase dependencies into a list of name/variable pairs.
+ (match (flatten
+ (map (lambda (ph)
+ (filter-map (lambda (t)
+ (assoc-ref* package "metadata" "prereqs" ph t))
+ '("requires" "recommends" "suggests")))
+ phases))
+ (#f
+ '())
+ ((inputs ...)
+ (delete-duplicates
+ ;; Listed dependencies may include core modules. Filter those out.
+ (filter-map (match-lambda
+ ((or (module . "0") ("perl" . _))
+ ;; TODO: A stronger test might to run MODULE through
+ ;; `corelist' from our perl package. This current test
+ ;; seems to be only a loose convention.
+ #f)
+ ((module . _)
+ (let ((name (guix-name (module->name module))))
+ (list name
+ (list 'unquote (string->symbol name))))))
+ inputs)))))
+
+ (define (maybe-inputs guix-name inputs)
+ (match inputs
+ (()
+ '())
+ ((inputs ...)
+ (list (list guix-name
+ (list 'quasiquote inputs))))))
+
+ (define source-url
+ (regexp-substitute/global
+ #f "https://" (assoc-ref package "download_url") 'pre "http://" 'post))
+
+ (let ((tarball (with-store store
+ (download-to-store store source-url))))
+ `(package
+ (name ,(guix-name name))
+ (version ,version)
+ (source (origin
+ (method url-fetch)
+ (uri (string-append ,@(factorize-uri source-url version)))
+ (sha256
+ (base32
+ ,(bytevector->nix-base32-string (file-sha256 tarball))))))
+ (build-system perl-build-system)
+ ,@(maybe-inputs 'native-inputs
+ ;; "runtime" and "test" may also be needed here. See
+ ;; https://metacpan.org/pod/CPAN::Meta::Spec#Phases,
+ ;; which says they are required during building. We
+ ;; have not yet had a need for cross-compiled perl
+ ;; modules, however, so we leave them out.
+ (convert-inputs '("configure" "build")))
+ ,@(maybe-inputs 'inputs
+ (convert-inputs '("runtime")))
+ (home-page ,(string-append "http://search.cpan.org/dist/" name))
+ (synopsis ,(assoc-ref package "abstract"))
+ (description fill-in-yourself!)
+ (license ,(string->license (assoc-ref package "license"))))))
+
+(define (cpan->guix-package package-name)
+ "Fetch the metadata for PACKAGE-NAME from www.metacpan.org, and return the
+`package' s-expression corresponding to that package, or #f on failure."
+ (let ((package (cpan-fetch package-name)))
+ (and=> package cpan-package->sexp)))
diff --git a/guix/scripts/import.scm b/guix/scripts/import.scm
index 86ef05b..7e75c10 100644
--- a/guix/scripts/import.scm
+++ b/guix/scripts/import.scm
@@ -73,7 +73,7 @@ rather than \\n."
;;; Entry point.
;;;
-(define importers '("gnu" "nix" "pypi"))
+(define importers '("gnu" "nix" "pypi" "cpan"))
(define (resolve-importer name)
(let ((module (resolve-interface
diff --git a/guix/scripts/import/cpan.scm b/guix/scripts/import/cpan.scm
new file mode 100644
index 0000000..1f4dedf
--- /dev/null
+++ b/guix/scripts/import/cpan.scm
@@ -0,0 +1,91 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2014 Eric Bavier <bavier@member.fsf.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix scripts import cpan)
+ #:use-module (guix ui)
+ #:use-module (guix utils)
+ #:use-module (guix import cpan)
+ #:use-module (guix scripts import)
+ #:use-module (srfi srfi-1)
+ #:use-module (srfi srfi-11)
+ #:use-module (srfi srfi-37)
+ #:use-module (ice-9 match)
+ #:use-module (ice-9 format)
+ #:export (guix-import-cpan))
+
+\f
+;;;
+;;; Command-line options.
+;;;
+
+(define %default-options
+ '())
+
+(define (show-help)
+ (display (_ "Usage: guix import cpan PACKAGE-NAME
+Import and convert the CPAN package for PACKAGE-NAME.\n"))
+ (display (_ "
+ -h, --help display this help and exit"))
+ (display (_ "
+ -V, --version display version information and exit"))
+ (newline)
+ (show-bug-report-information))
+
+(define %options
+ ;; Specification of the command-line options.
+ (cons* (option '(#\h "help") #f #f
+ (lambda args
+ (show-help)
+ (exit 0)))
+ (option '(#\V "version") #f #f
+ (lambda args
+ (show-version-and-exit "guix import cpan")))
+ %standard-import-options))
+
+\f
+;;;
+;;; Entry point.
+;;;
+
+(define (guix-import-cpan . args)
+ (define (parse-options)
+ ;; Return the alist of option values.
+ (args-fold* args %options
+ (lambda (opt name arg result)
+ (leave (_ "~A: unrecognized option~%") name))
+ (lambda (arg result)
+ (alist-cons 'argument arg result))
+ %default-options))
+
+ (let* ((opts (parse-options))
+ (args (filter-map (match-lambda
+ (('argument . value)
+ value)
+ (_ #f))
+ (reverse opts))))
+ (match args
+ ((package-name)
+ (let ((sexp (cpan->guix-package package-name)))
+ (unless sexp
+ (leave (_ "failed to download meta-data for package '~a'~%")
+ package-name))
+ sexp))
+ (()
+ (leave (_ "too few arguments~%")))
+ ((many ...)
+ (leave (_ "too many arguments~%"))))))
diff --git a/tests/cpan.scm b/tests/cpan.scm
new file mode 100644
index 0000000..af7b36e
--- /dev/null
+++ b/tests/cpan.scm
@@ -0,0 +1,107 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2015 Eric Bavier <bavier@member.fsf.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (test-cpan)
+ #:use-module (guix import cpan)
+ #:use-module (guix base32)
+ #:use-module (guix hash)
+ #:use-module (guix tests)
+ #:use-module (srfi srfi-64)
+ #:use-module (ice-9 match))
+
+(define test-json
+ "{
+ \"metadata\" : {
+ \"prereqs\" : {
+ \"configure\" : {
+ \"requires\" : {
+ \"ExtUtils::MakeMaker\" : \"0\",
+ \"Module::Build\" : \"0.28\"
+ }
+ },
+ \"runtime\" : {
+ \"requires\" : {
+ \"Getopt::Std\" : \"0\",
+ \"Test::Script\" : \"1.05\",
+ }
+ }
+ }
+ \"name\" : \"Foo-Bar\",
+ \"version\" : \"0.1\"
+ }
+ \"name\" : \"Foo-Bar-0.1\",
+ \"distribution\" : \"Foo-Bar\",
+ \"license\" : [
+ \"perl_5\"
+ ],
+ \"abstract\" : \"Fizzle Fuzz\",
+ \"download_url\" : \"http://example.com/Foo-Bar-0.1.tar.gz\",
+ \"author\" : \"GUIX\",
+ \"version\" : \"0.1\"
+}")
+
+(define test-source
+ "foobar")
+
+(test-begin "cpan")
+
+(test-assert "cpan->guix-package"
+ ;; Replace network resources with sample data.
+ (mock ((guix build download) url-fetch
+ (lambda* (url file-name #:key (mirrors '()))
+ (with-output-to-file file-name
+ (lambda ()
+ (display
+ (match url
+ ("http://api.metacpan.org/release/Foo-Bar"
+ test-json)
+ ("http://example.com/Foo-Bar-0.1.tar.gz"
+ test-source)
+ (_ (error "Unexpected URL: " url))))))))
+ (match (cpan->guix-package "Foo::Bar")
+ (('package
+ ('name "perl-foo-bar")
+ ('version "0.1")
+ ('source ('origin
+ ('method 'url-fetch)
+ ('uri ('string-append "http://example.com/Foo-Bar-"
+ 'version ".tar.gz"))
+ ('sha256
+ ('base32
+ (? string? hash)))))
+ ('build-system 'perl-build-system)
+ ('native-inputs
+ ('quasiquote
+ (("perl-module-build" ('unquote 'perl-module-build)))))
+ ('inputs
+ ('quasiquote
+ (("perl-test-script" ('unquote 'perl-test-script)))))
+ ('home-page "http://search.cpan.org/dist/Foo-Bar")
+ ('synopsis "Fizzle Fuzz")
+ ('description 'fill-in-yourself!)
+ ('license 'gpl1+))
+ (string=? (bytevector->nix-base32-string
+ (call-with-input-string test-source port-sha256))
+ hash))
+ (x
+ (pk 'fail x #f)))))
+
+(test-end "cpan")
+
+\f
+(exit (= (test-runner-fail-count (test-runner-current)) 0))
--
1.7.9.5
^ permalink raw reply related [flat|nested] 8+ messages in thread
* Re: [PATCH 1/4] import: gnu: Propagate the key-download argument.
2015-01-08 21:45 [PATCH 1/4] import: gnu: Propagate the key-download argument Eric Bavier
` (2 preceding siblings ...)
2015-01-08 21:45 ` [PATCH 4/4] import: Add CPAN importer Eric Bavier
@ 2015-01-09 13:31 ` Ludovic Courtès
3 siblings, 0 replies; 8+ messages in thread
From: Ludovic Courtès @ 2015-01-09 13:31 UTC (permalink / raw)
To: Eric Bavier; +Cc: guix-devel
Eric Bavier <ericbavier@gmail.com> skribis:
> * guix/import/gnu.scm (gnu->guix-package): Pass the key-download
> argument on to gnu-package->sexp.
OK! Good catch.
Ludo'.
^ permalink raw reply [flat|nested] 8+ messages in thread
* Re: [PATCH 2/4] import: Factorize utility functions.
2015-01-08 21:45 ` [PATCH 2/4] import: Factorize utility functions Eric Bavier
@ 2015-01-09 13:36 ` Ludovic Courtès
0 siblings, 0 replies; 8+ messages in thread
From: Ludovic Courtès @ 2015-01-09 13:36 UTC (permalink / raw)
To: Eric Bavier; +Cc: guix-devel
Eric Bavier <ericbavier@gmail.com> skribis:
> * guix/import/pypi.scm (hash-table->alist, flatten, assoc-ref*,
> url-fetch, json-fetch): Pull functions from here and...
> * guix/import/gnu.scm (file-sha256): here out into...
> * guix/import/utils.scm: Here, and...
> * guix/import/json.scm: Here. New file.
> * Makefile.am (MODULE)[guile-json]: Add it.
Should be:
* Makefile.am (MODULES)[HAVE_GUILE_JSON]: Add it.
> * tests/pypi.scm (pypi->guix-package): Update mock module reference.
LGTM, but could you move ‘file-sha256’ to (guix hash) instead, below
‘port-sha256’?
> --- a/guix/import/gnu.scm
> +++ b/guix/import/gnu.scm
> @@ -1,4 +1,4 @@
> -;;; GNU Guix --- Functional package management for GNU
> +;; GNU Guix --- Functional package management for GNU
Typo.
Thanks,
Ludo’.
^ permalink raw reply [flat|nested] 8+ messages in thread
* Re: [PATCH 3/4] tests: import: Factorize utility function.
2015-01-08 21:45 ` [PATCH 3/4] tests: import: Factorize utility function Eric Bavier
@ 2015-01-09 13:37 ` Ludovic Courtès
0 siblings, 0 replies; 8+ messages in thread
From: Ludovic Courtès @ 2015-01-09 13:37 UTC (permalink / raw)
To: Eric Bavier; +Cc: guix-devel
Eric Bavier <ericbavier@gmail.com> skribis:
> * tests/pypi.scm (mock): Move this...
> * guix/tests.scm: to here.
OK!
Ludo’.
^ permalink raw reply [flat|nested] 8+ messages in thread
* Re: [PATCH 4/4] import: Add CPAN importer.
2015-01-08 21:45 ` [PATCH 4/4] import: Add CPAN importer Eric Bavier
@ 2015-01-09 13:41 ` Ludovic Courtès
0 siblings, 0 replies; 8+ messages in thread
From: Ludovic Courtès @ 2015-01-09 13:41 UTC (permalink / raw)
To: Eric Bavier; +Cc: guix-devel
Eric Bavier <ericbavier@gmail.com> skribis:
> * guix/import/cpan.scm, guix/scripts/import/cpan.scm, tests/cpan.scm:
> New files.
> * Makefile.am (MODULE)[guile-json]: Add them.
> * guix/scripts/import.scm (importers): Add cpan.
> * doc/guix.texi (Requirements): Mention `guix import cpan` as a user
> of guile-json.
> (Invoking guix import): Document new `guix import cpan` command.
[...]
> +@item cpan
> +@cindex cpan
@cindex CPAN
> +(define-module (guix import cpan)
> + #:use-module (ice-9 match)
> + #:use-module (ice-9 regex)
> + #:use-module (srfi srfi-1)
> + #:use-module (json)
> + #:use-module (guix store)
> + #:use-module (guix base32)
> + #:use-module ((guix download) #:select (download-to-store))
> + #:use-module (guix import utils)
> + #:use-module (guix import json)
> + #:export (cpan->guix-package))
Could you add a short description in a “Commentary:” block?
Very nice, thank you!
Ludo’.
^ permalink raw reply [flat|nested] 8+ messages in thread
end of thread, other threads:[~2015-01-09 13:41 UTC | newest]
Thread overview: 8+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2015-01-08 21:45 [PATCH 1/4] import: gnu: Propagate the key-download argument Eric Bavier
2015-01-08 21:45 ` [PATCH 2/4] import: Factorize utility functions Eric Bavier
2015-01-09 13:36 ` Ludovic Courtès
2015-01-08 21:45 ` [PATCH 3/4] tests: import: Factorize utility function Eric Bavier
2015-01-09 13:37 ` Ludovic Courtès
2015-01-08 21:45 ` [PATCH 4/4] import: Add CPAN importer Eric Bavier
2015-01-09 13:41 ` Ludovic Courtès
2015-01-09 13:31 ` [PATCH 1/4] import: gnu: Propagate the key-download argument Ludovic Courtès
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/guix.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).