From: John Soo <jsoo1@asu.edu>
To: "Ludovic Courtès" <ludo@gnu.org>
Cc: 44460@debbugs.gnu.org
Subject: [bug#44460] Add copyright lines
Date: Wed, 11 Nov 2020 09:51:08 -0800 [thread overview]
Message-ID: <87imabok8j.fsf@asu.edu> (raw)
In-Reply-To: <87k0usn9jk.fsf@gnu.org> ("Ludovic Courtès"'s message of "Tue, 10 Nov 2020 23:15:11 +0100")
[-- Attachment #1: Type: text/plain, Size: 3553 bytes --]
Hello Ludo,
Ludovic Courtès <ludo@gnu.org> writes:
>> +@table @code
>> +@item --normalize
>> +Normalize the output records into record sets (@pxref{Record Sets,,,
>> +recutils, GNU recutils manual}). Normalizing into record sets allows
>> +joins across record types.
>> +
>> +@example
>> +$ guix processes --normalize | \
>> + recsel \
>> + -j Session \
>> + -t ChildProcess \
>> + -p Session.PID,PID \
>> + -e 'Session.ClientCommand ~ build'
>> +Session_PID: 4278
>> +PID: 4435
>> +
>> +Session_PID: 4278
>> +PID: 4554
>> +
>> +Session_PID: 4278
>> +PID: 4646
>> +@end example
>> +@end table
>
> Nice! Right above the example, I’d suggest adding a sentence like “The
> example below lists…” (what does it list actually? :-)).
>
> In the default format, I wonder if we could already change split
> ‘ChildProcess’ into ‘ChildPID’ and ‘ChildCommand’, as you had initially
> proposed on IRC; would that work?
I think we could do that, but I had two reasons to use the normalized
format instead.
* Backwards incompatibility - I didn't want to break any existing scripts
that may exist.
* Still not normalized - how can I search for just the child processes
associated with a particular command?
I wouldn't be opposed to splitting ChildProcess into ChildPID and
ChildCommand. I would like it best if that change was made in addition
to adding the normalized version, since the normalized version allows
more functionality.
>> +(define (lock->record lock port)
>> + (format port "LockHeld: ~a~%" lock))
>
> Maybe ‘lock->recutils’ for consistency and to avoid confusion with
> Scheme “records”?
Done.
>> +(define (format-single-record port)
>
> Maybe ‘daemon-sessions->recutils’? Should ‘sessions’ be a parameter for
> clarity?
Much better, thank you. I updated the normalized version too.
>
>> + "Display denormalized session information to PORT."
>> + (for-each (lambda (session)
>> + (daemon-session->recutils session port)
>> + (newline port))
> ^
> Indentation is off.
Fixed.
>> +(define (child-process->normalized-record process port)
>> + "Display PROCESS record on PORT in normalized form"
>> + (format port "PID: ~a" (process-id process))
>> + (newline port)
>> + (format port "Command:~{ ~a~}" (process-command process)))
>> +
>> +(define (format-normalized port)
>
> Please add a docstring. Perhaps make ‘sessions’ a parameter?
Done.
>> + (define sessions (daemon-sessions))
>> +
>> + (format port session-rec-type)
>
> As reported by ‘-Wformat’, passing a non-literal format string is risky;
> write this instead:
>
> (display session-rec-type port)
Done.
>> + (newline port)
>> + (newline port)
>> + (for-each
>> + (lambda (session)
>
> Preferable indent ‘for-each’ like so:
>
> (for-each (lambda (session)
Done.
> Likewise below.
>
>> + (display (G_ "
>> + --normalize display results as normalized record sets"))
>
> Should it be ‘--format=normalized’ (just like we have ‘--format’ in
> ‘guix describe’, for instance)?
That makes sense. What do you think of
Other changes:
* Updated the record descriptors to include the possible
fields for sessions. I got some nice guidance from the recutils irc on
that.
* Put the PID and Command first for the ChildProcess
* Add a --list-formats like guix describe has.
Thanks!
John
[-- Attachment #2: 0001-processes-Optionally-normalize-recutils-output.patch --]
[-- Type: text/x-patch, Size: 8681 bytes --]
From a19828e504288c03c7e17a88ac2a35eb70ab302c Mon Sep 17 00:00:00 2001
From: John Soo <jsoo1@asu.edu>
Date: Wed, 4 Nov 2020 07:51:52 -0800
Subject: [PATCH] processes: Optionally normalize recutils output.
* guix/scripts/processes.scm: Add "normalize" flag
---
doc/guix.texi | 29 ++++++++
guix/scripts/processes.scm | 132 +++++++++++++++++++++++++++++++------
2 files changed, 142 insertions(+), 19 deletions(-)
diff --git a/doc/guix.texi b/doc/guix.texi
index 5e3e0435b4..5df6096f39 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -82,6 +82,7 @@ Copyright @copyright{} 2020 Pierre Langlois@*
Copyright @copyright{} 2020 pinoaffe@*
Copyright @copyright{} 2020 André Batista@*
Copyright @copyright{} 2020 Alexandru-Sergiu Marton@*
+Copyright @copyright{} 2020 John Soo@*
Permission is granted to copy, distribute and/or modify this document
under the terms of the GNU Free Documentation License, Version 1.3 or
@@ -12691,6 +12692,34 @@ ClientPID: 19419
ClientCommand: cuirass --cache-directory /var/cache/cuirass @dots{}
@end example
+Additional options are listed below.
+
+@table @code
+@item --normalize
+Normalize the output records into record sets (@pxref{Record Sets,,,
+recutils, GNU recutils manual}). Normalizing into record sets allows
+joins across record types. The example below lists the PID of each
+ChildProcess and the associated PID for Session that spawned the
+ChildProcess where the Session was started using guix build.
+
+@example
+$ guix processes --normalize | \
+ recsel \
+ -j Session \
+ -t ChildProcess \
+ -p Session.PID,PID \
+ -e 'Session.ClientCommand ~ "guix build'"
+PID: 4435
+Session_PID: 4278
+
+PID: 4554
+Session_PID: 4278
+
+PID: 4646
+Session_PID: 4278
+@end example
+@end table
+
@node System Configuration
@chapter System Configuration
diff --git a/guix/scripts/processes.scm b/guix/scripts/processes.scm
index b4ca7b1687..af1d220774 100644
--- a/guix/scripts/processes.scm
+++ b/guix/scripts/processes.scm
@@ -1,5 +1,6 @@
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2018, 2019, 2020 Ludovic Courtès <ludo@gnu.org>
+;;; Copyright © 2020 John Soo <jsoo1@asu.edu>
;;;
;;; This file is part of GNU Guix.
;;;
@@ -176,6 +177,9 @@ active sessions, and the master 'guix-daemon' process."
(values (filter-map child-process->session children)
master)))
+(define (lock->recutils lock port)
+ (format port "LockHeld: ~a~%" lock))
+
(define (daemon-session->recutils session port)
"Display SESSION information in recutils format on PORT."
(format port "SessionPID: ~a~%"
@@ -184,8 +188,7 @@ active sessions, and the master 'guix-daemon' process."
(process-id (daemon-session-client session)))
(format port "ClientCommand:~{ ~a~}~%"
(process-command (daemon-session-client session)))
- (for-each (lambda (lock)
- (format port "LockHeld: ~a~%" lock))
+ (for-each (lambda (lock) (lock->recutils lock port))
(daemon-session-locks-held session))
(for-each (lambda (process)
(format port "ChildProcess: ~a:~{ ~a~}~%"
@@ -193,19 +196,89 @@ active sessions, and the master 'guix-daemon' process."
(process-command process)))
(daemon-session-children session)))
+(define (daemon-sessions->recutils port sessions)
+ "Display denormalized SESSIONS information to PORT."
+ (for-each (lambda (session)
+ (daemon-session->recutils session port)
+ (newline port))
+ sessions))
+
+(define session-rec-type
+ "%rec: Session
+%type: PID int
+%type: ClientPID int
+%key: PID
+%mandatory: ClientPID ClientCommand
+%allowed: LockHeld")
+
+(define child-process-rec-type
+ "%rec: ChildProcess
+%type: PID int
+%type: Session rec Session
+%key: PID
+%mandatory: Command")
+
+(define (session-key->recutils session port)
+ "Display SESSION PID as a recutils field on PORT."
+ (format
+ port "Session: ~a"
+ (process-id (daemon-session-process session))))
+
+(define (session-scalars->normalized-record session port)
+ "Display SESSION scalar fields to PORT in normalized form."
+ (format port "PID: ~a~%"
+ (process-id (daemon-session-process session)))
+ (format port "ClientPID: ~a~%"
+ (process-id (daemon-session-client session)))
+ (format port "ClientCommand:~{ ~a~}~%"
+ (process-command (daemon-session-client session))))
+
+(define (child-process->normalized-record process port)
+ "Display PROCESS record on PORT in normalized form"
+ (format port "PID: ~a" (process-id process))
+ (newline port)
+ (format port "Command:~{ ~a~}" (process-command process)))
+
+(define (daemon-sessions->normalized-record port sessions)
+ "Display SESSIONS recutils on PORT in normalized form"
+ (display session-rec-type port)
+ (newline port)
+ (newline port)
+ (for-each (lambda (session)
+ (session-scalars->normalized-record session port)
+ (for-each (lambda (lock)
+ (lock->recutils lock port))
+ (daemon-session-locks-held session))
+ (newline port))
+ sessions)
+
+ (display child-process-rec-type port)
+ (newline port)
+ (newline port)
+ (for-each (lambda (session)
+ (for-each (lambda (process)
+ (child-process->normalized-record process port)
+ (newline port)
+ (session-key->recutils session port)
+ (newline port)
+ (newline port))
+ (daemon-session-children session)))
+ sessions))
+
\f
;;;
;;; Options.
;;;
-(define %options
- (list (option '(#\h "help") #f #f
- (lambda args
- (show-help)
- (exit 0)))
- (option '(#\V "version") #f #f
- (lambda args
- (show-version-and-exit "guix processes")))))
+(define %available-formats
+ '("recutils" "recutils-normalized"))
+
+(define (list-formats)
+ (display (G_ "The available formats are:\n"))
+ (newline)
+ (for-each (lambda (f)
+ (format #t " - ~a~%" f))
+ %available-formats))
(define (show-help)
(display (G_ "Usage: guix processes
@@ -216,8 +289,33 @@ List the current Guix sessions and their processes."))
(display (G_ "
-V, --version display version information and exit"))
(newline)
+ (display (G_ "
+ -f, --format=FORMAT display results as normalized record sets"))
+ (newline)
+ (display (G_ "
+ --list-formats display available formats"))
(show-bug-report-information))
+(define %options
+ (list (option '(#\h "help") #f #f
+ (lambda args
+ (show-help)
+ (exit 0)))
+ (option '(#\V "version") #f #f
+ (lambda args
+ (show-version-and-exit "guix processes")))
+ (option '(#\f "format") #t #f
+ (lambda (opt name arg result)
+ (unless (member arg %available-formats)
+ (leave (G_ "~a: unsupported output format~%") arg))
+ (alist-cons 'format (string->symbol arg) result)))
+ (option '("list-formats") #f #f
+ (lambda (opt name arg result)
+ (list-formats)
+ (exit 0)))))
+
+(define %default-options '((format . recutils)))
+
\f
;;;
;;; Entry point.
@@ -227,17 +325,13 @@ List the current Guix sessions and their processes."))
(category plumbing)
(synopsis "list currently running sessions")
(define options
- (args-fold* args %options
- (lambda (opt name arg result)
- (leave (G_ "~A: unrecognized option~%") name))
- cons
- '()))
+ (parse-command-line args %options (list %default-options)))
(with-paginated-output-port port
- (for-each (lambda (session)
- (daemon-session->recutils session port)
- (newline port))
- (daemon-sessions))
+ (match (assoc-ref options 'format)
+ ('recutils-normalized
+ (daemon-sessions->normalized-record port (daemon-sessions)))
+ (_ (daemon-sessions->recutils port (daemon-sessions))))
;; Pass 'R' (instead of 'r') so 'less' correctly estimates line length.
#:less-options "FRX"))
--
2.29.1
next prev parent reply other threads:[~2020-11-11 17:52 UTC|newest]
Thread overview: 14+ messages / expand[flat|nested] mbox.gz Atom feed top
2020-11-05 4:31 [bug#44460] [PATCH] processes: Optionally normalize recutils output John Soo
2020-11-05 15:49 ` [bug#44460] processes: Don't normalize Locks John Soo
2020-11-05 16:01 ` [bug#44460] Fixup the output of Session John Soo
2020-11-06 23:34 ` [bug#44460] Add copyright lines John Soo
2020-11-10 22:15 ` Ludovic Courtès
2020-11-11 17:51 ` John Soo [this message]
2020-11-11 17:59 ` John Soo
2020-11-11 18:47 ` John Soo
2020-11-12 10:58 ` Ludovic Courtès
2020-11-12 15:37 ` John Soo
2020-11-12 20:29 ` Ludovic Courtès
2020-11-13 5:33 ` John Soo
2020-11-13 16:16 ` John Soo
2020-11-29 22:49 ` bug#44460: " Ludovic Courtès
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://guix.gnu.org/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=87imabok8j.fsf@asu.edu \
--to=jsoo1@asu.edu \
--cc=44460@debbugs.gnu.org \
--cc=ludo@gnu.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/guix.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).