new packages

new packages

[Julien Lepiller]

[-- Attachment #1: Type: text/plain, Size: 315 bytes --]

Hello,

I just compiled hexchat, my favorite IRC client (a fork of XChat) and
claws-mail, my favorite mail client (a fork of Sylpheed), so I could
send the first recipe :).

I don't really know where they should go (maybe mail.scm?), so I send
them as scheme files. Do whatever you want with them.

Julien Lepiller.

[-- Attachment #2: hexchat.scm --]
[-- Type: application/octet-stream, Size: 2631 bytes --]

;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2014 Lepiller Julien <julien@lepiller.eu>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu packages hexchat)
  #:use-module ((guix licenses) #:select (gpl2))
  #:use-module (guix packages)
  #:use-module (guix download)
  #:use-module (guix build-system gnu)
  #:use-module (gnu packages compression)
  #:use-module (gnu packages enchant)
  #:use-module (gnu packages glib)
  #:use-module (gnu packages gnome)
  #:use-module (gnu packages gtk)
  #:use-module (gnu packages libcanberra)
  #:use-module (gnu packages openssl)
  #:use-module (gnu packages perl)
  #:use-module (gnu packages pkg-config)
  #:use-module (gnu packages python)
  #:use-module (gnu packages xml))
;; Note: could be great to add enchant

(define-public hexchat
  (package
    (name "hexchat")
    (version "2.10.1")
    (source (origin
              (method url-fetch)
              (uri (string-append
                    "https://dl.hexchat.net/hexchat/hexchat-" version ".tar.xz"))
              (sha256
               (base32 "1ag9rmfisv0hsbk05jq4f1rnap7kwg90vgbmkr9zklkh6imfxk7z"))))
    (build-system gnu-build-system)
    (native-inputs `(("pkg-config" ,pkg-config)
              ("intltool" ,intltool)))
    (inputs `(("dbus-glib" ,dbus-glib)
              ("dbus" ,dbus)
              ("enchant" ,enchant)
              ("glib:bin" ,glib "bin") ;; need glib-genmarshal
              ("gtk" ,gtk+-2)
              ("libcanberra" ,libcanberra)
              ("libnotify" ,libnotify)
              ("openssl" ,openssl)
              ("perl-xml-parser" ,perl-xml-parser)
              ("python-2" ,python-2)))
    (synopsis "IRC Client")
    (description
     "HexChat is an IRC client based on XChat, but unlike XChat it is completely
free for both Windows and Unix-like systems. Since XChat is opensource, it is
perfectly legal.")
    (home-page "http://hexchat.net/")
    (license gpl2)))

;;; hexchat.scm ends here

[-- Attachment #3: claws-mail.scm --]
[-- Type: application/octet-stream, Size: 5803 bytes --]

;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2014 Lepiller Julien <julien@lepiller.eu>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu packages claws-mail)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (guix packages)
  #:use-module (guix download)
  #:use-module (guix build-system gnu)
  #:use-module (gnu packages autotools)
  #:use-module (gnu packages backup)
  #:use-module (gnu packages curl)
  #:use-module (gnu packages cyrus-sasl)
  #:use-module (gnu packages enchant)
  #:use-module (gnu packages ghostscript)
  #:use-module (gnu packages glib)
  #:use-module (gnu packages gnome)
  #:use-module (gnu packages gnupg)
  #:use-module (gnu packages gnutls)
  #:use-module (gnu packages gtk)
  #:use-module (gnu packages libcanberra)
  #:use-module (gnu packages mail)
  #:use-module (gnu packages openssl)
  #:use-module (gnu packages perl)
  #:use-module (gnu packages pkg-config)
  #:use-module (gnu packages python)
  #:use-module (gnu packages xml)
  #:use-module (gnu packages xorg))

(define-public libetpan
  (package
    (name "libetpan")
    (version "1.6")
    (source (origin
             (method url-fetch)
             (uri (string-append "https://github.com/dinhviethoa/" name "/archive/" version ".tar.gz"))
             (sha256
               (base32 "05qyqx2c1ppb1jnrs3m52i60f9xlxfxdmb9dnwg4vqjv8kwv2qkr"))))
    (build-system gnu-build-system)
    (native-inputs `(("autoconf" ,(autoconf-wrapper))
                     ("automake" ,automake)
                     ("libtool" ,libtool "bin")
                     ("pkg-config" ,pkg-config)))
    (propagated-inputs
     `(("cyrus-sasl" ,cyrus-sasl)
       ("openssl" ,openssl)))
    (inputs
     `(("curl" ,curl)
       ("expat" ,expat)))
    (arguments
      '(#:phases (alist-cons-before
                  'configure 'autogen
                  (lambda _
                    (setenv "SHELL" (which "sh"))
                    (system* "./autogen.sh")) ;; Note: this fails because the
                         ;; generated configure script uses /bin/sh. It is
                         ;; replaced in the configure phase by the correct
                         ;; value. TODO: replace the configure phase by the
                         ;; autogen phase and have the SHELL variable be replaced
                  %standard-phases)
        #:configure-flags
        '("--disable-static" "--disable-db")))
    (home-page "http://www.etpan.org/libetpan.html")
    (synopsis "A portable middleware for email access")
    (description
     "The purpose of this mail library is to provide a portable, efficient
framework for different kinds of mail access: IMAP, SMTP, POP and NNTP.
It provides an API for C language. It's the low-level API used by MailCore and
MailCore 2.")
    (license (license:fsf-free "http://raw.githubusercontent.com/dinhviethoa/libetpan/master/COPYRIGHT"))))

(define-public claws-mail
  (package
    (name "claws-mail")
    (version "3.11.1")
    (source (origin
              (method url-fetch)
              (uri (string-append
                    "http://downloads.sourceforge.net/project/claws-mail/Claws Mail/" version "/" name "-" version ".tar.xz"))
              (sha256
               (base32 "0cyixz1jgfpi8abh9fbb8ylx9mcvw4jqj81cms666wpqr6v828yp"))))
    (build-system gnu-build-system)
    (native-inputs `(("pkg-config" ,pkg-config)))
    (inputs `(("bogofilter" ,bogofilter)
              ("curl" ,curl)
              ("dbus-glib" ,dbus-glib)
              ("dbus" ,dbus)
              ("enchant" ,enchant)
              ("expat" ,expat)
              ("ghostscript" ,ghostscript)
              ("hicolor-icon-theme" ,hicolor-icon-theme)
              ("gnupg" ,gnupg)
              ("gnutls" ,gnutls)
              ("gpgme" ,gpgme)
              ("gtk" ,gtk+-2)
              ("libarchive" ,libarchive)
              ("libcanberra" ,libcanberra)
              ("libetpan" ,libetpan)
              ("libnotify" ,libnotify)
              ("libsm" ,libsm)
              ("libxml2" ,libxml2)
              ("perl" ,perl)
              ("python-2" ,python-2)))
    (arguments
      '(#:configure-flags
        '("--enable-gnutls" "--enable-pgpmime-plugin" "--enable-enchant")))
    (synopsis "The Email client that bites!")
    (description
     "Claws-Mail is an email client (and news reader) based on GTK+, featuring
Quick Response
Graceful, and sophisticated interface
Easy configuration, intuitive operation
Abundant features
Extensibility
Robustness and stability

The appearance and interface are disgned to be familiar to new users coming from
other popular email clients, as well as experienced users. Almost all commands
are accessible with the keyboard.

The messages are managed in the standard MH format, which features fast access
and data security. You'll be able to import your emails from almost any other
email client, and export them just as easily.

Lots of extra functionality, like an RSS aggregator, calendar, on laptop LED
handling, are provided by extra plugins.")
    (home-page "http://www.claws-mail.org/")
    (license license:gpl3)))

;;; claws-mail.scm ends here

Re: new packages

[Ludovic Courtès]

Julien Lepiller <julien@lepiller.eu> skribis:

> I just compiled hexchat, my favorite IRC client (a fork of XChat) and
> claws-mail, my favorite mail client (a fork of Sylpheed), so I could
> send the first recipe :).
>
> I don't really know where they should go (maybe mail.scm?), so I send
> them as scheme files. Do whatever you want with them.

Actually, could you send them as patches (one per package preferably),
like you did for Openbox?  :-)  That is easier to deal with.

mail.scm sounds like a good place for Claws-mail, and I think Hexchat
should go to messaging.scm.

Some comments inline:

>   #:use-module (gnu packages python)
>   #:use-module (gnu packages xml))
> ;; Note: could be great to add enchant

Leftover comment?

>     (synopsis "IRC Client")

Rather “Graphical IRC client”.

>     (description
>      "HexChat is an IRC client based on XChat, but unlike XChat it is completely
> free for both Windows and Unix-like systems. Since XChat is opensource, it is
> perfectly legal.")

Everything in the distro is free software and “perfectly legal”, so no
need to mention it.  Could you instead just write a couple sentences
about what it technically looks like?

>     (home-page "http://hexchat.net/")
>     (license gpl2)))

AFAICS, source files carry the “or any later version” clause, so it
should be ‘gpl2+’.

>              (uri (string-append "https://github.com/dinhviethoa/" name "/archive/" version ".tar.gz"))

<https://github.com/dinhviethoa/libetpan-1.6.tar.gz> is 404.

Please wrap to 80 chars.

>     (synopsis "A portable middleware for email access")

Remove “A”, and address other complaints ‘guix lint libetpan’ may have.

>     (license (license:fsf-free "http://raw.githubusercontent.com/dinhviethoa/libetpan/master/COPYRIGHT"))))

This file reads:

--8<---------------cut here---------------start------------->8---
Copyright (C) 2001 - 2005 - DINH Viet Hoa
All rights reserved.

Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions
are met:
1. Redistributions of source code must retain the above copyright
   notice, this list of conditions and the following disclaimer.
2. Redistributions in binary form must reproduce the above copyright
   notice, this list of conditions and the following disclaimer in the
   documentation and/or other materials provided with the distribution.
3. Neither the name of the libEtPan! project nor the names of its
   contributors may be used to endorse or promote products derived
   from this software without specific prior written permission.

THIS SOFTWARE IS PROVIDED BY THE AUTHORS AND CONTRIBUTORS ``AS IS'' AND
ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHORS OR CONTRIBUTORS BE LIABLE
FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
SUCH DAMAGE.

This project contains code from sendmail, NetBSD,
RSA Data Security MD5 Message-Digest Algorithm, Cyrus IMAP.
--8<---------------cut here---------------end--------------->8---

This file is BSD-3 with small wording changes.  So I think the ‘license’
field should be: (bsd-style "file://COPYING"), with the previous
sentence as a comment.

>     (synopsis "The Email client that bites!")

Rather something like “GTK-based graphical e-mail client”.

>     (description
>      "Claws-Mail is an email client (and news reader) based on GTK+, featuring
> Quick Response
> Graceful, and sophisticated interface
> Easy configuration, intuitive operation
> Abundant features
> Extensibility
> Robustness and stability
>
> The appearance and interface are disgned to be familiar to new users coming from
> other popular email clients, as well as experienced users. Almost all commands
> are accessible with the keyboard.
>
> The messages are managed in the standard MH format, which features fast access
> and data security. You'll be able to import your emails from almost any other
> email client, and export them just as easily.
>
> Lots of extra functionality, like an RSS aggregator, calendar, on laptop LED
> handling, are provided by extra plugins.")

The item list will not render well in user interfaces.  Also, could you
try to shorten it a bit?

Thanks!

Ludo’.