count all ispell(flyspell) errors in a buffer

count all ispell(flyspell) errors in a buffer

[Uwe Brauer]

Hi 

I usually use flyspell on most of my buffers, but sometimes are
interested to run ispell-region.

Is there any way to find out how many errors ispell finds when the
program starts, if I run it interactive, how many corrections of errors
I accepted?

I googled a bit but could not find anything.

Any ideas?

Thanks and regards

Uwe Brauer 
-- 
I strongly condemn Hamas heinous atrocities on Israel, especially the despicable pogroms.
I strongly condemn Putin's war of aggression against Ukraine.
I support to deliver weapons to Ukraine's military. 
I support the EU and NATO membership of Ukraine. 

Re: count all ispell(flyspell) errors in a buffer

[Emanuel Berg]

Uwe Brauer wrote:

> I usually use flyspell on most of my buffers, but sometimes
> are interested to run ispell-region.
>
> Is there any way to find out how many errors ispell finds
> when the program starts

You can use this

(condition-case nil
    (not (ispell-word))
  (error nil) )

It returns t if the word is correct, otherwise nil.

Put in a loop that iterates all the words in the region with
`forward-word'.

For every word that is nil, do `cl-incf' on some error
variable that is initiated to 0.

-- 
underground experts united
https://dataswamp.org/~incal

Re: count all ispell(flyspell) errors in a buffer

[Emanuel Berg]

Uwe Brauer wrote:

> I usually use flyspell on most of my buffers, but sometimes
> are interested to run ispell-region.
>
> Is there any way to find out how many errors ispell finds
> when the program starts, if I run it interactive, how many
> corrections of errors I accepted?
>
> I googled a bit but could not find anything.

(require 'cl-lib)
(require 'ispell)

(defun ispell-count (&optional beg end)
  (interactive
    (when (use-region-p)
      (list (region-beginning) (region-end)) ))
  (or beg (setq beg (point-min)))
  (or end (setq end (point-max)))
  (save-mark-and-excursion
    (goto-char beg)
    (backward-word)
    (forward-to-word)
    (cl-loop
      with errors = 0
      while (< (point) end)
      do (let ((word (thing-at-point 'word t)))
           (unless (ispell-lookup-words word) ; inefficient
             (cl-incf errors) )
           (forward-to-word) )
      finally (message "errors: %s" errors)) ))

;; this is a region wiht two
;; worsd spelled incorrectly

-- 
underground experts united
https://dataswamp.org/~incal

Re: count all ispell(flyspell) errors in a buffer

[Emanuel Berg]

Check out the below file URL, and this one

  https://dataswamp.org/~incal/emacs-init/dwim.el

for some further minor improvements of this program.

But the one I posted works fine and does not need the
dwim.el file.

;;; -*- lexical-binding: t -*-
;;
;; this file:
;;   https://dataswamp.org/~incal/emacs-init/spell.el

(require 'cl-lib)
(require 'dwim)
(require 'ispell)

(defun ispell-count (&optional beg end)
  (interactive (use-region))
  (or beg (setq beg (point-min)))
  (or end (setq end (point-max)))
  (save-mark-and-excursion
    (goto-char beg)
    (backward-word)
    (cl-loop
      with words  = 0
      with errors = 0
      while (< (point) end)
      do (let ((word (thing-at-point 'word t)))
           (cl-incf words)
           (unless (ispell-lookup-words word)
             (cl-incf errors) )
           (forward-to-word) )
      finally (message "%s words checked, %s errors" words errors) )))

-- 
underground experts united
https://dataswamp.org/~incal