* native-search-paths and shepherd services (help wanted)
@ 2020-02-08 9:06 Jonathan Frederickson
2020-02-08 10:28 ` Brice Waegeneire
0 siblings, 1 reply; 5+ messages in thread
From: Jonathan Frederickson @ 2020-02-08 9:06 UTC (permalink / raw)
To: guix-devel
[-- Attachment #1: Type: text/plain, Size: 1307 bytes --]
Hi - I'm working on a Guix service for Minetest, and I'm running into some issues. The Guix package for Minetest is divided into two variables: "minetest" and "minetest-data", with only the former being an installable package. The Minetest package uses native-search-paths to allow Minetest to find additional available games (MINETEST_SUBGAME_PATH), *including* minetest_game which is effectively the default.
This is all well and good when you're installing Minetest as a package and running it manually, but I'd like to do this with a Guix service instead. Problem is... the native-search-paths don't seem to affect the environment variables set when I run Minetest through Shepherd. I'm checking my env vars by running Minetest through strace in the shepherd service at the moment:
(start #~(make-forkexec-constructor
(list #$(file-append strace "/bin/strace") "-s1024" "-vfe" "trace=execve" #$(file-append package "/bin/minetest")
"--server" "testworld"
"--map-dir" #$map-dir)
#:user "minetest"
#:group "minetest"))
(I've attached my current services/games.scm for reference.)
Is there a way for me to use the native-search-paths from the installed Minetest package when starting it through Shepherd?
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: games.scm --]
[-- Type: text/x-scheme; name="games.scm", Size: 5280 bytes --]
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2018 Arun Isaac <arunisaac@systemreboot.net>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (gnu services games)
#:use-module (gnu services)
#:use-module (gnu services shepherd)
#:use-module (gnu packages admin)
#:use-module (gnu packages linux) ;; for strace - remove this
#:use-module (gnu packages games)
#:use-module (gnu system shadow)
#:use-module (guix gexp)
#:use-module (guix modules)
#:use-module (guix records)
#:use-module (ice-9 match)
#:export (wesnothd-configuration
wesnothd-configuration?
wesnothd-service-type
minetest-configuration
minetest-configuration?
minetest-service-type))
;;;
;;; The Battle for Wesnoth server
;;;
(define-record-type* <wesnothd-configuration>
wesnothd-configuration make-wesnothd-configuration wesnothd-configuration?
(package wesnothd-configuration-package
(default wesnoth-server))
(port wesnothd-configuration-port
(default 15000)))
(define %wesnothd-accounts
(list
(user-account
(name "wesnothd")
(group "wesnothd")
(system? #t)
(comment "Wesnoth daemon user")
(home-directory "/var/empty")
(shell
(file-append shadow "/sbin/nologin")))
(user-group
(name "wesnothd")
(system? #t))))
(define wesnothd-shepherd-service
(match-lambda
(($ <wesnothd-configuration> package port)
(with-imported-modules
(source-module-closure
'((gnu build shepherd)))
(shepherd-service
(documentation "The Battle for Wesnoth server")
(provision
'(wesnoth-daemon))
(requirement
'(networking))
(modules
'((gnu build shepherd)))
(start #~(make-forkexec-constructor/container
(list #$(file-append package "/bin/wesnothd")
"-p" #$(number->string port))
#:user "wesnothd" #:group "wesnothd"))
(stop #~(make-kill-destructor)))))))
(define wesnothd-service-type
(service-type
(name 'wesnothd)
(description
"Run The Battle for Wesnoth server @command{wesnothd}.")
(extensions
(list
(service-extension account-service-type
(const %wesnothd-accounts))
(service-extension shepherd-root-service-type
(compose list wesnothd-shepherd-service))))
(default-value
(wesnothd-configuration))))
(define-record-type* <minetest-configuration>
minetest-configuration make-minetest-configuration minetest-configuration?
(package minetest-configuration-package
(default minetest))
(config-file minetest-config-file
(default "/etc/minetest.conf"))
(map-dir minetest-map-dir
(default "/tmp")))
(define %minetest-accounts
(list
(user-account
(name "minetest")
(group "minetest")
(system? #t)
(comment "Minetest daemon user")
(home-directory "/var/minetest")
(shell
(file-append shadow "/sbin/nologin")))
(user-group
(name "minetest")
(system? #t))))
(define minetest-shepherd-service
(match-lambda
(($ <minetest-configuration> package port map-dir)
(shepherd-service
(documentation "Minetest server.")
(requirement '(networking))
(provision '(minetest))
(start #~(make-forkexec-constructor
;;(list #$(file-append package "/bin/minetest")
;; "--server" "testworld"
;; "--map-dir" #$map-dir)
(list #$(file-append strace "/bin/strace") "-s1024" "-vfe" "trace=execve" #$(file-append package "/bin/minetest")
"--server" "testworld"
"--map-dir" #$map-dir)
#:user "minetest"
#:group "minetest"))
;;#:environment-variables
;;'("HOME=/var/minetest")))
(stop #~(make-kill-destructor))))))
(define minetest-service-type
(service-type
(name 'minetest)
(description
"Run the Minetest server @command{minetest}.")
(extensions
(list (service-extension account-service-type
(const %minetest-accounts))
(service-extension profile-service-type
(lambda (config)
(list (minetest-configuration-package
config))))
(service-extension shepherd-root-service-type
(compose list minetest-shepherd-service))))
(default-value (minetest-configuration))))
^ permalink raw reply [flat|nested] 5+ messages in thread
* Re: native-search-paths and shepherd services (help wanted)
2020-02-08 9:06 native-search-paths and shepherd services (help wanted) Jonathan Frederickson
@ 2020-02-08 10:28 ` Brice Waegeneire
2020-02-08 19:10 ` Jonathan Frederickson
0 siblings, 1 reply; 5+ messages in thread
From: Brice Waegeneire @ 2020-02-08 10:28 UTC (permalink / raw)
To: Jonathan Frederickson; +Cc: guix-devel, Guix-devel
[-- Attachment #1: Type: text/plain, Size: 1786 bytes --]
On 2020-02-08 09:06, Jonathan Frederickson wrote:
> Hi - I'm working on a Guix service for Minetest, and I'm running into
> some issues. The Guix package for Minetest is divided into two
> variables: "minetest" and "minetest-data", with only the former being
> an installable package. The Minetest package uses native-search-paths
> to allow Minetest to find additional available games
> (MINETEST_SUBGAME_PATH), *including* minetest_game which is
> effectively the default.
>
> This is all well and good when you're installing Minetest as a package
> and running it manually, but I'd like to do this with a Guix service
> instead. Problem is... the native-search-paths don't seem to affect
> the environment variables set when I run Minetest through Shepherd.
> I'm checking my env vars by running Minetest through strace in the
> shepherd service at the moment:
>
> (start #~(make-forkexec-constructor
> (list #$(file-append strace "/bin/strace") "-s1024"
> "-vfe" "trace=execve" #$(file-append package "/bin/minetest")
> "--server" "testworld"
> "--map-dir" #$map-dir)
> #:user "minetest"
> #:group "minetest"))
>
> (I've attached my current services/games.scm for reference.)
>
> Is there a way for me to use the native-search-paths from the
> installed Minetest package when starting it through Shepherd?
I think I got it working, I managed to log and "play" on the server.
You were really close to have a working service for minetest though. You
were only missing the environment variable MINETEST_SUBGAME_PATH and
*maybe* your profile-service-type extension was wrong (I just blandly
copied how it was done for SDDM). I have attached your games.scm with
the added fixes.
[-- Attachment #2: games.scm --]
[-- Type: text/plain, Size: 5547 bytes --]
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2018 Arun Isaac <arunisaac@systemreboot.net>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (gnu services games)
#:use-module (gnu services)
#:use-module (gnu services shepherd)
#:use-module (gnu packages admin)
#:use-module (gnu packages linux) ;; for strace - remove this
#:use-module (gnu packages games)
#:use-module (gnu system shadow)
#:use-module (guix gexp)
#:use-module (guix modules)
#:use-module (guix records)
#:use-module (ice-9 match)
#:export (wesnothd-configuration
wesnothd-configuration?
wesnothd-service-type
minetest-configuration
minetest-configuration?
minetest-service-type))
;;;
;;; The Battle for Wesnoth server
;;;
(define-record-type* <wesnothd-configuration>
wesnothd-configuration make-wesnothd-configuration wesnothd-configuration?
(package wesnothd-configuration-package
(default wesnoth-server))
(port wesnothd-configuration-port
(default 15000)))
(define %wesnothd-accounts
(list
(user-account
(name "wesnothd")
(group "wesnothd")
(system? #t)
(comment "Wesnoth daemon user")
(home-directory "/var/empty")
(shell
(file-append shadow "/sbin/nologin")))
(user-group
(name "wesnothd")
(system? #t))))
(define wesnothd-shepherd-service
(match-lambda
(($ <wesnothd-configuration> package port)
(with-imported-modules
(source-module-closure
'((gnu build shepherd)))
(shepherd-service
(documentation "The Battle for Wesnoth server")
(provision
'(wesnoth-daemon))
(requirement
'(networking))
(modules
'((gnu build shepherd)))
(start #~(make-forkexec-constructor/container
(list #$(file-append package "/bin/wesnothd")
"-p" #$(number->string port))
#:user "wesnothd" #:group "wesnothd"))
(stop #~(make-kill-destructor)))))))
(define wesnothd-service-type
(service-type
(name 'wesnothd)
(description
"Run The Battle for Wesnoth server @command{wesnothd}.")
(extensions
(list
(service-extension account-service-type
(const %wesnothd-accounts))
(service-extension shepherd-root-service-type
(compose list wesnothd-shepherd-service))))
(default-value
(wesnothd-configuration))))
(define-record-type* <minetest-configuration>
minetest-configuration make-minetest-configuration minetest-configuration?
(package minetest-configuration-package
(default minetest))
(config-file minetest-config-file
(default "/etc/minetest.conf"))
(map-dir minetest-map-dir
(default "/tmp")))
(define %minetest-accounts
(list
(user-account
(name "minetest")
(group "minetest")
(system? #t)
(comment "Minetest daemon user")
(home-directory "/var/minetest")
(shell
(file-append shadow "/sbin/nologin")))
(user-group
(name "minetest")
(system? #t))))
(define minetest-shepherd-service
(match-lambda
(($ <minetest-configuration> package port map-dir)
(shepherd-service
(documentation "Minetest server.")
(requirement '(networking))
(provision '(minetest))
(start #~(make-forkexec-constructor
(list #$(file-append package "/bin/minetest")
"--server" "testworld"
"--map-dir" #$map-dir)
;; (list #$(file-append strace "/bin/strace") "-s1024" "-vfe" "trace=execve" #$(file-append package "/bin/minetest")
;; "--server" "testworld"
;; "--map-dir" #$map-dir)
#:user "minetest"
#:group "minetest";; ))
#:environment-variables
'("HOME=/var/minetest"
"MINETEST_SUBGAME_PATH=/run/current-system/profile/share/minetest/games")))
(stop #~(make-kill-destructor))))))
(define minetest-profile-service
(compose list minetest-configuration-package))
(define minetest-service-type
(service-type
(name 'minetest)
(description
"Run the Minetest server @command{minetest}.")
(extensions
(list (service-extension account-service-type
(const %minetest-accounts))
(service-extension profile-service-type
minetest-profile-service
;; (lambda (config)
;; (list (minetest-configuration-package
;; config)))
)
(service-extension shepherd-root-service-type
(compose list minetest-shepherd-service))))
(default-value (minetest-configuration))))
^ permalink raw reply [flat|nested] 5+ messages in thread
* Re: native-search-paths and shepherd services (help wanted)
2020-02-08 10:28 ` Brice Waegeneire
@ 2020-02-08 19:10 ` Jonathan Frederickson
2020-02-08 19:39 ` Brice Waegeneire
0 siblings, 1 reply; 5+ messages in thread
From: Jonathan Frederickson @ 2020-02-08 19:10 UTC (permalink / raw)
To: Brice Waegeneire; +Cc: guix-devel, Guix-devel
On Sat, Feb 8, 2020, at 10:28 AM, Brice Waegeneire wrote:
> I think I got it working, I managed to log and "play" on the server.
>
> You were really close to have a working service for minetest though. You
> were only missing the environment variable MINETEST_SUBGAME_PATH and
> *maybe* your profile-service-type extension was wrong (I just blandly
> copied how it was done for SDDM). I have attached your games.scm with
> the added fixes.
Aha, thank you very much! I didn't know where the profile path was for the current system, so that was very helpful.
I'm still not quite sure I have a good understanding of when 'native-search-paths' applies and when it doesn't, but... at least setting the env var directly seems to work in this case.
^ permalink raw reply [flat|nested] 5+ messages in thread
* Re: native-search-paths and shepherd services (help wanted)
2020-02-08 19:10 ` Jonathan Frederickson
@ 2020-02-08 19:39 ` Brice Waegeneire
2020-02-11 14:40 ` Ludovic Courtès
0 siblings, 1 reply; 5+ messages in thread
From: Brice Waegeneire @ 2020-02-08 19:39 UTC (permalink / raw)
To: Jonathan Frederickson; +Cc: guix-devel, Guix-devel
On 2020-02-08 19:10, Jonathan Frederickson wrote:
> I'm still not quite sure I have a good understanding of when
> 'native-search-paths' applies and when it doesn't, but... at least
> setting the env var directly seems to work in this case.
I just learned about native-search-paths when looking into your issue so
I may be off about how it works...
What I understand is that native-search-paths add an entry to your
/etc/profile when installed - for your default user profile it's
$HOME/.guix-profile/etc/profile. In our case, when installed, minetest
sets the environment variable MINETEST_SUBGAME_PATH so the binary know
where to looks for the games. But when called directly, as it's the case
in a shepherd service, the /etc/profile file isn't sourced so the
environment variable isn't set. That's why we need to set it manually in
the service.
^ permalink raw reply [flat|nested] 5+ messages in thread
* Re: native-search-paths and shepherd services (help wanted)
2020-02-08 19:39 ` Brice Waegeneire
@ 2020-02-11 14:40 ` Ludovic Courtès
0 siblings, 0 replies; 5+ messages in thread
From: Ludovic Courtès @ 2020-02-11 14:40 UTC (permalink / raw)
To: Brice Waegeneire; +Cc: guix-devel, Guix-devel
Hello,
Brice Waegeneire <brice@waegenei.re> skribis:
> On 2020-02-08 19:10, Jonathan Frederickson wrote:
>> I'm still not quite sure I have a good understanding of when
>> 'native-search-paths' applies and when it doesn't, but... at least
>> setting the env var directly seems to work in this case.
>
> I just learned about native-search-paths when looking into your issue
> so I may be off about how it works...
> What I understand is that native-search-paths add an entry to your
> /etc/profile when installed - for your default user profile it's
> $HOME/.guix-profile/etc/profile. In our case, when installed, minetest
> sets the environment variable MINETEST_SUBGAME_PATH so the binary know
> where to looks for the games. But when called directly, as it's the
> case in a shepherd service, the /etc/profile file isn't sourced so the
> environment variable isn't set. That's why we need to set it manually
> in the service.
Search paths are only used when building a profile, which is not the
case here.
I suppose you’d have to explicitly pass #:environment-variables to
‘make-forkexec-constructor’ to get the desired effect.
HTH,
Ludo’.
^ permalink raw reply [flat|nested] 5+ messages in thread
end of thread, other threads:[~2020-02-11 14:40 UTC | newest]
Thread overview: 5+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2020-02-08 9:06 native-search-paths and shepherd services (help wanted) Jonathan Frederickson
2020-02-08 10:28 ` Brice Waegeneire
2020-02-08 19:10 ` Jonathan Frederickson
2020-02-08 19:39 ` Brice Waegeneire
2020-02-11 14:40 ` Ludovic Courtès
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/guix.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).