* bug#55257: master f2d2fe6fc8: server-execute: Initialize the *scratch* buffer
[not found] ` <871qx74or6.fsf@melete.silentflame.com>
@ 2022-05-08 0:27 ` Sean Whitton
2022-05-09 18:11 ` Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors
[not found] ` <jwvr152prjh.fsf-monnier+emacs@gnu.org>
0 siblings, 2 replies; 3+ messages in thread
From: Sean Whitton @ 2022-05-08 0:27 UTC (permalink / raw)
To: emacs-devel, 55257; +Cc: Robert Pluim, Eli Zaretskii, Stefan Monnier
[-- Attachment #1: Type: text/plain, Size: 644 bytes --]
Hello,
On Thu 05 May 2022 at 03:07PM -07, Sean Whitton wrote:
> Hello,
>
> On Wed 04 May 2022 at 12:26PM -04, Stefan Monnier wrote:
>
>>> It looks like Fother_window is called only from Fcall_interactively and
>>> Fkill_buffer, so there probably isn't a bootstrapping issue if I make
>>> those Ffuncall my new `get-initial-buffer-create'. It looks like
>>> bootstrapping C code just makes an empty *scratch* and leaves it to
>>> startup.el to initialise it.
>>
>> Even better,
>
> Here's my fix. Haven't quite finished testing each and every call site
> but seemed worth posting it for comments.
Here's an updated patch.
--
Sean Whitton
[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #2: v2-0001-Factor-out-scratch-initialization.patch --]
[-- Type: text/x-patch, Size: 9132 bytes --]
From 4b80914abeb67065b22eb0a491cf684a5b1eff71 Mon Sep 17 00:00:00 2001
From: Sean Whitton <spwhitton@spwhitton.name>
Date: Thu, 5 May 2022 13:03:06 -0700
Subject: [PATCH v2] Factor out *scratch* initialization
* lisp/simple.el (get-initial-buffer-create): New function, factored
out of scratch-buffer, and additionally clearing the modification flag
and calling substitute-command-keys (bug#55257).
(scratch-buffer):
* lisp/server.el (server-execute):
* lisp/startup.el (normal-no-mouse-startup-screen, command-line-1):
* lisp/window.el (last-buffer, window-normalize-buffer-to-switch-to):
* src/buffer.c (Fother_buffer, other_buffer_safely): Use it.
(syms_of_buffer): Add Qget_initial_buffer_create.
* lisp/startup.el (startup--get-buffer-create-scratch): Delete
now-unused function.
* doc/lispref/os.texi (Summary: Sequence of Actions at Startup):
* NEWS (Incompatible changes in Emacs 29.1): Document the change.
---
doc/lispref/os.texi | 8 ++++----
etc/NEWS | 8 ++++++++
lisp/server.el | 2 +-
lisp/simple.el | 20 ++++++++++++++------
lisp/startup.el | 12 +++---------
lisp/window.el | 18 ++++++++----------
src/buffer.c | 22 +++-------------------
7 files changed, 41 insertions(+), 49 deletions(-)
diff --git a/doc/lispref/os.texi b/doc/lispref/os.texi
index 9df708532d..f4dd2e7072 100644
--- a/doc/lispref/os.texi
+++ b/doc/lispref/os.texi
@@ -329,10 +329,10 @@ Startup Summary
@end defopt
@defopt initial-scratch-message
-This variable, if non-@code{nil}, should be a string, which is
-treated as documentation to be
-inserted into the @file{*scratch*} buffer when Emacs starts up. If it
-is @code{nil}, the @file{*scratch*} buffer is empty.
+This variable, if non-@code{nil}, should be a string, which is treated
+as documentation to be inserted into the @file{*scratch*} buffer when
+Emacs starts up or when that buffer is recreated. If it is
+@code{nil}, the @file{*scratch*} buffer is empty.
@end defopt
@noindent
diff --git a/etc/NEWS b/etc/NEWS
index 6637eda00c..20ef8f7b52 100644
--- a/etc/NEWS
+++ b/etc/NEWS
@@ -238,6 +238,14 @@ encouraged to test timestamp-related code with this variable set to
nil, as it will default to nil in a future Emacs version and will be
removed some time after that.
++++
+** Functions which recreate the *scratch* buffer now also initialize it.
+When functions like 'other-buffer' and 'server-execute' recreate
+*scratch*, they now also insert 'initial-scratch-message' and change
+the major mode according to 'initial-major-mode', like at Emacs
+startup. Previously, these functions ignored
+'initial-scratch-message' and left *scratch* in 'fundamental-mode'.
+
\f
* Changes in Emacs 29.1
diff --git a/lisp/server.el b/lisp/server.el
index 763cf27f7a..042962b8e9 100644
--- a/lisp/server.el
+++ b/lisp/server.el
@@ -1367,7 +1367,7 @@ server-execute
((functionp initial-buffer-choice)
(funcall initial-buffer-choice)))))
(switch-to-buffer
- (if (buffer-live-p buf) buf (get-buffer-create "*scratch*"))
+ (if (buffer-live-p buf) buf (get-initial-buffer-create))
'norecord)))
;; Delete the client if necessary.
diff --git a/lisp/simple.el b/lisp/simple.el
index 861d9eefde..1ed82b0a48 100644
--- a/lisp/simple.el
+++ b/lisp/simple.el
@@ -10213,16 +10213,24 @@ capitalize-dwim
the number of seconds east of Greenwich.")
)
+(defun get-initial-buffer-create ()
+ "Return the \*scratch\* buffer, creating a new one if needed."
+ (or (get-buffer "*scratch*")
+ (let ((scratch (get-buffer-create "*scratch*")))
+ ;; Don't touch the buffer contents or mode unless we know that
+ ;; we just created it.
+ (with-current-buffer scratch
+ (when initial-scratch-message
+ (insert (substitute-command-keys initial-scratch-message))
+ (set-buffer-modified-p nil))
+ (funcall initial-major-mode))
+ scratch)))
+
(defun scratch-buffer ()
"Switch to the \*scratch\* buffer.
If the buffer doesn't exist, create it first."
(interactive)
- (if (get-buffer "*scratch*")
- (pop-to-buffer-same-window "*scratch*")
- (pop-to-buffer-same-window (get-buffer-create "*scratch*"))
- (when initial-scratch-message
- (insert initial-scratch-message))
- (funcall initial-major-mode)))
+ (pop-to-buffer-same-window (get-initial-buffer-create)))
\f
diff --git a/lisp/startup.el b/lisp/startup.el
index c7cf86a01e..3fa25ddee9 100644
--- a/lisp/startup.el
+++ b/lisp/startup.el
@@ -2355,7 +2355,7 @@ normal-no-mouse-startup-screen
(insert "\t\t")
(insert-button "Open *scratch* buffer"
'action (lambda (_button) (switch-to-buffer
- (startup--get-buffer-create-scratch)))
+ (get-initial-buffer-create)))
'follow-link t)
(insert "\n")
(save-restriction
@@ -2487,12 +2487,6 @@ display-about-screen
(defalias 'about-emacs 'display-about-screen)
(defalias 'display-splash-screen 'display-startup-screen)
-(defun startup--get-buffer-create-scratch ()
- (or (get-buffer "*scratch*")
- (with-current-buffer (get-buffer-create "*scratch*")
- (set-buffer-major-mode (current-buffer))
- (current-buffer))))
-
;; This avoids byte-compiler warning in the unexec build.
(declare-function pdumper-stats "pdumper.c" ())
@@ -2784,7 +2778,7 @@ command-line-1
(when (eq initial-buffer-choice t)
;; When `initial-buffer-choice' equals t make sure that *scratch*
;; exists.
- (startup--get-buffer-create-scratch))
+ (get-initial-buffer-create))
;; If *scratch* exists and is empty, insert initial-scratch-message.
;; Do this before switching to *scratch* below to handle bug#9605.
@@ -2808,7 +2802,7 @@ command-line-1
((functionp initial-buffer-choice)
(funcall initial-buffer-choice))
((eq initial-buffer-choice t)
- (startup--get-buffer-create-scratch))
+ (get-initial-buffer-create))
(t
(error "`initial-buffer-choice' must be a string, a function, or t")))))
(unless (buffer-live-p buf)
diff --git a/lisp/window.el b/lisp/window.el
index 9f78784612..615c5c078a 100644
--- a/lisp/window.el
+++ b/lisp/window.el
@@ -4886,10 +4886,7 @@ last-buffer
(setq frame (or frame (selected-frame)))
(or (get-next-valid-buffer (nreverse (buffer-list frame))
buffer visible-ok frame)
- (get-buffer "*scratch*")
- (let ((scratch (get-buffer-create "*scratch*")))
- (set-buffer-major-mode scratch)
- scratch)))
+ (get-initial-buffer-create)))
(defcustom frame-auto-hide-function #'iconify-frame
"Function called to automatically hide frames.
@@ -8621,12 +8618,13 @@ window-normalize-buffer-to-switch-to
`other-buffer'. Else, if a buffer specified by BUFFER-OR-NAME
exists, return that buffer. If no such buffer exists, create a
buffer with the name BUFFER-OR-NAME and return that buffer."
- (if buffer-or-name
- (or (get-buffer buffer-or-name)
- (let ((buffer (get-buffer-create buffer-or-name)))
- (set-buffer-major-mode buffer)
- buffer))
- (other-buffer)))
+ (pcase buffer-or-name
+ ('nil (other-buffer))
+ ("*scratch*" (get-initial-buffer-create))
+ (_ (or (get-buffer buffer-or-name)
+ (let ((buffer (get-buffer-create buffer-or-name)))
+ (set-buffer-major-mode buffer)
+ buffer)))))
(defcustom switch-to-buffer-preserve-window-point t
"If non-nil, `switch-to-buffer' tries to preserve `window-point'.
diff --git a/src/buffer.c b/src/buffer.c
index f8a7a4f510..a153ffe78c 100644
--- a/src/buffer.c
+++ b/src/buffer.c
@@ -1634,16 +1634,7 @@ DEFUN ("other-buffer", Fother_buffer, Sother_buffer, 0, 3, 0,
if (!NILP (notsogood))
return notsogood;
else
- {
- AUTO_STRING (scratch, "*scratch*");
- buf = Fget_buffer (scratch);
- if (NILP (buf))
- {
- buf = Fget_buffer_create (scratch, Qnil);
- Fset_buffer_major_mode (buf);
- }
- return buf;
- }
+ return safe_call (1, Qget_initial_buffer_create);
}
/* The following function is a safe variant of Fother_buffer: It doesn't
@@ -1659,15 +1650,7 @@ other_buffer_safely (Lisp_Object buffer)
if (candidate_buffer (buf, buffer))
return buf;
- AUTO_STRING (scratch, "*scratch*");
- buf = Fget_buffer (scratch);
- if (NILP (buf))
- {
- buf = Fget_buffer_create (scratch, Qnil);
- Fset_buffer_major_mode (buf);
- }
-
- return buf;
+ return safe_call (1, Qget_initial_buffer_create);
}
\f
DEFUN ("buffer-enable-undo", Fbuffer_enable_undo, Sbuffer_enable_undo,
@@ -5552,6 +5535,7 @@ syms_of_buffer (void)
DEFSYM (Qbefore_change_functions, "before-change-functions");
DEFSYM (Qafter_change_functions, "after-change-functions");
DEFSYM (Qkill_buffer_query_functions, "kill-buffer-query-functions");
+ DEFSYM (Qget_initial_buffer_create, "get-initial-buffer-create");
DEFSYM (Qvertical_scroll_bar, "vertical-scroll-bar");
Fput (Qvertical_scroll_bar, Qchoice, list4 (Qnil, Qt, Qleft, Qright));
--
2.30.2
^ permalink raw reply related [flat|nested] 3+ messages in thread
* bug#55257: master f2d2fe6fc8: server-execute: Initialize the *scratch* buffer
2022-05-08 0:27 ` bug#55257: master f2d2fe6fc8: server-execute: Initialize the *scratch* buffer Sean Whitton
@ 2022-05-09 18:11 ` Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors
[not found] ` <jwvr152prjh.fsf-monnier+emacs@gnu.org>
1 sibling, 0 replies; 3+ messages in thread
From: Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors @ 2022-05-09 18:11 UTC (permalink / raw)
To: Sean Whitton; +Cc: Robert Pluim, 55257, Eli Zaretskii, emacs-devel
> Here's an updated patch.
LGTM, thank you (feel free to push, as far as I'm concerned).
See further comments below.
Stefan
> +** Functions which recreate the *scratch* buffer now also initialize it.
> +When functions like 'other-buffer' and 'server-execute' recreate
> +*scratch*, they now also insert 'initial-scratch-message' and change
> +the major mode according to 'initial-major-mode', like at Emacs
> +startup. Previously, these functions ignored
> +'initial-scratch-message' and left *scratch* in 'fundamental-mode'.
I'd say "set the major mode" rather than "change the major mode".
> +(defun get-initial-buffer-create ()
I know you didn't like my `scratch-buffer--create` suggestion because of
the double dash, but I think at least "scratch" would be very welcome in it.
> + "Return the \*scratch\* buffer, creating a new one if needed."
> + (or (get-buffer "*scratch*")
> + (let ((scratch (get-buffer-create "*scratch*")))
> + ;; Don't touch the buffer contents or mode unless we know that
> + ;; we just created it.
> + (with-current-buffer scratch
> + (when initial-scratch-message
> + (insert (substitute-command-keys initial-scratch-message))
> + (set-buffer-modified-p nil))
> + (funcall initial-major-mode))
> + scratch)))
> +
> (defun scratch-buffer ()
> "Switch to the \*scratch\* buffer.
> If the buffer doesn't exist, create it first."
> (interactive)
> - (if (get-buffer "*scratch*")
> - (pop-to-buffer-same-window "*scratch*")
> - (pop-to-buffer-same-window (get-buffer-create "*scratch*"))
> - (when initial-scratch-message
> - (insert initial-scratch-message))
> - (funcall initial-major-mode)))
> + (pop-to-buffer-same-window (get-initial-buffer-create)))
Now that I look at it again, it occurs to me that maybe we should do
something like:
(defun scratch-buffer (&optional display)
"Create the \*scratch\* buffer.
If the buffer doesn't exist, create it first.
If DISPLAY (or when used interactively), switch to it."
(interactive (list t))
(let ((buf (get-buffer "*scratch*")))
(unless buf
;; Don't touch the buffer contents or mode unless we know that
;; we just created it.
(with-current-buffer (setq buf (get-buffer-create "*scratch*"))
(when initial-scratch-message
(insert (substitute-command-keys initial-scratch-message))
(set-buffer-modified-p nil))
(funcall initial-major-mode)))
(when display (pop-to-buffer-same-window buf))
buf))
i.e. combine the new function with the existing command, so we don't
need to come up with a new name.
^ permalink raw reply [flat|nested] 3+ messages in thread
* bug#55257: master f2d2fe6fc8: server-execute: Initialize the *scratch* buffer
[not found] ` <jwvr152prjh.fsf-monnier+emacs@gnu.org>
@ 2022-05-10 1:49 ` Sean Whitton
0 siblings, 0 replies; 3+ messages in thread
From: Sean Whitton @ 2022-05-10 1:49 UTC (permalink / raw)
To: Stefan Monnier; +Cc: Robert Pluim, 55257, Eli Zaretskii, emacs-devel
Hello,
On Mon 09 May 2022 at 02:11pm -04, Stefan Monnier wrote:
> I know you didn't like my `scratch-buffer--create` suggestion because of
> the double dash, but I think at least "scratch" would be very welcome in it.
I've done s/initial/scratch/ which is better because this function
always uses *scratch* rather than, say, looking at initial-buffer-choice.
> Now that I look at it again, it occurs to me that maybe we should do
> something like:
>
> (defun scratch-buffer (&optional display)
> "Create the \*scratch\* buffer.
> If the buffer doesn't exist, create it first.
> If DISPLAY (or when used interactively), switch to it."
> (interactive (list t))
> (let ((buf (get-buffer "*scratch*")))
> (unless buf
> ;; Don't touch the buffer contents or mode unless we know that
> ;; we just created it.
> (with-current-buffer (setq buf (get-buffer-create "*scratch*"))
> (when initial-scratch-message
> (insert (substitute-command-keys initial-scratch-message))
> (set-buffer-modified-p nil))
> (funcall initial-major-mode)))
> (when display (pop-to-buffer-same-window buf))
> buf))
>
> i.e. combine the new function with the existing command, so we don't
> need to come up with a new name.
Nice idea, but I'd argue for keeping them separate. I find it more
natural to distinguish functions called for their return values and
commands.
--
Sean Whitton
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2022-05-10 1:49 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
[not found] <165162665935.26821.8964921720746152690@vcs2.savannah.gnu.org>
[not found] ` <20220504011059.9F667C009A8@vcs2.savannah.gnu.org>
[not found] ` <jwva6byf3iz.fsf-monnier+emacs@gnu.org>
[not found] ` <87levhdfeh.fsf@athena.silentflame.com>
[not found] ` <jwvr159ea97.fsf-monnier+emacs@gnu.org>
[not found] ` <87y1zhe5qz.fsf@athena.silentflame.com>
[not found] ` <jwv8rrhxsyr.fsf-monnier+emacs@gnu.org>
[not found] ` <87levhe24h.fsf@athena.silentflame.com>
[not found] ` <jwvee19w9h4.fsf-monnier+emacs@gnu.org>
[not found] ` <871qx74or6.fsf@melete.silentflame.com>
2022-05-08 0:27 ` bug#55257: master f2d2fe6fc8: server-execute: Initialize the *scratch* buffer Sean Whitton
2022-05-09 18:11 ` Stefan Monnier via Bug reports for GNU Emacs, the Swiss army knife of text editors
[not found] ` <jwvr152prjh.fsf-monnier+emacs@gnu.org>
2022-05-10 1:49 ` Sean Whitton
Code repositories for project(s) associated with this public inbox
https://git.savannah.gnu.org/cgit/emacs.git
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).