all messages for Guix-related lists mirrored at yhetil.org
 help / color / mirror / code / Atom feed
blob 296d10c90befb95f0eb68ed05975784265e6cca0 3138 bytes (raw)
name: guix/scripts/import.scm 	 # note: path name is non-authoritative(*)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
 
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2012, 2013 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2014 David Thompson <davet@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (guix scripts import)
  #:use-module (guix ui)
  #:use-module (guix utils)
  #:use-module (guix scripts import nix)
  #:use-module (guix scripts import pypi)
  #:use-module (srfi srfi-1)
  #:use-module (srfi srfi-11)
  #:use-module (srfi srfi-26)
  #:use-module (srfi srfi-37)
  #:use-module (ice-9 match)
  #:use-module (ice-9 pretty-print)
  #:export (guix-import))

\f
;;;
;;; Helper.
;;;

(define (newline-rewriting-port output)
  "Return an output port that rewrites strings containing the \\n escape
to an actual newline.  This works around the behavior of `pretty-print'
and `write', which output these as \\n instead of actual newlines,
whereas we want the `description' field to contain actual newlines
rather than \\n."
  (define (write-string str)
    (let loop ((chars (string->list str)))
      (match chars
        (()
         #t)
        ((#\\ #\n rest ...)
         (newline output)
         (loop rest))
        ((chr rest ...)
         (write-char chr output)
         (loop rest)))))

  (make-soft-port (vector (cut write-char <>)
                          write-string
                          (lambda _ #t)           ; flush
                          #f
                          (lambda _ #t)           ; close
                          #f)
                  "w"))

\f
;;;
;;; Entry point.
;;;

(define importers
  `(("nix" . ,guix-import-nix)
    ("pypi" . ,guix-import-pypi)))

(define (show-help)
  (display (_ "Usage: guix import IMPORTER ARGS ...
Run IMPORTER with ARGS.\n"))
  (newline)
  (display (_ "IMPORTER must be one of the importers listed below:\n"))
  (format #t "~{   ~a~%~}" (map car importers))
  (display (_ "
  -h, --help             display this help and exit"))
  (display (_ "
  -V, --version          display version information and exit"))
  (newline)
  (show-bug-report-information))

(define (guix-import . args)
  (match args
    (()
     (format (current-error-port)
             (_ "guix import: missing importer name~%")))
    ((or ("-h") ("--help"))
     (show-help)
     (exit 0))
    (("--version")
     (show-version-and-exit "guix import"))
    ((importer args ...)
     (let ((expr (apply (assoc-ref importers importer) args)))
       (pretty-print expr (newline-rewriting-port (current-output-port)))))))

debug log:

solving 296d10c ...
found 296d10c in https://yhetil.org/guix/8761g8ojde.fsf@izanagi.i-did-not-set--mail-host-address--so-tickle-me/
found 6f75017 in https://git.savannah.gnu.org/cgit/guix.git
preparing index
index prepared:
100644 6f75017d6ea702466b614c2925030414b0a2c937	guix/scripts/import.scm

applying [1/1] https://yhetil.org/guix/8761g8ojde.fsf@izanagi.i-did-not-set--mail-host-address--so-tickle-me/
diff --git a/guix/scripts/import.scm b/guix/scripts/import.scm
index 6f75017..296d10c 100644

Checking patch guix/scripts/import.scm...
Applied patch guix/scripts/import.scm cleanly.

index at:
100644 296d10c90befb95f0eb68ed05975784265e6cca0	guix/scripts/import.scm

(*) Git path names are given by the tree(s) the blob belongs to.
    Blobs themselves have no identifier aside from the hash of its contents.^

Code repositories for project(s) associated with this external index

	https://git.savannah.gnu.org/cgit/guix.git

This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.