read key sequence according to input method?

read key sequence according to input method?

[Kai Großjohann]

How can I read a key sequence according to some input method?  The
read-key-sequence function appears to work according to keymaps, but
input methods don't define keymaps, I think.

kai
-- 
Silence is foo!

Re: read key sequence according to input method?

[Miles Bader]

Kai.Grossjohann@CS.Uni-Dortmund.DE (Kai Großjohann) writes:
> How can I read a key sequence according to some input method?  The
> read-key-sequence function appears to work according to keymaps, but
> input methods don't define keymaps, I think.

Hmmm.. I looked around, and couldn't find anything obvious, so I consed
up the following; is this the sort of thing you want?

(defun read-input-method-key-sequence (prompt &optional input-method)
  "Read one or more characters using an input method and return as a vector.
This returns a vector of one character unless the input method returns more.

First arg PROMPT is a prompt string.  If nil, do not prompt specially.
Second arg INPUT-METHOD is the input method to use; if nil, use the
current buffer's active input from `current-input-method'."
  (unless input-method
    (setq input-method current-input-method))
  (let ((cursor-in-echo-area prompt)
	(input-method-use-echo-area prompt))
    (when prompt
      (message prompt))
    (if input-method
	(let ((prev-input-method current-input-method))
	  (unwind-protect
	      (progn
		(activate-input-method input-method)
		(apply #'vector (funcall input-method-function (read-event))))
	    (activate-input-method prev-input-method)))
      (vector (read-event)))))

-Miles
-- 
`...the Soviet Union was sliding in to an economic collapse so comprehensive
 that in the end its factories produced not goods but bads: finished products
 less valuable than the raw materials they were made from.'  [The Economist]

Re: read key sequence according to input method?

[Kai Großjohann]

Miles Bader <miles@lsi.nec.co.jp> writes:

> Hmmm.. I looked around, and couldn't find anything obvious, so I consed
> up the following; is this the sort of thing you want?

Yes, this looks quite nice.  Thanks a lot!  I'll continue that other
thread about replacing C-x 8 with something based on your suggestion.

kai
-- 
Silence is foo!

Re: read key sequence according to input method?

[Miles Bader]

Kai.Grossjohann@CS.Uni-Dortmund.DE (Kai Großjohann) writes:
> Yes, this looks quite nice.  Thanks a lot!  I'll continue that other
> thread about replacing C-x 8 with something based on your suggestion.

Ah, so that's what you want it for...

I think that's even simpler; the following seems to actually work pretty
well (though no doubt there are corner cases that need addressing):

(defun insert-latin1-character ()
  (interactive)
  (let ((prev-input-method current-input-method))
    (unwind-protect
	(progn
	  (activate-input-method 'latin-1-prefix)
	  (apply #'insert (funcall input-method-function (read-event))))
      (activate-input-method prev-input-method))))

One nice thing about the old implementation, though, is that you can get
help by typing `C-h' during input...

-Miles
-- 
A zen-buddhist walked into a pizza shop and
said, "Make me one with everything."