* bug#45535: 28.0.50; [PATCH] Add some tests to find-func.el
[not found] <m1k0t01vsm.fsf.ref@yahoo.es>
@ 2020-12-29 15:22 ` Unknown
2020-12-30 4:00 ` Lars Ingebrigtsen
0 siblings, 1 reply; 4+ messages in thread
From: Unknown @ 2020-12-29 15:22 UTC (permalink / raw)
To: 45535
[-- Attachment #1: Type: text/plain, Size: 104 bytes --]
Here's a patch with some tests that cover interesting bits of
functionality in find-func.el.
Thanks.
[-- Attachment #2: 0001-Add-some-tests-to-find-func.el.patch --]
[-- Type: text/x-patch, Size: 3757 bytes --]
From 21c7c7ab2e4ec8cb262d91585296d43ebaf04ac5 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Daniel=20Mart=C3=ADn?= <mardani29@yahoo.es>
Date: Tue, 29 Dec 2020 16:12:58 +0100
Subject: [PATCH] Add some tests to find-func.el
---
test/lisp/emacs-lisp/find-func-tests.el | 61 +++++++++++++++++++++++++
1 file changed, 61 insertions(+)
diff --git a/test/lisp/emacs-lisp/find-func-tests.el b/test/lisp/emacs-lisp/find-func-tests.el
index 03df4bb9ff..14ad48fc65 100644
--- a/test/lisp/emacs-lisp/find-func-tests.el
+++ b/test/lisp/emacs-lisp/find-func-tests.el
@@ -27,6 +27,7 @@
;;; Code:
(require 'ert-x) ;For `ert-run-keys'.
+(require 'find-func)
(ert-deftest find-func-tests--library-completion () ;bug#43393
;; FIXME: How can we make this work in batch (see also
@@ -43,6 +44,66 @@ find-func-tests--library-completion
(concat data-directory (kbd "n x / TAB RET"))
(read-library-name)))))
+(ert-deftest find-func-tests--locate-symbols ()
+ (should (cdr
+ (find-function-search-for-symbol
+ #'goto-line nil "simple")))
+ (should (cdr
+ (find-function-search-for-symbol
+ 'minibuffer-history 'defvar "simple")))
+ (should (cdr
+ (find-function-search-for-symbol
+ 'with-current-buffer nil "subr")))
+ (should (cdr
+ (find-function-search-for-symbol
+ 'font-lock-warning-face 'defface "font-lock")))
+ (should-not (cdr
+ (find-function-search-for-symbol
+ 'wrong-variable 'defvar "simple")))
+ (should-not (cdr
+ (find-function-search-for-symbol
+ 'wrong-function nil "simple")))
+ (should (cdr (find-function-noselect #'goto-line)))
+ (should (cdr (find-function-noselect #'goto-char)))
+ ;; Setting LISP-ONLY and passing a primitive should error.
+ (should-error (find-function-noselect #'goto-char t))
+ (should-error (find-function-noselect 'wrong-function)))
+
+(defun test-locate-helper (func &optional expected-result)
+ "Assert on the result of `find-function-library' for FUNC.
+EXPECTED-RESULT is an alist (FUNC . LIBRARY) with the
+expected function symbol and function library, respectively."
+ (cl-destructuring-bind (orig-function . library)
+ (find-function-library func)
+ (cl-destructuring-bind (expected-func . expected-library)
+ expected-result
+ (should (eq orig-function expected-func))
+ (should (and
+ (not (string-empty-p expected-library))
+ (string-match-p expected-library library))))))
+
+(ert-deftest find-func-tests--locate-library ()
+ (test-locate-helper #'goto-line '(goto-line . "simple"))
+ (test-locate-helper #'forward-char '(forward-char . "cmds.c"))
+ (should-error (test-locate-helper 'wrong-function)))
+
+(ert-deftest find-func-tests--locate-adviced-symbols ()
+ (defun my-message ()
+ (message "Hello!"))
+ (advice-add #'mark-sexp :around 'my-message)
+ (test-locate-helper #'mark-sexp '(mark-sexp . "lisp"))
+ (advice-remove #'mark-sexp 'my-message))
+
+(ert-deftest find-func-tests--find-library-verbose ()
+ (find-function-library #'join-line nil t)
+ (with-current-buffer "*Messages*"
+ (save-excursion
+ (goto-char (point-max))
+ (skip-chars-backward "\n")
+ (should (string-equal
+ (buffer-substring (line-beginning-position) (point))
+ "‘join-line’ is an alias for ‘delete-indentation’")))))
+
;; Avoid a byte-compilation warning that may confuse people reading
;; the result of the following test.
(declare-function compilation--message->loc nil "compile")
--
2.28.0
^ permalink raw reply related [flat|nested] 4+ messages in thread
* bug#45535: 28.0.50; [PATCH] Add some tests to find-func.el
2020-12-29 15:22 ` bug#45535: 28.0.50; [PATCH] Add some tests to find-func.el Unknown
@ 2020-12-30 4:00 ` Lars Ingebrigtsen
2020-12-30 11:04 ` Unknown
0 siblings, 1 reply; 4+ messages in thread
From: Lars Ingebrigtsen @ 2020-12-30 4:00 UTC (permalink / raw)
To: Daniel Martín; +Cc: 45535
Daniel Martín <mardani29@yahoo.es> writes:
> Here's a patch with some tests that cover interesting bits of
> functionality in find-func.el.
find-func-tests--find-library-verbose fails with:
(string-equal "`join-line' is an alias for `delete-indentation'" "‘join-line’ is an alias for ‘delete-indentation’")
So the `' didn't turn into ‘’ here (Debian bullseye).
--
(domestic pets only, the antidote for overdose, milk.)
bloggy blog: http://lars.ingebrigtsen.no
^ permalink raw reply [flat|nested] 4+ messages in thread
* bug#45535: 28.0.50; [PATCH] Add some tests to find-func.el
2020-12-30 4:00 ` Lars Ingebrigtsen
@ 2020-12-30 11:04 ` Unknown
2020-12-31 3:31 ` Lars Ingebrigtsen
0 siblings, 1 reply; 4+ messages in thread
From: Unknown @ 2020-12-30 11:04 UTC (permalink / raw)
To: Lars Ingebrigtsen; +Cc: 45535
[-- Attachment #1: Type: text/plain, Size: 389 bytes --]
Lars Ingebrigtsen <larsi@gnus.org> writes:
>
> find-func-tests--find-library-verbose fails with:
>
> (string-equal "`join-line' is an alias for `delete-indentation'" "‘join-line’ is an alias for ‘delete-indentation’")
>
> So the `' didn't turn into ‘’ here (Debian bullseye).
Oh, thanks for catching this. I've edited the assertion to make it more
general.
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: 0001-Add-some-tests-to-find-func.el.patch --]
[-- Type: text/x-patch, Size: 3694 bytes --]
From a2290150f92689055b5f44dbda29cf28e6380a66 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Daniel=20Mart=C3=ADn?= <mardani29@yahoo.es>
Date: Tue, 29 Dec 2020 16:12:58 +0100
Subject: [PATCH] Add some tests to find-func.el
---
test/lisp/emacs-lisp/find-func-tests.el | 63 +++++++++++++++++++++++++
1 file changed, 63 insertions(+)
diff --git a/test/lisp/emacs-lisp/find-func-tests.el b/test/lisp/emacs-lisp/find-func-tests.el
index 03df4bb9ff..3960aff2a5 100644
--- a/test/lisp/emacs-lisp/find-func-tests.el
+++ b/test/lisp/emacs-lisp/find-func-tests.el
@@ -27,6 +27,7 @@
;;; Code:
(require 'ert-x) ;For `ert-run-keys'.
+(require 'find-func)
(ert-deftest find-func-tests--library-completion () ;bug#43393
;; FIXME: How can we make this work in batch (see also
@@ -43,6 +44,68 @@ find-func-tests--library-completion
(concat data-directory (kbd "n x / TAB RET"))
(read-library-name)))))
+(ert-deftest find-func-tests--locate-symbols ()
+ (should (cdr
+ (find-function-search-for-symbol
+ #'goto-line nil "simple")))
+ (should (cdr
+ (find-function-search-for-symbol
+ 'minibuffer-history 'defvar "simple")))
+ (should (cdr
+ (find-function-search-for-symbol
+ 'with-current-buffer nil "subr")))
+ (should (cdr
+ (find-function-search-for-symbol
+ 'font-lock-warning-face 'defface "font-lock")))
+ (should-not (cdr
+ (find-function-search-for-symbol
+ 'wrong-variable 'defvar "simple")))
+ (should-not (cdr
+ (find-function-search-for-symbol
+ 'wrong-function nil "simple")))
+ (should (cdr (find-function-noselect #'goto-line)))
+ (should (cdr (find-function-noselect #'goto-char)))
+ ;; Setting LISP-ONLY and passing a primitive should error.
+ (should-error (find-function-noselect #'goto-char t))
+ (should-error (find-function-noselect 'wrong-function)))
+
+(defun test-locate-helper (func &optional expected-result)
+ "Assert on the result of `find-function-library' for FUNC.
+EXPECTED-RESULT is an alist (FUNC . LIBRARY) with the
+expected function symbol and function library, respectively."
+ (cl-destructuring-bind (orig-function . library)
+ (find-function-library func)
+ (cl-destructuring-bind (expected-func . expected-library)
+ expected-result
+ (should (eq orig-function expected-func))
+ (should (and
+ (not (string-empty-p expected-library))
+ (string-match-p expected-library library))))))
+
+(ert-deftest find-func-tests--locate-library ()
+ (test-locate-helper #'goto-line '(goto-line . "simple"))
+ (test-locate-helper #'forward-char '(forward-char . "cmds.c"))
+ (should-error (test-locate-helper 'wrong-function)))
+
+(ert-deftest find-func-tests--locate-adviced-symbols ()
+ (defun my-message ()
+ (message "Hello!"))
+ (advice-add #'mark-sexp :around 'my-message)
+ (test-locate-helper #'mark-sexp '(mark-sexp . "lisp"))
+ (advice-remove #'mark-sexp 'my-message))
+
+(ert-deftest find-func-tests--find-library-verbose ()
+ (find-function-library #'join-line nil t)
+ (with-current-buffer "*Messages*"
+ (save-excursion
+ (goto-char (point-max))
+ (skip-chars-backward "\n")
+ (should (string-match-p
+ ".join-line. is an alias for .delete-indentation."
+ (buffer-substring
+ (line-beginning-position)
+ (point)))))))
+
;; Avoid a byte-compilation warning that may confuse people reading
;; the result of the following test.
(declare-function compilation--message->loc nil "compile")
--
2.28.0
^ permalink raw reply related [flat|nested] 4+ messages in thread
* bug#45535: 28.0.50; [PATCH] Add some tests to find-func.el
2020-12-30 11:04 ` Unknown
@ 2020-12-31 3:31 ` Lars Ingebrigtsen
0 siblings, 0 replies; 4+ messages in thread
From: Lars Ingebrigtsen @ 2020-12-31 3:31 UTC (permalink / raw)
To: Daniel Martín; +Cc: 45535
Daniel Martín <mardani29@yahoo.es> writes:
> Oh, thanks for catching this. I've edited the assertion to make it more
> general.
Thanks; looks good (and pushed to Emacs 28).
--
(domestic pets only, the antidote for overdose, milk.)
bloggy blog: http://lars.ingebrigtsen.no
^ permalink raw reply [flat|nested] 4+ messages in thread
end of thread, other threads:[~2020-12-31 3:31 UTC | newest]
Thread overview: 4+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
[not found] <m1k0t01vsm.fsf.ref@yahoo.es>
2020-12-29 15:22 ` bug#45535: 28.0.50; [PATCH] Add some tests to find-func.el Unknown
2020-12-30 4:00 ` Lars Ingebrigtsen
2020-12-30 11:04 ` Unknown
2020-12-31 3:31 ` Lars Ingebrigtsen
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/emacs.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).