bug#24902: 25.1; C-x = for Unicode

["Mattias Engdegård" <mattiase@acm.org>]

[-- Attachment #1: Type: text/plain, Size: 1413 bytes --]

> As others noted, `C-u C-x =' does display this info, and the reason that `C-x =' doesn't is because the names can be very long. We could add a user option to include it anyway, but in my opinion, it wouldn't be used much, and users that want this could just add advice to the command to do it instead. 

If many users would be served by an improved format, perhaps a change would be warranted after all? My local version replaces the standard

 Char: α (945, #o1661, #x3b1, file ...) point=419 of 423 (99%) column=0

with

 U+03B1 GREEK SMALL LETTER ALPHA pt=419/423 col=0

To save space, remove noise, unnecessary and/or obsolete characters. U+HHHH is the standard notation for code values nowadays; I have little use for decimal and octal (octal!) numbers although I know how to get them if I want. Nor do I generally need to see the character itself; it's right under the cursor.

Now almost all Unicode character names fit very comfortably on a single line in the echo area, and for the rare ones that do not, this area expands.

I'm not going to reopen the bug but believe such a format (or something similar) would be much more helpful for the typical user. But don't take my word for it: try running something like the attached code yourself for a while and see if it doesn't make you happier.

I doubt much thought has gone into the present format; it's just an artefact of history.


[-- Attachment #2: my-what-cursor-position.el --]
[-- Type: application/octet-stream, Size: 1095 bytes --]

;;; -*- lexical-binding: t -*-

(defun my-what-cursor-position (&optional detail)
  "Like `what-cursor-position', but with important information only."
  (interactive "P")
  (if detail
      (what-cursor-position detail)
    (let* ((char (char-after))
           (char-info
            (cond
             ((null char) "")
             ((<= #x3fff80 char #x3fffff)
              (format "#x%02X (raw byte) " (logand char #xff)))
             (t
              (format "U+%04X %s "
                      char
                      (or (get-char-code-property char 'name)
                          (get-char-code-property char 'old-name)
                          "(undefined)")))))
           (beg (point-min))
           (end (point-max))
           (narrow (if (and (= beg 1) (= (1- end) (buffer-size)))
                       ""
                     (format " <%d-%d>" beg end))))
      (message "%spt=%d/%d%s col=%d"
               char-info
               (point) (buffer-size)
               narrow
               (current-column)))))

(global-set-key (kbd "C-x =") 'my-what-cursor-position)