unofficial mirror of help-guix@gnu.org 
 help / color / mirror / Atom feed
* use guix shell with a file (e.g. tissue.scm)
@ 2022-11-26 14:38 Giovanni Biscuolo
  2022-11-26 18:43 ` indieterminacy
  2022-11-28 17:13 ` Andrea Rossi
  0 siblings, 2 replies; 4+ messages in thread
From: Giovanni Biscuolo @ 2022-11-26 14:38 UTC (permalink / raw)
  To: help-guix; +Cc: Arun Isaac, Pjotr Prins


[-- Attachment #1.1: Type: text/plain, Size: 239 bytes --]

Hi,

I just want to share with you a temporary solution for users who wish to
try out tissue or other packages before they are included in Guix
upstream.

...and yes, unlike me advanced Guix users may find this obvious :-)

Put this file


[-- Attachment #1.2: tissue and skribilo-latest packages --]
[-- Type: text/plain, Size: 3620 bytes --]

(use-modules (gnu packages autotools)
             (gnu packages gettext)
             (gnu packages guile)
             (gnu packages guile-xyz)
             ((gnu packages skribilo) #:prefix guix:)
             (guix build-system gnu)
             (guix gexp)
             (guix packages)
             (guix git-download)
             ((guix licenses) #:prefix license:))

(define skribilo-latest
  (let ((commit "621eb1945aec8f26f5aee4bdf896f2434e145182")
        (revision "1"))
    (package
      (inherit guix:skribilo)
      (name "skribilo")
      (version (git-version "0.9.5" revision commit))
      (source (origin
                (method git-fetch)
                (uri (git-reference
                      (url "https://git.systemreboot.net/skribilo")
                      (commit commit)))
                (file-name (git-file-name name version))
                (sha256
                 (base32
                  "16rdcvszl9x183y32hjdwns0lkrvkmwd2fsshymspb12k4cxj6i4"))))
      (native-inputs
       `(("autoconf" ,autoconf)
         ("automake" ,automake)
         ("gettext" ,gnu-gettext)
         ,@(package-native-inputs guix:skribilo))))))

(define tissue
  (let ((commit "6d6285d071132960835f848a1703faaea2356937")
        (revision "3"))
    (package
      (name "tissue")
      (version (git-version "0.1.0" revision commit))
      (source (origin
                (method git-fetch)
                (uri (git-reference
                      (url "https://git.systemreboot.net/tissue")
                      (commit commit)))
                (file-name (git-file-name name version))
                (sha256
                 (base32
                  "1dlcy7m4gz1vmklyny4mxky9822q5hjc4qdmn42yf2qvh8xy62g5"))))
      (build-system gnu-build-system)
      (arguments
       (list #:make-flags #~(list (string-append "prefix=" #$output))
             #:modules `(((guix build guile-build-system)
                          #:select (target-guile-effective-version))
                         ,@%gnu-build-system-modules)
             #:phases
             (with-imported-modules '((guix build guile-build-system))
               #~(modify-phases %standard-phases
                   (replace 'patch-source-shebangs
                     (lambda* (#:key inputs #:allow-other-keys)
                       (substitute* "bin/tissue"
                         (("^exec guile")
                          (string-append "exec " (search-input-file inputs "/bin/guile"))))))
                   (delete 'configure)
                   (add-after 'install 'wrap
                     (lambda* (#:key inputs outputs #:allow-other-keys)
                       (let ((out (assoc-ref outputs "out"))
                             (effective-version (target-guile-effective-version)))
                         (wrap-program (string-append out "/bin/tissue")
                           `("GUILE_LOAD_PATH" prefix
                             (,(string-append out "/share/guile/site/" effective-version)
                              ,(getenv "GUILE_LOAD_PATH")))
                           `("GUILE_LOAD_COMPILED_PATH" prefix
                             (,(string-append out "/lib/guile/" effective-version "/site-ccache")
                              ,(getenv "GUILE_LOAD_COMPILED_PATH")))))))))))
      (inputs (list guile-3.0 guile-filesystem guile-git guile-xapian))
      (propagated-inputs
       (list skribilo-latest))
      (home-page "https://tissue.systemreboot.net")
      (synopsis "Text based issue tracker")
      (description "tissue is a text based issue tracker.")
      (license license:gpl3+))))

tissue

[-- Attachment #1.3: Type: text/plain, Size: 832 bytes --]


in your preferred directory (~/guix/unpackaged/ in the example below)
and then:

--8<---------------cut here---------------start------------->8---

guix shell -f ~/guix/unpackaged/tissue.scm -- tissue help

--8<---------------cut here---------------end--------------->8---

The first time the package(s) gets compiled, so it'll take as time as
needed, from the second time onwards the guix shell cache will do its
job and the command will run immediatly.

With this trick you can use Guix to install tissue [1] and use it for
your project - or tissue issues [2] - before tissue is packaged in Guix.

«One Guix to rule them all» :-D

Happy hacking!

[1] even on foreign distros obviuosly

[2] web view: https://issues.genenetwork.org/?type=open-issue

-- 
Giovanni Biscuolo

Xelera IT Infrastructures

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 849 bytes --]

^ permalink raw reply	[flat|nested] 4+ messages in thread
end of thread, other threads:[~2022-11-29 13:03 UTC | newest]

Thread overview: 4+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2022-11-26 14:38 use guix shell with a file (e.g. tissue.scm) Giovanni Biscuolo
2022-11-26 18:43 ` indieterminacy
2022-11-27 21:12   ` Arun Isaac
2022-11-28 17:13 ` Andrea Rossi

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).