[bug#65848] [PATCH 0/1] gnu: Add asl.

[bug#65848] [PATCH 0/1] gnu: Add asl.

[Simon South]

This patch adds asl, a package for the UNIX version of AS, a macro
cross-assembler that targets a wide range of microprocessors and
microcontrollers.

I've tested this on AArch64 and x86-64 (including cross-building from each
platform for the other) and all appears well.

---

Simon South (1):
  gnu: Add asl.

 gnu/packages/assembly.scm | 61 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)


base-commit: 5db78e7c1b06d1b4892bdb3e153b95b21577271e
-- 
2.41.0

[bug#65848] [PATCH 1/1] gnu: Add asl.

[Simon South]

* gnu/packages/assembly.scm (asl): New variable.
---
 gnu/packages/assembly.scm | 61 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

diff --git a/gnu/packages/assembly.scm b/gnu/packages/assembly.scm
index 81e38c3f41..f8777ede31 100644
--- a/gnu/packages/assembly.scm
+++ b/gnu/packages/assembly.scm
@@ -13,6 +13,7 @@
 ;;; Copyright © 2021 Guillaume Le Vaillant <glv@posteo.net>
 ;;; Copyright © 2022 Felix Gruber <felgru@posteo.net>
 ;;; Copyright © 2022 Andy Tai <atai@atai.org>
+;;; Copyright © 2023 Simon South <simon@simonsouth.net>
 ;;;
 ;;; This file is part of GNU Guix.
 ;;;
@@ -33,6 +34,7 @@ (define-module (gnu packages assembly)
   #:use-module (guix build-system meson)
   #:use-module (guix build-system cmake)
   #:use-module (guix build-system gnu)
+  #:use-module ((guix build utils) #:select (parallel-job-count))
   #:use-module (guix download)
   #:use-module (guix git-download)
   #:use-module ((guix licenses) #:prefix license:)
@@ -55,10 +57,69 @@ (define-module (gnu packages assembly)
   #:use-module (gnu packages python)
   #:use-module (gnu packages sphinx)
   #:use-module (gnu packages shells)
+  #:use-module (gnu packages tex)
   #:use-module (gnu packages xml)
   #:use-module ((guix utils)
                 #:select (%current-system cc-for-target)))
 
+(define-public asl
+  (let ((build "247"))
+    (package
+      (name "asl")
+      (version (string-append "1.42-beta-" build))
+      (source
+       (origin
+         (method url-fetch)
+         (uri (string-append
+               "http://john.ccac.rwth-aachen.de:8000/ftp/as/source/c_version/"
+               "asl-current-142-bld" build ".tar.bz2"))
+         (sha256
+          (base32 "1qgz5yzg50vpwzrjqvw8bgnvm67dqhfb8ldxyqwaqmrj3icshp5s"))))
+      (build-system gnu-build-system)
+      (arguments
+       (list
+        #:make-flags #~(list "V=1")     ; ensures output during "check" phase
+        #:phases
+        #~(modify-phases %standard-phases
+            (delete 'bootstrap)
+            (replace 'configure
+              (lambda* (#:key target #:allow-other-keys)
+                (copy-file "Makefile.def-samples/Makefile.def-unknown-linux"
+                           "Makefile.def")
+
+                ;; Use the cross-compilation tools when cross-compiling.
+                (when #$(%current-target-system)
+                  (substitute* "Makefile.def"
+                    (("^(TARG_(CC|LD) = ).*" all prefix)
+                     (string-append prefix target "-gcc\n"))))
+
+                ;; Set the output directories appropriately.
+                (substitute* "Makefile.def"
+                  (("^(DOCDIR = ).*" all prefix)
+                   (string-append prefix #$output:doc "/share/doc/" #$name))
+                  (("/usr/local")
+                   #$output))))
+            (add-after 'check 'build-doc
+              (lambda* (#:key parallel-build? #:allow-other-keys)
+                (invoke "make"
+                        "-j" (if parallel-build?
+                                 (number->string (parallel-job-count))
+                                 "1")
+                        "docs"))))
+        #:test-target "test"))
+      (native-inputs
+       (list (texlive-updmap.cfg (list texlive-german texlive-hyperref))))
+      (outputs '("out" "doc"))
+      (home-page "http://john.ccac.rwth-aachen.de:8000/as/")
+      (synopsis
+       "AS macro cross-assembler for microprocessors and microcontrollers")
+      (description
+       "AS is a portable macro cross-assembler targeting a wide range of
+microprocessors and microcontrollers, including devices from Intel, Motorola,
+MOS Technology, Hitachi, Fujitsu, NEC, Texas Instruments, Zilog and many other
+manufacturers.")
+      (license (list license:gpl2 license:gpl3)))))
+
 (define-public nasm
   (package
     (name "nasm")
-- 
2.41.0

bug#65848: [PATCH 0/1] gnu: Add asl.

[Ludovic Courtès]

Hi,

Simon South <simon@simonsouth.net> skribis:

> * gnu/packages/assembly.scm (asl): New variable.

Applied, thanks!

Ludo’.