From: Danny Milosavljevic <dannym@scratchpost.org>
To: 31265@debbugs.gnu.org
Subject: [bug#31265] [PATCH 2/6] build: Add the Android NDK build-system.
Date: Thu, 26 Apr 2018 02:15:56 +0200 [thread overview]
Message-ID: <20180426001600.28974-2-dannym@scratchpost.org> (raw)
In-Reply-To: <20180426001600.28974-1-dannym@scratchpost.org>
* guix/build-system/android-ndk.scm: New file.
* guix/build/android-ndk-build-system.scm: New file.
* Makefile.am: Add them.
* gnu/packages/android.scm (android-make-stub): New variable.
---
Makefile.am | 2 +
gnu/packages/android.scm | 36 +++++++++
guix/build-system/android-ndk.scm | 126 ++++++++++++++++++++++++++++++++
guix/build/android-ndk-build-system.scm | 86 ++++++++++++++++++++++
4 files changed, 250 insertions(+)
create mode 100644 guix/build-system/android-ndk.scm
create mode 100644 guix/build/android-ndk-build-system.scm
diff --git a/Makefile.am b/Makefile.am
index 9f134c970..03fb870eb 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -96,6 +96,7 @@ MODULES = \
guix/workers.scm \
guix/zlib.scm \
guix/build-system.scm \
+ guix/build-system/android-ndk.scm \
guix/build-system/ant.scm \
guix/build-system/cargo.scm \
guix/build-system/cmake.scm \
@@ -128,6 +129,7 @@ MODULES = \
guix/svn-download.scm \
guix/i18n.scm \
guix/ui.scm \
+ guix/build/android-ndk-build-system.scm \
guix/build/ant-build-system.scm \
guix/build/download.scm \
guix/build/download-nar.scm \
diff --git a/gnu/packages/android.scm b/gnu/packages/android.scm
index 92de9736f..285a28515 100644
--- a/gnu/packages/android.scm
+++ b/gnu/packages/android.scm
@@ -39,6 +39,42 @@
#:use-module (gnu packages tls)
#:use-module (gnu packages linux))
+(define-public android-make-stub
+ (let ((commit "v0.1")
+ (revision "21"))
+ (package
+ (name "android-make-stub")
+ (version "0.1")
+ (source
+ (origin
+ (method git-fetch)
+ (uri (git-reference
+ (url "https://github.com/daym/android-make-stub.git")
+ (commit commit)))
+ (file-name (string-append "android-make-stub-"
+ version "-checkout"))
+ (sha256
+ (base32
+ "1ni4szpcx2clf3lpzrybabwk7bgvsl6ynng7xxfc49y4jkdkk4sh"))))
+ (build-system gnu-build-system)
+ (arguments
+ `(#:tests? #f ; None exist.
+ #:phases
+ (modify-phases %standard-phases
+ (delete 'configure)
+ (delete 'build)
+ (replace 'install
+ (lambda* (#:key outputs #:allow-other-keys)
+ (let* ((out (assoc-ref outputs "out")))
+ (invoke "make" (string-append "prefix=" out) "install")
+ #t))))))
+ (home-page "https://github.com/daym/android-make-stub")
+ (synopsis "Stubs for the @command{make} system of the Android platform")
+ (description "@code{android-make-stub} provides stubs for the
+@command{make} system of the Android platform. This allows us to
+use their packages mostly unmodified in our Android NDK build system.")
+ (license license:asl2.0))))
+
;; The Makefiles that we add are largely based on the Debian
;; packages. They are licensed under GPL-2 and have copyright:
;; 2012, Stefan Handschuh <handschuh.stefan@googlemail.com>
diff --git a/guix/build-system/android-ndk.scm b/guix/build-system/android-ndk.scm
new file mode 100644
index 000000000..842d983a6
--- /dev/null
+++ b/guix/build-system/android-ndk.scm
@@ -0,0 +1,126 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2016 Danny Milosavljevic <dannym@scratchpost.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build-system android-ndk)
+ #:use-module (guix search-paths)
+ #:use-module (guix store)
+ #:use-module (guix utils)
+ #:use-module (guix derivations)
+ #:use-module (guix packages)
+ #:use-module (guix build-system)
+ #:use-module (guix build-system gnu)
+ #:use-module (ice-9 match)
+ #:use-module (srfi srfi-26)
+ #:export (android-ndk-build-system))
+
+(define %android-ndk-build-system-modules
+ ;; Build-side modules imported by default.
+ `((guix build android-ndk-build-system)
+ (guix build syscalls)
+ ,@%gnu-build-system-modules))
+
+(define* (android-ndk-build store name inputs
+ #:key
+ (tests? #t)
+ (test-target #f)
+ (phases '(@ (guix build android-ndk-build-system)
+ %standard-phases))
+ (outputs '("out"))
+ (make-flags ''())
+ (search-paths '())
+ (system (%current-system))
+ (guile #f)
+ (imported-modules %android-ndk-build-system-modules)
+ (modules '((guix build android-ndk-build-system)
+ (guix build utils))))
+ "Build SOURCE using Android NDK, and with INPUTS."
+ (define builder
+ `(begin
+ (use-modules ,@modules)
+ (android-ndk-build #:name ,name
+ #:source ,(match (assoc-ref inputs "source")
+ (((? derivation? source))
+ (derivation->output-path source))
+ ((source)
+ source)
+ (source
+ source))
+ #:system ,system
+ #:test-target ,test-target
+ #:tests? ,tests?
+ #:phases ,phases
+ #:make-flags (cons* "-f"
+ ,(string-append
+ (derivation->output-path
+ (car (assoc-ref inputs "android-make-stub")))
+ "/share/android-make-stub/Makefile")
+ ,make-flags)
+ #:outputs %outputs
+ #:search-paths ',(map search-path-specification->sexp
+ search-paths)
+ #:inputs %build-inputs)))
+
+ (define guile-for-build
+ (match guile
+ ((? package?)
+ (package-derivation store guile system #:graft? #f))
+ (#f ; the default
+ (let* ((distro (resolve-interface '(gnu packages commencement)))
+ (guile (module-ref distro 'guile-final)))
+ (package-derivation store guile system #:graft? #f)))))
+
+ (build-expression->derivation store name builder
+ #:inputs inputs
+ #:system system
+ #:modules imported-modules
+ #:outputs outputs
+ #:guile-for-build guile-for-build))
+
+(define* (lower name
+ #:key source inputs native-inputs outputs system target
+ #:allow-other-keys
+ #:rest arguments)
+ "Return a bag for NAME."
+
+ (define private-keywords
+ '(#:source #:target #:inputs #:native-inputs #:outputs))
+
+ (and (not target) ;; TODO: support cross-compilation
+ (bag
+ (name name)
+ (system system)
+ (target target)
+ (host-inputs `(,@(if source
+ `(("source" ,source))
+ '())
+ ,@inputs
+
+ ;; Keep the standard inputs of 'gnu-build-system'
+ ,@(standard-packages)))
+ (build-inputs `(("android-make-stub" ,(module-ref (resolve-interface '(gnu packages android)) 'android-make-stub))
+ ,@native-inputs))
+ (outputs outputs)
+ (build android-ndk-build)
+ (arguments (strip-keyword-arguments private-keywords arguments)))))
+
+(define android-ndk-build-system
+ (build-system
+ (name 'android-ndk)
+ (description
+ "Android NDK build system, to build Android NDK packages")
+ (lower lower)))
diff --git a/guix/build/android-ndk-build-system.scm b/guix/build/android-ndk-build-system.scm
new file mode 100644
index 000000000..b5d4b36d3
--- /dev/null
+++ b/guix/build/android-ndk-build-system.scm
@@ -0,0 +1,86 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2018 Danny Milosavljevic <dannym@scratchpost.org>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (guix build android-ndk-build-system)
+ #:use-module ((guix build gnu-build-system) #:prefix gnu:)
+ #:use-module (guix build syscalls)
+ #:use-module (guix build utils)
+ #:use-module (ice-9 popen)
+ #:use-module (ice-9 rdelim)
+ #:use-module (ice-9 ftw)
+ #:use-module (ice-9 format)
+ #:use-module (ice-9 match)
+ #:use-module (rnrs io ports)
+ #:use-module (srfi srfi-1)
+ #:use-module (srfi srfi-26)
+ #:export (%standard-phases
+ android-ndk-build))
+
+;; Commentary:
+;;
+;; Builder-side code of the Android NDK build system.
+;;
+;; Code:
+
+(define* (configure #:key inputs outputs #:allow-other-keys)
+ (let ((library-directories (filter-map (match-lambda
+ ((name . path)
+ (if (eq? 'directory (stat:type (stat path)))
+ path
+ #f)))
+ inputs)))
+ (setenv "CC" "gcc")
+ (setenv "CXX" "g++")
+ (setenv "CPPFLAGS"
+ (string-join
+ (map (cut string-append "-I " <> "/include") library-directories)
+ " "))
+ (setenv "LDFLAGS"
+ (string-append "-L . "
+ (string-join
+ (map (lambda (x)
+ (string-append "-L " x "/lib" " -Wl,-rpath=" x "/lib"))
+ library-directories)
+ " ")))
+ #t))
+
+(define* (install #:key inputs outputs (make-flags '()) #:allow-other-keys)
+ (let ((out (assoc-ref outputs "out")))
+ (apply invoke "make" "install"
+ (string-append "prefix=" out)
+ make-flags)
+ (if (file-exists? "include")
+ (copy-recursively "include" (string-append out "/include")))
+ #t))
+
+(define* (check #:key inputs outputs tests? (make-flags '()) #:allow-other-keys)
+ ;; TODO: Also handle root-level tests.
+ (when (and (file-exists? "tests") tests?)
+ (with-directory-excursion "tests"
+ (apply invoke "make" "check" make-flags))))
+
+(define %standard-phases
+ (modify-phases gnu:%standard-phases
+ (replace 'configure configure)
+ (replace 'install install)
+ (replace 'check check)))
+
+(define* (android-ndk-build #:key inputs (phases %standard-phases)
+ #:allow-other-keys #:rest args)
+ "Build the given Android NDK package, applying all of PHASES in order."
+ (apply gnu:gnu-build #:inputs inputs #:phases phases args))
next prev parent reply other threads:[~2018-04-26 0:17 UTC|newest]
Thread overview: 9+ messages / expand[flat|nested] mbox.gz Atom feed top
2018-04-26 0:13 [bug#31265] [PATCH 0/6] Add Android NDK build system Danny Milosavljevic
2018-04-26 0:15 ` [bug#31265] [PATCH 1/6] gnu: Add f2fs-tools@1.7.0 Danny Milosavljevic
2018-04-26 0:15 ` Danny Milosavljevic [this message]
2018-04-26 0:15 ` [bug#31265] [PATCH 3/6] gnu: liblog: Use android-ndk-build-system Danny Milosavljevic
2018-04-26 0:15 ` [bug#31265] [PATCH 4/6] gnu: libbase: " Danny Milosavljevic
2018-04-26 0:15 ` [bug#31265] [PATCH 5/6] gnu: adb: " Danny Milosavljevic
2018-04-26 0:16 ` [bug#31265] [PATCH 6/6] gnu: mkbootimg: Install "bootimg.h" Danny Milosavljevic
2018-05-01 10:27 ` [bug#31265] Add Android NDK build system Julien Lepiller
2018-05-09 17:34 ` bug#31265: " Danny Milosavljevic
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://guix.gnu.org/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20180426001600.28974-2-dannym@scratchpost.org \
--to=dannym@scratchpost.org \
--cc=31265@debbugs.gnu.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/guix.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).