[bug#36652] [PATCH 0/2] Add Xygrib.

[bug#36652] [PATCH 0/2] Add Xygrib.

[Efraim Flashner]

Xygrib is the continuation of Zygrib, a now abandoned weather platform
which takes the weather data produced by various governments and makes
it easily available to everyone.

I wasn't sure where to put xygrib itself. I was going to put it in a new
weather.scm module, but geo seemed like it fit.

Efraim Flashner (2):
  gnu: Add libnova.
  gnu: Add xygrib.

 gnu/packages/astronomy.scm | 35 ++++++++++++++++++++
 gnu/packages/geo.scm       | 68 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 103 insertions(+)

-- 
2.22.0

[bug#36652] [PATCH 1/2] gnu: Add libnova.

[Efraim Flashner]

* gnu/packages/astronomy.scm (libnova): New variable.
---
 gnu/packages/astronomy.scm | 35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

diff --git a/gnu/packages/astronomy.scm b/gnu/packages/astronomy.scm
index 4cf7c10352..2bce26a754 100644
--- a/gnu/packages/astronomy.scm
+++ b/gnu/packages/astronomy.scm
@@ -254,3 +254,38 @@ accurately in real time at any rate desired.")
     (arguments
      `(#:configure-flags '("-DENABLE_GTK=ON" "-DENABLE_QT=OFF")
        #:tests? #f))))
+
+(define-public libnova
+  (package
+    (name "libnova")
+    (version "0.16")
+    (source
+      (origin
+        (method git-fetch)
+        (uri (git-reference
+               (url "https://git.code.sf.net/p/libnova/libnova.git")
+               (commit (string-append "v" version))))
+        (file-name (git-file-name name version))
+        (sha256
+         (base32
+          "0icwylwkixihzni0kgl0j8dx3qhqvym6zv2hkw2dy6v9zvysrb1b"))))
+    (build-system gnu-build-system)
+    (arguments
+     `(#:phases
+       (modify-phases %standard-phases
+         (add-after 'unpack 'patch-git-version
+           (lambda _
+             (substitute* "./git-version-gen"
+               (("/bin/sh") (which "sh")))
+             #t)))))
+    (native-inputs
+     `(("autoconf" ,autoconf)
+       ("automake" ,automake)
+       ("libtool" ,libtool)))
+    (synopsis "Celestial mechanics, astrometry and astrodynamics library")
+    (description "Libnova is a general purpose, double precision, Celestial
+Mechanics, Astrometry and Astrodynamics library.")
+     (home-page "http://libnova.sourceforge.net/")
+     (license (list license:lgpl2.0
+                    license:gpl2)))) ; examples/transforms.c & lntest/*.c
+
-- 
2.22.0

[bug#36652] [PATCH 2/2] gnu: Add xygrib.

[Efraim Flashner]

* gnu/packages/geo.scm (xygrib): New variable.
---
 gnu/packages/geo.scm | 68 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

diff --git a/gnu/packages/geo.scm b/gnu/packages/geo.scm
index 4cccd97643..e4b6a262c7 100644
--- a/gnu/packages/geo.scm
+++ b/gnu/packages/geo.scm
@@ -8,6 +8,7 @@
 ;;; Copyright © 2018 Joshua Sierles, Nextjournal <joshua@nextjournal.com>
 ;;; Copyright © 2018 Julien Lepiller <julien@lepiller.eu>
 ;;; Copyright © 2019 Guillaume Le Vaillant <glv@posteo.net>
+;;; Copyright © 2019 Efraim Flashner <efraim@flashner.co.il>
 ;;;
 ;;; This file is part of GNU Guix.
 ;;;
@@ -37,6 +38,7 @@
   #:use-module ((guix licenses) #:prefix license:)
   #:use-module (guix packages)
   #:use-module (guix utils)
+  #:use-module (gnu packages astronomy)
   #:use-module (gnu packages autotools)
   #:use-module (gnu packages boost)
   #:use-module (gnu packages check)
@@ -44,6 +46,7 @@
   #:use-module (gnu packages databases)
   #:use-module (gnu packages datastructures)
   #:use-module (gnu packages documentation)
+  #:use-module (gnu packages fonts)
   #:use-module (gnu packages fontutils)
   #:use-module (gnu packages glib)
   #:use-module (gnu packages gnome)
@@ -57,6 +60,7 @@
   #:use-module (gnu packages protobuf)
   #:use-module (gnu packages python)
   #:use-module (gnu packages python-xyz)
+  #:use-module (gnu packages qt)
   #:use-module (gnu packages sqlite)
   #:use-module (gnu packages web)
   #:use-module (gnu packages webkit)
@@ -902,3 +906,67 @@ given GPS coordinates,draws a GPS track, and points of interest on a moving
 map display.  Downloads map data from a number of websites, including
 @url{https://www.openstreetmap.org}.")
     (license license:gpl2+)))
+
+(define-public xygrib
+  (package
+    (name "xygrib")
+    (version "1.2.6")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                     (url "https://github.com/opengribs/XyGrib.git")
+                     (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "0qzaaavil2c7mkkai5mg54cv8r452i7psy7cg75qjja96d2d7rbd"))
+              (modules '((guix build utils)))
+              (snippet
+               '(begin (delete-file-recursively "data/fonts") #t))))
+    (build-system cmake-build-system)
+    (arguments
+     `(#:phases
+       (modify-phases %standard-phases
+         (add-after 'unpack 'patch-directories
+           (lambda* (#:key inputs #:allow-other-keys)
+             (let ((jpeg (assoc-ref inputs "openjpeg"))
+                   (font (assoc-ref inputs "font-liberation")))
+               (substitute* "CMakeLists.txt"
+                 ;; Find libjpeg.
+                 (("/usr") jpeg)
+                 ;; Fix install locations.
+                 (("set\\(PREFIX_BIN.*") "set(PREFIX_BIN \"bin\")\n")
+                 (("set\\(PREFIX_PKGDATA.*") "set(PREFIX_PKGDATA \"share/${PROJECT_NAME}\")\n")
+                 ;; Skip looking for the static library.
+                 (("\"libnova.a\"") ""))
+               ;; Don't use the bundled font-liberation.
+               (substitute* "src/util/Font.cpp"
+                 (("Util::pathFonts\\(\\)\\+\"liberation-fonts/\"")
+                  (string-append "\"" font "/share/fonts/truetype/\"")))
+               (substitute* "src/util/Util.h"
+                 (("pathData\\(\\)\\+\"data/fonts/\"")
+                  (string-append "\"" font "/share/fonts/\""))))
+             #t)))
+       #:tests? #f)) ; no tests
+    (native-inputs
+     `(("qttools" ,qttools)))
+    (inputs
+     `(("bzip2" ,bzip2)
+       ("font-liberation" ,font-liberation)
+       ("libnova" ,libnova)
+       ("libpng" ,libpng)
+       ("openjpeg" ,openjpeg)
+       ("proj.4" ,proj.4)
+       ("qtbase" ,qtbase)
+       ("zlib" ,zlib)))
+    (synopsis "Weather Forecast Visualization")
+    (description
+     "XyGrib is a Grib file reader and visualizes meteorological data providing
+an off-line capability to analyse weather forecasts or hindcasts.  It is
+intended to be used as a capable weather work station for anyone with a serious
+interest in examining weather. This would include members of the sailing
+community, private and sport aviators, farmers, weather buffs and many more.
+XyGrib is the continuation of the zyGrib software package with a new team of
+volunteers.")
+    (home-page "https://opengribs.org")
+    (license license:gpl3+)))
-- 
2.22.0

[bug#36652] [PATCH 1/2] gnu: Add libnova.

[Ludovic Courtès]

Hello!

Efraim Flashner <efraim@flashner.co.il> skribis:

> * gnu/packages/astronomy.scm (libnova): New variable.

[...]

> +    (synopsis "Celestial mechanics, astrometry and astrodynamics library")
> +    (description "Libnova is a general purpose, double precision, Celestial
> +Mechanics, Astrometry and Astrodynamics library.")
> +     (home-page "http://libnova.sourceforge.net/")
> +     (license (list license:lgpl2.0
        ^

Extra space here and on the line before.  :-)

From a quick sampling of the source file headers, it appears to be
‘lgpl2.0+’.


> +                    license:gpl2)))) ; examples/transforms.c & lntest/*.c

These files are ‘gpl2+’ AFAICS.

Otherwise LGTM, thanks!

Ludo’.

[bug#36652] [PATCH 2/2] gnu: Add xygrib.

[Ludovic Courtès]

Efraim Flashner <efraim@flashner.co.il> skribis:

> * gnu/packages/geo.scm (xygrib): New variable.

LGTM, thanks!

bug#36652: [PATCH 2/2] gnu: Add xygrib.

[Efraim Flashner]

[-- Attachment #1: Type: text/plain, Size: 427 bytes --]

On Wed, Jul 17, 2019 at 03:13:03PM +0200, Ludovic Courtès wrote:
> Efraim Flashner <efraim@flashner.co.il> skribis:
> 
> > * gnu/packages/geo.scm (xygrib): New variable.
> 
> LGTM, thanks!

Patches pushed

-- 
Efraim Flashner   <efraim@flashner.co.il>   אפרים פלשנר
GPG key = A28B F40C 3E55 1372 662D  14F7 41AA E7DC CA3D 8351
Confidentiality cannot be guaranteed on emails sent or received unencrypted

[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 833 bytes --]