bug#45688: 28.0.50; New action for display-buffer?

[martin rudalics <rudalics@gmx.at>]

[-- Attachment #1: Type: text/plain, Size: 726 bytes --]

 > I put some messaging in that code, and it is indeed that bit that does
 > the resizing.
 >
 > Here's a reproducer from emacs -Q:
 >
 > (progn
 >    (setq display-buffer-alist '((".*" display-buffer-use-least-recent-window)))
 >    (pop-to-buffer "file1")
 >    (pop-to-buffer "file2")
 >    (split-window-below)
 >    (pop-to-buffer "file3"))
 >
 > I end up with the following, and file3 in an oddly large window.

So you have been splicing in a 'split-window-below' between those calls.
Why didn't you tell me before?  'split-window-below' copies the
'quit-restore' parameter to the new window and that's what you get.

Let's try to clean up the height value when copying the 'quit-restore'
parameter as attached.

martin

[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: split-window-quit-restore.diff --]
[-- Type: text/x-patch; name="split-window-quit-restore.diff", Size: 2338 bytes --]

diff --git a/lisp/window.el b/lisp/window.el
index a6cdd4dec2..8651d7502f 100644
--- a/lisp/window.el
+++ b/lisp/window.el
@@ -5528,6 +5528,24 @@ split-window-keep-point
   :type 'boolean
   :group 'windows)

+(defun window--split-window-quit-restore (old-window new-window)
+  "Copy 'quit-restore' parameter to new window after splitting.
+OLD-WINDOW is the window that was split, NEW-WINDOW is the new
+window.  This cleans up any height value that could be used to
+restore the old height of NEW-WINDOW in a later invocation of
+`display-buffer'."
+  (let* ((quit-restore (window-parameter old-window 'quit-restore))
+	 (quad (nth 1 quit-restore)))
+    (when quit-restore
+      (when (and (listp quad) (integerp (nth 3 quad)))
+        ;; nth 3 of quad is the old-window height of OLD-WINDOW.  This
+        ;; value is meaningless in NEW-WINDOW so set it to the present
+        ;; height of NEW-WINDOW.
+        (setq quit-restore (copy-tree quit-restore))
+        (rplaca (cdddr (nth 1 quit-restore)) (window-total-height new-window)))
+
+      (set-window-parameter new-window 'quit-restore quit-restore))))
+
 (defun split-window-below (&optional size)
   "Split the selected window into two windows, one above the other.
 The selected window is above.  The newly split-off window is
@@ -5575,9 +5593,7 @@ split-window-below
 	     (set-window-point new-window old-point)
 	     (select-window new-window))))
     ;; Always copy quit-restore parameter in interactive use.
-    (let ((quit-restore (window-parameter old-window 'quit-restore)))
-      (when quit-restore
-	(set-window-parameter new-window 'quit-restore quit-restore)))
+    (window--split-window-quit-restore old-window new-window)
     new-window))

 (defalias 'split-window-vertically 'split-window-below)
@@ -5604,9 +5620,7 @@ split-window-right
       (error "Size of new window too small"))
     (setq new-window (split-window nil size t))
     ;; Always copy quit-restore parameter in interactive use.
-    (let ((quit-restore (window-parameter old-window 'quit-restore)))
-      (when quit-restore
-	(set-window-parameter new-window 'quit-restore quit-restore)))
+    (window--split-window-quit-restore old-window new-window)
     new-window))

 (defalias 'split-window-horizontally 'split-window-right)