Re: Elisp: help on string operations for fast file visiting

[John Kitchin <jkitchin@andrew.cmu.edu>]

This is a different approach to what I think you want.

Here is what I assume in this:
1. All the things you want to search for are in a file called
archive.org which is in the same directory you are searching for (use an
absolute path if it is not).
2. You have file links that only have a path, i.e. nothing like
file:test.odp::45
3. You want the query to match some part of the path in a file link.
4. if you click on the link you want, it will open the file in the
external program you want it to open in. This will probably work if they
are always absolute paths, and might be a problem for relative paths
(they would need to be correctly converted to absolute paths).

What it does is get all the file links in the archive.org file that
have a path that matches the query. If there is none, you get a message.
If there is one, it opens it as if you clicked on the link. and if there
is more than one, it prompts you with completing read to choose one,
then opens it.

#+BEGIN_SRC emacs-lisp
(defun memacs-file (query)
  "Open memacs files by QUERY."
  (interactive "sQuery: ")
  (with-current-buffer (find-file-noselect "archive.org")
    (let ((links (org-element-map (org-element-parse-buffer) 'link
		   (lambda (link)
		     (when (string-match query (org-element-property :path link)) link)))))
      (cond
       ((= 0 (length links))
	(message "No files found."))
       ((= 1 (length links))
	(org-open-link-from-string
	 (format "[[file:%s]]" (org-element-property :path (car links)))))
       (t
	(org-open-link-from-string 
	 (completing-read
	  "File: "
	  (mapcar (lambda (link)
		    (format "[[file:%s]]" (org-element-property :path link)))
		  links))))))))
#+END_SRC

For a large archive file, you might be better off with a grep solution,
since this has to parse the file first.



Karl Voit writes:

> Hi!
>
> For Memacs[1], I'd like to come up with a very fast Org-mode method to
> open files independent of their location on your disk. I accomplished
> everything necessary so far. However, I've got issues writing an elisp
> function for extracting a file and sending it to a function that calls
> the operating system app associated. My elisp knowledge is still too
> bad :-(
>
> What I've got is a string (from the lookup) which contains:
> (1) nothing
> (2) one line like "** <2008-06-17 21:43> [[file:/home/user/dir/2008-06-17 description of file.odp][2008-06-17 description of file.odp]]"
> (3) multiple lines like (2) but with different files and links
>
> I'd like to get a "Sorry" message for (1). Easy, if only I know how to
> count lines in strings (as opposed to buffers).
>
> For (2) I'd like to call my-open-in-external-app(string).
>
> For (3), I'd like to use the first line just as in (2) as a starter. I
> do have some ideas on gracious "error-recovering" on this one but
> that's maybe too complicated to code for now: getting rid of
> substrings delimited by not-'a-zA-Z0-9' from the end of the link
> until a match is found; message in case there is no unique match which
> could be found this way.
>
> Could you please help me here? It'd help all users of the file index
> module of Memacs.
>
>
> The mini fragment I have so far is following but the regex seems to
> be broken:
>
> #+BEGIN_SRC elisp
>     (let (
>       (result (replace-regexp-in-string "\r?\n$" ""
>                         (shell-command-to-string (concat "grep "
>                                          "2008-06-17"
>                                          " ~/org/memacs/files.org_archive");; hard coded stuff for testing purposes
>                                      )
>                         )
>           )
>       )
>       (message (concat "result -> " result))
>       (re-search-forward " \[\[.+\]\[" nil t 1)
>       (let (
>         (firstlink ((match-string 1)))
>         )
>         (message (concat "first link -> " firstlink))
>        )
>       )
> #+END_SRC
>
>
>
> [1] https://github.com/novoid/Memacs


-- 
Professor John Kitchin
Doherty Hall A207F
Department of Chemical Engineering
Carnegie Mellon University
Pittsburgh, PA 15213
412-268-7803
@johnkitchin
http://kitchingroup.cheme.cmu.edu