bug#50680: eww-retrieve-synchronously

bug#50680: eww-retrieve-synchronously

[Juri Linkov]

[-- Attachment #1: Type: text/plain, Size: 634 bytes --]

Tags: patch

This is a spin-off from bug#50497.

>> What do you think about supporting synchronous mode in eww?
>> When adding a variable that causes eww-retrieve to use
>> url-retrieve-synchronously, isearch part could look like this:
>>
>>   (defun eww-isearch-next-buffer (&optional _buffer wrap)
>>     (let ((eww-synchronous t))
>>       (if wrap
>>           (condition-case nil
>>               (eww-top-url)
>>             (error nil))
>>         (if isearch-forward
>>             (eww-next-url)
>>           (eww-previous-url))))
>>     (current-buffer))
>
> Sure, makes sense to me.

Here is a patch that implements this:


[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: eww-retrieve-synchronously.patch --]
[-- Type: text/x-diff, Size: 2648 bytes --]

diff --git a/lisp/net/eww.el b/lisp/net/eww.el
index c1202974f4..7ae44fdc71 100644
--- a/lisp/net/eww.el
+++ b/lisp/net/eww.el
@@ -143,11 +143,13 @@ eww-history-limit
 
 (defcustom eww-retrieve-command nil
   "Command to retrieve an URL via an external program.
-If nil, `url-retrieve' is used to download the data.  If non-nil,
-this should be a list where the first item is the program, and
-the rest are the arguments."
+If nil, `url-retrieve' is used to download the data.
+If `sync', `url-retrieve-synchronously' is used.
+For other non-nil values, this should be a list where the first item
+is the program, and the rest are the arguments."
   :version "28.1"
   :type '(choice (const :tag "Use `url-retrieve'" nil)
+                 (const :tag "Use `url-retrieve-synchronously'" sync)
                  (repeat string)))
 
 (defcustom eww-use-external-browser-for-content-type
@@ -366,9 +368,16 @@ eww
                     (list url nil (current-buffer))))))
 
 (defun eww-retrieve (url callback cbargs)
-  (if (null eww-retrieve-command)
-      (url-retrieve url #'eww-render
-                    (list url nil (current-buffer)))
+  (cond
+   ((null eww-retrieve-command)
+    (url-retrieve url #'eww-render
+                  (list url nil (current-buffer))))
+   ((eq eww-retrieve-command 'sync)
+    (let ((orig-buffer (current-buffer))
+          (data-buffer (url-retrieve-synchronously url)))
+      (with-current-buffer data-buffer
+        (eww-render nil url nil orig-buffer))))
+   (t
     (let ((buffer (generate-new-buffer " *eww retrieve*"))
           (error-buffer (generate-new-buffer " *eww error*")))
       (with-current-buffer buffer
@@ -388,7 +397,7 @@ eww-retrieve
                          (with-current-buffer buffer
                            (goto-char (point-min))
                            (insert "Content-type: text/html; charset=utf-8\n\n")
-                           (apply #'funcall callback nil cbargs))))))))))
+                           (apply #'funcall callback nil cbargs)))))))))))
 
 (function-put 'eww 'browse-url-browser-kind 'internal)
 
@@ -2398,13 +2407,14 @@ eww-restore-desktop
 
 (defun eww-isearch-next-buffer (&optional _buffer wrap)
   "Go to the next page to search using `rel' attribute for navigation."
-  (if wrap
-      (condition-case nil
-	  (eww-top-url)
-	(error nil))
-    (if isearch-forward
-	(eww-next-url)
-      (eww-previous-url)))
+  (let ((eww-retrieve-command 'sync))
+    (if wrap
+        (condition-case nil
+	    (eww-top-url)
+	  (error nil))
+      (if isearch-forward
+	  (eww-next-url)
+        (eww-previous-url))))
   (current-buffer))
 
 (provide 'eww)

bug#50680: eww-retrieve-synchronously

[Lars Ingebrigtsen]

Juri Linkov <juri@linkov.net> writes:

> Here is a patch that implements this:

I haven't tried the patch, but skimming it, it makes sense to me, so
please go ahead and push it.

-- 
(domestic pets only, the antidote for overdose, milk.)
   bloggy blog: http://lars.ingebrigtsen.no

bug#50680: eww-retrieve-synchronously

[Juri Linkov]

tags 50680 fixed
close 50680 28.0.50
quit

>> Here is a patch that implements this:
>
> I haven't tried the patch, but skimming it, it makes sense to me, so
> please go ahead and push it.

Now pushed.