bug#14261: [guile-1.8] guile-readline fails to build with automake-1.13

bug#14261: [guile-1.8] guile-readline fails to build with automake-1.13

[Cyprien Nicolas]

[-- Attachment #1: Type: text/plain, Size: 997 bytes --]

Per Gentoo bug 467064 [1], aclocal.out reports:

----8<----8<----8<----8<----8<----8<----8<----8<-----

***** aclocal *****
***** PWD: /var/tmp/paludis/dev-scheme-guile-1.8.8-r1/work/guile-1.8.8/guile-readline
***** aclocal

aclocal-1.13: warning: autoconf input should be named 'configure.ac', not 'configure.in'
configure.in:12: error: 'AM_CONFIG_HEADER': this macro is obsolete.
    You should use the 'AC_CONFIG_HEADERS' macro instead.
/usr/share/aclocal-1.13/obsolete-err.m4:12: AM_CONFIG_HEADER is expanded from...
configure.in:12: the top level
autom4te-2.69: /usr/bin/m4 failed with exit status: 1
aclocal-1.13: error: echo failed with exit status: 1

---->8---->8---->8---->8---->8---->8---->8---->8----

I attach two patches here. The first one replace AM_CONFIG_HEADER with
AC_CONFIG_HEADERS and remove AM_PROG_CC_STDC from configure.in, while
se second one renames configure.in into configure.ac per above
warning.


1. https://bugs.gentoo.org/show_bug.cgi?id=467064
-- 
Cyprien/Fulax

[-- Attachment #2: 0001-Fix-configure.in-macro-for-automake-1.13.patch --]
[-- Type: text/x-diff, Size: 1043 bytes --]

From 80a8464c41ca1f30a19936d5524104c5297cc95b Mon Sep 17 00:00:00 2001
From: Cyprien Nicolas <cyprien@nicolas.tf>
Date: Thu, 25 Apr 2013 00:15:40 +0200
Subject: [PATCH 1/2] Fix configure.in macro for automake-1.13

Reported through https://bugs.gentoo.org/show_bug.cgi?id=467064
Fix by Arfrever Frehtes Taifersar Arahesis

* Replace AM_CONFIG_HEADER by AC_CONFIG_HEADERS, the former
  being deprecated since automake-1.13

---
 guile-readline/configure.in | 3 +--
 1 file changed, 1 insertion(+), 2 deletions(-)

diff --git a/guile-readline/configure.in b/guile-readline/configure.in
index 7c9d3d9..c17bee6 100644
--- a/guile-readline/configure.in
+++ b/guile-readline/configure.in
@@ -9,14 +9,13 @@ AC_INIT(guile-readline,
 
 AC_CONFIG_AUX_DIR([.])
 AC_CONFIG_SRCDIR(readline.c)
-AM_CONFIG_HEADER([guile-readline-config.h])
+AC_CONFIG_HEADERS([guile-readline-config.h])
 AM_INIT_AUTOMAKE([foreign no-define])
 
 . $srcdir/../GUILE-VERSION
 
 AC_PROG_INSTALL
 AC_PROG_CC
-AM_PROG_CC_STDC
 AC_LIBTOOL_WIN32_DLL
 AC_PROG_LIBTOOL
 
-- 
1.7.11.7


[-- Attachment #3: 0002-Rename-guile-readline-configure-from-.in-to-.ac.patch --]
[-- Type: text/x-diff, Size: 6154 bytes --]

From 19be2c9fcf92b6ec92fd051e114d074b496cce70 Mon Sep 17 00:00:00 2001
From: Cyprien Nicolas <cyprien@nicolas.tf>
Date: Thu, 25 Apr 2013 00:17:13 +0200
Subject: [PATCH 2/2] Rename guile-readline/configure from .in to .ac

* Rename guile-readline/configure.in to guile-readline/configure.ac.
  Since automake-1.13, configure.in file produce a warning. 

---
 guile-readline/configure.ac | 86 +++++++++++++++++++++++++++++++++++++++++++++
 guile-readline/configure.in | 86 ---------------------------------------------
 2 files changed, 86 insertions(+), 86 deletions(-)
 create mode 100644 guile-readline/configure.ac
 delete mode 100644 guile-readline/configure.in

diff --git a/guile-readline/configure.ac b/guile-readline/configure.ac
new file mode 100644
index 0000000..c17bee6
--- /dev/null
+++ b/guile-readline/configure.ac
@@ -0,0 +1,86 @@
+AC_PREREQ(2.50)
+
+dnl Don't use "echo -n", which is not portable (e.g., not available on
+dnl MacOS X).  Instead, use `patsubst' to remove the newline.
+AC_INIT(guile-readline,
+        patsubst(m4_esyscmd(. ../GUILE-VERSION && echo ${GUILE_VERSION}), [
+]),
+	[bug-guile@gnu.org])
+
+AC_CONFIG_AUX_DIR([.])
+AC_CONFIG_SRCDIR(readline.c)
+AC_CONFIG_HEADERS([guile-readline-config.h])
+AM_INIT_AUTOMAKE([foreign no-define])
+
+. $srcdir/../GUILE-VERSION
+
+AC_PROG_INSTALL
+AC_PROG_CC
+AC_LIBTOOL_WIN32_DLL
+AC_PROG_LIBTOOL
+
+dnl
+dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
+dnl
+AC_CYGWIN
+AC_MINGW32
+EXTRA_DEFS=""
+if test "$MINGW32" = "yes" ; then
+    if test $enable_shared = yes ; then
+      EXTRA_DEFS="-DSCM_IMPORT"
+    fi
+fi
+AC_SUBST(EXTRA_DEFS)
+
+for termlib in ncurses curses termcap terminfo termlib ; do
+   AC_CHECK_LIB(${termlib}, tgoto,
+                [LIBS="-l${termlib} $LIBS"; break])
+done
+
+AC_CHECK_LIB(readline, readline)
+if test $ac_cv_lib_readline_readline = no; then
+  AC_MSG_WARN([libreadline was not found on your system.])
+fi
+
+AC_CHECK_FUNCS(siginterrupt rl_clear_signals rl_cleanup_after_signal)
+
+dnl Check for modern readline naming
+AC_CHECK_FUNCS(rl_filename_completion_function)
+
+dnl Check for rl_get_keymap.  We only use this for deciding whether to
+dnl install paren matching on the Guile command line (when using
+dnl readline for input), so it's completely optional.
+AC_CHECK_FUNCS(rl_get_keymap)
+
+AC_CACHE_CHECK([for rl_getc_function pointer in readline],
+		 ac_cv_var_rl_getc_function,
+		 [AC_TRY_LINK([
+#include <stdio.h>
+#include <readline/readline.h>],
+			      [printf ("%ld", (long) rl_getc_function)],
+			      [ac_cv_var_rl_getc_function=yes],
+			      [ac_cv_var_rl_getc_function=no])])
+if test "${ac_cv_var_rl_getc_function}" = "yes"; then
+  AC_DEFINE(HAVE_RL_GETC_FUNCTION, 1,
+    [Define if your readline library has the rl_getc_function variable.])
+fi
+
+if test $ac_cv_lib_readline_readline = yes \
+        -a $ac_cv_var_rl_getc_function = no; then
+  AC_MSG_WARN([*** libreadline is too old on your system.])
+  AC_MSG_WARN([*** You need readline version 2.1 or later.])
+fi
+
+AC_CHECK_FUNCS(strdup)
+
+. $srcdir/LIBGUILEREADLINE-VERSION
+AC_SUBST(LIBGUILEREADLINE_MAJOR)
+AC_SUBST(LIBGUILEREADLINE_INTERFACE_CURRENT)
+AC_SUBST(LIBGUILEREADLINE_INTERFACE_REVISION)
+AC_SUBST(LIBGUILEREADLINE_INTERFACE_AGE)
+AC_SUBST(LIBGUILEREADLINE_INTERFACE)
+
+AC_SUBST(GUILE_EFFECTIVE_VERSION)
+
+AC_CONFIG_FILES(Makefile ice-9/Makefile)
+AC_OUTPUT
diff --git a/guile-readline/configure.in b/guile-readline/configure.in
deleted file mode 100644
index c17bee6..0000000
--- a/guile-readline/configure.in
+++ /dev/null
@@ -1,86 +0,0 @@
-AC_PREREQ(2.50)
-
-dnl Don't use "echo -n", which is not portable (e.g., not available on
-dnl MacOS X).  Instead, use `patsubst' to remove the newline.
-AC_INIT(guile-readline,
-        patsubst(m4_esyscmd(. ../GUILE-VERSION && echo ${GUILE_VERSION}), [
-]),
-	[bug-guile@gnu.org])
-
-AC_CONFIG_AUX_DIR([.])
-AC_CONFIG_SRCDIR(readline.c)
-AC_CONFIG_HEADERS([guile-readline-config.h])
-AM_INIT_AUTOMAKE([foreign no-define])
-
-. $srcdir/../GUILE-VERSION
-
-AC_PROG_INSTALL
-AC_PROG_CC
-AC_LIBTOOL_WIN32_DLL
-AC_PROG_LIBTOOL
-
-dnl
-dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
-dnl
-AC_CYGWIN
-AC_MINGW32
-EXTRA_DEFS=""
-if test "$MINGW32" = "yes" ; then
-    if test $enable_shared = yes ; then
-      EXTRA_DEFS="-DSCM_IMPORT"
-    fi
-fi
-AC_SUBST(EXTRA_DEFS)
-
-for termlib in ncurses curses termcap terminfo termlib ; do
-   AC_CHECK_LIB(${termlib}, tgoto,
-                [LIBS="-l${termlib} $LIBS"; break])
-done
-
-AC_CHECK_LIB(readline, readline)
-if test $ac_cv_lib_readline_readline = no; then
-  AC_MSG_WARN([libreadline was not found on your system.])
-fi
-
-AC_CHECK_FUNCS(siginterrupt rl_clear_signals rl_cleanup_after_signal)
-
-dnl Check for modern readline naming
-AC_CHECK_FUNCS(rl_filename_completion_function)
-
-dnl Check for rl_get_keymap.  We only use this for deciding whether to
-dnl install paren matching on the Guile command line (when using
-dnl readline for input), so it's completely optional.
-AC_CHECK_FUNCS(rl_get_keymap)
-
-AC_CACHE_CHECK([for rl_getc_function pointer in readline],
-		 ac_cv_var_rl_getc_function,
-		 [AC_TRY_LINK([
-#include <stdio.h>
-#include <readline/readline.h>],
-			      [printf ("%ld", (long) rl_getc_function)],
-			      [ac_cv_var_rl_getc_function=yes],
-			      [ac_cv_var_rl_getc_function=no])])
-if test "${ac_cv_var_rl_getc_function}" = "yes"; then
-  AC_DEFINE(HAVE_RL_GETC_FUNCTION, 1,
-    [Define if your readline library has the rl_getc_function variable.])
-fi
-
-if test $ac_cv_lib_readline_readline = yes \
-        -a $ac_cv_var_rl_getc_function = no; then
-  AC_MSG_WARN([*** libreadline is too old on your system.])
-  AC_MSG_WARN([*** You need readline version 2.1 or later.])
-fi
-
-AC_CHECK_FUNCS(strdup)
-
-. $srcdir/LIBGUILEREADLINE-VERSION
-AC_SUBST(LIBGUILEREADLINE_MAJOR)
-AC_SUBST(LIBGUILEREADLINE_INTERFACE_CURRENT)
-AC_SUBST(LIBGUILEREADLINE_INTERFACE_REVISION)
-AC_SUBST(LIBGUILEREADLINE_INTERFACE_AGE)
-AC_SUBST(LIBGUILEREADLINE_INTERFACE)
-
-AC_SUBST(GUILE_EFFECTIVE_VERSION)
-
-AC_CONFIG_FILES(Makefile ice-9/Makefile)
-AC_OUTPUT
-- 
1.7.11.7

bug#14261: [guile-1.8] guile-readline fails to build with automake-1.13

[Ludovic Courtès]

Cyprien Nicolas <cyprien@nicolas.tf> skribis:

> From: Cyprien Nicolas <cyprien@nicolas.tf>
> Date: Thu, 25 Apr 2013 00:15:40 +0200
> Subject: [PATCH 1/2] Fix configure.in macro for automake-1.13
>
> Reported through https://bugs.gentoo.org/show_bug.cgi?id=467064
> Fix by Arfrever Frehtes Taifersar Arahesis
>
> * Replace AM_CONFIG_HEADER by AC_CONFIG_HEADERS, the former
>   being deprecated since automake-1.13

Thanks, applied in branch_release-1-8.

I omitted the .in -> .ac rename, though, since it’s harmless.

Ludo’.