1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
| | ;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2021 Xinglu Chen <public@yoctocell.xyz>
;;; Copyright © 2021 Andrew Tropin <andrew@trop.in>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (gnu home services utils)
#:use-module (ice-9 string-fun)
#:use-module (srfi srfi-1)
#:use-module (srfi srfi-26)
#:use-module (ice-9 match)
#:use-module (gnu services configuration)
#:export (maybe-object->string
object->snake-case-string
object->camel-case-string
list->human-readable-list
ini-config?
generic-serialize-ini-config
generic-serialize-git-ini-config))
(define (maybe-object->string object)
"Like @code{object->string} but don't do anyting if OBJECT already is
a string."
(if (string? object)
object
(object->string object)))
;; Snake case: <https://en.wikipedia.org/wiki/Snake_case>
(define* (object->snake-case-string object #:optional (style 'lower))
"Convert the object OBJECT to the equivalent string in ``snake
case''. STYLE can be three `@code{lower}', `@code{upper}', or
`@code{capitalize}', defaults to `@code{lower}'.
@example
(object->snake-case-string 'variable-name 'upper)
@result{} \"VARIABLE_NAME\" @end example"
(if (not (member style '(lower upper capitalize)))
(error 'invalid-style (format #f "~a is not a valid style" style))
(let ((stringified (maybe-object->string object)))
(string-replace-substring
(cond
((equal? style 'lower) stringified)
((equal? style 'upper) (string-upcase stringified))
(else (string-capitalize stringified)))
"-" "_"))))
(define* (object->camel-case-string object #:optional (style 'lower))
"Convert the object OBJECT to the equivalent string in ``camel case''.
STYLE can be three `@code{lower}', `@code{upper}', defaults to
`@code{lower}'.
@example
(object->camel-case-string 'variable-name 'upper)
@result{} \"VariableName\"
@end example"
(if (not (member style '(lower upper)))
(error 'invalid-style (format #f "~a is not a valid style" style))
(let ((stringified (maybe-object->string object)))
(cond
((eq? style 'upper)
(string-concatenate
(map string-capitalize
(string-split stringified (cut eqv? <> #\-)))))
((eq? style 'lower)
(let ((splitted-string (string-split stringified (cut eqv? <> #\-))))
(string-concatenate
(cons (first splitted-string)
(map string-capitalize
(cdr splitted-string))))))))))
(define* (list->human-readable-list lst
#:key
(cumulative? #f)
(proc identity))
"Turn a list LST into a sequence of terms readable by humans.
If CUMULATIVE? is @code{#t}, use ``and'', otherwise use ``or'' before
the last term.
PROC is a procedure to apply to each of the elements of a list before
turning them into a single human readable string.
@example
(list->human-readable-list '(1 4 9) #:cumulative? #t #:proc sqrt)
@result{} \"1, 2, and 3\"
@end example
yields:"
(let* ((word (if cumulative? "and " "or "))
(init (append (drop-right lst 1))))
(format #f "~a" (string-append
(string-join
(map (compose maybe-object->string proc) init)
", " 'suffix)
word
(maybe-object->string (proc (last lst)))))))
\f
;;;
;;; Serializers.
;;;
(define ini-config? list?)
(define (generic-serialize-ini-config-section section proc)
"Format a section from SECTION for an INI configuration.
Apply the procedure PROC on SECTION after it has been converted to a string"
(format #f "[~a]\n" (proc section)))
(define default-ini-format-section
(match-lambda
((section subsection)
(string-append (maybe-object->string section) " "
(maybe-object->string subsection)))
(section
(maybe-object->string section))))
(define* (generic-serialize-ini-config
#:key
(combine-ini string-join)
(combine-alist string-append)
(combine-section-alist string-append)
(format-section default-ini-format-section)
serialize-field
fields)
"Create an INI configuration from nested lists FIELDS. This uses
@code{generic-serialize-ini-config-section} and @{generic-serialize-alist} to
serialize the section and the association lists, respectively.
@example
(generic-serialize-ini-config
#:serialize-field (lambda (a b) (format #f \"~a = ~a\n\" a b))
#:format-section (compose string-capitalize symbol->string)
#:fields '((application ((key . value)))))
@end example
@result{} \"[Application]\nkey = value\n\""
(combine-ini
(map (match-lambda
((section alist)
(combine-section-alist
(generic-serialize-ini-config-section section format-section)
(generic-serialize-alist combine-alist serialize-field alist))))
fields)
"\n"))
(define* (generic-serialize-git-ini-config
#:key
(combine-ini string-join)
(combine-alist string-append)
(combine-section-alist string-append)
(format-section default-ini-format-section)
serialize-field
fields)
"Like @code{generic-serialize-ini-config}, but the section can also
have a @dfn{subsection}. FORMAT-SECTION will take a list of two
elements: the section and the subsection."
(combine-ini
(map (match-lambda
((section subsection alist)
(combine-section-alist
(generic-serialize-ini-config-section
(list section subsection) format-section)
(generic-serialize-alist combine-alist serialize-field alist)))
((section alist)
(combine-section-alist
(generic-serialize-ini-config-section section format-section)
(generic-serialize-alist combine-alist serialize-field alist))))
fields)
"\n"))
|