bug#26432: image-dired: Adding support for PDF thumbnails.

bug#26432: image-dired: Adding support for PDF thumbnails.

[Keith David Bershatsky]

I posted the following answer on emacs.stackexchange.com, which adds the ability to display thumbnail images in image-dired:

http://emacs.stackexchange.com/questions/18151/thumbnail-previews-of-pdf-files

The Emacs team may wish to consider adding this ability at some point in the future:

(require 'image-dired)

;;; The `-flatten` argument makes a transparent PNG background white.
(setq image-dired-cmd-create-thumbnail-options
  "%p -size %wx%h \"%f\" -resize \"%wx%h>\" -flatten -strip jpeg:\"%t\"")

(defun image-dired-get-thumbnail-image (file)
  "Return the image descriptor for a thumbnail of image file FILE."
  (unless (or (string-match (image-file-name-regexp) file)
              (string-match "\\.\\(PDF\\)\\'" file))
    (error "%s is not a valid image file" file))
  (let ((thumb-file (image-dired-thumb-name file)))
    (unless (and (file-exists-p thumb-file)
     (<= (float-time (nth 5 (file-attributes file)))
         (float-time (nth 5 (file-attributes thumb-file)))))
      (image-dired-create-thumb file thumb-file))
    (create-image thumb-file)))

(defun image-dired-dired-toggle-marked-thumbs (&optional arg)
  "Toggle thumbnails in front of file names in the dired buffer.
If no marked file could be found, insert or hide thumbnails on the
current line.  ARG, if non-nil, specifies the files to use instead
of the marked files.  If ARG is an integer, use the next ARG (or
previous -ARG, if ARG<0) files."
  (interactive "P")
  (dired-map-over-marks
   (let* ((image-pos  (dired-move-to-filename))
          (image-file (dired-get-filename nil t))
          thumb-file
          overlay)
     (when (and image-file
                (or (string-match-p (image-file-name-regexp) image-file)
                    (string-match-p "\\.\\(PDF\\)\\'" image-file)))
       (setq thumb-file (image-dired-get-thumbnail-image image-file))
       ;; If image is not already added, then add it.
       (let* ((cur-ovs (overlays-in (point) (1+ (point))))
              (thumb-ov (car (cl-remove-if-not
                              (lambda (ov) (overlay-get ov 'thumb-file))
                              cur-ovs))))
         (if thumb-ov
             (delete-overlay thumb-ov)
     (put-image thumb-file image-pos)
     (setq overlay
                 (cl-loop for o in (overlays-in (point) (1+ (point)))
                          when (overlay-get o 'put-image) collect o into ov
                          finally return (car ov)))
     (overlay-put overlay 'image-file image-file)
     (overlay-put overlay 'thumb-file thumb-file)))))
   arg             ; Show or hide image on ARG next files.
   'show-progress) ; Update dired display after each image is updated.
  (add-hook 'dired-after-readin-hook
            'image-dired-dired-after-readin-hook nil t))

(defun image-dired-display-thumbs (&optional arg append do-not-pop)
  "Display thumbnails of all marked files, in `image-dired-thumbnail-buffer'.
If a thumbnail image does not exist for a file, it is created on the
fly.  With prefix argument ARG, display only thumbnail for file at
point (this is useful if you have marked some files but want to show
another one).

Recommended usage is to split the current frame horizontally so that
you have the dired buffer in the left window and the
`image-dired-thumbnail-buffer' buffer in the right window.

With optional argument APPEND, append thumbnail to thumbnail buffer
instead of erasing it first.

Optional argument DO-NOT-POP controls if `pop-to-buffer' should be
used or not.  If non-nil, use `display-buffer' instead of
`pop-to-buffer'.  This is used from functions like
`image-dired-next-line-and-display' and
`image-dired-previous-line-and-display' where we do not want the
thumbnail buffer to be selected."
  (interactive "P")
  (let ((buf (image-dired-create-thumbnail-buffer))
        thumb-name files dired-buf)
    (if arg
        (setq files (list (dired-get-filename)))
      (setq files (dired-get-marked-files)))
    (setq dired-buf (current-buffer))
    (with-current-buffer buf
      (let ((inhibit-read-only t))
        (if (not append)
            (erase-buffer)
          (goto-char (point-max)))
        (mapc
         (lambda (curr-file)
           (cond
             ((string-match (image-file-name-regexp) curr-file)
               (setq thumb-name (image-dired-thumb-name curr-file))
               (if (and (not (file-exists-p thumb-name))
                        (not (= 0 (image-dired-create-thumb
                                    curr-file thumb-name))))
                   (message "Thumb could not be created for file %s" curr-file)
                 (image-dired-insert-thumbnail thumb-name curr-file dired-buf)))
             ((string-match "\\.\\(PDF\\)\\'" curr-file)
               ;;; convert source.pdf[0] output.jpeg
               ;;; You can also select ranges, e.g., using source.pdf[0-3].
               (let* ((absolute-basename (file-name-sans-extension curr-file))
                      (png-filename (concat absolute-basename ".png"))
                      (pdf-first-page-filename (concat curr-file "[0]"))
                      (thumb-name (image-dired-thumb-name png-filename)))
                 (if (and (not (file-exists-p thumb-name))
                          (not (= 0 (image-dired-create-thumb
                                      pdf-first-page-filename thumb-name))))
                     (message "Thumb could not be created for file %s"
                              pdf-first-page-filename)
                   (image-dired-insert-thumbnail
                      thumb-name pdf-first-page-filename dired-buf))))
             (t
               (message "%s does not match `image-file-name-regexp'."
                        curr-file))))
         files))
      (cond ((eq 'dynamic image-dired-line-up-method)
             (image-dired-line-up-dynamic))
            ((eq 'fixed image-dired-line-up-method)
             (image-dired-line-up))
            ((eq 'interactive image-dired-line-up-method)
             (image-dired-line-up-interactive))
            ((eq 'none image-dired-line-up-method)
             nil)
            (t
             (image-dired-line-up-dynamic))))
    (if do-not-pop
        (display-buffer image-dired-thumbnail-buffer)
      (pop-to-buffer image-dired-thumbnail-buffer))))

(defun image-dired-show-all-from-dir (dir)
  "Make a preview buffer for all images in DIR and display it.
If the number of files in DIR matching `image-file-name-regexp'
exceeds `image-dired-show-all-from-dir-max-files', a warning will be
displayed."
  (interactive "DDir: ")
  (dired dir)
  (dired-mark-files-regexp (image-file-name-regexp))
  (dired-mark-files-regexp "\\.\\(PDF\\)\\'")
  (let ((files (dired-get-marked-files)))
    (if (or (<= (length files) image-dired-show-all-from-dir-max-files)
            (and (> (length files) image-dired-show-all-from-dir-max-files)
                 (y-or-n-p
                  (format
                   "Directory contains more than %d image files.  Proceed? "
                   image-dired-show-all-from-dir-max-files))))
        (progn
          (image-dired-display-thumbs)
          (pop-to-buffer image-dired-thumbnail-buffer))
      (message "Canceled."))))

bug#26432: Acknowledgement (image-dired: Adding support for PDF thumbnails.)

[Keith David Bershatsky]

In my own setup, I added the ability to detect the image size of the thumbnails and compare it to the current value of the image-dired width/height variables so that a new thumbnail will be created if the width/height of a stored cache thumbnail is different the current call.  For example, multiple thumbnails might be 100 pixels, but perhaps I want to see an 800 thumbnail of just the selected file.  This modification enables me to change the thumbnail image programmatically:

(defun image-dimensions (filename)
  (let* ((convert-program image-dired-cmd-create-thumbnail-program)
         (raw-dimensions
           (shell-command-to-string
             (concat convert-program " " "\"" filename "\"" " -ping -format \"%w x %h\" info:")))
         (list-dimensions
           (delete "x" (split-string raw-dimensions))))
    (cons
      (string-to-number (car list-dimensions))
      (string-to-number (cadr list-dimensions)))))

;;; ALTERNATIVE VERSION:

(defun image-dired-display-thumbs (&optional arg append do-not-pop)
  "Display thumbnails of all marked files, in `image-dired-thumbnail-buffer'.
If a thumbnail image does not exist for a file, it is created on the
fly.  With prefix argument ARG, display only thumbnail for file at
point (this is useful if you have marked some files but want to show
another one).

Recommended usage is to split the current frame horizontally so that
you have the dired buffer in the left window and the
`image-dired-thumbnail-buffer' buffer in the right window.

With optional argument APPEND, append thumbnail to thumbnail buffer
instead of erasing it first.

Optional argument DO-NOT-POP controls if `pop-to-buffer' should be
used or not.  If non-nil, use `display-buffer' instead of
`pop-to-buffer'.  This is used from functions like
`image-dired-next-line-and-display' and
`image-dired-previous-line-and-display' where we do not want the
thumbnail buffer to be selected."
  (interactive "P")
  (let ((buf (image-dired-create-thumbnail-buffer))
        thumb-name files dired-buf)
    (if arg
        (setq files (list (dired-get-filename)))
      (setq files (dired-get-marked-files)))
    (setq dired-buf (current-buffer))
    (with-current-buffer buf
      (let ((inhibit-read-only t))
        (if (not append)
            (erase-buffer)
          (goto-char (point-max)))
        (mapc
         (lambda (curr-file)
           (cond
             ((string-match (image-file-name-regexp) curr-file)
               (let* ((thumb-name (image-dired-thumb-name curr-file))
                      (thumbnail-dimensions
                        (when (file-exists-p thumb-name)
                          (image-dimensions thumb-name))))
                 (if (and
                        ;;; The goal is to move on to `image-dired-create-thumb' IF
                        ;;; the thumbnail exists and is the wrong size, or it does not exist.
                        (or (and (file-exists-p thumb-name)
                                 (not (or (= image-dired-thumb-width
                                             (car thumbnail-dimensions))
                                          (= image-dired-thumb-height
                                             (cdr thumbnail-dimensions))))
                                 (progn
                                   (clear-image-cache)
                                   'create-new-image))
                            (not (file-exists-p thumb-name)))
                        (not (= 0 (image-dired-create-thumb curr-file thumb-name))))
                   (message "Thumb could not be created for file %s" curr-file)
                   (image-dired-insert-thumbnail thumb-name curr-file dired-buf))))
             ((string-match "\\.\\(PDF\\)\\'" curr-file)
               (let* ((absolute-basename (file-name-sans-extension curr-file))
                      (png-filename (concat absolute-basename ".png"))
                      (pdf-first-page-filename (concat curr-file "[0]"))
                      (thumb-name (image-dired-thumb-name png-filename))
                      (thumbnail-dimensions
                        (when (file-exists-p thumb-name)
                          (image-dimensions thumb-name))))
                 (if (and
                        ;;; The goal is to move on to `image-dired-create-thumb' IF
                        ;;; the thumbnail exists and is the wrong size, or it does not exist.
                        (or (and (file-exists-p thumb-name)
                                 (not (or (= image-dired-thumb-width
                                             (car thumbnail-dimensions))
                                          (= image-dired-thumb-height
                                             (cdr thumbnail-dimensions))))
                                 (progn
                                   (clear-image-cache)
                                   'create-new-image))
                            (not (file-exists-p thumb-name)))
                        (not (= 0 (image-dired-create-thumb pdf-first-page-filename thumb-name))))
                     (message "Thumb could not be created for file %s" pdf-first-page-filename)
                   (image-dired-insert-thumbnail thumb-name pdf-first-page-filename dired-buf))))
             (t
               (message "%s does not match `image-file-name-regexp'" curr-file))))
         files))
      (cond ((eq 'dynamic image-dired-line-up-method)
             (image-dired-line-up-dynamic))
            ((eq 'fixed image-dired-line-up-method)
             (image-dired-line-up))
            ((eq 'interactive image-dired-line-up-method)
             (image-dired-line-up-interactive))
            ((eq 'none image-dired-line-up-method)
             nil)
            (t
             (image-dired-line-up-dynamic))))
    (if do-not-pop
        (display-buffer image-dired-thumbnail-buffer)
      (pop-to-buffer image-dired-thumbnail-buffer))))

bug#26432: Acknowledgement (image-dired: Adding support for PDF thumbnails.)

[Glenn Morris]

Thanks. You can increase the chances of this being applied by sending it
as a patch (preferably against the latest version of Emacs from git),
and including the necessary commit message.

Please note that if the changes are more than about 10 lines, a
copyright assignment would be needed.

See
https://www.gnu.org/software/emacs/manual/html_node/emacs/Contributing.html
and references therein for more information.

bug#26432: Acknowledgement (image-dired: Adding support for PDF thumbnails.)

[Lars Ingebrigtsen]

Glenn Morris <rgm@gnu.org> writes:

> Thanks. You can increase the chances of this being applied by sending it
> as a patch (preferably against the latest version of Emacs from git),
> and including the necessary commit message.
>
> Please note that if the changes are more than about 10 lines, a
> copyright assignment would be needed.
>
> See
> https://www.gnu.org/software/emacs/manual/html_node/emacs/Contributing.html
> and references therein for more information.

Keith, did you look into sending the change as a patch, and doing
copyright assignments?  Otherwise it's unlikely that this feature is
going to be added to Emacs.

-- 
(domestic pets only, the antidote for overdose, milk.)
   bloggy blog: http://lars.ingebrigtsen.no

bug#26432: Acknowledgement (image-dired: Adding support for PDF thumbnails.)

[Keith David Bershatsky]

Thank you Lars and Glenn for looking into tracker #26432.  I would be pleased to look at this again in the coming days and see what changes I made to the functions at issue to enable this particular feature.  My guess is that I only added a few lines of code to existing functions.

Drew:  I hope it is okay for me to add you to this discussion .....  In your dired+ adventures, have you already added support for displaying thumbnails of PDF files?

Keith

On Sep 29, 2019, at 5:11 AM, Lars Ingebrigtsen wrote:

> Glenn Morris <rgm@gnu.org> writes:
> 
>> Thanks. You can increase the chances of this being applied by sending it
>> as a patch (preferably against the latest version of Emacs from git),
>> and including the necessary commit message.
>> 
>> Please note that if the changes are more than about 10 lines, a
>> copyright assignment would be needed.
>> 
>> See
>> https://www.gnu.org/software/emacs/manual/html_node/emacs/Contributing.html
>> and references therein for more information.
> 
> Keith, did you look into sending the change as a patch, and doing
> copyright assignments?  Otherwise it's unlikely that this feature is
> going to be added to Emacs.
> 
> -- 
> (domestic pets only, the antidote for overdose, milk.)
>   bloggy blog: http://lars.ingebrigtsen.no

bug#26432: Acknowledgement (image-dired: Adding support for PDF thumbnails.)

[Lars Ingebrigtsen]

Keith David Bershatsky <esq@lawlist.com> writes:

> Thank you Lars and Glenn for looking into tracker #26432.  I would be
> pleased to look at this again in the coming days and see what changes
> I made to the functions at issue to enable this particular feature.
> My guess is that I only added a few lines of code to existing
> functions.

Did you make any progress here?

-- 
(domestic pets only, the antidote for overdose, milk.)
   bloggy blog: http://lars.ingebrigtsen.no

bug#26432: Acknowledgement (image-dired: Adding support for PDF thumbnails.)

[Keith David Bershatsky]

[-- Attachment #1: Type: text/plain, Size: 2759 bytes --]

The attached proof concept patch applies to the master branch as of 10/23/2019 bearing commit 53e7a763dd16509d90418bdf14d161db13271ea3.

I spent a couple of hours today fiddling around with a current version of image-dired.el, but I was not able to figure out how to get feature 26432 to work properly.  My problems had something do with the need for a return value from image-dired-create-thumb and the old way of doing things processed subprocesses consecutively using call-process, whereas the current way of doing things uses start-process and run-at-time ....  After unsuccessfully spinning my wheels, I went ahead and reverted the relevant functions in image-dired to where it was several years ago so that I could still use call-process and get a return value from image-dired-create-thumb; e.g., things like:

  (not (= 0 (image-dired-create-thumb file thumb-name)))

and

  (not (= 0 (image-dired-create-thumb curr-file thumb-name)))

I performed the following tests after applying the attached patch:

M-x image-dired:  On a directory containing a few PDF, PNG, JPG files.

M-x image-dired-dired-toggle-marked-thumbs:  In a dired-mode buffer containing a few PDF, PNG, JPG files.

In an *image-dired* buffer, move the cursor to different images and watch the files selection change in the corresponding dired-mode buffer.

In an *image-dired* buffer, press the enter key on an image and watch an *image-dired-display-image* buffer open with a larger image.

I understand that the Emacs development team would prefer a patch that uses the current system of start-process and run-at-time; however, that would likely take me several more hours to figure out.  In terms of me signing Emacs copyright papers and so forth, I would be happy to do that whenever the Emacs development team feels that I have a contribution that rises to a programming level worthy of Emacs.  At this time, my proof concept patch is far from being ready for production ....

Keith

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

> Date: [10-23-2019 03:03:29] <23 Oct 2019 12:03:29 +0200>
> From: Lars Ingebrigtsen <larsi@gnus.org>
> To: Keith David Bershatsky <esq@lawlist.com>
> Cc: Drew Adams <drew.adams@oracle.com>, 26432@debbugs.gnu.org, Glenn Morris <rgm@gnu.org>
> Subject: Re: bug#26432: Acknowledgement (image-dired: Adding support for PDF thumbnails.)
> 
> Keith David Bershatsky <esq@lawlist.com> writes:
> 
> > Thank you Lars and Glenn for looking into tracker #26432.  I would be
> > pleased to look at this again in the coming days and see what changes
> > I made to the functions at issue to enable this particular feature.
> > My guess is that I only added a few lines of code to existing
> > functions.
> 
> Did you make any progress here?


[-- Attachment #2: 2019_10_23__20_00_17_777.diff --]
[-- Type: application/diff, Size: 17594 bytes --]

bug#26432: Acknowledgement (image-dired: Adding support for PDF thumbnails.)

[Lars Ingebrigtsen]

Keith David Bershatsky <esq@lawlist.com> writes:

> I understand that the Emacs development team would prefer a patch that
> uses the current system of start-process and run-at-time; however,
> that would likely take me several more hours to figure out.

Yeah, I think it would be better to try to use the current scaffolding.

> In terms of me signing Emacs copyright papers and so forth, I would be
> happy to do that whenever the Emacs development team feels that I have
> a contribution that rises to a programming level worthy of Emacs.  At
> this time, my proof concept patch is far from being ready for
> production ....

But signing papers now doesn't -- it just makes things ready for a
future contribution.  I'll send you the form to get started off-list.

-- 
(domestic pets only, the antidote for overdose, milk.)
   bloggy blog: http://lars.ingebrigtsen.no

bug#26432: Acknowledgement (image-dired: Adding support for PDF thumbnails.)

[Lars Ingebrigtsen]

Lars Ingebrigtsen <larsi@gnus.org> writes:

> Keith David Bershatsky <esq@lawlist.com> writes:
>
>> I understand that the Emacs development team would prefer a patch that
>> uses the current system of start-process and run-at-time; however,
>> that would likely take me several more hours to figure out.
>
> Yeah, I think it would be better to try to use the current scaffolding.

Did you make any further progress here?  If I understand things
correctly, previously the thumbnail creation was more synchronous (with
call-process), and that made some times easier to work with, but
I think an asynchronous interface makes for a better user experience.

-- 
(domestic pets only, the antidote for overdose, milk.)
   bloggy blog: http://lars.ingebrigtsen.no

bug#26432: image-dired: Adding support for PDF thumbnails.

[Stefan Kangas]

Lars Ingebrigtsen <larsi@gnus.org> writes:

> Lars Ingebrigtsen <larsi@gnus.org> writes:
>
>> Keith David Bershatsky <esq@lawlist.com> writes:
>>
>>> I understand that the Emacs development team would prefer a patch that
>>> uses the current system of start-process and run-at-time; however,
>>> that would likely take me several more hours to figure out.
>>
>> Yeah, I think it would be better to try to use the current scaffolding.
>
> Did you make any further progress here?  If I understand things
> correctly, previously the thumbnail creation was more synchronous (with
> call-process), and that made some times easier to work with, but
> I think an asynchronous interface makes for a better user experience.

That was one year ago, so here's another friendly ping.

bug#26432: image-dired: Adding support for PDF thumbnails.

[Stefan Kangas]

Lars Ingebrigtsen <larsi@gnus.org> writes:

>> In terms of me signing Emacs copyright papers and so forth, I would be
>> happy to do that whenever the Emacs development team feels that I have
>> a contribution that rises to a programming level worthy of Emacs.  At
>> this time, my proof concept patch is far from being ready for
>> production ....
>
> But signing papers now doesn't -- it just makes things ready for a
> future contribution.  I'll send you the form to get started off-list.

Where are we at with the papers here?

bug#26432: image-dired: Adding support for PDF thumbnails.

[Keith David Bershatsky]

[-- Attachment #1: Type: text/plain, Size: 1090 bytes --]

Thank you, Stefan, for following up on the copyright assignment.  My records indicate that this was handled on 10/31/2019 -- see attached.

Keith

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

> Date: [09-15-2022 17:39:18] <15 Sep 2022 17:39:18 -0700>
> From: Stefan Kangas <stefankangas@gmail.com>
> To: Lars Ingebrigtsen <larsi@gnus.org>
> Cc: Keith David Bershatsky <esq@lawlist.com>, 26432@debbugs.gnu.org, Glenn Morris <rgm@gnu.org>
> Subject: Re: bug#26432: image-dired: Adding support for PDF thumbnails.
> 
> Lars Ingebrigtsen <larsi@gnus.org> writes:
> 
> >> In terms of me signing Emacs copyright papers and so forth, I would be
> >> happy to do that whenever the Emacs development team feels that I have
> >> a contribution that rises to a programming level worthy of Emacs.  At
> >> this time, my proof concept patch is far from being ready for
> >> production ....
> >
> > But signing papers now doesn't -- it just makes things ready for a
> > future contribution.  I'll send you the form to get started off-list.
> 
> Where are we at with the papers here?


[-- Attachment #2: 0.emacs_copyright_assignment.pdf --]
[-- Type: application/pdf, Size: 222245 bytes --]

bug#26432: image-dired: Adding support for PDF thumbnails.

[Eli Zaretskii]

> Cc: 26432@debbugs.gnu.org, Glenn Morris <rgm@gnu.org>,
>  Lars Ingebrigtsen <larsi@gnus.org>
> Date: Thu, 15 Sep 2022 20:21:09 -0700
> From: Keith David Bershatsky <esq@lawlist.com>
> 
> Thank you, Stefan, for following up on the copyright assignment.  My records indicate that this was handled on 10/31/2019 -- see attached.

Yes, Keith's copyright assignment is on file.

bug#26432: image-dired: Adding support for PDF thumbnails.

[Stefan Kangas]

tags 26432 + pending
thanks

Keith David Bershatsky <esq@lawlist.com> writes:

> I posted the following answer on emacs.stackexchange.com, which adds
> the ability to display thumbnail images in image-dired:
>
> http://emacs.stackexchange.com/questions/18151/thumbnail-previews-of-pdf-files
>
> The Emacs team may wish to consider adding this ability at some point in the future:

I took a look at your patch, but I think adding PDF support could
actually be done in an easier way.  So I implemented it in a different
way on master (commit aaf39c3878).

Could you please test and see if it works for you?

Thanks in advance.

bug#26432: image-dired: Adding support for PDF thumbnails.

[Stefan Kangas]

close 26432 29.1
thanks

Stefan Kangas <stefankangas@gmail.com> writes:

> Could you please test and see if it works for you?

Other users have reported that it works for them too (with some
changes).  See Bug#57961.

I'm therefore closing this bug report.  If you see any issues, please
reply to this email (use "Reply to all") and I will reopen.