[PATCH] gnu: Add postgresql-service.

[PATCH] gnu: Add postgresql-service.

[David Thompson]

[-- Attachment #1: Type: text/plain, Size: 142 bytes --]

Hello everyone,

Below is a patch for my very first service: postgresql-service.  What do
you think?

Thanks in advance for the code review!


[-- Attachment #2: 0001-gnu-Add-postgresql-service.patch --]
[-- Type: text/x-diff, Size: 7112 bytes --]

From 888bb58253ab708f38609aa839e77a46a96bd0df Mon Sep 17 00:00:00 2001
From: David Thompson <dthompson2@worcester.edu>
Date: Sun, 3 May 2015 17:02:59 -0400
Subject: [PATCH] gnu: Add postgresql-service.

* gnu/services/databases.scm: New file.
* gnu-system.am (GNU_SYSTEM_MODULES): Add it.
* doc/guix.texi ("Database Services"): New subsubsection.
---
 doc/guix.texi              |  16 +++++++
 gnu-system.am              |   1 +
 gnu/services/databases.scm | 114 +++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 131 insertions(+)
 create mode 100644 gnu/services/databases.scm

diff --git a/doc/guix.texi b/doc/guix.texi
index dd6af80..5da12f7 100644
--- a/doc/guix.texi
+++ b/doc/guix.texi
@@ -4577,6 +4577,7 @@ declaration.
 * Base Services::               Essential system services.
 * Networking Services::         Network setup, SSH daemon, etc.
 * X Window::                    Graphical display.
+* Database Services::           SQL databases.
 * Various Services::            Other services.
 @end menu
 
@@ -4916,6 +4917,21 @@ appropriate screen resolution; otherwise, it must be a list of
 resolutions---e.g., @code{((1024 768) (640 480))}.
 @end deffn
 
+@node Database Services
+@subsubsection Database Services
+
+The @code{(gnu services databases)} module provides the following service.
+
+@deffn {Monadic Procedure} postgresql-service [#:postgresql postgresql] @
+       [#:config-file] [#:data-directory ``/var/lib/postgresql/data'']
+Return a service that runs @var{postgresql}, the PostgreSQL database
+server.
+
+The PostgreSQL daemon loads its runtime configuration from
+@var{config-file} and stores the database cluster in
+@var{data-directory}.
+@end deffn
+
 @node Various Services
 @subsubsection Various Services
 
diff --git a/gnu-system.am b/gnu-system.am
index bb6601e..8596049 100644
--- a/gnu-system.am
+++ b/gnu-system.am
@@ -328,6 +328,7 @@ GNU_SYSTEM_MODULES =				\
   gnu/services/avahi.scm			\
   gnu/services/base.scm				\
   gnu/services/colord.scm			\
+  gnu/services/databases.scm			\
   gnu/services/dbus.scm				\
   gnu/services/dmd.scm				\
   gnu/services/lirc.scm				\
diff --git a/gnu/services/databases.scm b/gnu/services/databases.scm
new file mode 100644
index 0000000..a275396
--- /dev/null
+++ b/gnu/services/databases.scm
@@ -0,0 +1,114 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2015
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu services databases)
+  #:use-module (gnu services)
+  #:use-module (gnu system shadow)
+  #:use-module (gnu packages admin)
+  #:use-module (gnu packages databases)
+  #:use-module (guix records)
+  #:use-module (guix monads)
+  #:use-module (guix store)
+  #:use-module (guix gexp)
+  #:export (postgresql-service))
+
+;;; Commentary:
+;;;
+;;; Database services.
+;;;
+;;; Code:
+
+(define %default-postgres-hba
+  (text-file* "pg_hba.conf"
+              "local	all	all			trust\n"
+              "host	all	all	127.0.0.1/32 	trust\n"
+              "host	all	all	::1/128 	trust\n"))
+
+(define %default-postgres-ident
+  (text-file* "pg_ident.conf"
+              "# MAPNAME       SYSTEM-USERNAME         PG-USERNAME"))
+
+(define %default-postgres-config
+  (mlet %store-monad ((hba %default-postgres-hba)
+                      (ident %default-postgres-ident))
+    (text-file* "postgresql.conf"
+                ;; The daemon will not start without these.
+                "hba_file = '" hba "'\n"
+                "ident_file = '" ident "'\n")))
+
+(define* (postgresql-service #:key (postgresql postgresql)
+                             (config-file %default-postgres-config)
+                             (data-directory "/var/lib/postgresql/data"))
+  "Return a service that runs @var{postgresql}, the PostgreSQL database server.
+
+The PostgreSQL daemon loads its runtime configuration from @var{config-file}
+and stores the database cluster in @var{data-directory}."
+  ;; Wrapper script that switches to the 'postgres' user before launching
+  ;; daemon.
+  (define start-script
+    (mlet %store-monad ((config-file config-file))
+      (gexp->script "start-postgres"
+                    #~(let ((user (getpwnam "postgres"))
+                            (postgres (string-append #$postgresql
+                                                     "/bin/postgres")))
+                        (setgid (passwd:gid user))
+                        (setuid (passwd:uid user))
+                        (system* postgres
+                                 (string-append "--config-file=" #$config-file)
+                                 "-D" #$data-directory)))))
+
+  (define activate
+    #~(begin
+        (use-modules (guix build utils)
+                     (ice-9 match))
+
+        (let ((user (getpwnam "postgres"))
+              (initdb (string-append #$postgresql "/bin/initdb")))
+          ;; Create db state directory.
+          (mkdir-p #$data-directory)
+          (chown #$data-directory (passwd:uid user) (passwd:gid user))
+
+          ;; Drop privileges and init state directory in a new
+          ;; process.  Wait for it to finish before proceeding.
+          (match (primitive-fork)
+            (0
+             (setgid (passwd:gid user))
+             (setuid (passwd:uid user))
+             (primitive-exit (system* initdb "-D" #$data-directory)))
+            (pid (waitpid pid))))))
+
+  (mlet %store-monad ((start-script start-script))
+    (return
+     (service
+      (provision '(postgres))
+      (documentation "Run the PostgreSQL daemon.")
+      (requirement '(user-processes loopback))
+      (start #~(make-forkexec-constructor #$start-script))
+      (stop #~(make-kill-destructor))
+      (activate activate)
+      (user-groups (list (user-group
+                          (name "postgres")
+                          (system? #t))))
+      (user-accounts (list (user-account
+                            (name "postgres")
+                            (group "postgres")
+                            (system? #t)
+                            (comment "PostgreSQL server user")
+                            (home-directory "/var/empty")
+                            (shell
+                             #~(string-append #$shadow "/sbin/nologin")))))))))
-- 
2.1.4


[-- Attachment #3: Type: text/plain, Size: 136 bytes --]


-- 
David Thompson
Web Developer - Free Software Foundation - http://fsf.org
GPG Key: 0FF1D807
Support the FSF: https://fsf.org/donate

Re: [PATCH] gnu: Add postgresql-service.

[Ludovic Courtès]

David Thompson <dthompson2@worcester.edu> skribis:

> From 888bb58253ab708f38609aa839e77a46a96bd0df Mon Sep 17 00:00:00 2001
> From: David Thompson <dthompson2@worcester.edu>
> Date: Sun, 3 May 2015 17:02:59 -0400
> Subject: [PATCH] gnu: Add postgresql-service.
>
> * gnu/services/databases.scm: New file.
> * gnu-system.am (GNU_SYSTEM_MODULES): Add it.
> * doc/guix.texi ("Database Services"): New subsubsection.

Nice!  I haven’t tested it, but it looks good.  I only have minor
comments:

> +;;; Copyright © 2015

Line truncated.  :-)

> +(define %default-postgres-hba
> +  (text-file* "pg_hba.conf"
> +              "local	all	all			trust\n"
> +              "host	all	all	127.0.0.1/32 	trust\n"
> +              "host	all	all	::1/128 	trust\n"))
> +
> +(define %default-postgres-ident
> +  (text-file* "pg_ident.conf"
> +              "# MAPNAME       SYSTEM-USERNAME         PG-USERNAME"))

Since these two are purely text (they do not contain references to store
items), ‘text-file’ is enough and even better.

(‘text-file*’ returns a derivation that builds the file, and that
derivation depends on Guile; conversely, ‘text-file’ simply creates a
new file in the store.)

> +          ;; Drop privileges and init state directory in a new
> +          ;; process.  Wait for it to finish before proceeding.
> +          (match (primitive-fork)
> +            (0
> +             (setgid (passwd:gid user))
> +             (setuid (passwd:uid user))
> +             (primitive-exit (system* initdb "-D" #$data-directory)))

It may be a good idea to wrap the child process’s body in:

  (dynamic-wind
    (const #t)
    (lambda ()
      ...)
    (lambda ()
      (primitive-exit 1)))

This makes sure that it doesn’t keep going if an exception is thrown
(yes it’s quite ugly.)

OK to push with these changes!

Thanks,
Ludo’.

Re: [PATCH] gnu: Add postgresql-service.

[David Thompson]

Ludovic Courtès <ludo@gnu.org> writes:

> OK to push with these changes!

Done and pushed.  Thanks!

-- 
David Thompson
Web Developer - Free Software Foundation - http://fsf.org
GPG Key: 0FF1D807
Support the FSF: https://fsf.org/donate