* bug#65511: [PATCH] copy-next-command-output suggestion
@ 2023-08-24 21:46 Jeremy Bryant
2023-08-25 6:05 ` Eli Zaretskii
0 siblings, 1 reply; 6+ messages in thread
From: Jeremy Bryant @ 2023-08-24 21:46 UTC (permalink / raw)
To: 65511, monnier
[-- Attachment #1: Type: text/plain, Size: 575 bytes --]
Hello, Emacs maintainers.
The command copy-next-command-output copies the output of the next
command, and having used it for several months, I would like to suggest
this for Emacs core. It doesn't appear to be part of Emacs. I
typically bind this C-c u.
This code was provided by Stefan on this list or emacs-devel, so the
author should be changed accordingly (I haven't modified Stefan's code,
just used it).
Thoughts welcome as this is my first patch suggestion. It could also be
put in a package in ELPA. I have signed the paperwork.
Thanks in advance
Jeremy
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: patch --]
[-- Type: text/x-diff, Size: 2822 bytes --]
From 4b797454bbf09556bfb23cbd01cae3e424da29d7 Mon Sep 17 00:00:00 2001
From: Jeremy Bryant <jb@jeremybryant.net>
Date: Thu, 24 Aug 2023 22:42:29 +0100
Subject: [PATCH] Add output of next command to the kill ring
---
lisp/misc.el | 47 +++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 47 insertions(+)
diff --git a/lisp/misc.el b/lisp/misc.el
index e8b38fad42e..5bd3c720206 100644
--- a/lisp/misc.el
+++ b/lisp/misc.el
@@ -327,6 +327,53 @@ list-dynamic-libraries
(display-buffer buffer)
nil)
+(defun copy-next-command-output ()
+ "Prefix command to add the output of the next command to the `kill-ring`."
+ (interactive)
+ (let ((md (minibuffer-depth))
+ (marker (with-current-buffer "*Messages*"
+ (point-max-marker))))
+ (cl-labels ((pre ()
+ (unless (> (minibuffer-depth) md)
+ (add-hook 'post-command-hook #'post)
+ (prepare)))
+ (prepare ()
+ (with-current-buffer "*Messages*"
+ (move-marker marker (point-max))))
+ (preserve ()
+ (unless (> (minibuffer-depth) md)
+ (remove-hook 'post-command-hook #'post)
+ (add-hook 'pre-command-hook #'pre)))
+ (echo ()
+ (unless (> (minibuffer-depth) md)
+ "[copy-output]"))
+ (post ()
+ (if (> (minibuffer-depth) md)
+ ;; Prepare, in case there's no pre-command-hook before
+ ;; the next post-command-hook. E.g. in the case of
+ ;; execute-extended-command.
+ (prepare)
+ (remove-hook 'pre-command-hook #'pre)
+ (remove-hook 'post-command-hook #'post)
+ (remove-hook 'prefix-command-preserve-state-hook
+ #'preserve)
+ (remove-hook 'prefix-command-echo-keystrokes-functions
+ #'echo)
+ (prefix-command-update)
+ (with-current-buffer (marker-buffer marker)
+ (when (< marker (point-max))
+ (kill-new (buffer-substring marker (point-max)))))
+ (set-marker marker nil))))
+ (add-hook 'prefix-command-preserve-state-hook #'preserve)
+ (add-hook 'prefix-command-echo-keystrokes-functions #'echo)
+ ;; (message "BEFORE: prefix-arg=%S current-prefix-arg=%S"
+ ;; prefix-arg current-prefix-arg)
+ (prefix-command-preserve-state)
+ ;; (message "AFTER: prefix-arg=%S current-prefix-arg=%S"
+ ;; prefix-arg current-prefix-arg)
+ )))
+
+
(provide 'misc)
;;; misc.el ends here
--
2.40.1
^ permalink raw reply related [flat|nested] 6+ messages in thread
* bug#65511: [PATCH] copy-next-command-output suggestion
2023-08-24 21:46 bug#65511: [PATCH] copy-next-command-output suggestion Jeremy Bryant
@ 2023-08-25 6:05 ` Eli Zaretskii
2023-09-04 22:17 ` Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors
0 siblings, 1 reply; 6+ messages in thread
From: Eli Zaretskii @ 2023-08-25 6:05 UTC (permalink / raw)
To: Jeremy Bryant; +Cc: 65511, monnier
> From: Jeremy Bryant <jb@jeremybryant.net>
> Date: Thu, 24 Aug 2023 22:46:28 +0100
>
> The command copy-next-command-output copies the output of the next
> command, and having used it for several months, I would like to suggest
> this for Emacs core. It doesn't appear to be part of Emacs. I
> typically bind this C-c u.
>
> This code was provided by Stefan on this list or emacs-devel, so the
> author should be changed accordingly (I haven't modified Stefan's code,
> just used it).
>
> Thoughts welcome as this is my first patch suggestion. It could also be
> put in a package in ELPA. I have signed the paperwork.
Thanks. On the formal level, this needs a NEWS entry and a suitable
change for the user manual. Also, please always accompany changes by
a commit log message formatted according to our conventions (see
CONTRIBUTE and the examples shown by "git log").
Reading the code, I'm worried by adding/removing hooks without
suitable unwind-protect protection: what if some code signals an error
or the user hits C-g before this code runs to completion? We need to
make sure these hooks are cleaned up properly in those cases.
I also wonder whether we should bind interprogram-cut-function to nil
around the call to kill-new, since this stuff probably should be put
in the clipboard, right?
Also, what happens if some process-filter or process-sentinel or timer
fire during the time these hooks are in effect: will the stuff added
to the kill-ring include their output as well? if not, how does this
command prevent that?
And finally, this feature only works with commands whose output goes
to *Messages*, right? If so, there are commands which show messages
in other ways, and at the very least the doc string should mention
that caveat. Bonus points for adding ways of capturing those other
kinds of output as well.
^ permalink raw reply [flat|nested] 6+ messages in thread
* bug#65511: [PATCH] copy-next-command-output suggestion
2023-08-25 6:05 ` Eli Zaretskii
@ 2023-09-04 22:17 ` Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-09-05 11:14 ` Eli Zaretskii
0 siblings, 1 reply; 6+ messages in thread
From: Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors @ 2023-09-04 22:17 UTC (permalink / raw)
To: Eli Zaretskii; +Cc: Jeremy Bryant, 65511
> Reading the code, I'm worried by adding/removing hooks without
> suitable unwind-protect protection: what if some code signals an error
> or the user hits C-g before this code runs to completion? We need to
> make sure these hooks are cleaned up properly in those cases.
This is a prefix command, like `C-u`, `C-x 8 u`, and a few more: it runs
to completion before it does anything useful, since its mode of
operation is to arrange for the next command to be run
slightly differently.
The way it tries to make sure to disable itself "soon" is to use
`pre/post-command-hooks` in a way that should hopefully ensure it won't
linger longer than desired.
It's not as definite as I'd like either, but it's the best way I could
come up with so far. I think that if we want to make it better, then we
should seriously look at improving our command-loop to provide better
built-in support for prefix commands.
The patch below includes a longer comment explaining the various
possible states,, which should hopefully help convince oneself that it
should work acceptably.
> I also wonder whether we should bind interprogram-cut-function to nil
> around the call to kill-new, since this stuff probably should be put
> in the clipboard, right?
I don't understand: binding it to nil would *prevent* it from making it
to the clipboard, whereas I don't see why we shouldn't obey
`select-enable-clipboard` and `select-enable-primary` here.
> Also, what happens if some process-filter or process-sentinel or timer
> fire during the time these hooks are in effect: will the stuff added
> to the kill-ring include their output as well?
Yes.
Not sure we should try to do something about it.
> And finally, this feature only works with commands whose output goes
> to *Messages*, right?
Yup.
> If so, there are commands which show messages in other ways, and at
> the very least the doc string should mention that caveat.
> Bonus points for adding ways of capturing those other kinds of output
> as well.
Agreed.
BTW, the reason why I haven't pushed to include it in Emacs is that I'm
not really satisfied with the UI: in most cases I don't know beforehand
that I want to capture a command's output, so a "postfix command"
(i.e. one we can run after the fact) would be much preferable.
It might not be that hard to do: tho: just push markers in *Messages* at
the beginning/end of every command (unless there have been no messages
since the last push), make sure we throw away those markers that reach
`point-min`, and then add a `copy-last-command-output` command that uses
those markers to extract the last message using those markers.
The tricky part will be to find the right message when messages are
emitted (e.g. by the completion UI) while the user types
`M-x copy-last-command-output RET`.
Stefan
diff --git a/doc/emacs/screen.texi b/doc/emacs/screen.texi
index 5e9e89e6b11..4e65bc1105f 100644
--- a/doc/emacs/screen.texi
+++ b/doc/emacs/screen.texi
@@ -146,6 +146,11 @@ Echo Area
this limit, one line is deleted from the beginning whenever a new
message line is added at the end.
+@cindex{copy-next-command-output}
+ You can also capture the messages of a command by running the
+command @code{copy-next-command-output} beforehand, which will put them
+in the kill ring.
+
@xref{Display Custom}, for options that control how Emacs uses the
echo area.
diff --git a/etc/NEWS b/etc/NEWS
index fbb13254e64..d5bd372ecfb 100644
--- a/etc/NEWS
+++ b/etc/NEWS
@@ -162,6 +162,8 @@ displayed on the mode line when 'appt-display-mode-line' is non-nil.
\f
* Editing Changes in Emacs 30.1
+** New command 'copy-next-command-output' to capture echo area messages
+
---
** New global minor mode 'kill-ring-deindent-mode'.
When enabled, text being saved to the kill ring will be de-indented by
diff --git a/lisp/simple.el b/lisp/simple.el
index 05a3c4b93d6..2fc1b2dad96 100644
--- a/lisp/simple.el
+++ b/lisp/simple.el
@@ -5877,6 +5877,67 @@ copy-region-as-kill
(setq deactivate-mark t)
nil)
+(defun copy-next-command-output ()
+ "Prefix command to add the output of the next command to the `kill-ring`.
+\"Output\" here refers to text emitted in the echo area, and currently this
+is limited to those messages which also appear in the *Messages* buffer."
+ (interactive)
+ (let ((md (minibuffer-depth))
+ (marker (with-current-buffer "*Messages*"
+ (point-max-marker))))
+ ;; We consider the following states:
+ ;; - The command (and potentially a few other prefix commands) has just
+ ;; been run, `post-command-hook' is unaffected yet and `pre-command-hook'
+ ;; and `prefix-command-*' hooks are set.
+ ;; - The next command is about to be executed: we already run
+ ;; `pre-command-hook'. All the hooks are set.
+ ;; - We just finished running the next command: `post-command-hook'
+ ;; should then hopefully remove all the hooks.
+ ;; - Within a minibuffer: commands run in the minibuffer should not affects
+ ;; hooks since they are either "within" another prefix command
+ ;; (such as `C-x 8 u') or within the command we want to affect.
+ ;; We do (re)set the `marker', OTOH so as to try and skip the messages
+ ;; that occur while we're inside the minibuffer.
+ (cl-labels ((pre ()
+ (unless (> (minibuffer-depth) md)
+ (add-hook 'post-command-hook #'post)
+ (prepare)))
+ (prepare ()
+ (with-current-buffer "*Messages*"
+ (move-marker marker (point-max))))
+ (preserve ()
+ (unless (> (minibuffer-depth) md)
+ (remove-hook 'post-command-hook #'post)
+ (add-hook 'pre-command-hook #'pre)))
+ (echo ()
+ (unless (> (minibuffer-depth) md)
+ "[copy-output]"))
+ (post ()
+ (if (> (minibuffer-depth) md)
+ ;; Prepare, in case there's no pre-command-hook before
+ ;; the next post-command-hook. E.g. in the case of
+ ;; execute-extended-command.
+ (prepare)
+ (remove-hook 'pre-command-hook #'pre)
+ (remove-hook 'post-command-hook #'post)
+ (remove-hook 'prefix-command-preserve-state-hook
+ #'preserve)
+ (remove-hook 'prefix-command-echo-keystrokes-functions
+ #'echo)
+ (prefix-command-update)
+ (with-current-buffer (marker-buffer marker)
+ (when (< marker (point-max))
+ (kill-new (buffer-substring marker (point-max)))))
+ (set-marker marker nil))))
+ (add-hook 'prefix-command-preserve-state-hook #'preserve)
+ (add-hook 'prefix-command-echo-keystrokes-functions #'echo)
+ ;; (message "BEFORE: prefix-arg=%S current-prefix-arg=%S"
+ ;; prefix-arg current-prefix-arg)
+ (prefix-command-preserve-state)
+ ;; (message "AFTER: prefix-arg=%S current-prefix-arg=%S"
+ ;; prefix-arg current-prefix-arg)
+ )))
+
(defun kill-ring-save (beg end &optional region)
"Save the region as if killed, but don't kill it.
In Transient Mark mode, deactivate the mark.
^ permalink raw reply related [flat|nested] 6+ messages in thread
* bug#65511: [PATCH] copy-next-command-output suggestion
2023-09-04 22:17 ` Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors
@ 2023-09-05 11:14 ` Eli Zaretskii
2023-09-05 13:10 ` Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors
0 siblings, 1 reply; 6+ messages in thread
From: Eli Zaretskii @ 2023-09-05 11:14 UTC (permalink / raw)
To: Stefan Monnier; +Cc: jb, 65511
> From: Stefan Monnier <monnier@iro.umontreal.ca>
> Cc: Jeremy Bryant <jb@jeremybryant.net>, 65511@debbugs.gnu.org
> Date: Mon, 04 Sep 2023 18:17:44 -0400
>
> > I also wonder whether we should bind interprogram-cut-function to nil
> > around the call to kill-new, since this stuff probably should be put
> > in the clipboard, right?
>
> I don't understand: binding it to nil would *prevent* it from making it
> to the clipboard, whereas I don't see why we shouldn't obey
> `select-enable-clipboard` and `select-enable-primary` here.
Sorry, I meant to say that this stuff should NOT be put into the
clipboard. Which is why I suggested to bind interprogram-cut-function
to nil.
> > Also, what happens if some process-filter or process-sentinel or timer
> > fire during the time these hooks are in effect: will the stuff added
> > to the kill-ring include their output as well?
>
> Yes.
> Not sure we should try to do something about it.
Maybe just document it?
> BTW, the reason why I haven't pushed to include it in Emacs is that I'm
> not really satisfied with the UI: in most cases I don't know beforehand
> that I want to capture a command's output, so a "postfix command"
> (i.e. one we can run after the fact) would be much preferable.
>
> It might not be that hard to do: tho: just push markers in *Messages* at
> the beginning/end of every command (unless there have been no messages
> since the last push), make sure we throw away those markers that reach
> `point-min`, and then add a `copy-last-command-output` command that uses
> those markers to extract the last message using those markers.
> The tricky part will be to find the right message when messages are
> emitted (e.g. by the completion UI) while the user types
> `M-x copy-last-command-output RET`.
Maybe we should indeed try to come up with such an alternative
implementation.
> +@cindex{copy-next-command-output}
> + You can also capture the messages of a command by running the
> +command @code{copy-next-command-output} beforehand, which will put them
> +in the kill ring.
That "them" is ambiguous. Better say "those messages" or somesuch.
> --- a/etc/NEWS
> +++ b/etc/NEWS
> @@ -162,6 +162,8 @@ displayed on the mode line when 'appt-display-mode-line' is non-nil.
> \f
> * Editing Changes in Emacs 30.1
>
> +** New command 'copy-next-command-output' to capture echo area messages
^
Period missing there.
> + ;; - Within a minibuffer: commands run in the minibuffer should not affects
^^^^^^^
"affect"
^ permalink raw reply [flat|nested] 6+ messages in thread
* bug#65511: [PATCH] copy-next-command-output suggestion
2023-09-05 11:14 ` Eli Zaretskii
@ 2023-09-05 13:10 ` Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-09-05 18:33 ` Jeremy Bryant
0 siblings, 1 reply; 6+ messages in thread
From: Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors @ 2023-09-05 13:10 UTC (permalink / raw)
To: Eli Zaretskii; +Cc: jb, 65511
>> It might not be that hard to do: tho: just push markers in *Messages* at
>> the beginning/end of every command (unless there have been no messages
>> since the last push), make sure we throw away those markers that reach
>> `point-min`, and then add a `copy-last-command-output` command that uses
>> those markers to extract the last message using those markers.
>> The tricky part will be to find the right message when messages are
>> emitted (e.g. by the completion UI) while the user types
>> `M-x copy-last-command-output RET`.
> Maybe we should indeed try to come up with such an alternative
> implementation.
Jeremy, do you want to take a crack at it?
Stefan
^ permalink raw reply [flat|nested] 6+ messages in thread
* bug#65511: [PATCH] copy-next-command-output suggestion
2023-09-05 13:10 ` Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors
@ 2023-09-05 18:33 ` Jeremy Bryant
0 siblings, 0 replies; 6+ messages in thread
From: Jeremy Bryant @ 2023-09-05 18:33 UTC (permalink / raw)
To: Stefan Monnier; +Cc: Eli Zaretskii, 65511
Yes, I will work on this.
Stefan Monnier <monnier@iro.umontreal.ca> writes:
>>> It might not be that hard to do: tho: just push markers in *Messages* at
>>> the beginning/end of every command (unless there have been no messages
>>> since the last push), make sure we throw away those markers that reach
>>> `point-min`, and then add a `copy-last-command-output` command that uses
>>> those markers to extract the last message using those markers.
>>> The tricky part will be to find the right message when messages are
>>> emitted (e.g. by the completion UI) while the user types
>>> `M-x copy-last-command-output RET`.
>> Maybe we should indeed try to come up with such an alternative
>> implementation.
>
> Jeremy, do you want to take a crack at it?
>
>
> Stefan
^ permalink raw reply [flat|nested] 6+ messages in thread
end of thread, other threads:[~2023-09-05 18:33 UTC | newest]
Thread overview: 6+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2023-08-24 21:46 bug#65511: [PATCH] copy-next-command-output suggestion Jeremy Bryant
2023-08-25 6:05 ` Eli Zaretskii
2023-09-04 22:17 ` Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-09-05 11:14 ` Eli Zaretskii
2023-09-05 13:10 ` Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors
2023-09-05 18:33 ` Jeremy Bryant
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/emacs.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).