1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
| | ;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2024 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2024 Giacomo Leidi <goodoldpaul@autistici.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (gnu home services dotfiles)
#:use-module (gnu home services)
#:use-module (gnu services)
#:use-module (gnu services configuration)
#:autoload (guix build utils) (find-files)
#:use-module (guix diagnostics)
#:use-module (guix gexp)
#:use-module (guix i18n)
#:use-module ((guix utils) #:select (current-source-directory))
#:use-module (srfi srfi-1)
#:use-module (ice-9 ftw)
#:use-module (ice-9 match)
#:use-module (ice-9 regex)
#:export (home-dotfiles-service-type
home-dotfiles-configuration->files
home-dotfiles-stow-directory
home-dotfiles-stow-directory?
home-dotfiles-stow-directory-fields
home-dotfiles-stow-directory-name
home-dotfiles-stow-directory-applications
home-dotfiles-plain-directory
home-dotfiles-plain-directory?
home-dotfiles-plain-directory-fields
home-dotfiles-plain-directory-name
home-dotfiles-configuration
home-dotfiles-configuration?
home-dotfiles-configuration-fields
home-dotfiles-configuration-source-directory
home-dotfiles-configuration-directories
home-dotfiles-configuration-excluded))
(define %home-dotfiles-excluded
'(".*~"
".*\\.swp"
"\\.git"
"\\.gitignore"))
(define list-of-strings?
(list-of string?))
(define-maybe list-of-strings)
(define-configuration/no-serialization home-dotfiles-stow-directory
(name
(string)
"The name of the dotfile directory where @code{home-dotfiles-service-type}
will look for application dotfiles.")
(applications
(maybe-list-of-strings)
"A subset of the names of the application layer directories. When provided
the @code{home-dotfiles-service-type} will only provision dotfiles from this
subset of applications."))
(define-configuration/no-serialization home-dotfiles-plain-directory
(name
(string)
"The name of the dotfile directory where @code{home-dotfiles-service-type}
will look for plain dotfiles."))
(define (list-of-plain-or-stow-directories? value)
(unless (list? value)
(raise
(formatted-message
(G_ "directories field of home-dotfiles-configuration should be a list but
~a was found.")
value)))
(for-each
(lambda (d)
(unless (or (home-dotfiles-plain-directory? d)
(home-dotfiles-stow-directory? d))
(raise
(formatted-message
(G_ "directories field of home-dotfiles-configuration should contain
only home-dotfiles-plain-directory or home-dotfiles-stow-directory records, but
~a was found.")
d))))
value))
(define-configuration/no-serialization home-dotfiles-configuration
(source-directory
(string (current-source-directory))
"The path where dotfile directories are resolved. By default dotfile
directories are resolved relative the source location where
@code{home-dotfiles-configuration} appears.")
(directories
(list-of-plain-or-stow-directories '())
"The list of dotfiles directories where @code{home-dotfiles-service-type}
will look for application dotfiles. Each element of the list is supposed to be
either a @code{home-dotfiles-plain-directory} or a
@code{home-dotfiles-stow-directory} record.")
(excluded
(list-of-strings %home-dotfiles-excluded)
"The list of file patterns @code{home-dotfiles-service-type} will exclude
while visiting each one of the @code{directories}."))
(define (strip-stow-dotfile file-name directory)
(let ((dotfile-name (string-drop file-name (1+ (string-length directory)))))
(match (string-split dotfile-name #\/)
((package parts ...)
(string-join parts "/")))))
(define (strip-plain-dotfile file-name directory)
(string-drop file-name (+ 1 (string-length directory))))
(define (import-dotfiles directory files strip)
"Return a list of objects compatible with @code{home-files-service-type}'s
value. Each object is a pair where the first element is the relative path
of a file and the second is a gexp representing the file content. Objects are
generated by recursively visiting DIRECTORY and mapping its contents to the
user's home directory, excluding files that match any of the patterns in EXCLUDED."
(define (format file)
;; Remove from FILE characters that cannot be used in the store.
(string-append
"home-dotfiles-"
(string-map (lambda (chr)
(if (and (char-set-contains? char-set:ascii chr)
(char-set-contains? char-set:graphic chr)
(not (memv chr '(#\. #\/ #\space))))
chr
#\-))
file)))
(map (lambda (file)
(let ((stripped (strip file directory)))
(list stripped
(local-file file (format stripped)
#:recursive? #t))))
files))
(define (home-dotfiles-configuration->files config)
"Return a list of objects compatible with @code{home-files-service-type}'s
value, generated following GNU Stow's algorithm for each of the
directories in CONFIG, excluding files that match any of the patterns configured."
(define excluded
(home-dotfiles-configuration-excluded config))
(define exclusion-rx
(make-regexp (string-append "^.*(" (string-join excluded "|") ")$")))
(define* (directory-contents directory #:key (applications #f))
(define (filter-files directory)
(find-files directory
(lambda (file stat)
(not (regexp-exec exclusion-rx
(basename file))))))
(if applications
(append-map filter-files
(map (lambda (app)
(string-append directory "/" app))
applications))
(filter-files directory)))
(define (resolve directory)
;; Resolve DIRECTORY relative to the 'source-directory' field of CONFIG.
(if (string-prefix? "/" directory)
directory
(in-vicinity (home-dotfiles-configuration-source-directory config)
directory)))
(append-map (lambda (record)
(let* ((name (if (home-dotfiles-plain-directory? record)
(home-dotfiles-plain-directory-name record)
(home-dotfiles-stow-directory-name record)))
(strip (if (home-dotfiles-plain-directory? record)
strip-plain-dotfile
strip-stow-dotfile))
(applications
(and (home-dotfiles-stow-directory? record)
(let ((apps
(home-dotfiles-stow-directory-applications
record)))
(and (maybe-value-set? apps) apps))))
(directory (resolve name))
(contents
(directory-contents directory
#:applications applications)))
(import-dotfiles directory contents strip)))
(home-dotfiles-configuration-directories config)))
(define-public home-dotfiles-service-type
(service-type (name 'home-dotfiles)
(extensions
(list (service-extension home-files-service-type
home-dotfiles-configuration->files)))
(default-value (home-dotfiles-configuration))
(description "Files that will be put in the user's home directory
following GNU Stow's algorithm, and further processed during activation.")))
|