[PATCH] gnu: Add gmime

[PATCH] gnu: Add gmime

[Mark H Weaver]

[-- Attachment #1: Type: text/plain, Size: 64 bytes --]

This adds gmime, another step toward notmuch (mail).

    Mark


[-- Attachment #2: [PATCH] gnu: Add gmime --]
[-- Type: text/x-patch, Size: 3503 bytes --]

From c848b174fc5ab2268f72736fe574a2def50ed095 Mon Sep 17 00:00:00 2001
From: Mark H Weaver <mhw@netris.org>
Date: Tue, 18 Feb 2014 23:08:04 -0500
Subject: [PATCH] gnu: Add gmime.

* gnu/packages/mail.scm (gmime): New variable.
---
 gnu/packages/mail.scm | 54 +++++++++++++++++++++++++++++++++++++++++++++++++--
 1 file changed, 52 insertions(+), 2 deletions(-)

diff --git a/gnu/packages/mail.scm b/gnu/packages/mail.scm
index bdb3d52..9c6e0c8 100644
--- a/gnu/packages/mail.scm
+++ b/gnu/packages/mail.scm
@@ -1,5 +1,6 @@
 ;;; GNU Guix --- Functional package management for GNU
 ;;; Copyright © 2013 Ludovic Courtès <ludo@gnu.org>
+;;; Copyright © 2014 Mark H Weaver <mhw@netris.org>
 ;;;
 ;;; This file is part of GNU Guix.
 ;;;
@@ -33,11 +34,15 @@
   #:use-module (gnu packages perl)
   #:use-module (gnu packages readline)
   #:use-module (gnu packages texinfo)
+  #:use-module (gnu packages compression)
+  #:use-module (gnu packages glib)
+  #:use-module (gnu packages pkg-config)
   #:use-module ((guix licenses)
-                #:select (gpl2+ gpl3+ lgpl3+))
+                #:select (gpl2+ gpl3+ lgpl2.1+ lgpl3+))
   #:use-module (guix packages)
   #:use-module (guix download)
-  #:use-module (guix build-system gnu))
+  #:use-module (guix build-system gnu)
+  #:use-module (srfi srfi-1))
 
 (define-public mailutils
   (package
@@ -162,3 +167,48 @@ aliasing facilities to work just as they would on normal mail.")
      "Mutt is a small but very powerful text-based mail client for Unix
 operating systems.")
     (license gpl2+)))
+
+(define-public gmime
+  (package
+    (name "gmime")
+    (version "2.6.19")
+    (source (origin
+              (method url-fetch)
+              (uri (string-append "http://download.gnome.org/sources/gmime/"
+                                  (string-join (take (string-split version #\.)
+                                                     2)
+                                               ".")
+                                  "/gmime-" version ".tar.xz"))
+              (sha256
+               (base32
+                "0jm1fgbjgh496rsc0il2y46qd4bqq2ln9168p4zzh68mk4ml1yxg"))))
+    (build-system gnu-build-system)
+    (native-inputs
+     `(("pkg-config" ,pkg-config)
+       ("gnupg" ,gnupg)))               ; for tests only
+    (inputs `(("glib" ,glib)
+              ("gpgme" ,gpgme)
+              ("zlib" ,zlib)))
+    (arguments
+     `(#:phases
+       (alist-cons-after
+        'unpack 'patch-bin-rm-in-tests
+        (lambda _
+          ;; The test programs run several programs using 'system'
+          ;; with hard-coded paths.  Here we patch them all.  We also
+          ;; change "gpg" to "gpg2".
+          (substitute* (find-files "tests" "\\.c$")
+            (("(system *\\(\")(/[^ ]*)" all pre prog-path)
+             (let* ((base (basename prog-path))
+                    (prog (which (if (string=? base "gpg") "gpg2" base))))
+              (string-append pre (or prog (error "not found: " base)))))))
+        %standard-phases)))
+    (home-page "http://spruce.sourceforge.net/gmime/")
+    (synopsis "MIME message parser and creator library")
+    (description
+     "GMime provides a core library and set of utilities which may be used for
+the creation and parsing of messages using the Multipurpose Internet Mail
+Extension (MIME).")
+    (license (list lgpl2.1+ gpl2+ gpl3+))))
+
+;;; mail.scm ends here
-- 
1.8.4

Re: [PATCH] gnu: Add gmime

[Andreas Enge]

On Tue, Feb 18, 2014 at 11:09:16PM -0500, Mark H Weaver wrote:
> This adds gmime, another step toward notmuch (mail).
> +  #:use-module (srfi srfi-1))

Is this module needed in the sense that the solution is preferable to what
is done, for instance, to determine the file name of qt?

Andreas

Re: [PATCH] gnu: Add gmime

[Mark H Weaver]

Andreas Enge <andreas@enge.fr> writes:

> On Tue, Feb 18, 2014 at 11:09:16PM -0500, Mark H Weaver wrote:
>> This adds gmime, another step toward notmuch (mail).
>> +  #:use-module (srfi srfi-1))
>
> Is this module needed in the sense that the solution is preferable to what
> is done, for instance, to determine the file name of qt?

The code in the qt recipe removes everything after (and including) the
last period.  I think that's not as robust, because it fails to properly
handle a version number with more (or less) than 3 components.

srfi-1 is very widely used.  It is certainly already loaded already, so
importing it is a cheap operation.

What do you think?

      Mark

Re: [PATCH] gnu: Add gmime

[Andreas Enge]

On Wed, Feb 19, 2014 at 05:17:44AM -0500, Mark H Weaver wrote:
> srfi-1 is very widely used.  It is certainly already loaded already, so
> importing it is a cheap operation.
> 
> What do you think?

I was just asking and am definitely fine with it, if you want to push.

Andreas

Re: [PATCH] gnu: Add gmime

[Ludovic Courtès]

Mark H Weaver <mhw@netris.org> skribis:

> Andreas Enge <andreas@enge.fr> writes:
>
>> On Tue, Feb 18, 2014 at 11:09:16PM -0500, Mark H Weaver wrote:
>>> This adds gmime, another step toward notmuch (mail).
>>> +  #:use-module (srfi srfi-1))
>>
>> Is this module needed in the sense that the solution is preferable to what
>> is done, for instance, to determine the file name of qt?
>
> The code in the qt recipe removes everything after (and including) the
> last period.  I think that's not as robust, because it fails to properly
> handle a version number with more (or less) than 3 components.
>
> srfi-1 is very widely used.  It is certainly already loaded already, so
> importing it is a cheap operation.
>
> What do you think?

Fine with me.

Thanks!

Ludo’.