;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2012, 2013, 2014, 2015, 2016, 2017, 2019, 2020 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2014, 2015, 2018 Mark H Weaver <mhw@netris.org>
;;; Copyright © 2015, 2017 Leo Famulari <leo@famulari.name>
;;; Copyright © 2016, 2017, 2018, 2019 Efraim Flashner <efraim@flashner.co.il>
;;; Copyright © 2018, 2019, 2020 Tobias Geerinckx-Rice <me@tobias.gr>
;;; Copyright © 2019 Mathieu Othacehe <m.othacehe@gmail.com>
;;; Copyright © 2020 Zhu Zihao <all_but_last@163.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu packages bash)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (gnu packages)
  #:use-module (gnu packages admin)
  #:use-module (gnu packages base)
  #:use-module (gnu packages bootstrap)
  #:use-module (gnu packages compression)
  #:use-module (gnu packages curl)
  #:use-module (gnu packages dns)
  #:use-module (gnu packages ed)
  #:use-module (gnu packages elf)
  #:use-module (gnu packages freedesktop)
  #:use-module (gnu packages gawk)
  #:use-module (gnu packages gtk)
  #:use-module (gnu packages ncurses)
  #:use-module (gnu packages networking)
  #:use-module (gnu packages readline)
  #:use-module (gnu packages bison)
  #:use-module (gnu packages linux)
  #:use-module (gnu packages libffi)
  #:use-module (gnu packages pcre)
  #:use-module (gnu packages perl)
  #:use-module (gnu packages php)
  #:use-module (gnu packages pkg-config)
  #:use-module (gnu packages python)
  #:use-module (gnu packages python-xyz)
  #:use-module (gnu packages guile)
  #:use-module (gnu packages guile-xyz)
  #:use-module (gnu packages tcl)
  #:use-module (gnu packages web)
  #:use-module (gnu packages xml)
  #:use-module (guix packages)
  #:use-module (guix download)
  #:use-module (guix git-download)
  #:use-module (guix utils)
  #:use-module (guix gexp)
  #:use-module (guix monads)
  #:use-module (guix store)
  #:use-module (guix build-system gnu)
  #:use-module (guix build-system trivial)
  #:autoload   (guix gnupg) (gnupg-verify*)
  #:autoload   (guix base32) (bytevector->nix-base32-string)

  ;; See <https://bugs.gnu.org/41457> for why not #:autoload here.
  #:use-module ((gcrypt hash) #:select (port-sha256))

  #:use-module (srfi srfi-1)
  #:use-module (srfi srfi-26)
  #:use-module (ice-9 format))

(define (patch-url seqno)
  "Return the URL of Bash patch number SEQNO."
  (format #f "mirror://gnu/bash/bash-5.0-patches/bash50-~3,'0d" seqno))

(define (bash-patch seqno sha256-bv)
  "Return the origin of Bash patch SEQNO, with expected hash SHA256-BV."
  (origin
    (method url-fetch)
    (uri (patch-url seqno))
    (sha256 sha256-bv)))

(define-syntax-rule (patch-series (seqno hash) ...)
  (list (bash-patch seqno (base32 hash))
        ...))

(define %patch-series-5.0
  ;; This is the current patches series for 5.0, generated using
  ;; 'download-patches' below.
  (patch-series
    (1 "12bjfdy6bg8nhyw27bdgxn7h4paylx8d927skfmi9pxd1wgrxzpj")
    (2 "01w7yrzmz10mw06ys0546vhl7isv2v402ziyvfd7k67588spvs47")
    (3 "0ny81ridp5n0j69hb8ixrc7dmxybby54jbsz5hikly8kgg1wvssf")
    (4 "021gqqvgydixkrmqss64b6srfdlkvnx88lyfzpxfrn5d6bc7li0l")
    (5 "0xl2kyzm84nlyklrqzkn73ixabhzfhn9x91lzcmis89cppclvxav")
    (6 "0844749ixk1z60437nkznzms1f0nzh9an62kj7sny6r0zyk2k1fn")
    (7 "16xg37gp1b8zlj5969w8mcrparwqlcbj9695vn3qhgb7wdz1xd0p")
    (8 "1qyp19krjh8zxvb0jgwmyjz40djslwcf4xi7kc1ab0iaca44bipf")
    (9 "00yrjjqd95s81b21qq3ba1y7h879q8jaajlkjggc6grhcwbs4g7d")
    (10 "04ca5bjv456v538mkspzvn4xb2zdphh31r4fpvfm9p5my0jw7yyn")
    (11 "1sklyixvsv8993kxzs0jigacpdchjrq7jv5xpdx7kbqyp4rf6k9c")
    (12 "0cz21qg2gbr40lfgza7g02bqi2qknwqgxnq459pjj640d0cywhr9")
    (13 "16h9nwz3yzwj7fnxvlidjymdc4yr30h818433gh9j1x3in6igmzm")
    (14 "12gm5bvv2pd3m72z2ilj26pa08c61az253dsgfl24vpf2ijywvjx")
    (15 "0pm0px758w4i23s55wajcv6lqfiym7zgxvq0pxf6vclkv8nxy5x5")
    (16 "0vdha332km2iwx8g2ld15jy7d24cbplzgr1531dpzylr9ajxglgz")))

(define (download-patches store count)
  "Download COUNT Bash patches into store.  Return a list of
number/base32-hash tuples, directly usable in the 'patch-series' form."
  (unfold (cut > <> count)
          (lambda (number)
            (let* ((patch  (download-to-store store (patch-url number)))
                   (sig    (download-to-store store
                                              (string-append (patch-url number)
                                                             ".sig"))))
              (unless (eq? 'valid-signature (gnupg-verify* sig patch))
                (error "failed to verify signature" patch))

              (list number
                    (bytevector->nix-base32-string
                     (call-with-input-file patch port-sha256)))))
          1+
          1))

(define-public bash
  (let* ((cppflags (string-join '("-DDEFAULT_PATH_VALUE='\"/no-such-path\"'"
                                  "-DSTANDARD_UTILS_PATH='\"/no-such-path\"'"
                                  "-DNON_INTERACTIVE_LOGIN_SHELLS"
                                  "-DSSH_SOURCE_BASHRC")
                                " "))
         (configure-flags
          ``("--with-installed-readline"
             ,,(string-append "CPPFLAGS=" cppflags)
             ,(string-append
               "LDFLAGS=-Wl,-rpath -Wl,"
               (assoc-ref %build-inputs "readline")
               "/lib"
               " -Wl,-rpath -Wl,"
               (assoc-ref %build-inputs "ncurses")
               "/lib")))
         (version "5.0"))
    (package
     (name "bash")
     (source (origin
              (method url-fetch)
              (uri (string-append
                    "mirror://gnu/bash/bash-" version ".tar.gz"))
              (sha256
               (base32
                "0kgvfwqdcd90waczf4gx39xnrxzijhjrzyzv7s8v4w31qqm0za5l"))
              (patch-flags '("-p0"))
              (patches (cons (search-patch "bash-linux-pgrp-pipe.patch")
                             %patch-series-5.0))))
     (version (string-append version "." (number->string (length %patch-series-5.0))))
     (build-system gnu-build-system)

     (outputs '("out"
                "doc"                         ;1.7 MiB of HTML and extra files
                "include"))                   ;headers used by extensions
     (inputs `(("readline" ,readline)
               ("ncurses" ,ncurses)))             ;TODO: add texinfo
     (arguments
      `(;; When cross-compiling, `configure' incorrectly guesses that job
        ;; control is missing.
        #:configure-flags ,(if (%current-target-system)
                               `(cons* "bash_cv_job_control_missing=no"
                                       ,configure-flags)
                               configure-flags)

        ;; Bash is reportedly not parallel-safe.  See, for instance,
        ;; <http://patches.openembedded.org/patch/32745/> and
        ;; <http://git.buildroot.net/buildroot/commit/?h=79e2d802a>.
        #:parallel-build? #f
        #:parallel-tests? #f

        ;; XXX: The tests have a lot of hard-coded paths, so disable them
        ;; for now.
        #:tests? #f

        #:modules ((srfi srfi-26)
                   (guix build utils)
                   (guix build gnu-build-system))

        #:phases
        (modify-phases %standard-phases
          (add-after 'install 'install-sh-symlink
            (lambda* (#:key outputs #:allow-other-keys)
              ;; Add a `sh' -> `bash' link.
              (let ((out (assoc-ref outputs "out")))
                (with-directory-excursion (string-append out "/bin")
                  (symlink "bash" "sh")
                  #t))))

          (add-after 'install 'move-development-files
            (lambda* (#:key outputs #:allow-other-keys)
              ;; Move 'Makefile.inc' and 'bash.pc' to "include" to avoid
              ;; circular references among the outputs.
              (let ((out     (assoc-ref outputs "out"))
                    (include (assoc-ref outputs "include"))
                    (lib     (cut string-append <> "/lib/bash")))
                (mkdir-p (lib include))
                (rename-file (string-append (lib out)
                                            "/Makefile.inc")
                             (string-append (lib include)
                                            "/Makefile.inc"))
                (rename-file (string-append out "/lib/pkgconfig")
                             (string-append include
                                            "/lib/pkgconfig"))

                ;; Don't capture the absolute file name of 'install' to avoid
                ;; retaining a dependency on Coreutils.
                (substitute* (string-append (lib include)
                                            "/Makefile.inc")
                  (("^INSTALL =.*")
                   "INSTALL = install -c\n"))
                #t))))))

     (native-search-paths
      (list (search-path-specification            ;new in 4.4
             (variable "BASH_LOADABLES_PATH")
             (files '("lib/bash")))))

     (synopsis "The GNU Bourne-Again SHell")
     (description
      "Bash is the shell, or command-line interpreter, of the GNU system.  It
is compatible with the Bourne Shell, but it also integrates useful features
from the Korn Shell and the C Shell and new improvements of its own.  It
allows command-line editing, unlimited command history, shell functions and
aliases, and job control while still allowing most sh scripts to be run
without modification.")
     (license license:gpl3+)
     (home-page "https://www.gnu.org/software/bash/"))))

(define-public bash-minimal
  ;; A stripped-down Bash for non-interactive use.
  (package (inherit bash)
    (name "bash-minimal")
    (inputs '())                                ; no readline, no curses

    ;; No "include" output because there's no support for loadable modules.
    (outputs (delete "include" (package-outputs bash)))

    (arguments
     (substitute-keyword-arguments (package-arguments bash)
       ((#:modules _ '())
        '((guix build gnu-build-system)
          (guix build utils)
          (srfi srfi-1)
          (srfi srfi-26)))
       ((#:configure-flags flags '())
        `(list "--without-bash-malloc"
               "--disable-readline"
               "--disable-history"
               "--disable-help-builtin"
               "--disable-progcomp"
               "--disable-net-redirections"
               "--disable-nls"

               ;; Pretend 'dlopen' is missing so we don't build loadable
               ;; modules and related code.
               "ac_cv_func_dlopen=no"

               ,@(if (%current-target-system)
                     '("bash_cv_job_control_missing=no"
                       "bash_cv_getcwd_malloc=yes")
                     '())))
       ((#:phases phases)
        `(modify-phases ,phases
           ;; No loadable modules.
           (delete 'move-development-files)))))))

(define-public static-bash
  ;; Statically-linked Bash that contains nothing but the 'bash' binary and
  ;; 'sh' symlink, without any reference.
  (let ((bash (static-package bash-minimal)))
    (package
      (inherit bash)
      (name "bash-static")
      (arguments
       (substitute-keyword-arguments
           `(#:allowed-references ("out") ,@(package-arguments bash))
         ((#:phases phases)
          `(modify-phases ,phases
             (add-after 'strip 'remove-everything-but-the-binary
               (lambda* (#:key outputs #:allow-other-keys)
                 (let* ((out (assoc-ref outputs "out"))
                        (bin (string-append out "/bin")))
                   (remove-store-references (string-append bin "/bash"))
                   (delete-file (string-append bin "/bashbug"))
                   (delete-file-recursively (string-append out "/share"))
                   #t))))))))))

(define-public bash-completion
  (package
    (name "bash-completion")
    (version "2.8")
    (source (origin
              (method url-fetch)
              (uri (string-append
                    "https://github.com/scop/" name "/releases/download/"
                    version "/" name "-" version ".tar.xz"))
              (sha256
               (base32
                "0kgmflrr1ga9wfk770vmakna3nj46ylb5ky9ipd0v2k9ymq5a7y0"))
              (patches
               (search-patches "bash-completion-directories.patch"))))
    (build-system gnu-build-system)
    (native-inputs `(("util-linux" ,util-linux)))
    (arguments
     `(#:phases (modify-phases %standard-phases
                  (add-after
                   'install 'remove-redundant-completions
                   (lambda* (#:key
                             inputs native-inputs
                             outputs #:allow-other-keys)
                     ;; Util-linux comes with a bunch of completion files for
                     ;; its own commands which are more sophisticated and
                     ;; up-to-date than those of bash-completion.  Remove those
                     ;; from bash-completion.
                     (let* ((out         (assoc-ref outputs "out"))
                            (util-linux  (assoc-ref (or native-inputs inputs)
                                                    "util-linux"))
                            (completions (string-append out
                                                        "/share/bash-completion"
                                                        "/completions"))
                            (already     (find-files
                                          (string-append
                                           util-linux
                                           "/etc/bash_completion.d"))))
                       (with-directory-excursion completions
                         (for-each (lambda (file)
                                     (when (file-exists? file)
                                       (delete-file file)))
                                   (map basename already)))
                       #t))))))
    (synopsis "Bash completions for common commands")
    (description
     "This package provides extensions that allow Bash to provide adapted
completion for many common commands.")
    (home-page "https://github.com/scop/bash-completion")
    (license license:gpl2+)))

(define-public bash-tap
  (package
    (name "bash-tap")
    (version "1.0.2")
    (source
     (origin
       (method git-fetch)
       (uri (git-reference
             (url "https://github.com/illusori/bash-tap")
             (commit version)))
       (file-name (git-file-name name version))
       (sha256
        (base32 "13zz9h6bhhnk3hiwhlpafrnf2isws249h3fz785dcgymk02arz9c"))))
    ;; There is no compilation process to use this package, however, the bash
    ;; scripts installed by this package start with "#!/bin/bash".  To fix
    ;; these lines, we use the patch-shebangs of the GNU build system.  The
    ;; project does not use a Makefile.
    (build-system gnu-build-system)
    (arguments
     `(#:tests? #f ; There is no test suite.
       #:phases
       (modify-phases %standard-phases
         ;; Because there are no configure scripts or Makefile, we can
         ;; remove these phases.
         (delete 'configure)
         (delete 'build)
         ;; The installation involves manually copying the files to a location.
         ;; To make them easily accessible by setting PATH, we add the scripts
         ;; to the "bin" folder.
         (replace 'install
           (lambda* (#:key outputs #:allow-other-keys)
             (let ((bin (string-append (assoc-ref outputs "out") "/bin")))
               (install-file "bash-tap" bin)
               (install-file "bash-tap-bootstrap" bin)
               (install-file "bash-tap-mock" bin)))))))
    (home-page "https://www.illusori.co.uk/projects/bash-tap/")
    (synopsis "Bash port of a Test::More/Test::Builder-style TAP-compliant
test library")
    (description "Bash TAP is a TAP-compliant Test::More-style testing library
for Bash shell scripts and functions.  Along with the Test::More-style testing
helpers it provides helper functions for mocking commands and in-process output
capturing.")
    (license license:expat)))

(define-public bats
  (package
    (name "bats")
    (version "1.2.0")
    (source (origin
              (method git-fetch)
              (uri (git-reference
                    (url "https://github.com/bats-core/bats-core")
                    (commit (string-append "v" version))))
              (file-name (git-file-name name version))
              (sha256
               (base32
                "0f59zh4d4pa1a7ybs5zl6h0csbqqv11lbnq0jl1dgwm1s6p49bsq"))))
    (inputs
     `(("bash" ,bash)
       ("coreutils" ,coreutils)
       ("guile" ,guile-3.0) ;for wrap-script
       ("grep" ,grep)))
    (arguments
     `(#:modules ((guix build utils))
       #:builder
       (begin
         (use-modules (guix build utils))
         (copy-recursively (assoc-ref %build-inputs "source") ".")
         (setenv "PATH"
                 (string-append (assoc-ref %build-inputs "bash") "/bin"
                                ":" (assoc-ref %build-inputs "coreutils") "/bin"
                                ":" (assoc-ref %build-inputs "grep") "/bin"
                                ":" (assoc-ref %build-inputs "guile") "/bin"
                                ":" (getenv "PATH")))
         (for-each (lambda (file) (patch-shebang file)) (find-files "."))
         (substitute* "bin/bats"
           (("export BATS_ROOT" line)
            (string-append "BATS_ROOT=\"${BATS_ROOT:-" %output "/libexec/bats-core}\"\n"
                           line)))
         ;; Install phase
         (invoke "./install.sh" %output)
         (wrap-script (string-append %output "/bin/bats")
                      (list "PATH" 'prefix (string-split (getenv "PATH")
                                                         #\:))))))
    (build-system trivial-build-system)
    (home-page "https://github.com/bats-core/bats-core/")
    (synopsis "Bash Automated Testing System")
    (description
     "Bats is a @acronym{TAP, Test Anything Protocol}-compliant testing
framework for Bash.  It provides a simple way to verify that the UNIX programs
you write behave as expected.  Bats is most useful when testing software written
in Bash, but you can use it to test any UNIX program.")
    (license license:expat)))

(define-public bash-ctypes
  (package
    (name "bash-ctypes")
    (version "1.2")
    (source
     (origin
       (method url-fetch)
       (uri (string-append "https://github.com/taviso/ctypes.sh/releases/download/v"
                           version "/ctypes-sh-" version ".tar.gz"))
       (sha256
        (base32 "0s1sifqzqmr0dnciv06yqrpzgj11d7n0gy5zaxh6b3x8bx7k75l8"))))
    (build-system gnu-build-system)
    (inputs
     `(("elfutils" ,elfutils)
       ("libelf" ,libelf)
       ("libffi" ,libffi)
       ("zlib" ,zlib)
       ;; Require a bash with C plugin support to build.
       ("bash" ,bash)))
    (native-inputs
     `(("pkg-config" ,pkg-config)))
    (home-page "https://github.com/taviso/ctypes.sh")
    (synopsis "Foreign function interface for Bash")
    (description "Bash-ctypes is a Bash plugin that provides a foreign
function interface (FFI) directly in your shell.  In other words, it allows
you to call routines in shared libraries from within Bash.")
    (license license:expat)))

(define-public bash-coding-utils
  (let ()
    (package
      (name "bash-coding-utils")
      (version "0.2.0")
      (source
       (origin
         (method git-fetch)
         (uri (git-reference
               (commit "40d6527a9effb4e18778c37bebaa9f3a58de12d6")
               (url "https://gitlab.com/methuselah-0/bash-coding-utils.sh.git")
               ;; Include submodules/.  TODO: These seem to be worth packaging?
               (recursive? #t)))
         (sha256
          (base32 "007g6wfybjr0ms32qikb545r11lgm3p98cd7dbzpfyh0grgn9vj1"))))
      (inputs `(("bash" ,bash)
                ("bindutils" ,isc-bind "utils")
                ("coreutils" ,coreutils)
                ("ctypes.sh" ,bash-ctypes)
                ("curl" ,curl)
                ("diffutils" ,diffutils)
                ("ed" ,ed)
                ("expect" ,expect)
                ("find" ,findutils)
                ("gawk" ,gawk)
                ("grep" ,grep)
                ("guile" ,guile-3.0)
                ("guile-bash" ,guile-bash)
                ("guile-daemon" ,guile-daemon)
                ("inetutils" ,inetutils)
                ("jq" ,jq)
                ("libxml2-xpath0" ,libxml2-xpath0)
                ("netcat" ,netcat)
                ("nmap" ,nmap)
                ("pcre/bin" ,pcre "bin")
                ("perl" ,perl)
                ("php" ,php)
                ("prips" ,prips)
                ("python" ,python)
                ("python-elementpath" ,python-elementpath)
                ("python-lxml" ,python-lxml)
                ("python-netaddr" ,python-netaddr)
                ("python-yq" ,python-yq)
                ("sed" ,sed)
                ("socat" ,socat)
                ("util-linux" ,util-linux)
                ("which" ,which)
                ("xdg-utils" ,xdg-utils)
                ("yad" ,yad)))
      (build-system trivial-build-system)
      (arguments
       `(#:modules ((guix build utils))
         #:builder
         (begin
           (use-modules (guix build utils))
           (let* ((bash (assoc-ref %build-inputs "bash"))
                  ;; Some Guile libraries such as GNU Bash will need
                  ;; to be added to GUILE_LOAD_PATH.
                  (guile-bash (assoc-ref %build-inputs "guile-bash"))
                  (g-bash-lib (string-append guile-bash
                                        "/share/guile/site/"
                                        ,(version-major+minor (package-version guile-3.0))))
                  ;; Some Python libraries needs added to PYTHONPATH.
                  (python-version ,(version-major+minor (package-version python)))
                  (p-elementpath-lib (string-append
                                      (assoc-ref %build-inputs "python-elementpath")
                                      "/lib/python" python-version "/site-packages"))
                  (p-lxml-lib (string-append
                               (assoc-ref %build-inputs "python-lxml")
                               "/lib/python" python-version "/site-packages"))
                  (p-netaddr-lib (string-append
                                  (assoc-ref %build-inputs "python-netaddr")
                                  "/lib/python" python-version "/site-packages"))
                  (p-lib (string-append
                          (assoc-ref %build-inputs "python")
                          "/lib/python" python-version "/site-packages"))
                  (pylibsline (string-append
                               p-elementpath-lib ":" p-lxml-lib
                               ":" p-netaddr-lib ":" p-lib))
                  (out (assoc-ref %outputs "out"))
                  (bin (string-append out "/bin"))
                  ;; Everything but bcu.sh itself is only accessed
                  ;; internally by bcu so we put it in libexec.
                  (libexec (string-append out "/libexec/bcu")))
             (mkdir-p libexec)
             (copy-recursively (assoc-ref %build-inputs "source") libexec)
             ;; Create a bcu.sh wrapping script manually that ensures
             ;; we prepend necessary PATHs.
             (mkdir-p bin)
             (let* ((bcu.sh (string-append bin "/bcu.sh"))
                    (path (string-append
                               "/run/setuid-programs"
                               ":" bash "/bin"
                               ":" (assoc-ref %build-inputs "bindutils") "/bin"
                               ":" (assoc-ref %build-inputs "coreutils") "/bin"
                               ":" (assoc-ref %build-inputs "ctypes.sh") "/bin"
                               ":" (assoc-ref %build-inputs "curl") "/bin"
                               ":" (assoc-ref %build-inputs "diffutils") "/bin"
                               ":" (assoc-ref %build-inputs "ed") "/bin"
                               ":" (assoc-ref %build-inputs "expect") "/bin"
                               ":" (assoc-ref %build-inputs "find") "/bin"
                               ":" (assoc-ref %build-inputs "gawk") "/bin"
                               ":" (assoc-ref %build-inputs "grep") "/bin"
                               ":" (assoc-ref %build-inputs "guile") "/bin"
                               ":" (assoc-ref %build-inputs "inetutils") "/bin"
                               ":" (assoc-ref %build-inputs "jq") "/bin"
                               ":" (assoc-ref %build-inputs "libxml2-xpath0") "/bin"
                               ":" (assoc-ref %build-inputs "netcat") "/bin"
                               ":" (assoc-ref %build-inputs "nmap") "/bin"
                               ":" (assoc-ref %build-inputs "pcre/bin") "/bin"
                               ":" (assoc-ref %build-inputs "perl") "/bin"
                               ":" (assoc-ref %build-inputs "php") "/bin"
                               ":" (assoc-ref %build-inputs "prips") "/bin"
                               ":" (assoc-ref %build-inputs "python") "/bin"
                               ":" (assoc-ref %build-inputs "python-yq") "/bin"
                               ":" (assoc-ref %build-inputs "sed") "/bin"
                               ":" (assoc-ref %build-inputs "socat") "/bin"
                               ":" (assoc-ref %build-inputs "util-linux") "/bin"
                               ":" (assoc-ref %build-inputs "which") "/bin"
                               ":" (assoc-ref %build-inputs "xdg-utils") "/bin"
                               ":" (assoc-ref %build-inputs "yad") "/bin")))
               (with-output-to-file bcu.sh
                 (lambda _
                   (display (string-append "#!" bash "/bin/bash\n"))
                   (display "[[ \"$_BCU_SH_LOADED\" == YES ]] || { \n")
                   (display (string-append "export PATH=\"" path
                                           "${PATH:+:}${PATH}\"\n"))
                   (display (string-append "export PYTHONPATH=\"" pylibsline
                                           "${PYTHONPATH:+:}${PYTHONPATH}\"\n"))
                   (display
                    (string-append "export GUILE_LOAD_PATH=\"" g-bash-lib
                                   "${GUILE_LOAD_PATH:+:}${GUILE_LOAD_PATH}\"\n"))
                   ;; XDG_DATA_DIRS needs set for yad to load icons properly.
                   (display (string-append
                             "[[ -e /run/current-system/profile/share ]] && "
                             "export XDG_DATA_DIRS="
                             "/run/current-system/profile/share"
                             "${XDG_DATA_DIRS:+:}${XDG_DATA_DIRS}\n"))
                   (display (string-append "source " libexec "/bcu.sh\n"))
                   (display "}\n")))
               (chmod bcu.sh #o555)
               (setenv "PATH" (string-append path ":" (getenv "PATH"))))
             (substitute* (find-files out ".*\\.sh")
               (("~/\\.guix-profile/lib/bash/libguile-bash\\.so")
                (string-append guile-bash "/lib/bash/libguile-bash.so"))
               (("\"\\$GUIX_PROFILE\"/lib/bash/libguile-bash\\.so")
                (string-append guile-bash "/lib/bash/libguile-bash.so")))
             (for-each (lambda (file)
                         (patch-shebang file))
                       (find-files out ".*\\.(sh|scm|awk|php|py)$")   )
             ;; Set up PATH for tests.
             (setenv "PATH" (string-append bin ":" (getenv "PATH")))
             ;; Some tests need a HOME directory.
             (setenv "HOME" "/tmp")
             ;; Disable network tests, and all tests for setopts which
             ;; don't work inside the Guix build environment.
             (with-output-to-file (string-append libexec "/disabled_tests.txt")
               (lambda _
                 (format #t "~{~a~%~}"
                         (list "ip_of_test_1"
                               "setopts_test_1"
                               "setopts_test_2"
                               "setopts_test_3"
                               "setopts_test_4"
                               "setopts_test_5"
                               "setopts_test_6"))))
             (invoke (string-append libexec "/bcu-test.sh"))))))
      (home-page "https://gitlab.com/methuselah-0/bash-coding-utils.sh")
      (synopsis "Functions and tools for software prototyping in Bash")
      (description
       "This package contains Bash functions and wrappers that can be useful
when writing quick implementations of new programs.  It helps you work with
JSON, XML, and parallelization, and installs some commonly used helper programs
used in Bash scripting.  Just run @command{. bcu.sh}, type @command{bcu__}, hit
@key{TAB} to see available functions and give any of them the @code{--help}
flag to see how to use it, or run @command{bcu__docs} for the full HTML
documentation.")
      (license license:gpl3))))