bug#45618: development childhurd fails to build: glib@2.62.6: build system `meson'

[Jan Nieuwenhuizen <jan.nieuwenhuizen@verum.com>]

[-- Attachment #1: Type: text/plain, Size: 586 bytes --]

Jan Nieuwenhuizen writes:

Hello,

> On current master
>
>     395489cdc959c3f3c026bf545c3ed95efc9919f0
>     gnu: spice-vdagent: Update to 0.20.0.
>
> building
>
>     ./pre-inst-env guix system disk-image --target=i586-pc-gnu gnu/system/examples/devel-hurd.tmpl
>
> fail with
>
> guix system: error: gnu/packages/glib.scm:181:2: glib@2.62.6: build system `meson' does not support cross builds

My bad, turns out to be the new guile-avahi dependency that cannot be
cross-built.

For the archives, find an updated devel-hurd.tmpl attached that removes
guile-avahi.

Greetings,
Janneke


[-- Attachment #2: devel-hurd.tmpl --]
[-- Type: application/octet-stream, Size: 4198 bytes --]

;; -*-scheme-*-

;; This is an operating system configuration template for a "bare bones
;; development" setup, with no X11 display server.

;; chmod a+w /dev/null
;;
;; GUIX_PROFILE=/run/current-system/bootstrap-profile
;; . $GUIX_PROFILE/etc/profile
;;
;; guix build hello

(use-modules (srfi srfi-1)
             (ice-9 match)
             (gnu)
             (gnu system hurd)
             (guix gexp)
             (guix monads)
             (guix packages)
             (guix profiles)
             (guix store)
             (guix utils))
(use-service-modules ssh)
(use-package-modules base bootstrap commencement compression file gawk gdb
                     less m4 package-management ssh version-control)

(define %default-bootstrap-profile-packages
  (list %bootstrap-gcc %bootstrap-binutils %bootstrap-glibc))

;; XXX works, but clumsy
(define* (bootstrap-packages->profile-entry
          #:optional (bootstrap-packages %default-bootstrap-profile-packages))
  "Return a system entry for the profile containing BOOTSTRAP-PACKAGES."

  (define (cross-bootstrap thing)
    (let ((target (match (%current-target-system)
                    ("i586-pc-gnu" "i586-gnu"))))
      (with-parameters ((%current-system target))
        thing)))

  (define (cross-bootstrap-entry entry)
    (manifest-entry
      (inherit entry)
      (item (cross-bootstrap (manifest-entry-item entry)))))

  (with-monad %store-monad
    (return `(("bootstrap-profile" ,(profile
                                     (content
                                      (map-manifest-entries
                                       cross-bootstrap-entry
                                       (packages->manifest
                                        bootstrap-packages)))))))))

(define bootstrap-profile-service-type
  (service-type (name 'profile)
                (extensions
                 (list (service-extension system-service-type
                                          bootstrap-packages->profile-entry)))
                (compose concatenate)
                (extend append)
                (description
                 "This adds %bootstrap packages to the @dfn{system profile},
available as @file{/run/current-system/profile}.")))

(define (input->packages input)
  "Return the list of packages in INPUT."
  (match input
    ((label (and (? package?) package) . output)
     (list package))
    (_ '())))

(define %hurd-os
  (operating-system
    (inherit %hurd-default-operating-system)
    (bootloader (bootloader-configuration
                 (bootloader grub-minimal-bootloader)
                 (target "/dev/sdX")))
    (file-systems (cons (file-system
                          (device (file-system-label "hurd"))
                          (mount-point "/")
                          (type "ext2"))
                        %base-file-systems))
    (host-name "guixydevel")
    (timezone "Europe/Berlin")
    (users (cons (user-account
                  (name "guix")
                  (group "users")
                  (supplementary-groups '("wheel")))
                 %base-user-accounts))
    (packages (cons*
               diffutils
               gawk
               gdb-minimal
               git-minimal
               gzip gnu-make m4 openssh-sans-x tar xz
               (append
                (append-map input->packages
                            (fold alist-delete (package-direct-inputs guix)
                                  '("graphviz"
                                    "guile-avahi" ;; Needs glib => meson => cross-build meson-build-system
                                    "po4a")))
                %base-packages/hurd)))
    (services (cons*
               (service bootstrap-profile-service-type %default-bootstrap-profile-packages)
               (service openssh-service-type
                        (openssh-configuration
                         (openssh openssh-sans-x)
                         (use-pam? #f)
                         (port-number 2222)
                         (permit-root-login #t)
                         (allow-empty-passwords? #t)
                         (password-authentication? #t)))
               %base-services/hurd))))

%hurd-os



[-- Attachment #3: Type: text/plain, Size: 152 bytes --]


-- 
Jan Nieuwenhuizen <janneke@gnu.org> | GNU LilyPond http://lilypond.org
Freelance IT http://JoyofSource.com | Avatar® http://AvatarAcademy.com