[bug#41490] [PATCH 0/5] Add pEp (pretty Easy privacy)

[bug#41490] [PATCH 0/5] Add pEp (pretty Easy privacy)

[Hartmut Goebel]

This adds the build tools and libraries for pretty Easy Privacy, a library for
automatic key management and encryption of messages.

How shall we name the packages here?
I'd appreciate feedback to the package names, since the original packages have
quiet uncommon names:

- pEpEngine -> pep-engine (main library)
- libpEpAdapter -> intermediate layer library
- pEpPythonAdapter -> python-pep-adapter
- pEpJNIAdapter -> java-pep-adapter

The project as other packages like these:
- pEpQtAdapter
- pEpJSONServerAdapter
- pEpObjCAdapter

In Arch Linux AUR packages are named pep-engine, libpep-adapter,
python-pep-adapter, pep-jni-adapter, pep-qt-adapter.

Hartmut Goebel (5):
  gnu: Add yml2.
  gnu: Add pep-engine.
  gnu: Add libpepadapter.
  gnu: Add python-pep-adapter.
  gnu: Add java-pep-adapter.

 gnu/local.mk         |   1 +
 gnu/packages/pep.scm | 349 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 350 insertions(+)
 create mode 100644 gnu/packages/pep.scm

-- 
2.21.3

[bug#41490] [PATCH 1/5] gnu: Add yml2.

[Hartmut Goebel]

* gnu/packages/pep.scm: New file.
* gnu/locak.mk (GNU_SYSTEM_MODULES): Add it.
---
 gnu/local.mk         |  1 +
 gnu/packages/pep.scm | 49 ++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 50 insertions(+)
 create mode 100644 gnu/packages/pep.scm

diff --git a/gnu/local.mk b/gnu/local.mk
index 2f24f892b1..ac22c7f224 100644
--- a/gnu/local.mk
+++ b/gnu/local.mk
@@ -412,6 +412,7 @@ GNU_SYSTEM_MODULES =				\
   %D%/packages/pcre.scm				\
   %D%/packages/pdf.scm				\
   %D%/packages/pem.scm				\
+  %D%/packages/pep.scm				\
   %D%/packages/perl.scm				\
   %D%/packages/perl-check.scm			\
   %D%/packages/perl-compression.scm		\
diff --git a/gnu/packages/pep.scm b/gnu/packages/pep.scm
new file mode 100644
index 0000000000..9e5be66f78
--- /dev/null
+++ b/gnu/packages/pep.scm
@@ -0,0 +1,49 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2016, 2020 Hartmut Goebel <h.goebel@crazy-compilers.com>
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu packages pep)
+  #:use-module ((guix licenses) #:prefix license:)
+  #:use-module (guix packages)
+  #:use-module (guix hg-download)
+  #:use-module (guix build-system python)
+  #:use-module (gnu packages)
+  #:use-module (gnu packages xml))
+
+(define-public yml2
+  (package
+    (name "yml2")
+    (version "2.6.3")
+    (source (origin
+       (method hg-fetch)
+       (uri (hg-reference
+             (url "https://pep.foundation/dev/repos/yml2")
+             (changeset version)))
+       (file-name (string-append name "-" version "-checkout"))
+       (sha256
+        (base32 "10jjjyq1mz18zkzvxd62aba00h69gd9cglisqcvb81j67ml2v1bx"))))
+    (build-system python-build-system)
+    (propagated-inputs
+     `(("python-lxml" ,python-lxml)))
+    (home-page "https://fdik.org/yml/")
+    (synopsis "Use a Domain Specific Language for XML without defining
+a grammar")
+    (description "The YML compiler is a small Python script.  It
+provides the command line front end yml2c.  As default, it compiles
+your script and outputs to stdout, that usually is the terminal.  Your
+shell provides options to redirect the output into a pipe or a file.")
+    (license license:gpl2)))
-- 
2.21.3

[bug#41490] [PATCH 2/5] gnu: Add pep-engine.

[Hartmut Goebel]

* gnu/packages/pep.scm (fdik-libetpan, sequoia4pEp, pep-engine): New
  variables.
---
 gnu/packages/pep.scm | 106 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 106 insertions(+)

diff --git a/gnu/packages/pep.scm b/gnu/packages/pep.scm
index 9e5be66f78..57fb0e88f3 100644
--- a/gnu/packages/pep.scm
+++ b/gnu/packages/pep.scm
@@ -19,9 +19,19 @@
 (define-module (gnu packages pep)
   #:use-module ((guix licenses) #:prefix license:)
   #:use-module (guix packages)
+  #:use-module (guix git-download)
   #:use-module (guix hg-download)
+  #:use-module (guix build-system gnu)
   #:use-module (guix build-system python)
   #:use-module (gnu packages)
+  #:use-module (gnu packages base)
+  #:use-module (gnu packages linux)
+  #:use-module (gnu packages mail) ; for libetpan
+  #:use-module (gnu packages nettle)
+  #:use-module (gnu packages pkg-config)
+  #:use-module (gnu packages sequoia)
+  #:use-module (gnu packages sqlite)
+  #:use-module (gnu packages tls)
   #:use-module (gnu packages xml))
 
 (define-public yml2
@@ -47,3 +57,99 @@ provides the command line front end yml2c.  As default, it compiles
 your script and outputs to stdout, that usually is the terminal.  Your
 shell provides options to redirect the output into a pipe or a file.")
     (license license:gpl2)))
+
+(define fdik-libetpan
+  ;; pEp Engine requires libetpan with a set of patches that have not been
+  ;; upstreamed yet.
+  (let ((commit "370050956b7ee95b0c3b54c018b40ad1f366683a") ; 2019-11-12
+        (checksum "0lcqcnij3ray7nssvq0lzb352wmnab8ffzk7dgff2c68mvjbh1l6")
+        (revision "4"))
+   (package
+    (inherit libetpan)
+    (name "fdik-libetpan")
+    (version (string-append "1.6-" revision "." (string-take commit 8)))
+    (source
+     (origin
+       (inherit (package-source libetpan))
+       (method git-fetch)
+       (uri (git-reference
+             (url "https://github.com/fdik/libetpan")
+             (commit commit)))
+       (file-name (string-append name "-" version))
+       (sha256 (base32 checksum)))))))
+
+(define sequoia4pEp
+  ;; Currently pEp Engine requires sequoia in not-so-current version
+  (package/inherit sequoia
+    (name "sequoia")
+    (version "0.15.0-pEp")
+    (source
+     (origin
+       (method git-fetch)
+       (uri (git-reference
+             (url "https://gitlab.com/sequoia-pgp/sequoia.git")
+             (commit "0eb1b6cd846ea8c36b3dfdf01ec88383fc64f2fe")))
+       (sha256
+        (base32 "06dqs9whwp9lfibwp8dqm0aw4nm3s3v4jp2n4fz51zcvsld40nfh"))
+       (file-name (git-file-name name version))))))
+
+(define-public pep-engine
+  (package
+    (name "pep-engine")
+    (version "2.0.5")
+    (source
+     (origin
+       (method hg-fetch)
+       (uri (hg-reference
+             (url "https://pep.foundation/dev/repos/pEpEngine")
+             (changeset "3db667f48863"))) ;; r4701
+       (file-name (string-append name "-" version "-checkout"))
+       (sha256
+        (base32 "0ljf79j4ng7l8w6pbdcrfzb4yk51zslypvq0n72ib1d7grqvnagi"))))
+    (build-system gnu-build-system)
+    (arguments
+     '(#:parallel-build? #f
+       #:phases
+       (modify-phases %standard-phases
+         (replace 'configure
+           ;; pEpEngie does not use autotools and configure,
+           ;; but a local.conf. We need to tweak the values there.
+           (lambda* (#:key inputs outputs #:allow-other-keys)
+             (let ((out (assoc-ref outputs "out"))
+                   (yml2 (assoc-ref inputs "yml2")))
+               (with-output-to-file "local.conf"
+                 (lambda ()
+                   (format #t "
+PREFIX=~a
+PER_MACHINE_DIRECTORY=${PREFIX}/share/pEp
+SYSTEM_DB=~a/share/pEp/system.db
+ASN1C=~a
+YML2_PATH=~a
+OPENPGP=SEQUOIA
+"
+                           out out (which "asn1c")
+                           (string-append yml2 "/bin"))))
+               #t)))
+         (delete 'check)
+         (add-after 'install 'install-db
+           (lambda _
+             (invoke "make" "-C" "db" "install"))))))
+    (native-inputs
+     `(("asn1c" ,asn1c) ; >= 0.9.27
+       ("pkg-config" ,pkg-config)
+       ("yml2" ,yml2)))
+    (inputs
+     `(("libetpan" ,fdik-libetpan)
+       ("libiconv" ,libiconv)
+       ("nettle" ,nettle)
+       ("openssl" ,openssl)
+       ("sequoia" ,sequoia4pEp)
+       ("sqlite3" ,sqlite)
+       ("util-linux" ,util-linux "lib"))) ;; uuid.h
+    (home-page "https://pep.foundation/")
+    (synopsis "Library for automatic key management and encryption of
+messages")
+    (description "The p≡p engine is the core part of p≡p (pretty Easy
+privacy).")
+    (license ;; code: GPL 3, docs: CC-BY-SA
+     (list license:gpl3 license:cc-by-sa3.0))))
-- 
2.21.3

[bug#41490] [PATCH 3/5] gnu: Add libpepadapter.

[Hartmut Goebel]

* gnu/packages/pep.scm (libpepadapter): New variable.
---
 gnu/packages/pep.scm | 41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

diff --git a/gnu/packages/pep.scm b/gnu/packages/pep.scm
index 57fb0e88f3..9452435c35 100644
--- a/gnu/packages/pep.scm
+++ b/gnu/packages/pep.scm
@@ -153,3 +153,44 @@ messages")
 privacy).")
     (license ;; code: GPL 3, docs: CC-BY-SA
      (list license:gpl3 license:cc-by-sa3.0))))
+
+(define-public libpepadapter
+  (package
+    (name "libpepadapter")
+    (version "2.0.2")
+    (source
+     (origin
+       (method hg-fetch)
+       (uri (hg-reference
+             (url "https://pep.foundation/dev/repos/libpEpAdapter")
+             (changeset "e8fe371c870a"))) ;; r168
+       (file-name (string-append name "-" version "-checkout"))
+       (sha256
+        (base32 "1mlpavjbnmslvmr5jxcvpjgb2x40nhmxjb10hza3kn4qzj0k1pjz"))))
+    (build-system gnu-build-system)
+    (arguments
+     '(#:test-target "test"
+       #:tests? #f ;; building the tests fails
+       #:phases
+       (modify-phases %standard-phases
+         (replace 'configure
+           ;; libpEpAdapter does not use autotools and configure,
+           ;; but a local.conf. We need to tweak the values there.
+           (lambda* (#:key inputs outputs #:allow-other-keys)
+             (let ((out (assoc-ref outputs "out"))
+                   (engine (assoc-ref inputs "pep-engine")))
+               (with-output-to-file "local.conf"
+                 (lambda _ ;()
+                   (format #t "
+PREFIX=~a
+ENGINE_LIB_PATH=~a/lib
+ENGINE_INC_PATH=~a/include
+" out engine engine))))
+             #t)))))
+    (inputs
+     `(("pep-engine" ,pep-engine)))
+    (home-page "https://pep.foundation/")
+    (synopsis "Library for building p≡p adapters")
+    (description "This C++ library provides common structures used in p≡p
+(pretty Easy privacy) adapters.")
+    (license license:bsd-3)))
-- 
2.21.3

[bug#41490] [PATCH 4/5] gnu: Add python-pep-adapter.

[Hartmut Goebel]

* gnu/packages/pep.scm (python-pep-adapter): New variable.
---
 gnu/packages/pep.scm | 53 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/gnu/packages/pep.scm b/gnu/packages/pep.scm
index 9452435c35..bcef915970 100644
--- a/gnu/packages/pep.scm
+++ b/gnu/packages/pep.scm
@@ -25,6 +25,7 @@
   #:use-module (guix build-system python)
   #:use-module (gnu packages)
   #:use-module (gnu packages base)
+  #:use-module (gnu packages boost)
   #:use-module (gnu packages linux)
   #:use-module (gnu packages mail) ; for libetpan
   #:use-module (gnu packages nettle)
@@ -194,3 +195,55 @@ ENGINE_INC_PATH=~a/include
     (description "This C++ library provides common structures used in p≡p
 (pretty Easy privacy) adapters.")
     (license license:bsd-3)))
+
+(define-public python-pep-adapter
+  (package
+    (name "python-pep-adapter")
+    (version "2.0.5")
+    (source
+     (origin
+       (method hg-fetch)
+       (uri (hg-reference
+             (url "https://pep.foundation/dev/repos/pEpPythonAdapter")
+             (changeset "66df0e5b9405"))) ;; r374
+       (file-name (string-append name "-" version "-checkout"))
+       (sha256
+        (base32 "107i1s8jf8gyhpmqcs64q9csxa3fwc8g7s57iyccqb4czw8gph6d"))))
+    (build-system python-build-system)
+    (arguments
+     `(;; Adding configure-flags does not work, running `build_ext`
+       ;; with these flags, neither does adding the options to
+       ;; `setup.cfg`: Either `build` or `install` fails (since
+       ;; flags are given or missing), or "command 'BuildExtCommand'
+       ;; has no such option 'pep_engine"
+       ;; '(#:configure-flags
+       ;;          (list (string-append "--with-pEp-engine="
+       ;;                           (assoc-ref inputs "pEpEngine"))
+       ;;                (string-append "--with-pEp-libadapter="
+       ;;                           (assoc-ref inputs "libpEpAdapter"))
+       ;;                ;;(string-append "--boost="
+       ;;                           (assoc-ref inputs "boost")) not supported
+       ;;                (string-append "--with-asn1c-share="
+       ;;                           (assoc-ref inputs "asn1c") "/share"))
+       #:phases
+       (modify-phases %standard-phases
+         (add-before 'build 'fix-setup.py
+           (lambda _
+             (substitute* "setup.py"
+               (("^(\\s+SYS_INCLUDES = )\\['/usr.*" _ a)
+                (string-append a "os.getenv('CPATH', '').split(os.pathsep)\n"))
+               (("^(\\s+SYS_LIB_PREFIXES = )\\['/usr.*" _ a)
+                (string-append a "os.getenv('LIBRARY_PATH', '').split(os.pathsep)\n"))
+               (("^(\\s+SYS_SHARES = )\\['/usr.*" _ a)
+                (string-append a "['" (assoc-ref %build-inputs "asn1c") "/share']\n")))
+             #t)))))
+    (inputs
+     `(("asn1c" ,asn1c)
+       ("boost-python" ,boost-with-python3)
+       ("libpepadapter" ,libpepadapter)
+       ("pep-engine" ,pep-engine)))
+    (home-page "https://pep.foundation/")
+    (synopsis "Python adapter for p≡p (pretty Easy Privacy)")
+    (description "The p≡p Python adapter is an adaptor interface to the p≡p
+(pretty Easy privacy) engine.")
+    (license license:gpl3)))
-- 
2.21.3

[bug#41490] [PATCH 5/5] gnu: Add java-pep-adapter.

[Hartmut Goebel]

* gnu/packages/pep.scm (java-pep-adapter): New variable.
---
 gnu/packages/pep.scm | 100 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 100 insertions(+)

diff --git a/gnu/packages/pep.scm b/gnu/packages/pep.scm
index bcef915970..0f169efd22 100644
--- a/gnu/packages/pep.scm
+++ b/gnu/packages/pep.scm
@@ -26,6 +26,8 @@
   #:use-module (gnu packages)
   #:use-module (gnu packages base)
   #:use-module (gnu packages boost)
+  #:use-module (gnu packages documentation)
+  #:use-module (gnu packages java)
   #:use-module (gnu packages linux)
   #:use-module (gnu packages mail) ; for libetpan
   #:use-module (gnu packages nettle)
@@ -247,3 +249,101 @@ ENGINE_INC_PATH=~a/include
     (description "The p≡p Python adapter is an adaptor interface to the p≡p
 (pretty Easy privacy) engine.")
     (license license:gpl3)))
+
+(define-public java-pep-adapter
+  (package
+    (name "java-pep-adapter")
+    (version "2.0.2")
+    (source
+     (origin
+       (method hg-fetch)
+       (uri (hg-reference
+             (url "https://pep.foundation/dev/repos/pEpJNIAdapter")
+             (changeset "9292f1b1a76a"))) ;; r699
+       (file-name (string-append name "-" version "-checkout"))
+       (sha256
+        (base32 "107ldpssc80bq8kndn2nqmav31gphj4lqagaiv3fddlfph4vji48"))))
+    (build-system gnu-build-system)
+    (outputs '("out" "doc"))
+    (arguments
+     `(#:test-target "test"
+       #:make-flags (list "doxy-all")
+       #:phases
+       (modify-phases %standard-phases
+         (add-before 'configure 'fix-includes
+           (lambda _
+             (substitute* "src/jniutils.hh"
+               (("#pragma once\n" line)
+                (string-append line
+                               "#include <mutex>\n"
+                               "#include <cassert>\n"
+                               "#include <cstring>\n")))
+             #t))
+         (add-before 'configure 'pin-shared-lib-path
+           (lambda* (#:key outputs #:allow-other-keys)
+             (substitute* "src/foundation/pEp/jniadapter/AbstractEngine.java"
+               (("System.loadLibrary\\(\"pEpJNI\"\\);")
+                (string-append "System.load(\""
+                               (assoc-ref outputs "out")
+                               "/lib/libpEpJNI.so" "\");")))
+             #t))
+         (replace 'configure
+           ;; pEpJNIAdapter does not use autotools and configure,
+           ;; but a local.conf. We need to tweak the values there.
+           (lambda* (#:key inputs outputs #:allow-other-keys)
+             (let ((out (assoc-ref outputs "out"))
+                   (engine (assoc-ref inputs "pep-engine"))
+                   (libadapter (assoc-ref inputs "libpepadapter"))
+                   (openjdk  (assoc-ref inputs "openjdk")))
+               (with-output-to-file "local.conf"
+                 (lambda _ ;()
+                   (format #t "
+PREFIX=~a
+ENGINE_LIB_PATH=~a/lib
+ENGINE_INC_PATH=~a/include
+AD_LIB_PATH=~a/lib
+AD_INC_PATH=~a/include
+YML2_PROC=~a
+JAVA_HOME=~a
+"
+                           out engine engine libadapter libadapter
+                           (which "yml2proc") openjdk)))
+               (substitute* "src/Makefile"  ;; suppress some warnings
+                 (("^\\s+OLD_JAVA=") "    xxx_OLD_JAVA="))
+               #t)))
+         (replace 'install
+           (lambda* (#:key outputs #:allow-other-keys)
+             (let* ((out (assoc-ref outputs "out"))
+                    (libout (string-append out "/lib/"))
+                    (javaout (string-append out "/share/java/")))
+               (mkdir-p libout)
+               (mkdir-p javaout)
+               (copy-file "src/libpEpJNI.so"
+                          (string-append libout "/libpEpJNI.so"))
+               (copy-file "src/pEp.jar" (string-append javaout "/pEp.jar"))
+               #t)))
+         (add-after 'install 'install-docs
+           (lambda* (#:key outputs #:allow-other-keys)
+             (let* ((out (assoc-ref outputs "doc"))
+                    (docout (string-append out "/share/doc/pEp-JNI-adapter"))
+                    (cxxout (string-append docout "/cxx"))
+                    (javaout (string-append docout "/java")))
+               (mkdir-p cxxout)
+               (mkdir-p javaout)
+               (copy-recursively "doc/doxygen/cxx/html" cxxout)
+               (copy-recursively "doc/doxygen/java/html" javaout)
+               #t))))))
+    (native-inputs
+     `(("doxygen" ,doxygen)
+       ("openjdk" ,openjdk9 "jdk")
+       ("which" ,which)
+       ("yml2" ,yml2)))
+    (inputs
+     `(("libpepadapter" ,libpepadapter)
+       ("pep-engine" ,pep-engine)
+       ("util-linux" ,util-linux))) ;; uuid.h
+    (home-page "https://pep.foundation/")
+    (synopsis "Java adapter for p≡p (pretty Easy Privacy)")
+    (description "The p≡p JNI adapter is a Java adapter interface to the p≡p
+(pretty Easy privacy) engine.")
+    (license license:gpl3)))
-- 
2.21.3

[bug#41490] Advice on package naming

[Ludovic Courtès]

Hi Hartmut,

Hartmut Goebel <h.goebel@crazy-compilers.com> skribis:

> I'm still seeking advice on how to name these packages, since the
> original packages have
> quiet uncommon names. Shall I keep the names I'm currently using, or are
> there any other suggestions?
>
> Current names:
>
> pep-engine
> libpepadapter.
> python-pep-adapter
> java-pep-adapter

That LGTM, I think it’s pretty much in line with:

  https://guix.gnu.org/manual/en/html_node/Package-Naming.html

Thanks,
Ludo’.

bug#41490: Advice on package naming

[Hartmut Goebel]

Hi Ludo,
> That LGTM, I think it’s pretty much in line with: 

Thanks.

Pushed as 3cf7088fc646e07158914dea1314151123472ec2


-- 
Regards
Hartmut Goebel

| Hartmut Goebel          | h.goebel@crazy-compilers.com               |
| www.crazy-compilers.com | compilers which you thought are impossible |