bug#54027: Wishlist: Support full CSI u specification for terminal input

[Stefan Monnier via "Bug reports for GNU Emacs, the Swiss army knife of text editors" <bug-gnu-emacs@gnu.org>]

Alex Hutcheson [2022-02-27 13:21:20] wrote:
>> I think just adding the missing combinations is a better way forward.
> I think we're in agreement here, I was just suggesting how to add
> the combinations to xterm.el without introducing a lot of boilerplate
> code.

Actually, for `ESC [ 27 ...` the better option is to bind `ESC [ 27` to
a function that reads the subsequent parameters so it will handle *all*
cases in one go, as in the barely tested patch below.

For `ESC [ ... u` it's a bit more tricky because it doesn't have such
a "clean" prefix (it's distinguished by the final `u` instead), so we'd
have to rework a lot of the rest of the `ESC [` bindings.
Maybe not a bad idea, tho.


        Stefan


diff --git a/lisp/term/xterm.el b/lisp/term/xterm.el
index a7e257f41c5..9bf6a5750b1 100644
--- a/lisp/term/xterm.el
+++ b/lisp/term/xterm.el
@@ -192,6 +192,41 @@ xterm-rxvt-function-map
     map)
   "Keymap of escape sequences, shared between xterm and rxvt support.")
 
+(defun xterm--read-csi ()
+  ;; Format described in the "Control Sequence Introducer" section:
+  ;; https://en.wikipedia.org/wiki/ANSI_escape_code#CSIsection.
+  (let ((params '())
+        (intermediates '())
+        (final nil))
+    (setq final (read-char))
+    (while (<= #x30 final #x3F)
+      (push final params) ;And read more.
+      (setq final (read-char)))
+    (while (<= #x20 final #x2F)
+      (push final intermediates)
+      (setq final (read-char)))
+    (list (nreverse params) (nreverse intermediates) final)))
+
+(defun xterm--csi-27-modified-keys (&rest _)
+  (pcase-let* ((csi (xterm--read-csi))
+               (`(,params ,intermediates ,final) csi)
+               (tmp nil))
+    (cond
+     ((and (eq final ?~) (null intermediates)
+           (setq tmp (apply #'string params))
+           (string-match "\\([1-9][0-9]*\\);\\([0-9]+\\)" tmp))
+      (let ((modifiers (1- (string-to-number (match-string 1 tmp))))
+            (char (string-to-number (match-string 2 tmp))))
+        (vector
+         (+ char
+            (if (zerop (logand modifiers 1)) 0 ?\S-\0)
+            (if (zerop (logand modifiers 2)) 0 ?\A-\0)
+            (if (zerop (logand modifiers 4)) 0 ?\C-\0)
+            (if (zerop (logand modifiers 8)) 0 ?\M-\0)))))
+     (t
+      (message "Unknown CSI-27 sequence: %S" csi)
+      []))))
+
 (defvar xterm-function-map
   (let ((map (make-sparse-keymap)))
     (set-keymap-parent map xterm-rxvt-function-map)
@@ -576,12 +611,12 @@ xterm-function-map
 
                     (6 9   [C-S-tab])
                     (6 13  [C-S-return])))
-      (define-key map
-        (format "\e[27;%d;%d~" (nth 0 bind) (nth 1 bind)) (nth 2 bind))
       ;; For formatOtherKeys=1, the sequence is a bit shorter (bug#13839).
       (define-key map
         (format "\e[%d;%du" (nth 1 bind) (nth 0 bind)) (nth 2 bind)))
 
+    (define-key map "\e[27;" #'xterm--csi-27-modified-keys)
+
     ;; Other versions of xterm might emit these.
     (define-key map "\e[1~" [home])