;;; ob.el --- working with code blocks in org-mode

;; Copyright (C) 2009-2012  Free Software Foundation, Inc.

;; Authors: Eric Schulte
;;	Dan Davison
;; Keywords: literate programming, reproducible research
;; Homepage: http://orgmode.org

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Code:
(eval-when-compile
  (require 'cl))

(require 'org-macs)
(require 'org-compat)
(require 'comint)

;;; ob-eval
(defvar org-babel-error-buffer-name "*Org-Babel Error Output*")

(defun org-babel-eval-error-notify (exit-code stderr)
  "Open a buffer to display STDERR and a message with the value of EXIT-CODE."
  (let ((buf (get-buffer-create org-babel-error-buffer-name)))
    (with-current-buffer buf
      (goto-char (point-max))
      (save-excursion (insert stderr)))
    (display-buffer buf))
  (message "Babel evaluation exited with code %S" exit-code))

(defun org-babel-eval (cmd body)
  "Run CMD on BODY.
If CMD succeeds then return its results, otherwise display
STDERR with `org-babel-eval-error-notify'."
  (let ((err-buff (get-buffer-create " *Org-Babel Error*")) exit-code)
    (with-current-buffer err-buff (erase-buffer))
    (with-temp-buffer
      (insert body)
      (setq exit-code
	    (org-babel-shell-command-on-region
	     (point-min) (point-max) cmd t 'replace err-buff))
      (if (or (not (numberp exit-code)) (> exit-code 0))
	  (progn
	    (with-current-buffer err-buff
	      (org-babel-eval-error-notify exit-code (buffer-string)))
	    nil)
	(buffer-string)))))

(defun org-babel-eval-read-file (file)
  "Return the contents of FILE as a string."
  (with-temp-buffer (insert-file-contents file)
		    (buffer-string)))

(defun org-babel-shell-command-on-region (start end command
						&optional output-buffer replace
						error-buffer display-error-buffer)
  "Execute COMMAND in an inferior shell with region as input.

Fixes bugs in the emacs 23.1.1 version of `shell-command-on-region'

Normally display output (if any) in temp buffer `*Shell Command Output*';
Prefix arg means replace the region with it.  Return the exit code of
COMMAND.

To specify a coding system for converting non-ASCII characters in
the input and output to the shell command, use
\\[universal-coding-system-argument] before this command.  By
default, the input (from the current buffer) is encoded in the
same coding system that will be used to save the file,
`buffer-file-coding-system'.  If the output is going to replace
the region, then it is decoded from that same coding system.

The noninteractive arguments are START, END, COMMAND,
OUTPUT-BUFFER, REPLACE, ERROR-BUFFER, and DISPLAY-ERROR-BUFFER.
Noninteractive callers can specify coding systems by binding
`coding-system-for-read' and `coding-system-for-write'.

If the command generates output, the output may be displayed
in the echo area or in a buffer.
If the output is short enough to display in the echo area
\(determined by the variable `max-mini-window-height' if
`resize-mini-windows' is non-nil), it is shown there.  Otherwise
it is displayed in the buffer `*Shell Command Output*'.  The output
is available in that buffer in both cases.

If there is output and an error, a message about the error
appears at the end of the output.

If there is no output, or if output is inserted in the current buffer,
then `*Shell Command Output*' is deleted.

If the optional fourth argument OUTPUT-BUFFER is non-nil,
that says to put the output in some other buffer.
If OUTPUT-BUFFER is a buffer or buffer name, put the output there.
If OUTPUT-BUFFER is not a buffer and not nil,
insert output in the current buffer.
In either case, the output is inserted after point (leaving mark after it).

If REPLACE, the optional fifth argument, is non-nil, that means insert
the output in place of text from START to END, putting point and mark
around it.

If optional sixth argument ERROR-BUFFER is non-nil, it is a buffer
or buffer name to which to direct the command's standard error output.
If it is nil, error output is mingled with regular output.
If DISPLAY-ERROR-BUFFER is non-nil, display the error buffer if there
were any errors.  (This is always t, interactively.)
In an interactive call, the variable `shell-command-default-error-buffer'
specifies the value of ERROR-BUFFER."
  (interactive (let (string)
		 (unless (mark)
		   (error "The mark is not set now, so there is no region"))
		 ;; Do this before calling region-beginning
		 ;; and region-end, in case subprocess output
		 ;; relocates them while we are in the minibuffer.
		 (setq string (read-shell-command "Shell command on region: "))
		 ;; call-interactively recognizes region-beginning and
		 ;; region-end specially, leaving them in the history.
		 (list (region-beginning) (region-end)
		       string
		       current-prefix-arg
		       current-prefix-arg
		       shell-command-default-error-buffer
		       t)))
  (let ((error-file
	 (if error-buffer
	     (make-temp-file
	      (expand-file-name "scor"
                                (if (featurep 'xemacs)
                                    (temp-directory)
                                  temporary-file-directory)))
	   nil))
	exit-status)
    (if (or replace
	    (and output-buffer
		 (not (or (bufferp output-buffer) (stringp output-buffer)))))
	;; Replace specified region with output from command.
	(let ((swap (and replace (< start end))))
	  ;; Don't muck with mark unless REPLACE says we should.
	  (goto-char start)
	  (and replace (push-mark (point) 'nomsg))
	  (setq exit-status
		(call-process-region start end shell-file-name t
				     (if error-file
					 (list output-buffer error-file)
				       t)
				     nil shell-command-switch command))
	  ;; It is rude to delete a buffer which the command is not using.
	  ;; (let ((shell-buffer (get-buffer "*Shell Command Output*")))
	  ;;   (and shell-buffer (not (eq shell-buffer (current-buffer)))
	  ;; 	 (kill-buffer shell-buffer)))
	  ;; Don't muck with mark unless REPLACE says we should.
	  (and replace swap (exchange-point-and-mark)))
      ;; No prefix argument: put the output in a temp buffer,
      ;; replacing its entire contents.
      (let ((buffer (get-buffer-create
		     (or output-buffer "*Shell Command Output*"))))
	(unwind-protect
	    (if (eq buffer (current-buffer))
		;; If the input is the same buffer as the output,
		;; delete everything but the specified region,
		;; then replace that region with the output.
		(progn (setq buffer-read-only nil)
		       (delete-region (max start end) (point-max))
		       (delete-region (point-min) (min start end))
		       (setq exit-status
			     (call-process-region (point-min) (point-max)
						  shell-file-name t
						  (if error-file
						      (list t error-file)
						    t)
						  nil shell-command-switch
						  command)))
	      ;; Clear the output buffer, then run the command with
	      ;; output there.
	      (let ((directory default-directory))
		(with-current-buffer buffer
		  (setq buffer-read-only nil)
		  (if (not output-buffer)
		      (setq default-directory directory))
		  (erase-buffer)))
	      (setq exit-status
		    (call-process-region start end shell-file-name nil
					 (if error-file
					     (list buffer error-file)
					   buffer)
					 nil shell-command-switch command)))
	  ;; Report the output.
	  (with-current-buffer buffer
	    (setq mode-line-process
		  (cond ((null exit-status)
			 " - Error")
			((stringp exit-status)
			 (format " - Signal [%s]" exit-status))
			((not (equal 0 exit-status))
			 (format " - Exit [%d]" exit-status)))))
	  (if (with-current-buffer buffer (> (point-max) (point-min)))
	      ;; There's some output, display it
	      (display-message-or-buffer buffer)
	    ;; No output; error?
	    (let ((output
		   (if (and error-file
			    (< 0 (nth 7 (file-attributes error-file))))
		       "some error output"
		     "no output")))
	      (cond ((null exit-status)
		     (message "(Shell command failed with error)"))
		    ((equal 0 exit-status)
		     (message "(Shell command succeeded with %s)"
			      output))
		    ((stringp exit-status)
		     (message "(Shell command killed by signal %s)"
			      exit-status))
		    (t
		     (message "(Shell command failed with code %d and %s)"
			      exit-status output))))
	    ;; Don't kill: there might be useful info in the undo-log.
	    ;; (kill-buffer buffer)
	    ))))

    (when (and error-file (file-exists-p error-file))
      (if (< 0 (nth 7 (file-attributes error-file)))
	  (with-current-buffer (get-buffer-create error-buffer)
	    (let ((pos-from-end (- (point-max) (point))))
	      (or (bobp)
		  (insert "\f\n"))
	      ;; Do no formatting while reading error file,
	      ;; because that can run a shell command, and we
	      ;; don't want that to cause an infinite recursion.
	      (format-insert-file error-file nil)
	      ;; Put point after the inserted errors.
	      (goto-char (- (point-max) pos-from-end)))
	    (and display-error-buffer
		 (display-buffer (current-buffer)))))
      (delete-file error-file))
    exit-status))

(defun org-babel-eval-wipe-error-buffer ()
  "Delete the contents of the Org code block error buffer.
This buffer is named by `org-babel-error-buffer-name'."
  (when (get-buffer org-babel-error-buffer-name)
    (with-current-buffer org-babel-error-buffer-name
      (delete-region (point-min) (point-max)))))

(defconst org-babel-exeext
  (if (memq system-type '(windows-nt cygwin))
      ".exe"
    nil))
(defvar org-babel-call-process-region-original)
(defvar org-src-lang-modes)
(defvar org-babel-library-of-babel)
(declare-function show-all "outline" ())
(declare-function org-reduce "org" (CL-FUNC CL-SEQ &rest CL-KEYS))
(declare-function org-mark-ring-push "org" (&optional pos buffer))
(declare-function tramp-compat-make-temp-file "tramp-compat"
                  (filename &optional dir-flag))
(declare-function tramp-dissect-file-name "tramp" (name &optional nodefault))
(declare-function tramp-file-name-user "tramp" (vec))
(declare-function tramp-file-name-host "tramp" (vec))
(declare-function with-parsed-tramp-file-name "tramp" (filename var &rest body))
(declare-function org-icompleting-read "org" (&rest args))
(declare-function org-edit-src-code "org-src"
                  (&optional context code edit-buffer-name quietp))
(declare-function org-edit-src-exit "org-src"  (&optional context))
(declare-function org-open-at-point "org" (&optional in-emacs reference-buffer))
(declare-function org-save-outline-visibility "org-macs" (use-markers &rest body))
(declare-function org-outline-overlay-data "org" (&optional use-markers))
(declare-function org-set-outline-overlay-data "org" (data))
(declare-function org-narrow-to-subtree "org" ())
(declare-function org-entry-get "org"
		  (pom property &optional inherit literal-nil))
(declare-function org-make-options-regexp "org" (kwds &optional extra))
(declare-function org-do-remove-indentation "org" (&optional n))
(declare-function org-show-context "org" (&optional key))
(declare-function org-at-table-p "org" (&optional table-type))
(declare-function org-cycle "org" (&optional arg))
(declare-function org-uniquify "org" (list))
(declare-function org-current-level "org" ())
(declare-function org-table-import "org-table" (file arg))
(declare-function org-add-hook "org-compat"
		  (hook function &optional append local))
(declare-function org-table-align "org-table" ())
(declare-function org-table-end "org-table" (&optional table-type))
(declare-function orgtbl-to-generic "org-table" (table params))
(declare-function orgtbl-to-orgtbl "org-table" (table params))
(declare-function org-number-sequence "org-compat" (from &optional to inc))
(declare-function org-at-item-p "org-list" ())
(declare-function org-list-parse-list "org-list" (&optional delete))
(declare-function org-list-to-generic "org-list" (LIST PARAMS))
(declare-function org-list-struct "org-list" ())
(declare-function org-list-prevs-alist "org-list" (struct))
(declare-function org-list-get-list-end "org-list" (item struct prevs))
(declare-function org-remove-if "org" (predicate seq))
(declare-function org-completing-read "org" (&rest args))
(declare-function org-escape-code-in-region "org-src" (beg end))
(declare-function org-unescape-code-in-string "org-src" (s))
(declare-function org-table-to-lisp "org-table" (&optional txt))

(defgroup org-babel nil
  "Code block evaluation and management in `org-mode' documents."
  :tag "Babel"
  :group 'org)

(defcustom org-confirm-babel-evaluate t
  "Confirm before evaluation.
Require confirmation before interactively evaluating code
blocks in Org-mode buffers.  The default value of this variable
is t, meaning confirmation is required for any code block
evaluation.  This variable can be set to nil to inhibit any
future confirmation requests.  This variable can also be set to a
function which takes two arguments the language of the code block
and the body of the code block.  Such a function should then
return a non-nil value if the user should be prompted for
execution or nil if no prompt is required.

Warning: Disabling confirmation may result in accidental
evaluation of potentially harmful code.  It may be advisable
remove code block execution from C-c C-c as further protection
against accidental code block evaluation.  The
`org-babel-no-eval-on-ctrl-c-ctrl-c' variable can be used to
remove code block execution from the C-c C-c keybinding."
  :group 'org-babel
  :version "24.1"
  :type '(choice boolean function))
;; don't allow this variable to be changed through file settings
(put 'org-confirm-babel-evaluate 'safe-local-variable (lambda (x) (eq x t)))

(defcustom org-babel-no-eval-on-ctrl-c-ctrl-c nil
  "Remove code block evaluation from the C-c C-c key binding."
  :group 'org-babel
  :version "24.1"
  :type 'boolean)

(defcustom org-babel-results-keyword "RESULTS"
  "Keyword used to name results generated by code blocks.
Should be either RESULTS or NAME however any capitalization may
be used."
  :group 'org-babel
  :type 'string)

(defcustom org-babel-noweb-wrap-start "<<"
  "String used to begin a noweb reference in a code block.
See also `org-babel-noweb-wrap-end'."
  :group 'org-babel
  :type 'string)

(defcustom org-babel-noweb-wrap-end ">>"
  "String used to end a noweb reference in a code block.
See also `org-babel-noweb-wrap-start'."
  :group 'org-babel
  :type 'string)

(defun org-babel-noweb-wrap (&optional regexp)
  (concat org-babel-noweb-wrap-start
	  (or regexp "\\([^ \t\n].+?[^ \t]\\|[^ \t\n]\\)")
	  org-babel-noweb-wrap-end))

(defvar org-babel-src-name-regexp
  "^[ \t]*#\\+name:[ \t]*"
  "Regular expression used to match a source name line.")

(defvar org-babel-multi-line-header-regexp
  "^[ \t]*#\\+headers?:[ \t]*\\([^\n]*\\)$"
  "Regular expression used to match multi-line header arguments.")

(defvar org-babel-src-name-w-name-regexp
  (concat org-babel-src-name-regexp
	  "\\("
	  org-babel-multi-line-header-regexp
	  "\\)*"
	  "\\([^ ()\f\t\n\r\v]+\\)\\(\(\\(.*\\)\)\\|\\)")
  "Regular expression matching source name lines with a name.")

(defvar org-babel-src-block-regexp
  (concat
   ;; (1) indentation                 (2) lang
   "^\\([ \t]*\\)#\\+begin_src[ \t]+\\([^ \f\t\n\r\v]+\\)[ \t]*"
   ;; (3) switches
   "\\([^\":\n]*\"[^\"\n*]*\"[^\":\n]*\\|[^\":\n]*\\)"
   ;; (4) header arguments
   "\\([^\n]*\\)\n"
   ;; (5) body
   "\\([^\000]*?\n\\)?[ \t]*#\\+end_src")
  "Regexp used to identify code blocks.")

(defvar org-babel-inline-src-block-regexp
  (concat
   ;; (1) replacement target (2) lang
   "\\(?:^\\|[^-[:alnum:]]\\)\\(src_\\([^ \f\t\n\r\v]+\\)"
   ;; (3,4) (unused, headers)
   "\\(\\|\\[\\(.*?\\)\\]\\)"
   ;; (5) body
   "{\\([^\f\n\r\v]+?\\)}\\)")
  "Regexp used to identify inline src-blocks.")

(defun org-babel-get-header (params key &optional others)
  "Select only header argument of type KEY from a list.
Optional argument OTHERS indicates that only the header that do
not match KEY should be returned."
  (delq nil
	(mapcar
	 (lambda (p) (when (funcall (if others #'not #'identity) (eq (car p) key)) p))
	 params)))

(defun org-babel-get-inline-src-block-matches()
  "Set match data if within body of an inline source block.
Returns non-nil if match-data set"
  (let ((src-at-0-p (save-excursion
		      (beginning-of-line 1)
		      (string= "src" (thing-at-point 'word))))
	(first-line-p (= 1 (line-number-at-pos)))
	(orig (point)))
    (let ((search-for (cond ((and src-at-0-p first-line-p  "src_"))
			    (first-line-p "[[:punct:] \t]src_")
			    (t "[[:punct:] \f\t\n\r\v]src_")))
	  (lower-limit (if first-line-p
			   nil
			 (- (point-at-bol) 1))))
      (save-excursion
	(when (or (and src-at-0-p (bobp))
		  (and (re-search-forward "}" (point-at-eol) t)
		       (re-search-backward search-for lower-limit t)
		       (> orig (point))))
	  (when (looking-at org-babel-inline-src-block-regexp)
	    t ))))))

(defvar org-babel-inline-lob-one-liner-regexp)
(defun org-babel-get-lob-one-liner-matches()
  "Set match data if on line of an lob one liner.
Returns non-nil if match-data set"
  (save-excursion
    (unless (= (point) (point-at-bol)) ;; move before inline block
      (re-search-backward "[ \f\t\n\r\v]" nil t))
    (if (looking-at org-babel-inline-lob-one-liner-regexp)
	t
      nil)))

(defun org-babel-get-src-block-info (&optional light)
  "Get information on the current source block.

Optional argument LIGHT does not resolve remote variable
references; a process which could likely result in the execution
of other code blocks.

Returns a list
 (language body header-arguments-alist switches name indent)."
  (let ((case-fold-search t) head info name indent)
    ;; full code block
    (if (setq head (org-babel-where-is-src-block-head))
	(save-excursion
	  (goto-char head)
	  (setq info (org-babel-parse-src-block-match))
	  (setq indent (car (last info)))
	  (setq info (butlast info))
	  (while (and (forward-line -1)
		      (looking-at org-babel-multi-line-header-regexp))
	    (setf (nth 2 info)
		  (org-babel-merge-params
		   (nth 2 info)
		   (org-babel-parse-header-arguments (match-string 1)))))
	  (when (looking-at org-babel-src-name-w-name-regexp)
	    (setq name (org-no-properties (match-string 3)))
	    (when (and (match-string 5) (> (length (match-string 5)) 0))
	      (setf (nth 2 info) ;; merge functional-syntax vars and header-args
		    (org-babel-merge-params
		     (mapcar
		      (lambda (ref) (cons :var ref))
		      (mapcar
		       (lambda (var) ;; check that each variable is initialized
			 (if (string-match ".+=.+" var)
			     var
			   (error
			    "variable \"%s\"%s must be assigned a default value"
			    var (if name (format " in block \"%s\"" name) ""))))
		       (org-babel-ref-split-args (match-string 5))))
		     (nth 2 info))))))
      ;; inline source block
      (when (org-babel-get-inline-src-block-matches)
	(setq info (org-babel-parse-inline-src-block-match))))
    ;; resolve variable references and add summary parameters
    (when (and info (not light))
      (setf (nth 2 info) (org-babel-process-params (nth 2 info))))
    (when info (append info (list name indent)))))

(defvar org-current-export-file) ; dynamically bound
(defun org-babel-confirm-evaluate (info)
  "Confirm evaluation of the code block INFO.
This behavior can be suppressed by setting the value of
`org-confirm-babel-evaluate' to nil, in which case all future
interactive code block evaluations will proceed without any
confirmation from the user.

Note disabling confirmation may result in accidental evaluation
of potentially harmful code."
  (let* ((eval (or (cdr (assoc :eval (nth 2 info)))
		   (when (assoc :noeval (nth 2 info)) "no")))
         (query (cond ((equal eval "query") t)
		      ((and (boundp 'org-current-export-file)
			    org-current-export-file
			    (equal eval "query-export")) t)
                      ((functionp org-confirm-babel-evaluate)
                       (funcall org-confirm-babel-evaluate
                                (nth 0 info) (nth 1 info)))
                      (t org-confirm-babel-evaluate))))
    (if (or (equal eval "never") (equal eval "no")
	    (and (boundp 'org-current-export-file)
		 org-current-export-file
		 (or (equal eval "no-export")
		     (equal eval "never-export")))
	    (and query
		 (not (yes-or-no-p
		       (format "Evaluate this%scode block%son your system? "
			       (if info (format " %s " (nth 0 info)) " ")
			       (if (nth 4 info)
				   (format " (%s) " (nth 4 info)) " "))))))
	(prog1 nil (message "Evaluation %s"
			    (if (or (equal eval "never") (equal eval "no")
				    (equal eval "no-export")
				    (equal eval "never-export"))
				"Disabled" "Aborted")))
      t)))

;;;###autoload
(defun org-babel-execute-safely-maybe ()
  (unless org-babel-no-eval-on-ctrl-c-ctrl-c
    (org-babel-execute-maybe)))

(add-hook 'org-ctrl-c-ctrl-c-hook 'org-babel-execute-safely-maybe)

;;;###autoload
(defun org-babel-execute-maybe ()
  (interactive)
  (or (org-babel-execute-src-block-maybe)
      (org-babel-lob-execute-maybe)))

(defun org-babel-execute-src-block-maybe ()
  "Conditionally execute a source block.
Detect if this is context for a Babel src-block and if so
then run `org-babel-execute-src-block'."
  (interactive)
  (let ((info (org-babel-get-src-block-info)))
    (if info
	(progn (org-babel-eval-wipe-error-buffer)
	       (org-babel-execute-src-block current-prefix-arg info) t) nil)))

;;;###autoload
(defun org-babel-view-src-block-info ()
  "Display information on the current source block.
This includes header arguments, language and name, and is largely
a window into the `org-babel-get-src-block-info' function."
  (interactive)
  (let ((info (org-babel-get-src-block-info 'light))
	(full (lambda (it) (> (length it) 0)))
	(printf (lambda (fmt &rest args) (princ (apply #'format fmt args)))))
    (when info
      (with-help-window (help-buffer)
	(let ((name        (nth 4 info))
	      (lang        (nth 0 info))
	      (switches    (nth 3 info))
	      (header-args (nth 2 info)))
	  (when name            (funcall printf "Name: %s\n"     name))
	  (when lang            (funcall printf "Lang: %s\n"     lang))
	  (when (funcall full switches) (funcall printf "Switches: %s\n" switches))
	  (funcall printf "Header Arguments:\n")
	  (dolist (pair (sort header-args
			      (lambda (a b) (string< (symbol-name (car a))
						     (symbol-name (car b))))))
	    (when (funcall full (cdr pair))
	      (funcall printf "\t%S%s\t%s\n"
		       (car pair)
		       (if (> (length (format "%S" (car pair))) 7) "" "\t")
		       (cdr pair)))))))))

;;;###autoload
(defun org-babel-expand-src-block-maybe ()
  "Conditionally expand a source block.
Detect if this is context for a org-babel src-block and if so
then run `org-babel-expand-src-block'."
  (interactive)
  (let ((info (org-babel-get-src-block-info)))
    (if info
	(progn (org-babel-expand-src-block current-prefix-arg info) t)
      nil)))

;;;###autoload
(defun org-babel-load-in-session-maybe ()
  "Conditionally load a source block in a session.
Detect if this is context for a org-babel src-block and if so
then run `org-babel-load-in-session'."
  (interactive)
  (let ((info (org-babel-get-src-block-info)))
    (if info
	(progn (org-babel-load-in-session current-prefix-arg info) t)
      nil)))

(add-hook 'org-metaup-hook 'org-babel-load-in-session-maybe)

;;;###autoload
(defun org-babel-pop-to-session-maybe ()
  "Conditionally pop to a session.
Detect if this is context for a org-babel src-block and if so
then run `org-babel-pop-to-session'."
  (interactive)
  (let ((info (org-babel-get-src-block-info)))
    (if info (progn (org-babel-pop-to-session current-prefix-arg info) t) nil)))

(add-hook 'org-metadown-hook 'org-babel-pop-to-session-maybe)

(defconst org-babel-common-header-args-w-values
  '((cache	. ((no yes)))
    (cmdline	. :any)
    (colnames	. ((nil no yes)))
    (comments	. ((no link yes org both noweb)))
    (dir	. :any)
    (eval	. ((never query)))
    (exports	. ((code results both none)))
    (file	. :any)
    (file-desc  . :any)
    (hlines	. ((no yes)))
    (mkdirp	. ((yes no)))
    (no-expand)
    (noeval)
    (noweb	. ((yes no tangle no-export strip-export)))
    (noweb-ref	. :any)
    (noweb-sep  . :any)
    (padline	. ((yes no)))
    (results	. ((file list vector table scalar verbatim)
		   (raw html latex org code pp drawer)
		   (replace silent none append prepend)
		   (output value)))
    (rownames	. ((no yes)))
    (sep	. :any)
    (session	. :any)
    (shebang	. :any)
    (tangle	. ((tangle yes no :any)))
    (var	. :any)
    (wrap       . :any)))

(defconst org-babel-header-arg-names
  (mapcar #'car org-babel-common-header-args-w-values)
  "Common header arguments used by org-babel.
Note that individual languages may define their own language
specific header arguments as well.")

(defvar org-babel-default-header-args
  '((:session . "none") (:results . "replace") (:exports . "code")
    (:cache . "no") (:noweb . "no") (:hlines . "no") (:tangle . "no")
    (:padnewline . "yes"))
  "Default arguments to use when evaluating a source block.")

(defvar org-babel-default-inline-header-args
  '((:session . "none") (:results . "replace") (:exports . "results"))
  "Default arguments to use when evaluating an inline source block.")

(defvar org-babel-data-names '("tblname" "results" "name"))

(defvar org-babel-result-regexp
  (concat "^[ \t]*#\\+"
	  (regexp-opt org-babel-data-names t)
	  "\\(\\[\\([[:alnum:]]+\\)\\]\\)?\\:[ \t]*")
  "Regular expression used to match result lines.
If the results are associated with a hash key then the hash will
be saved in the second match data.")

(defvar org-babel-result-w-name-regexp
  (concat org-babel-result-regexp
	  "\\([^ ()\f\t\n\r\v]+\\)\\(\(\\(.*\\)\)\\|\\)"))

(defvar org-babel-min-lines-for-block-output 10
  "The minimum number of lines for block output.
If number of lines of output is equal to or exceeds this
value, the output is placed in a #+begin_example...#+end_example
block.  Otherwise the output is marked as literal by inserting
colons at the starts of the lines.  This variable only takes
effect if the :results output option is in effect.")

(defvar org-babel-noweb-error-langs nil
  "Languages for which Babel will raise literate programming errors.
List of languages for which errors should be raised when the
source code block satisfying a noweb reference in this language
can not be resolved.")

(defvar org-babel-hash-show 4
  "Number of initial characters to show of a hidden results hash.")

(defvar org-babel-after-execute-hook nil
  "Hook for functions to be called after `org-babel-execute-src-block'")

(defun org-babel-named-src-block-regexp-for-name (name)
  "This generates a regexp used to match a src block named NAME."
  (concat org-babel-src-name-regexp (regexp-quote name)
	  "[ \t(]*[\r\n]\\(?:^#.*[\r\n]\\)*"
	  (substring org-babel-src-block-regexp 1)))

(defun org-babel-named-data-regexp-for-name (name)
  "This generates a regexp used to match data named NAME."
  (concat org-babel-result-regexp (regexp-quote name) "\\([ \t]\\|$\\)"))

;;; ob-keys

(defvar org-babel-key-prefix "\C-c\C-v"
  "The key prefix for Babel interactive key-bindings.
See `org-babel-key-bindings' for the list of interactive babel
functions which are assigned key bindings, and see
`org-babel-map' for the actual babel keymap.")

(defvar org-babel-map (make-sparse-keymap)
  "The keymap for interactive Babel functions.")

;;;###autoload
(defun org-babel-describe-bindings ()
  "Describe all keybindings behind `org-babel-key-prefix'."
  (interactive)
  (describe-bindings org-babel-key-prefix))

(defvar org-babel-key-bindings
  '(("p" . org-babel-previous-src-block)
    ("\C-p" . org-babel-previous-src-block)
    ("n" . org-babel-next-src-block)
    ("\C-n" . org-babel-next-src-block)
    ("e" . org-babel-execute-maybe)
    ("\C-e" . org-babel-execute-maybe)
    ("o" . org-babel-open-src-block-result)
    ("\C-o" . org-babel-open-src-block-result)
    ("\C-v" . org-babel-expand-src-block)
    ("v" . org-babel-expand-src-block)
    ("u" . org-babel-goto-src-block-head)
    ("\C-u" . org-babel-goto-src-block-head)
    ("g" . org-babel-goto-named-src-block)
    ("r" . org-babel-goto-named-result)
    ("\C-r" . org-babel-goto-named-result)
    ("\C-b" . org-babel-execute-buffer)
    ("b" . org-babel-execute-buffer)
    ("\C-s" . org-babel-execute-subtree)
    ("s" . org-babel-execute-subtree)
    ("\C-d" . org-babel-demarcate-block)
    ("d" . org-babel-demarcate-block)
    ("\C-t" . org-babel-tangle)
    ("t" . org-babel-tangle)
    ("\C-f" . org-babel-tangle-file)
    ("f" . org-babel-tangle-file)
    ("\C-c" . org-babel-check-src-block)
    ("c" . org-babel-check-src-block)
    ("\C-j" . org-babel-insert-header-arg)
    ("j" . org-babel-insert-header-arg)
    ("\C-l" . org-babel-load-in-session)
    ("l" . org-babel-load-in-session)
    ("\C-i" . org-babel-lob-ingest)
    ("i" . org-babel-lob-ingest)
    ("\C-I" . org-babel-view-src-block-info)
    ("I" . org-babel-view-src-block-info)
    ("\C-z" . org-babel-switch-to-session)
    ("z" . org-babel-switch-to-session-with-code)
    ("\C-a" . org-babel-sha1-hash)
    ("a" . org-babel-sha1-hash)
    ("h" . org-babel-describe-bindings)
    ("\C-x" . org-babel-do-key-sequence-in-edit-buffer)
    ("x" . org-babel-do-key-sequence-in-edit-buffer)
    ("\C-\M-h" . org-babel-mark-block))
  "Alist of key bindings and interactive Babel functions.
This list associates interactive Babel functions
with keys.  Each element of this list will add an entry to the
`org-babel-map' using the letter key which is the `car' of the
a-list placed behind the generic `org-babel-key-prefix'.")

;;; functions
(defvar call-process-region)

;;;###autoload
(defun org-babel-execute-src-block (&optional arg info params)
  "Execute the current source code block.
Insert the results of execution into the buffer.  Source code
execution and the collection and formatting of results can be
controlled through a variety of header arguments.

With prefix argument ARG, force re-execution even if an existing
result cached in the buffer would otherwise have been returned.

Optionally supply a value for INFO in the form returned by
`org-babel-get-src-block-info'.

Optionally supply a value for PARAMS which will be merged with
the header arguments specified at the front of the source code
block."
  (interactive)
  (let ((info (or info (org-babel-get-src-block-info))))
    (when (org-babel-confirm-evaluate
	   (let ((i info))
	     (setf (nth 2 i) (org-babel-merge-params (nth 2 info) params))
	     i))
      (let* ((lang (nth 0 info))
	     (params (if params
			 (org-babel-process-params
			  (org-babel-merge-params (nth 2 info) params))
		       (nth 2 info)))
	     (cache? (and (not arg) (cdr (assoc :cache params))
			  (string= "yes" (cdr (assoc :cache params)))))
	     (result-params (cdr (assoc :result-params params)))
	     (new-hash (when cache? (org-babel-sha1-hash info)))
	     (old-hash (when cache? (org-babel-current-result-hash)))
	     (body (setf (nth 1 info)
			 (if (org-babel-noweb-p params :eval)
			     (org-babel-expand-noweb-references info)
			   (nth 1 info))))
	     (dir (cdr (assoc :dir params)))
	     (default-directory
	       (or (and dir (file-name-as-directory (expand-file-name dir)))
		   default-directory))
	     (org-babel-call-process-region-original
	      (if (boundp 'org-babel-call-process-region-original)
		  org-babel-call-process-region-original
		(symbol-function 'call-process-region)))
	     (indent (car (last info)))
	     result cmd)
	(unwind-protect
	    (let ((call-process-region
		   (lambda (&rest args)
		     (apply 'org-babel-tramp-handle-call-process-region args))))
	      (let ((lang-check (lambda (f)
				  (let ((f (intern (concat "org-babel-execute:" f))))
				    (when (fboundp f) f)))))
		(setq cmd
		      (or (funcall lang-check lang)
			  (funcall lang-check (symbol-name
					       (cdr (assoc lang org-src-lang-modes))))
			  (error "No org-babel-execute function for %s!" lang))))
	      (if (and (not arg) new-hash (equal new-hash old-hash))
		  (save-excursion ;; return cached result
		    (goto-char (org-babel-where-is-src-block-result nil info))
		    (end-of-line 1) (forward-char 1)
		    (setq result (org-babel-read-result))
		    (message (replace-regexp-in-string
			      "%" "%%" (format "%S" result))) result)
		(message "executing %s code block%s..."
			 (capitalize lang)
			 (if (nth 4 info) (format " (%s)" (nth 4 info)) ""))
		(if (member "none" result-params)
		    (progn
		      (funcall cmd body params)
		      (message "result silenced"))
		(setq result
		      ((lambda (result)
			 (if (and (eq (cdr (assoc :result-type params)) 'value)
				  (or (member "vector" result-params)
				      (member "table" result-params))
				  (not (listp result)))
			     (list (list result)) result))
		       (funcall cmd body params)))
		;; if non-empty result and :file then write to :file
		(when (cdr (assoc :file params))
		  (when result
		    (with-temp-file (cdr (assoc :file params))
		      (insert
		       (org-babel-format-result
			result (cdr (assoc :sep (nth 2 info)))))))
		  (setq result (cdr (assoc :file params))))
		(org-babel-insert-result
		 result result-params info new-hash indent lang)
		(run-hooks 'org-babel-after-execute-hook)
		result
		)))
	  (setq call-process-region 'org-babel-call-process-region-original))))))

(defun org-babel-expand-body:generic (body params &optional var-lines)
  "Expand BODY with PARAMS.
Expand a block of code with org-babel according to its header
arguments.  This generic implementation of body expansion is
called for languages which have not defined their own specific
org-babel-expand-body:lang function."
  (mapconcat #'identity (append var-lines (list body)) "\n"))

;;;###autoload
(defun org-babel-expand-src-block (&optional arg info params)
  "Expand the current source code block.
Expand according to the source code block's header
arguments and pop open the results in a preview buffer."
  (interactive)
  (let* ((info (or info (org-babel-get-src-block-info)))
         (lang (nth 0 info))
	 (params (setf (nth 2 info)
                       (sort (org-babel-merge-params (nth 2 info) params)
                             (lambda (el1 el2) (string< (symbol-name (car el1))
							(symbol-name (car el2)))))))
         (body (setf (nth 1 info)
		     (if (org-babel-noweb-p params :eval)
			 (org-babel-expand-noweb-references info) (nth 1 info))))
         (expand-cmd (intern (concat "org-babel-expand-body:" lang)))
	 (assignments-cmd (intern (concat "org-babel-variable-assignments:"
					  lang)))
         (expanded
	  (if (fboundp expand-cmd) (funcall expand-cmd body params)
	    (org-babel-expand-body:generic
	     body params (and (fboundp assignments-cmd)
			      (funcall assignments-cmd params))))))
    (org-edit-src-code
     nil expanded (concat "*Org-Babel Preview " (buffer-name) "[ " lang " ]*"))))

(defun org-babel-edit-distance (s1 s2)
  "Return the edit (levenshtein) distance between strings S1 S2."
  (let* ((l1 (length s1))
	 (l2 (length s2))
	 (dist (vconcat (mapcar (lambda (_) (make-vector (1+ l2) nil))
				(number-sequence 1 (1+ l1)))))
	 (in (lambda (i j) (aref (aref dist i) j))))
    (setf (aref (aref dist 0) 0) 0)
    (dolist (j (number-sequence 1 l2))
      (setf (aref (aref dist 0) j) j))
    (dolist (i (number-sequence 1 l1))
      (setf (aref (aref dist i) 0) i)
      (dolist (j (number-sequence 1 l2))
	(setf (aref (aref dist i) j)
	      (min
	       (1+ (funcall in (1- i) j))
	       (1+ (funcall in i (1- j)))
	       (+ (if (equal (aref s1 (1- i)) (aref s2 (1- j))) 0 1)
		  (funcall in (1- i) (1- j)))))))
    (funcall in l1 l2)))

(defun org-babel-combine-header-arg-lists (original &rest others)
  "Combine a number of lists of header argument names and arguments."
  (let ((results (copy-sequence original)))
    (dolist (new-list others)
      (dolist (arg-pair new-list)
	(let ((header (car arg-pair))
	      (args (cdr arg-pair)))
	  (setq results
		(cons arg-pair (org-remove-if
				(lambda (pair) (equal header (car pair)))
				results))))))
    results))

;;;###autoload
(defun org-babel-check-src-block ()
  "Check for misspelled header arguments in the current code block."
  (interactive)
  ;; TODO: report malformed code block
  ;; TODO: report incompatible combinations of header arguments
  ;; TODO: report uninitialized variables
  (let ((too-close 2) ;; <- control closeness to report potential match
	(names (mapcar #'symbol-name org-babel-header-arg-names)))
    (dolist (header (mapcar (lambda (arg) (substring (symbol-name (car arg)) 1))
			    (and (org-babel-where-is-src-block-head)
				 (org-babel-parse-header-arguments
				  (org-no-properties
				   (match-string 4))))))
      (dolist (name names)
	(when (and (not (string= header name))
		   (<= (org-babel-edit-distance header name) too-close)
		   (not (member header names)))
	  (error "Supplied header \"%S\" is suspiciously close to \"%S\""
		 header name))))
    (message "No suspicious header arguments found.")))

;;;###autoload
(defun org-babel-insert-header-arg ()
  "Insert a header argument selecting from lists of common args and values."
  (interactive)
  (let* ((lang (car (org-babel-get-src-block-info 'light)))
	 (lang-headers (intern (concat "org-babel-header-args:" lang)))
	 (headers (org-babel-combine-header-arg-lists
		   org-babel-common-header-args-w-values
		   (if (boundp lang-headers) (eval lang-headers) nil)))
	 (arg (org-icompleting-read
	       "Header Arg: "
	       (mapcar
		(lambda (header-spec) (symbol-name (car header-spec)))
		headers))))
    (insert ":" arg)
    (let ((vals (cdr (assoc (intern arg) headers))))
      (when vals
	(insert
	 " "
	 (cond
	  ((eq vals :any)
	   (read-from-minibuffer "value: "))
	  ((listp vals)
	   (mapconcat
	    (lambda (group)
	      (let ((arg (org-icompleting-read
			  "value: "
			  (cons "default" (mapcar #'symbol-name group)))))
		(if (and arg (not (string= "default" arg)))
		    (concat arg " ")
		  "")))
	    vals ""))))))))

;; Add support for completing-read insertion of header arguments after ":"
(defun org-babel-header-arg-expand ()
  "Call `org-babel-enter-header-arg-w-completion' in appropriate contexts."
  (when (and (equal (char-before) ?\:) (org-babel-where-is-src-block-head))
    (org-babel-enter-header-arg-w-completion (match-string 2))))

(defun org-babel-enter-header-arg-w-completion (&optional lang)
  "Insert header argument appropriate for LANG with completion."
  (let* ((lang-headers-var (intern (concat "org-babel-header-args:" lang)))
         (lang-headers (when (boundp lang-headers-var) (eval lang-headers-var)))
	 (headers-w-values (org-babel-combine-header-arg-lists
			    org-babel-common-header-args-w-values lang-headers))
         (headers (mapcar #'symbol-name (mapcar #'car headers-w-values)))
         (header (org-completing-read "Header Arg: " headers))
         (args (cdr (assoc (intern header) headers-w-values)))
         (arg (when (and args (listp args))
                (org-completing-read
                 (format "%s: " header)
                 (mapcar #'symbol-name (apply #'append args))))))
    (insert (concat header " " (or arg "")))
    (cons header arg)))

(add-hook 'org-tab-first-hook 'org-babel-header-arg-expand)

;;;###autoload
(defun org-babel-load-in-session (&optional arg info)
  "Load the body of the current source-code block.
Evaluate the header arguments for the source block before
entering the session.  After loading the body this pops open the
session."
  (interactive)
  (let* ((info (or info (org-babel-get-src-block-info)))
         (lang (nth 0 info))
         (params (nth 2 info))
         (body (setf (nth 1 info)
		     (if (org-babel-noweb-p params :eval)
                         (org-babel-expand-noweb-references info)
		       (nth 1 info))))
         (session (cdr (assoc :session params)))
	 (dir (cdr (assoc :dir params)))
	 (default-directory
	   (or (and dir (file-name-as-directory dir)) default-directory))
	 (cmd (intern (concat "org-babel-load-session:" lang))))
    (unless (fboundp cmd)
      (error "No org-babel-load-session function for %s!" lang))
    (pop-to-buffer (funcall cmd session body params))
    (end-of-line 1)))

;;;###autoload
(defun org-babel-initiate-session (&optional arg info)
  "Initiate session for current code block.
If called with a prefix argument then resolve any variable
references in the header arguments and assign these variables in
the session.  Copy the body of the code block to the kill ring."
  (interactive "P")
  (let* ((info (or info (org-babel-get-src-block-info (not arg))))
         (lang (nth 0 info))
         (body (nth 1 info))
         (params (nth 2 info))
         (session (cdr (assoc :session params)))
	 (dir (cdr (assoc :dir params)))
	 (default-directory
	   (or (and dir (file-name-as-directory dir)) default-directory))
	 (init-cmd (intern (format "org-babel-%s-initiate-session" lang)))
	 (prep-cmd (intern (concat "org-babel-prep-session:" lang))))
    (if (and (stringp session) (string= session "none"))
	(error "This block is not using a session!"))
    (unless (fboundp init-cmd)
      (error "No org-babel-initiate-session function for %s!" lang))
    (with-temp-buffer (insert (org-babel-trim body))
                      (copy-region-as-kill (point-min) (point-max)))
    (when arg
      (unless (fboundp prep-cmd)
	(error "No org-babel-prep-session function for %s!" lang))
      (funcall prep-cmd session params))
    (funcall init-cmd session params)))

;;;###autoload
(defun org-babel-switch-to-session (&optional arg info)
  "Switch to the session of the current code block.
Uses `org-babel-initiate-session' to start the session.  If called
with a prefix argument then this is passed on to
`org-babel-initiate-session'."
  (interactive "P")
  (pop-to-buffer (org-babel-initiate-session arg info))
  (end-of-line 1))

(defalias 'org-babel-pop-to-session 'org-babel-switch-to-session)

;;;###autoload
(defun org-babel-switch-to-session-with-code (&optional arg info)
  "Switch to code buffer and display session."
  (interactive "P")
  (let ((swap-windows
	 (lambda ()
	   (let ((other-window-buffer (window-buffer (next-window))))
	     (set-window-buffer (next-window) (current-buffer))
	     (set-window-buffer (selected-window) other-window-buffer))
	   (other-window 1)))
	(info (org-babel-get-src-block-info))
	(org-src-window-setup 'reorganize-frame))
    (save-excursion
      (org-babel-switch-to-session arg info))
    (org-edit-src-code)
    (funcall swap-windows)))

(defmacro org-babel-do-in-edit-buffer (&rest body)
  "Evaluate BODY in edit buffer if there is a code block at point.
Return t if a code block was found at point, nil otherwise."
  `(let ((org-src-window-setup 'switch-invisibly))
     (when (and (org-babel-where-is-src-block-head)
		(org-edit-src-code nil nil nil))
       (unwind-protect (progn ,@body)
	 (if (org-bound-and-true-p org-edit-src-from-org-mode)
	     (org-edit-src-exit)))
       t)))
(def-edebug-spec org-babel-do-in-edit-buffer (body))

(defun org-babel-do-key-sequence-in-edit-buffer (key)
  "Read key sequence and execute the command in edit buffer.
Enter a key sequence to be executed in the language major-mode
edit buffer.  For example, TAB will alter the contents of the
Org-mode code block according to the effect of TAB in the
language major-mode buffer.  For languages that support
interactive sessions, this can be used to send code from the Org
buffer to the session for evaluation using the native major-mode
evaluation mechanisms."
  (interactive "kEnter key-sequence to execute in edit buffer: ")
  (org-babel-do-in-edit-buffer
   (call-interactively
    (key-binding (or key (read-key-sequence nil))))))

(defvar org-bracket-link-regexp)

;;;###autoload
(defun org-babel-open-src-block-result (&optional re-run)
  "If `point' is on a src block then open the results of the
source code block, otherwise return nil.  With optional prefix
argument RE-RUN the source-code block is evaluated even if
results already exist."
  (interactive "P")
  (let ((info (org-babel-get-src-block-info)))
    (when info
      (save-excursion
	;; go to the results, if there aren't any then run the block
	(goto-char (or (and (not re-run) (org-babel-where-is-src-block-result))
		       (progn (org-babel-execute-src-block)
			      (org-babel-where-is-src-block-result))))
	(end-of-line 1)
	(while (looking-at "[\n\r\t\f ]") (forward-char 1))
	;; open the results
	(if (looking-at org-bracket-link-regexp)
	    ;; file results
	    (org-open-at-point)
	  (let ((r (org-babel-format-result
		    (org-babel-read-result) (cdr (assoc :sep (nth 2 info))))))
	    (pop-to-buffer (get-buffer-create "*Org-Babel Results*"))
	    (delete-region (point-min) (point-max))
	    (insert r)))
	t))))

;;;###autoload
(defmacro org-babel-map-src-blocks (file &rest body)
  "Evaluate BODY forms on each source-block in FILE.
If FILE is nil evaluate BODY forms on source blocks in current
buffer.  During evaluation of BODY the following local variables
are set relative to the currently matched code block.

full-block ------- string holding the entirety of the code block
beg-block -------- point at the beginning of the code block
end-block -------- point at the end of the matched code block
lang ------------- string holding the language of the code block
beg-lang --------- point at the beginning of the lang
end-lang --------- point at the end of the lang
switches --------- string holding the switches
beg-switches ----- point at the beginning of the switches
end-switches ----- point at the end of the switches
header-args ------ string holding the header-args
beg-header-args -- point at the beginning of the header-args
end-header-args -- point at the end of the header-args
body ------------- string holding the body of the code block
beg-body --------- point at the beginning of the body
end-body --------- point at the end of the body"
  (declare (indent 1))
  (let ((tempvar (make-symbol "file")))
    `(let* ((,tempvar ,file)
	    (visited-p (or (null ,tempvar)
			   (get-file-buffer (expand-file-name ,tempvar))))
	    (point (point)) to-be-removed)
       (save-window-excursion
	 (when ,tempvar (find-file ,tempvar))
	 (setq to-be-removed (current-buffer))
	 (goto-char (point-min))
	 (while (re-search-forward org-babel-src-block-regexp nil t)
	   (goto-char (match-beginning 0))
	   (let ((full-block (match-string 0))
		 (beg-block (match-beginning 0))
		 (end-block (match-end 0))
		 (lang (match-string 2))
		 (beg-lang (match-beginning 2))
		 (end-lang (match-end 2))
		 (switches (match-string 3))
		 (beg-switches (match-beginning 3))
		 (end-switches (match-end 3))
		 (header-args (match-string 4))
		 (beg-header-args (match-beginning 4))
		 (end-header-args (match-end 4))
		 (body (match-string 5))
		 (beg-body (match-beginning 5))
		 (end-body (match-end 5)))
	     ,@body
	     (goto-char end-block))))
       (unless visited-p (kill-buffer to-be-removed))
       (goto-char point))))
(def-edebug-spec org-babel-map-src-blocks (form body))

;;;###autoload
(defmacro org-babel-map-inline-src-blocks (file &rest body)
  "Evaluate BODY forms on each inline source-block in FILE.
If FILE is nil evaluate BODY forms on source blocks in current
buffer."
  (declare (indent 1))
  (let ((tempvar (make-symbol "file")))
    `(let* ((,tempvar ,file)
	    (visited-p (or (null ,tempvar)
			   (get-file-buffer (expand-file-name ,tempvar))))
	    (point (point)) to-be-removed)
       (save-window-excursion
	 (when ,tempvar (find-file ,tempvar))
	 (setq to-be-removed (current-buffer))
	 (goto-char (point-min))
	 (while (re-search-forward org-babel-inline-src-block-regexp nil t)
	   (goto-char (match-beginning 1))
	   (save-match-data ,@body)
	   (goto-char (match-end 0))))
       (unless visited-p (kill-buffer to-be-removed))
       (goto-char point))))
(def-edebug-spec org-babel-map-inline-src-blocks (form body))

(defvar org-babel-lob-one-liner-regexp)

;;;###autoload
(defmacro org-babel-map-call-lines (file &rest body)
  "Evaluate BODY forms on each call line in FILE.
If FILE is nil evaluate BODY forms on source blocks in current
buffer."
  (declare (indent 1))
  (let ((tempvar (make-symbol "file")))
    `(let* ((,tempvar ,file)
	    (visited-p (or (null ,tempvar)
			   (get-file-buffer (expand-file-name ,tempvar))))
	    (point (point)) to-be-removed)
       (save-window-excursion
	 (when ,tempvar (find-file ,tempvar))
	 (setq to-be-removed (current-buffer))
	 (goto-char (point-min))
	 (while (re-search-forward org-babel-lob-one-liner-regexp nil t)
	   (goto-char (match-beginning 1))
	   (save-match-data ,@body)
	   (goto-char (match-end 0))))
       (unless visited-p (kill-buffer to-be-removed))
       (goto-char point))))
(def-edebug-spec org-babel-map-call-lines (form body))

;;;###autoload
(defmacro org-babel-map-executables (file &rest body)
  (declare (indent 1))
  (let ((tempvar (make-symbol "file"))
	(rx (make-symbol "rx")))
    `(let* ((,tempvar ,file)
	    (,rx (concat "\\(" org-babel-src-block-regexp
			 "\\|" org-babel-inline-src-block-regexp
			 "\\|" org-babel-lob-one-liner-regexp "\\)"))
	    (visited-p (or (null ,tempvar)
			   (get-file-buffer (expand-file-name ,tempvar))))
	    (point (point)) to-be-removed)
       (save-window-excursion
	 (when ,tempvar (find-file ,tempvar))
	 (setq to-be-removed (current-buffer))
	 (goto-char (point-min))
	 (while (re-search-forward ,rx nil t)
	   (goto-char (match-beginning 1))
	   (when (looking-at org-babel-inline-src-block-regexp)(forward-char 1))
	   (save-match-data ,@body)
	   (goto-char (match-end 0))))
       (unless visited-p (kill-buffer to-be-removed))
       (goto-char point))))
(def-edebug-spec org-babel-map-executables (form body))

;;;###autoload
(defun org-babel-execute-buffer (&optional arg)
  "Execute source code blocks in a buffer.
Call `org-babel-execute-src-block' on every source block in
the current buffer."
  (interactive "P")
  (org-babel-eval-wipe-error-buffer)
  (org-save-outline-visibility t
    (org-babel-map-executables nil
      (if (looking-at org-babel-lob-one-liner-regexp)
          (org-babel-lob-execute-maybe)
        (org-babel-execute-src-block arg)))))

;;;###autoload
(defun org-babel-execute-subtree (&optional arg)
  "Execute source code blocks in a subtree.
Call `org-babel-execute-src-block' on every source block in
the current subtree."
  (interactive "P")
  (save-restriction
    (save-excursion
      (org-narrow-to-subtree)
      (org-babel-execute-buffer arg)
      (widen))))

;;;###autoload
(defun org-babel-sha1-hash (&optional info)
  "Generate an sha1 hash based on the value of info."
  (interactive)
  (let ((print-level nil)
	(info (or info (org-babel-get-src-block-info))))
    (setf (nth 2 info)
	  (sort (copy-sequence (nth 2 info))
		(lambda (a b) (string< (car a) (car b)))))
    (let* ((rm (lambda (lst)
		 (dolist (p '("replace" "silent" "none"
			      "append" "prepend"))
		   (setq lst (remove p lst)))
		 lst))
	   (norm (lambda (arg)
		   (let ((v (if (and (listp (cdr arg)) (null (cddr arg)))
				(copy-sequence (cdr arg))
			      (cdr arg))))
		     (when (and v (not (and (sequencep v)
					    (not (consp v))
					    (= (length v) 0))))
		       (cond
			((and (listp v) ; lists are sorted
			      (member (car arg) '(:result-params)))
			 (sort (funcall rm v) #'string<))
			((and (stringp v) ; strings are sorted
			      (member (car arg) '(:results :exports)))
			 (mapconcat #'identity (sort (funcall rm (split-string v))
						     #'string<) " "))
			(t v)))))))
      ((lambda (hash)
	 (when (org-called-interactively-p 'interactive) (message hash)) hash)
       (let ((it (format "%s-%s"
			 (mapconcat
			  #'identity
			  (delq nil (mapcar (lambda (arg)
					      (let ((normalized (funcall norm arg)))
						(when normalized
						  (format "%S" normalized))))
					    (nth 2 info))) ":")
			 (nth 1 info))))
	 (sha1 it))))))

(defun org-babel-current-result-hash ()
  "Return the current in-buffer hash."
  (org-babel-where-is-src-block-result)
  (org-no-properties (match-string 3)))

(defun org-babel-set-current-result-hash (hash)
  "Set the current in-buffer hash to HASH."
  (org-babel-where-is-src-block-result)
  (save-excursion (goto-char (match-beginning 3))
		  ;; (mapc #'delete-overlay (overlays-at (point)))
		  (replace-match hash nil nil nil 3)
		  (org-babel-hide-hash)))

(defun org-babel-hide-hash ()
  "Hide the hash in the current results line.
Only the initial `org-babel-hash-show' characters of the hash
will remain visible."
  (add-to-invisibility-spec '(org-babel-hide-hash . t))
  (save-excursion
    (when (and (re-search-forward org-babel-result-regexp nil t)
               (match-string 3))
      (let* ((start (match-beginning 3))
             (hide-start (+ org-babel-hash-show start))
             (end (match-end 3))
             (hash (match-string 3))
             ov1 ov2)
        (setq ov1 (make-overlay start hide-start))
        (setq ov2 (make-overlay hide-start end))
        (overlay-put ov2 'invisible 'org-babel-hide-hash)
        (overlay-put ov1 'babel-hash hash)))))

(defun org-babel-hide-all-hashes ()
  "Hide the hash in the current buffer.
Only the initial `org-babel-hash-show' characters of each hash
will remain visible.  This function should be called as part of
the `org-mode-hook'."
  (save-excursion
    (while (re-search-forward org-babel-result-regexp nil t)
      (goto-char (match-beginning 0))
      (org-babel-hide-hash)
      (goto-char (match-end 0)))))
(add-hook 'org-mode-hook 'org-babel-hide-all-hashes)

(defun org-babel-hash-at-point (&optional point)
  "Return the value of the hash at POINT.
The hash is also added as the last element of the kill ring.
This can be called with C-c C-c."
  (interactive)
  (let ((hash (car (delq nil (mapcar
			      (lambda (ol) (overlay-get ol 'babel-hash))
                              (overlays-at (or point (point))))))))
    (when hash (kill-new hash) (message hash))))
(add-hook 'org-ctrl-c-ctrl-c-hook 'org-babel-hash-at-point)

(defun org-babel-result-hide-spec ()
  "Hide portions of results lines.
Add `org-babel-hide-result' as an invisibility spec for hiding
portions of results lines."
  (add-to-invisibility-spec '(org-babel-hide-result . t)))
(add-hook 'org-mode-hook 'org-babel-result-hide-spec)

(defvar org-babel-hide-result-overlays nil
  "Overlays hiding results.")

(defun org-babel-result-hide-all ()
  "Fold all results in the current buffer."
  (interactive)
  (org-babel-show-result-all)
  (save-excursion
    (while (re-search-forward org-babel-result-regexp nil t)
      (save-excursion (goto-char (match-beginning 0))
                      (org-babel-hide-result-toggle-maybe)))))

(defun org-babel-show-result-all ()
  "Unfold all results in the current buffer."
  (mapc 'delete-overlay org-babel-hide-result-overlays)
  (setq org-babel-hide-result-overlays nil))

;;;###autoload
(defun org-babel-hide-result-toggle-maybe ()
  "Toggle visibility of result at point."
  (interactive)
  (let ((case-fold-search t))
    (if (save-excursion
          (beginning-of-line 1)
          (looking-at org-babel-result-regexp))
        (progn (org-babel-hide-result-toggle)
               t) ;; to signal that we took action
      nil))) ;; to signal that we did not

(defun org-babel-hide-result-toggle (&optional force)
  "Toggle the visibility of the current result."
  (interactive)
  (save-excursion
    (beginning-of-line)
    (if (re-search-forward org-babel-result-regexp nil t)
        (let ((start (progn (beginning-of-line 2) (- (point) 1)))
	      (end (progn
		     (while (looking-at org-babel-multi-line-header-regexp)
		       (forward-line 1))
		     (goto-char (- (org-babel-result-end) 1)) (point)))
	      ov)
          (if (memq t (mapcar (lambda (overlay)
                                (eq (overlay-get overlay 'invisible)
				    'org-babel-hide-result))
                              (overlays-at start)))
              (if (or (not force) (eq force 'off))
                  (mapc (lambda (ov)
                          (when (member ov org-babel-hide-result-overlays)
                            (setq org-babel-hide-result-overlays
                                  (delq ov org-babel-hide-result-overlays)))
                          (when (eq (overlay-get ov 'invisible)
                                    'org-babel-hide-result)
                            (delete-overlay ov)))
                        (overlays-at start)))
            (setq ov (make-overlay start end))
            (overlay-put ov 'invisible 'org-babel-hide-result)
            ;; make the block accessible to isearch
            (overlay-put
             ov 'isearch-open-invisible
             (lambda (ov)
               (when (member ov org-babel-hide-result-overlays)
                 (setq org-babel-hide-result-overlays
                       (delq ov org-babel-hide-result-overlays)))
               (when (eq (overlay-get ov 'invisible)
                         'org-babel-hide-result)
                 (delete-overlay ov))))
            (push ov org-babel-hide-result-overlays)))
      (error "Not looking at a result line"))))

;; org-tab-after-check-for-cycling-hook
(add-hook 'org-tab-first-hook 'org-babel-hide-result-toggle-maybe)
;; Remove overlays when changing major mode
(add-hook 'org-mode-hook
	  (lambda () (org-add-hook 'change-major-mode-hook
				   'org-babel-show-result-all 'append 'local)))

(defvar org-file-properties)
(defun org-babel-params-from-properties (&optional lang)
  "Retrieve parameters specified as properties.
Return an association list of any source block params which
may be specified in the properties of the current outline entry."
  (save-match-data
    (let (val sym)
      (org-babel-parse-multiple-vars
       (delq nil
	     (mapcar
	      (lambda (header-arg)
		(and (setq val (org-entry-get (point) header-arg t))
		     (cons (intern (concat ":" header-arg))
			   (org-babel-read val))))
	      (mapcar
	       #'symbol-name
	       (mapcar
		#'car
		(org-babel-combine-header-arg-lists
		 org-babel-common-header-args-w-values
		 (progn
		   (setq sym (intern (concat "org-babel-header-args:" lang)))
		   (and (boundp sym) (eval sym))))))))))))

(defvar org-src-preserve-indentation)
(defun org-babel-parse-src-block-match ()
  "Parse the results from a match of the `org-babel-src-block-regexp'."
  (let* ((block-indentation (length (match-string 1)))
	 (lang (org-no-properties (match-string 2)))
         (lang-headers (intern (concat "org-babel-default-header-args:" lang)))
	 (switches (match-string 3))
         (body (org-no-properties
		(let* ((body (match-string 5))
		       (sub-length (- (length body) 1)))
		  (if (and (> sub-length 0)
			   (string= "\n" (substring body sub-length)))
		      (substring body 0 sub-length)
		    (or body "")))))
	 (preserve-indentation (or org-src-preserve-indentation
				   (save-match-data
				     (string-match "-i\\>" switches)))))
    (list lang
          ;; get block body less properties, protective commas, and indentation
          (with-temp-buffer
            (save-match-data
              (insert (org-unescape-code-in-string body))
	      (unless preserve-indentation (org-do-remove-indentation))
              (buffer-string)))
	  (org-babel-merge-params
	   org-babel-default-header-args
           (org-babel-params-from-properties lang)
	   (if (boundp lang-headers) (eval lang-headers) nil)
	   (org-babel-parse-header-arguments
            (org-no-properties (or (match-string 4) ""))))
	  switches
	  block-indentation)))

(defun org-babel-parse-inline-src-block-match ()
  "Parse the results from a match of the `org-babel-inline-src-block-regexp'."
  (let* ((lang (org-no-properties (match-string 2)))
         (lang-headers (intern (concat "org-babel-default-header-args:" lang))))
    (list lang
          (org-unescape-code-in-string (org-no-properties (match-string 5)))
          (org-babel-merge-params
           org-babel-default-inline-header-args
           (org-babel-params-from-properties lang)
           (if (boundp lang-headers) (eval lang-headers) nil)
           (org-babel-parse-header-arguments
            (org-no-properties (or (match-string 4) "")))))))

(defun org-babel-balanced-split (string alts)
  "Split STRING on instances of ALTS.
ALTS is a cons of two character options where each option may be
either the numeric code of a single character or a list of
character alternatives.  For example to split on balanced
instances of \"[ \t]:\" set ALTS to '((32 9) . 58)."
  (let* ((matches (lambda (ch spec) (if (listp spec) (member ch spec) (equal spec ch))))
	 (matched (lambda (ch last)
		    (if (consp alts)
			(and (funcall matches ch (cdr alts))
			     (funcall matches last (car alts)))
		      (funcall matches ch alts))))
	 (balance 0) (last 0)
	 quote partial lst)
    (mapc (lambda (ch)  ; split on [], (), "" balanced instances of [ \t]:
	    (setq balance (+ balance
			     (cond ((or (equal 91 ch) (equal 40 ch)) 1)
				   ((or (equal 93 ch) (equal 41 ch)) -1)
				   (t 0))))
	    (when (and (equal 34 ch) (not (equal 92 last)))
	      (setq quote (not quote)))
	    (setq partial (cons ch partial))
	    (when (and (= balance 0) (not quote) (funcall matched ch last))
	      (setq lst (cons (apply #'string (nreverse
					       (if (consp alts)
						   (cddr partial)
						 (cdr partial))))
			      lst))
	      (setq partial nil))
	    (setq last ch))
	  (string-to-list string))
    (nreverse (cons (apply #'string (nreverse partial)) lst))))

(defun org-babel-join-splits-near-ch (ch list)
  "Join splits where \"=\" is on either end of the split."
  (let ((last= (lambda (str) (= ch (aref str (1- (length str))))))
	(first= (lambda (str) (= ch (aref str 0)))))
    (reverse
     (org-reduce (lambda (acc el)
		   (let ((head (car acc)))
		     (if (and head (or (funcall last= head) (funcall first= el)))
			 (cons (concat head el) (cdr acc))
		       (cons el acc))))
		 list :initial-value nil))))

(defun org-babel-parse-header-arguments (arg-string)
  "Parse a string of header arguments returning an alist."
  (when (> (length arg-string) 0)
    (org-babel-parse-multiple-vars
     (delq nil
	   (mapcar
	    (lambda (arg)
	      (if (string-match
		   "\\([^ \f\t\n\r\v]+\\)[ \f\t\n\r\v]+\\([^ \f\t\n\r\v]+.*\\)"
		   arg)
		  (cons (intern (match-string 1 arg))
			(org-babel-read (org-babel-chomp (match-string 2 arg))))
		(cons (intern (org-babel-chomp arg)) nil)))
	    ((lambda (raw)
	       (cons (car raw) (mapcar (lambda (r) (concat ":" r)) (cdr raw))))
	     (org-babel-balanced-split arg-string '((32 9) . 58))))))))

(defun org-babel-parse-multiple-vars (header-arguments)
  "Expand multiple variable assignments behind a single :var keyword.

This allows expression of multiple variables with one :var as
shown below.

#+PROPERTY: var foo=1, bar=2"
  (let (results)
    (mapc (lambda (pair)
	    (if (eq (car pair) :var)
		(mapcar (lambda (v) (push (cons :var (org-babel-trim v)) results))
			(org-babel-join-splits-near-ch
			 61 (org-babel-balanced-split (cdr pair) 32)))
	      (push pair results)))
	  header-arguments)
    (nreverse results)))

(defun org-babel-process-params (params)
  "Expand variables in PARAMS and add summary parameters."
  (let* ((processed-vars (mapcar (lambda (el)
				   (if (consp (cdr el))
				       (cdr el)
				     (org-babel-ref-parse (cdr el))))
				 (org-babel-get-header params :var)))
	 (vars-and-names (if (and (assoc :colname-names params)
				  (assoc :rowname-names params))
			     (list processed-vars)
			   (org-babel-disassemble-tables
			    processed-vars
			    (cdr (assoc :hlines params))
			    (cdr (assoc :colnames params))
			    (cdr (assoc :rownames params)))))
	 (raw-result (or (cdr (assoc :results params)) ""))
	 (result-params (append
			 (split-string (if (stringp raw-result)
					   raw-result
					 (eval raw-result)))
			 (cdr (assoc :result-params params)))))
    (append
     (mapcar (lambda (var) (cons :var var)) (car vars-and-names))
     (list
      (cons :colname-names (or (cdr (assoc :colname-names params))
			       (cadr  vars-and-names)))
      (cons :rowname-names (or (cdr (assoc :rowname-names params))
			       (caddr vars-and-names)))
      (cons :result-params result-params)
      (cons :result-type  (cond ((member "output" result-params) 'output)
				((member "value" result-params) 'value)
				(t 'value))))
     (org-babel-get-header params :var 'other))))

;; row and column names
(defun org-babel-del-hlines (table)
  "Remove all 'hlines from TABLE."
  (remove 'hline table))

(defun org-babel-get-colnames (table)
  "Return the column names of TABLE.
Return a cons cell, the `car' of which contains the TABLE less
colnames, and the `cdr' of which contains a list of the column
names."
  (if (equal 'hline (nth 1 table))
      (cons (cddr table) (car table))
    (cons (cdr table) (car table))))

(defun org-babel-get-rownames (table)
  "Return the row names of TABLE.
Return a cons cell, the `car' of which contains the TABLE less
colnames, and the `cdr' of which contains a list of the column
names.  Note: this function removes any hlines in TABLE."
  (let* ((trans (lambda (table) (apply #'mapcar* #'list table)))
	 (width (apply 'max
		       (mapcar (lambda (el) (if (listp el) (length el) 0)) table)))
	 (table (funcall trans (mapcar (lambda (row)
					 (if (not (equal row 'hline))
					     row
					   (setq row '())
					   (dotimes (n width)
					     (setq row (cons 'hline row)))
					   row))
				       table))))
    (cons (mapcar (lambda (row) (if (equal (car row) 'hline) 'hline row))
		  (funcall trans (cdr table)))
	  (remove 'hline (car table)))))

(defun org-babel-put-colnames (table colnames)
  "Add COLNAMES to TABLE if they exist."
  (if colnames (apply 'list colnames 'hline table) table))

(defun org-babel-put-rownames (table rownames)
  "Add ROWNAMES to TABLE if they exist."
  (if rownames
      (mapcar (lambda (row)
                (if (listp row)
                    (cons (or (pop rownames) "") row)
                  row)) table)
    table))

(defun org-babel-pick-name (names selector)
  "Select one out of an alist of row or column names.
SELECTOR can be either a list of names in which case those names
will be returned directly, or an index into the list NAMES in
which case the indexed names will be return."
  (if (listp selector)
      selector
    (when names
      (if (and selector (symbolp selector) (not (equal t selector)))
	  (cdr (assoc selector names))
	(if (integerp selector)
	    (nth (- selector 1) names)
	  (cdr (car (last names))))))))

(defun org-babel-disassemble-tables (vars hlines colnames rownames)
  "Parse tables for further processing.
Process the variables in VARS according to the HLINES,
ROWNAMES and COLNAMES header arguments.  Return a list consisting
of the vars, cnames and rnames."
  (let (cnames rnames)
    (list
     (mapcar
      (lambda (var)
        (when (listp (cdr var))
          (when (and (not (equal colnames "no"))
                     (or colnames (and (equal (nth 1 (cdr var)) 'hline)
                                       (not (member 'hline (cddr (cdr var)))))))
            (let ((both (org-babel-get-colnames (cdr var))))
              (setq cnames (cons (cons (car var) (cdr both))
                                 cnames))
              (setq var (cons (car var) (car both)))))
          (when (and rownames (not (equal rownames "no")))
            (let ((both (org-babel-get-rownames (cdr var))))
              (setq rnames (cons (cons (car var) (cdr both))
                                 rnames))
              (setq var (cons (car var) (car both)))))
          (when (and hlines (not (equal hlines "yes")))
            (setq var (cons (car var) (org-babel-del-hlines (cdr var))))))
        var)
      vars)
     (reverse cnames) (reverse rnames))))

(defun org-babel-reassemble-table (table colnames rownames)
  "Add column and row names to a table.
Given a TABLE and set of COLNAMES and ROWNAMES add the names
to the table for reinsertion to org-mode."
  (if (listp table)
      ((lambda (table)
         (if (and colnames (listp (car table)) (= (length (car table))
                                                  (length colnames)))
             (org-babel-put-colnames table colnames) table))
       (if (and rownames (= (length table) (length rownames)))
           (org-babel-put-rownames table rownames) table))
    table))

(defun org-babel-where-is-src-block-head ()
  "Find where the current source block begins.
Return the point at the beginning of the current source
block.  Specifically at the beginning of the #+BEGIN_SRC line.
If the point is not on a source block then return nil."
  (let ((initial (point)) (case-fold-search t) top bottom)
    (or
     (save-excursion ;; on a source name line or a #+header line
       (beginning-of-line 1)
       (and (or (looking-at org-babel-src-name-regexp)
		(looking-at org-babel-multi-line-header-regexp))
	    (progn
	      (while (and (forward-line 1)
			  (or (looking-at org-babel-src-name-regexp)
			      (looking-at org-babel-multi-line-header-regexp))))
	      (looking-at org-babel-src-block-regexp))
            (point)))
     (save-excursion ;; on a #+begin_src line
       (beginning-of-line 1)
       (and (looking-at org-babel-src-block-regexp)
            (point)))
     (save-excursion ;; inside a src block
       (and
        (re-search-backward "^[ \t]*#\\+begin_src" nil t) (setq top (point))
        (re-search-forward "^[ \t]*#\\+end_src" nil t) (setq bottom (point))
        (< top initial) (< initial bottom)
        (progn (goto-char top) (beginning-of-line 1)
	       (looking-at org-babel-src-block-regexp))
        (point))))))

;;;###autoload
(defun org-babel-goto-src-block-head ()
  "Go to the beginning of the current code block."
  (interactive)
  ((lambda (head)
     (if head (goto-char head) (error "Not currently in a code block")))
   (org-babel-where-is-src-block-head)))

;;;###autoload
(defun org-babel-goto-named-src-block (name)
  "Go to a named source-code block."
  (interactive
   (let ((completion-ignore-case t)
	 (case-fold-search t)
	 (under-point (thing-at-point 'line)))
     (list (org-icompleting-read
	    "source-block name: " (org-babel-src-block-names) nil t
	    (cond
	     ;; noweb
	     ((string-match (org-babel-noweb-wrap) under-point)
	      (let ((block-name (match-string 1 under-point)))
		(string-match "[^(]*" block-name)
		(match-string 0 block-name)))
	     ;; #+call:
	     ((string-match org-babel-lob-one-liner-regexp under-point)
	      (let ((source-info (car (org-babel-lob-get-info))))
		(if (string-match "^\\([^\\[]+?\\)\\(\\[.*\\]\\)?(" source-info)
		    (let ((source-name (match-string 1 source-info)))
		      source-name))))
	     ;; #+results:
	     ((string-match (concat "#\\+" org-babel-results-keyword
				    "\\:\s+\\([^\\(]*\\)") under-point)
	      (match-string 1 under-point))
	     ;; symbol-at-point
	     ((and (thing-at-point 'symbol))
	      (org-babel-find-named-block (thing-at-point 'symbol))
	      (thing-at-point 'symbol))
	     (""))))))
  (let ((point (org-babel-find-named-block name)))
    (if point
        ;; taken from `org-open-at-point'
        (progn (org-mark-ring-push) (goto-char point) (org-show-context))
      (message "source-code block '%s' not found in this buffer" name))))

(defun org-babel-find-named-block (name)
  "Find a named source-code block.
Return the location of the source block identified by source
NAME, or nil if no such block exists.  Set match data according to
org-babel-named-src-block-regexp."
  (save-excursion
    (let ((case-fold-search t)
	  (regexp (org-babel-named-src-block-regexp-for-name name)) msg)
      (goto-char (point-min))
      (when (or (re-search-forward regexp nil t)
		(re-search-backward regexp nil t))
        (match-beginning 0)))))

(defun org-babel-src-block-names (&optional file)
  "Returns the names of source blocks in FILE or the current buffer."
  (save-excursion
    (when file (find-file file)) (goto-char (point-min))
    (let ((case-fold-search t) names)
      (while (re-search-forward org-babel-src-name-w-name-regexp nil t)
	(setq names (cons (match-string 3) names)))
      names)))

;;;###autoload
(defun org-babel-goto-named-result (name)
  "Go to a named result."
  (interactive
   (let ((completion-ignore-case t))
     (list (org-icompleting-read "source-block name: "
				 (org-babel-result-names) nil t))))
  (let ((point (org-babel-find-named-result name)))
    (if point
        ;; taken from `org-open-at-point'
        (progn (goto-char point) (org-show-context))
      (message "result '%s' not found in this buffer" name))))

(defun org-babel-find-named-result (name &optional point)
  "Find a named result.
Return the location of the result named NAME in the current
buffer or nil if no such result exists."
  (save-excursion
    (let ((case-fold-search t))
      (goto-char (or point (point-min)))
      (catch 'is-a-code-block
	(when (re-search-forward
	       (concat org-babel-result-regexp
		       "[ \t]" (regexp-quote name) "[ \t]*[\n\f\v\r]") nil t)
	  (when (and (string= "name" (downcase (match-string 1)))
		     (or (beginning-of-line 1)
			 (looking-at org-babel-src-block-regexp)
			 (looking-at org-babel-multi-line-header-regexp)))
	    (throw 'is-a-code-block (org-babel-find-named-result name (point))))
	  (beginning-of-line 0) (point))))))

(defun org-babel-result-names (&optional file)
  "Returns the names of results in FILE or the current buffer."
  (save-excursion
    (when file (find-file file)) (goto-char (point-min))
    (let ((case-fold-search t) names)
      (while (re-search-forward org-babel-result-w-name-regexp nil t)
	(setq names (cons (match-string 4) names)))
      names)))

;;;###autoload
(defun org-babel-next-src-block (&optional arg)
  "Jump to the next source block.
With optional prefix argument ARG, jump forward ARG many source blocks."
  (interactive "P")
  (when (looking-at org-babel-src-block-regexp) (forward-char 1))
  (condition-case nil
      (re-search-forward org-babel-src-block-regexp nil nil (or arg 1))
    (error (error "No further code blocks")))
  (goto-char (match-beginning 0)) (org-show-context))

;;;###autoload
(defun org-babel-previous-src-block (&optional arg)
  "Jump to the previous source block.
With optional prefix argument ARG, jump backward ARG many source blocks."
  (interactive "P")
  (condition-case nil
      (re-search-backward org-babel-src-block-regexp nil nil (or arg 1))
    (error (error "No previous code blocks")))
  (goto-char (match-beginning 0)) (org-show-context))

(defvar org-babel-load-languages)

;;;###autoload
(defun org-babel-mark-block ()
  "Mark current src block."
  (interactive)
  ((lambda (head)
     (when head
       (save-excursion
	 (goto-char head)
	 (looking-at org-babel-src-block-regexp))
       (push-mark (match-end 5) nil t)
       (goto-char (match-beginning 5))))
   (org-babel-where-is-src-block-head)))

(defun org-babel-demarcate-block (&optional arg)
  "Wrap or split the code in the region or on the point.
When called from inside of a code block the current block is
split.  When called from outside of a code block a new code block
is created.  In both cases if the region is demarcated and if the
region is not active then the point is demarcated."
  (interactive "P")
  (let ((info (org-babel-get-src-block-info 'light))
	(headers (progn (org-babel-where-is-src-block-head)
			(match-string 4)))
	(stars (concat (make-string (or (org-current-level) 1) ?*) " ")))
    (if info
        (mapc
         (lambda (place)
           (save-excursion
             (goto-char place)
             (let ((lang (nth 0 info))
                   (indent (make-string (nth 5 info) ? )))
	       (when (string-match "^[[:space:]]*$"
				   (buffer-substring (point-at-bol)
						     (point-at-eol)))
		 (delete-region (point-at-bol) (point-at-eol)))
               (insert (concat
			(if (looking-at "^") "" "\n")
			indent "#+end_src\n"
			(if arg stars indent) "\n"
			indent "#+begin_src " lang
			(if (> (length headers) 1)
			    (concat " " headers) headers)
			(if (looking-at "[\n\r]")
			    ""
			  (concat "\n" (make-string (current-column) ? )))))))
	   (move-end-of-line 2))
         (sort (if (org-region-active-p) (list (mark) (point)) (list (point))) #'>))
      (let ((start (point))
	    (lang (org-icompleting-read "Lang: "
					(mapcar (lambda (el) (symbol-name (car el)))
						org-babel-load-languages)))
	    (body (delete-and-extract-region
		   (if (org-region-active-p) (mark) (point)) (point))))
	(insert (concat (if (looking-at "^") "" "\n")
			(if arg (concat stars "\n") "")
			"#+begin_src " lang "\n"
			body
			(if (or (= (length body) 0)
				(string-match "[\r\n]$" body)) "" "\n")
			"#+end_src\n"))
	(goto-char start) (move-end-of-line 1)))))

(defvar org-babel-lob-one-liner-regexp)
(defun org-babel-where-is-src-block-result (&optional insert info hash indent)
  "Find where the current source block results begin.
Return the point at the beginning of the result of the current
source block.  Specifically at the beginning of the results line.
If no result exists for this block then create a results line
following the source block."
  (save-excursion
    (let* ((case-fold-search t)
	   (on-lob-line (save-excursion
			  (beginning-of-line 1)
			  (looking-at org-babel-lob-one-liner-regexp)))
	   (inlinep (when (org-babel-get-inline-src-block-matches)
		      (match-end 0)))
	   (name (if on-lob-line
		     (mapconcat #'identity (butlast (org-babel-lob-get-info)) "")
		   (nth 4 (or info (org-babel-get-src-block-info 'light)))))
	   (head (unless on-lob-line (org-babel-where-is-src-block-head)))
	   found beg end)
      (when head (goto-char head))
      (org-with-wide-buffer
       (setq
	found ;; was there a result (before we potentially insert one)
	(or
	 inlinep
	 (and
	  ;; named results:
	  ;; - return t if it is found, else return nil
	  ;; - if it does not need to be rebuilt, then don't set end
	  ;; - if it does need to be rebuilt then do set end
	  name (setq beg (org-babel-find-named-result name))
	  (prog1 beg
	    (when (and hash (not (string= hash (match-string 3))))
	      (goto-char beg) (setq end beg) ;; beginning of result
	      (forward-line 1)
	      (delete-region end (org-babel-result-end)) nil)))
	 (and
	  ;; unnamed results:
	  ;; - return t if it is found, else return nil
	  ;; - if it is found, and the hash doesn't match, delete and set end
	  (or on-lob-line (re-search-forward "^[ \t]*#\\+end_src" nil t))
	  (progn (end-of-line 1)
		 (if (eobp) (insert "\n") (forward-char 1))
		 (setq end (point))
		 (or (and (not name)
			  (progn ;; unnamed results line already exists
			    (re-search-forward "[^ \f\t\n\r\v]" nil t)
			    (beginning-of-line 1)
			    (looking-at
			     (concat org-babel-result-regexp "\n")))
			  (prog1 (point)
			    ;; must remove and rebuild if hash!=old-hash
			    (if (and hash (not (string= hash (match-string 3))))
				(prog1 nil
				  (forward-line 1)
				  (delete-region
				   end (org-babel-result-end)))
			      (setq end nil))))))))))
      (if (not (and insert end)) found
	(goto-char end)
	(unless beg
	  (if (looking-at "[\n\r]") (forward-char 1) (insert "\n")))
	(insert (concat
		 (when (wholenump indent) (make-string indent ? ))
		 "#+" org-babel-results-keyword
		 (when hash (concat "["hash"]"))
		 ":"
		 (when name (concat " " name)) "\n"))
	(unless beg (insert "\n") (backward-char))
	(beginning-of-line 0)
	(if hash (org-babel-hide-hash))
	(point)))))

(defvar org-block-regexp)
(defun org-babel-read-result ()
  "Read the result at `point' into emacs-lisp."
  (let ((case-fold-search t) result-string)
    (cond
     ((org-at-table-p) (org-babel-read-table))
     ((org-at-item-p) (org-babel-read-list))
     ((looking-at org-bracket-link-regexp) (org-babel-read-link))
     ((looking-at org-block-regexp) (org-babel-trim (match-string 4)))
     ((looking-at "^[ \t]*: ")
      (setq result-string
	    (org-babel-trim
	     (mapconcat (lambda (line)
                          (if (and (> (length line) 1)
                                   (string-match "^[ \t]*: \\(.+\\)" line))
                              (match-string 1 line)
                            line))
			(split-string
			 (buffer-substring
                          (point) (org-babel-result-end)) "[\r\n]+")
			"\n")))
      (or (org-babel-number-p result-string) result-string))
     ((looking-at org-babel-result-regexp)
      (save-excursion (forward-line 1) (org-babel-read-result))))))

(defun org-babel-read-table ()
  "Read the table at `point' into emacs-lisp."
  (mapcar (lambda (row)
            (if (and (symbolp row) (equal row 'hline)) row
              (mapcar (lambda (el) (org-babel-read el 'inhibit-lisp-eval)) row)))
          (org-table-to-lisp)))

(defun org-babel-read-list ()
  "Read the list at `point' into emacs-lisp."
  (mapcar (lambda (el) (org-babel-read el 'inhibit-lisp-eval))
	  (mapcar #'cadr (cdr (org-list-parse-list)))))

(defvar org-link-types-re)
(defun org-babel-read-link ()
  "Read the link at `point' into emacs-lisp.
If the path of the link is a file path it is expanded using
`expand-file-name'."
  (let* ((case-fold-search t)
         (raw (and (looking-at org-bracket-link-regexp)
                   (org-no-properties (match-string 1))))
         (type (and (string-match org-link-types-re raw)
                    (match-string 1 raw))))
    (cond
     ((not type) (expand-file-name raw))
     ((string= type "file")
      (and (string-match "file\\(.*\\):\\(.+\\)" raw)
           (expand-file-name (match-string 2 raw))))
     (t raw))))

(defun org-babel-format-result (result &optional sep)
  "Format RESULT for writing to file."
  (let ((echo-res (lambda (r) (if (stringp r) r (format "%S" r)))))
    (if (listp result)
	;; table result
	(orgtbl-to-generic
	 result (list :sep (or sep "\t") :fmt echo-res))
      ;; scalar result
      (funcall echo-res result))))

(defun org-babel-insert-result
  (result &optional result-params info hash indent lang)
  "Insert RESULT into the current buffer.
By default RESULT is inserted after the end of the
current source block.  With optional argument RESULT-PARAMS
controls insertion of results in the org-mode file.
RESULT-PARAMS can take the following values:

replace - (default option) insert results after the source block
          replacing any previously inserted results

silent -- no results are inserted into the Org-mode buffer but
          the results are echoed to the minibuffer and are
          ingested by Emacs (a potentially time consuming
          process)

file ---- the results are interpreted as a file path, and are
          inserted into the buffer using the Org-mode file syntax

list ---- the results are interpreted as an Org-mode list.

raw ----- results are added directly to the Org-mode file.  This
          is a good option if you code block will output org-mode
          formatted text.

drawer -- results are added directly to the Org-mode file as with
          \"raw\", but are wrapped in a RESULTS drawer, allowing
          them to later be replaced or removed automatically.

org ----- results are added inside of a \"#+BEGIN_SRC org\" block.
          They are not comma-escaped when inserted, but Org syntax
          here will be discarded when exporting the file.

html ---- results are added inside of a #+BEGIN_HTML block.  This
          is a good option if you code block will output html
          formatted text.

latex --- results are added inside of a #+BEGIN_LATEX block.
          This is a good option if you code block will output
          latex formatted text.

code ---- the results are extracted in the syntax of the source
          code of the language being evaluated and are added
          inside of a #+BEGIN_SRC block with the source-code
          language set appropriately.  Note this relies on the
          optional LANG argument."
  (if (stringp result)
      (progn
        (setq result (org-no-properties result))
        (when (member "file" result-params)
	  (setq result (org-babel-result-to-file
			result (when (assoc :file-desc (nth 2 info))
				 (or (cdr (assoc :file-desc (nth 2 info)))
				     result))))))
    (unless (listp result) (setq result (format "%S" result))))
  (if (and result-params (member "silent" result-params))
      (progn
	(message (replace-regexp-in-string "%" "%%" (format "%S" result)))
	result)
    (save-excursion
      (let* ((inlinep
	      (save-excursion
		(when (or (org-babel-get-inline-src-block-matches)
			  (org-babel-get-lob-one-liner-matches))
		  (goto-char (match-end 0))
		  (insert (if (listp result) "\n" " "))
		  (point))))
	     (existing-result (unless inlinep
				(org-babel-where-is-src-block-result
				 t info hash indent)))
	     (results-switches
	      (cdr (assoc :results_switches (nth 2 info))))
	     (visible-beg (copy-marker (point-min)))
	     (visible-end (copy-marker (point-max)))
	     ;; When results exist outside of the current visible
	     ;; region of the buffer, be sure to widen buffer to
	     ;; update them.
	     (outside-scope-p (and existing-result
				   (or (> visible-beg existing-result)
				       (<= visible-end existing-result))))
	     beg end)
	(when (and (stringp result)  ; ensure results end in a newline
		   (not inlinep)
		   (> (length result) 0)
		   (not (or (string-equal (substring result -1) "\n")
			    (string-equal (substring result -1) "\r"))))
	  (setq result (concat result "\n")))
	(unwind-protect
	    (progn
	      (when outside-scope-p (widen))
	      (if (not existing-result)
		  (setq beg (or inlinep (point)))
		(goto-char existing-result)
		(save-excursion
		  (re-search-forward "#" nil t)
		  (setq indent (- (current-column) 1)))
		(forward-line 1)
		(setq beg (point))
		(cond
		 ((member "replace" result-params)
		  (delete-region (point) (org-babel-result-end)))
		 ((member "append" result-params)
		  (goto-char (org-babel-result-end)) (setq beg (point-marker)))
		 ((member "prepend" result-params)))) ; already there
	      (setq results-switches
		    (if results-switches (concat " " results-switches) ""))
	      (let ((wrap (lambda (start finish &optional no-escape)
			    (goto-char end) (insert (concat finish "\n"))
			    (goto-char beg) (insert (concat start "\n"))
			    (unless no-escape
			      (org-escape-code-in-region (point) end))
			    (goto-char end) (goto-char (point-at-eol))
			    (setq end (point-marker))))
		    (proper-list-p (lambda (it) (and (listp it) (null (cdr (last it)))))))
		;; insert results based on type
		(cond
		 ;; do nothing for an empty result
		 ((null result))
		 ;; insert a list if preferred
		 ((member "list" result-params)
		  (insert
		   (org-babel-trim
		    (org-list-to-generic
		     (cons 'unordered
			   (mapcar
			    (lambda (el) (list nil (if (stringp el) el (format "%S" el))))
			    (if (listp result) result (list result))))
		     '(:splicep nil :istart "- " :iend "\n")))
		   "\n"))
		 ;; assume the result is a table if it's not a string
		 ((funcall proper-list-p result)
		  (goto-char beg)
		  (insert (concat (orgtbl-to-orgtbl
				   (if (or (eq 'hline (car result))
					   (and (listp (car result))
						(listp (cdr (car result)))))
				       result (list result))
				   '(:fmt (lambda (cell) (format "%s" cell)))) "\n"))
		  (goto-char beg) (when (org-at-table-p) (org-table-align)))
		 ((and (listp result) (not (funcall proper-list-p result)))
		  (insert (format "%s\n" result)))
		 ((member "file" result-params)
		  (when inlinep (goto-char inlinep))
		  (insert result))
		 (t (goto-char beg) (insert result)))
		(when (funcall proper-list-p result) (goto-char (org-table-end)))
		(setq end (point-marker))
		;; possibly wrap result
		(cond
		 ((assoc :wrap (nth 2 info))
		  (let ((name (or (cdr (assoc :wrap (nth 2 info))) "RESULTS")))
		    (funcall wrap (concat "#+BEGIN_" name) (concat "#+END_" name))))
		 ((member "html" result-params)
		  (funcall wrap "#+BEGIN_HTML" "#+END_HTML"))
		 ((member "latex" result-params)
		  (funcall wrap "#+BEGIN_LaTeX" "#+END_LaTeX"))
		 ((member "org" result-params)
		  (funcall wrap "#+BEGIN_SRC org" "#+END_SRC"))
		 ((member "code" result-params)
		  (funcall wrap (format "#+BEGIN_SRC %s%s" (or lang "none") results-switches)
			   "#+END_SRC"))
		 ((member "raw" result-params)
		  (goto-char beg) (if (org-at-table-p) (org-cycle)))
		 ((or (member "drawer" result-params)
		      ;; Stay backward compatible with <7.9.2
		      (member "wrap" result-params))
		  (funcall wrap ":RESULTS:" ":END:" 'no-escape))
		 ((and (not (funcall proper-list-p result))
		       (not (member "file" result-params)))
		  (org-babel-examplize-region beg end results-switches)
		  (setq end (point)))))
	      ;; possibly indent the results to match the #+results line
	      (when (and (not inlinep) (numberp indent) indent (> indent 0)
			 ;; in this case `table-align' does the work for us
			 (not (and (listp result)
				   (member "append" result-params))))
		(indent-rigidly beg end indent))
	      (if (null result)
		  (if (member "value" result-params)
		      (message "Code block returned no value.")
		    (message "Code block produced no output."))
		(message "Code block evaluation complete.")))
	  (when outside-scope-p (narrow-to-region visible-beg visible-end))
	  (set-marker visible-beg nil)
	  (set-marker visible-end nil))))))

(defun org-babel-remove-result (&optional info)
  "Remove the result of the current source block."
  (interactive)
  (let ((location (org-babel-where-is-src-block-result nil info)) start)
    (when location
      (setq start (- location 1))
      (save-excursion
        (goto-char location) (forward-line 1)
        (delete-region start (org-babel-result-end))))))

(defun org-babel-result-end ()
  "Return the point at the end of the current set of results."
  (save-excursion
    (cond
     ((org-at-table-p) (progn (goto-char (org-table-end)) (point)))
     ((org-at-item-p) (let* ((struct (org-list-struct))
			     (prvs (org-list-prevs-alist struct)))
			(org-list-get-list-end (point-at-bol) struct prvs)))
     ((let ((case-fold-search t)) (looking-at "^\\([ \t]*\\):results:"))
      (progn (re-search-forward (concat "^" (match-string 1) ":END:"))
	     (forward-char 1) (point)))
     (t
      (let ((case-fold-search t))
	(if (looking-at (concat "[ \t]*#\\+begin_\\([^ \t\n\r]+\\)"))
	    (progn (re-search-forward (concat "[ \t]*#\\+end_" (match-string 1))
				      nil t)
		   (forward-char 1))
	  (while (looking-at "[ \t]*\\(: \\|\\[\\[\\)")
	    (forward-line 1))))
      (point)))))

(defun org-babel-result-to-file (result &optional description)
  "Convert RESULT into an `org-mode' link with optional DESCRIPTION.
If the `default-directory' is different from the containing
file's directory then expand relative links."
  (when (stringp result)
    (format "[[file:%s]%s]"
	    (if (and default-directory
		     buffer-file-name
		     (not (string= (expand-file-name default-directory)
				   (expand-file-name
				    (file-name-directory buffer-file-name)))))
		(expand-file-name result default-directory)
	      result)
	    (if description (concat "[" description "]") ""))))

(defvar org-babel-capitalize-examplize-region-markers nil
  "Make true to capitalize begin/end example markers inserted by code blocks.")

(defun org-babel-examplize-region (beg end &optional results-switches)
  "Comment out region using the inline '==' or ': ' org example quote."
  (interactive "*r")
  (let ((chars-between (lambda (b e)
			 (not (string-match "^[\\s]*$" (buffer-substring b e)))))
	(maybe-cap (lambda (str) (if org-babel-capitalize-examplize-region-markers
				     (upcase str) str))))
    (if (or (funcall chars-between (save-excursion (goto-char beg) (point-at-bol)) beg)
	    (funcall chars-between end (save-excursion (goto-char end) (point-at-eol))))
	(save-excursion
	  (goto-char beg)
	  (insert (format "=%s=" (prog1 (buffer-substring beg end)
				   (delete-region beg end)))))
      (let ((size (count-lines beg end)))
	(save-excursion
	  (cond ((= size 0))	      ; do nothing for an empty result
		((< size org-babel-min-lines-for-block-output)
		 (goto-char beg)
		 (dotimes (n size)
		   (beginning-of-line 1) (insert ": ") (forward-line 1)))
		(t
		 (goto-char beg)
		 (insert (if results-switches
			     (format "%s%s\n"
				     (funcall maybe-cap "#+begin_example")
				     results-switches)
			   (funcall maybe-cap "#+begin_example\n")))
		 (if (markerp end) (goto-char end) (forward-char (- end beg)))
		 (insert (funcall maybe-cap "#+end_example\n")))))))))

(defun org-babel-update-block-body (new-body)
  "Update the body of the current code block to NEW-BODY."
  (if (not (org-babel-where-is-src-block-head))
      (error "Not in a source block")
    (save-match-data
      (replace-match (concat (org-babel-trim new-body) "\n") nil t nil 5))
    (indent-rigidly (match-beginning 5) (match-end 5) 2)))

(defun org-babel-merge-params (&rest plists)
  "Combine all parameter association lists in PLISTS.
Later elements of PLISTS override the values of previous elements.
This takes into account some special considerations for certain
parameters when merging lists."
  (let* ((results-exclusive-groups
	  (mapcar (lambda (group) (mapcar #'symbol-name group))
		  (cdr (assoc 'results org-babel-common-header-args-w-values))))
	 (exports-exclusive-groups
	  (mapcar (lambda (group) (mapcar #'symbol-name group))
		  (cdr (assoc 'exports org-babel-common-header-args-w-values))))
	 (variable-index 0)
	 (e-merge (lambda (exclusive-groups &rest result-params)
		    ;; maintain exclusivity of mutually exclusive parameters
		    (let (output)
		      (mapc (lambda (new-params)
			      (mapc (lambda (new-param)
				      (mapc (lambda (exclusive-group)
					      (when (member new-param exclusive-group)
						(mapcar (lambda (excluded-param)
							  (setq output
								(delete
								 excluded-param
								 output)))
							exclusive-group)))
					    exclusive-groups)
				      (setq output (org-uniquify
						    (cons new-param output))))
				    new-params))
			    result-params)
		      output)))
	 params results exports tangle noweb cache vars shebang comments padline)

    (mapc
     (lambda (plist)
       (mapc
	(lambda (pair)
	  (case (car pair)
	    (:var
	     (let ((name (if (listp (cdr pair))
			     (cadr pair)
			   (and (string-match "^\\([^= \f\t\n\r\v]+\\)[ \t]*="
					      (cdr pair))
				(intern (match-string 1 (cdr pair)))))))
	       (if name
		   (setq vars
			 (append
			  (if (member name (mapcar #'car vars))
			      (delq nil
				    (mapcar
				     (lambda (p)
				       (unless (equal (car p) name) p))
				     vars))
			    vars)
			  (list (cons name pair))))
		 ;; if no name is given and we already have named variables
		 ;; then assign to named variables in order
		 (if (and vars (nth variable-index vars))
		     (prog1 (setf (cddr (nth variable-index vars))
				  (concat (symbol-name
					   (car (nth variable-index vars)))
					  "=" (cdr pair)))
		       (incf variable-index))
		   (error "Variable \"%s\" must be assigned a default value"
			  (cdr pair))))))
	    (:results
	     (setq results (funcall e-merge results-exclusive-groups
				    results
				    (split-string
				     (let ((r (cdr pair)))
				       (if (stringp r) r (eval r)))))))
	    (:file
	     (when (cdr pair)
	       (setq results (funcall e-merge results-exclusive-groups
				      results '("file")))
	       (unless (or (member "both" exports)
			   (member "none" exports)
			   (member "code" exports))
		 (setq exports (funcall e-merge exports-exclusive-groups
					exports '("results"))))
	       (setq params (cons pair (assq-delete-all (car pair) params)))))
	    (:exports
	     (setq exports (funcall e-merge exports-exclusive-groups
				    exports (split-string (cdr pair)))))
	    (:tangle ;; take the latest -- always overwrite
	     (setq tangle (or (list (cdr pair)) tangle)))
	    (:noweb
	     (setq noweb (funcall e-merge
				  '(("yes" "no" "tangle" "no-export"
				     "strip-export" "eval"))
				  noweb
				  (split-string (or (cdr pair) "")))))
	    (:cache
	     (setq cache (funcall e-merge '(("yes" "no")) cache
				  (split-string (or (cdr pair) "")))))
	    (:padline
	     (setq padline (funcall e-merge '(("yes" "no")) padline
				    (split-string (or (cdr pair) "")))))
	    (:shebang ;; take the latest -- always overwrite
	     (setq shebang (or (list (cdr pair)) shebang)))
	    (:comments
	     (setq comments (funcall e-merge '(("yes" "no")) comments
				     (split-string (or (cdr pair) "")))))
	    (t ;; replace: this covers e.g. :session
	     (setq params (cons pair (assq-delete-all (car pair) params))))))
	plist))
     plists)
    (setq vars (reverse vars))
    (while vars (setq params (cons (cons :var (cddr (pop vars))) params)))
    (mapc
     (lambda (hd)
       (let ((key (intern (concat ":" (symbol-name hd))))
	     (val (eval hd)))
	 (setf params (cons (cons key (mapconcat 'identity val " ")) params))))
     '(results exports tangle noweb padline cache shebang comments))
    params))

(defvar org-babel-use-quick-and-dirty-noweb-expansion nil
  "Set to true to use regular expressions to expand noweb references.
This results in much faster noweb reference expansion but does
not properly allow code blocks to inherit the \":noweb-ref\"
header argument from buffer or subtree wide properties.")

(defun org-babel-noweb-p (params context)
  "Check if PARAMS require expansion in CONTEXT.
CONTEXT may be one of :tangle, :export or :eval."
  (let* (intersect
	 (intersect (lambda (as bs)
		      (when as
			(if (member (car as) bs)
			    (car as)
			  (funcall intersect (cdr as) bs))))))
    (funcall intersect (case context
			 (:tangle '("yes" "tangle" "no-export" "strip-export"))
			 (:eval   '("yes" "no-export" "strip-export" "eval"))
			 (:export '("yes")))
	     (split-string (or (cdr (assoc :noweb params)) "")))))

(defun org-babel-expand-noweb-references (&optional info parent-buffer)
  "Expand Noweb references in the body of the current source code block.

For example the following reference would be replaced with the
body of the source-code block named 'example-block'.

<<example-block>>

Note that any text preceding the <<foo>> construct on a line will
be interposed between the lines of the replacement text.  So for
example if <<foo>> is placed behind a comment, then the entire
replacement text will also be commented.

This function must be called from inside of the buffer containing
the source-code block which holds BODY.

In addition the following syntax can be used to insert the
results of evaluating the source-code block named 'example-block'.

<<example-block()>>

Any optional arguments can be passed to example-block by placing
the arguments inside the parenthesis following the convention
defined by `org-babel-lob'.  For example

<<example-block(a=9)>>

would set the value of argument \"a\" equal to \"9\".  Note that
these arguments are not evaluated in the current source-code
block but are passed literally to the \"example-block\"."
  (let* ((parent-buffer (or parent-buffer (current-buffer)))
         (info (or info (org-babel-get-src-block-info)))
         (lang (nth 0 info))
         (body (nth 1 info))
	 (ob-nww-start org-babel-noweb-wrap-start)
	 (ob-nww-end org-babel-noweb-wrap-end)
	 (comment (string= "noweb" (cdr (assoc :comments (nth 2 info)))))
	 (rx-prefix (concat "\\(" org-babel-src-name-regexp "\\|"
			    ":noweb-ref[ \t]+" "\\)"))
         (new-body "")
	 (nb-add (lambda (text) (setq new-body (concat new-body text))))
	 (c-wrap (lambda (text)
		   (with-temp-buffer
		     (funcall (intern (concat lang "-mode")))
		     (comment-region (point) (progn (insert text) (point)))
		     (org-babel-trim (buffer-string)))))
	 index source-name evaluate prefix blocks-in-buffer)
    (with-temp-buffer
      (org-set-local 'org-babel-noweb-wrap-start ob-nww-start)
      (org-set-local 'org-babel-noweb-wrap-end ob-nww-end)
      (insert body) (goto-char (point-min))
      (setq index (point))
      (while (and (re-search-forward (org-babel-noweb-wrap) nil t))
	(save-match-data (setf source-name (match-string 1)))
	(save-match-data (setq evaluate (string-match "\(.*\)" source-name)))
	(save-match-data
	  (setq prefix
		(buffer-substring (match-beginning 0)
				  (save-excursion
				    (beginning-of-line 1) (point)))))
	;; add interval to new-body (removing noweb reference)
	(goto-char (match-beginning 0))
	(funcall nb-add (buffer-substring index (point)))
	(goto-char (match-end 0))
	(setq index (point))
	(funcall nb-add
		 (with-current-buffer parent-buffer
		   (save-restriction
		     (widen)
		     (mapconcat ;; interpose PREFIX between every line
		      #'identity
		      (split-string
		       (if evaluate
			   (let ((raw (org-babel-ref-resolve source-name)))
			     (if (stringp raw) raw (format "%S" raw)))
			 (or
			  ;; retrieve from the library of babel
			  (nth 2 (assoc (intern source-name)
					org-babel-library-of-babel))
			  ;; return the contents of headlines literally
			  (save-excursion
			    (when (org-babel-ref-goto-headline-id source-name)
			      (org-babel-ref-headline-body)))
			  ;; find the expansion of reference in this buffer
			  (let ((rx (concat rx-prefix source-name "[ \t\n]"))
				expansion)
			    (save-excursion
			      (goto-char (point-min))
			      (if org-babel-use-quick-and-dirty-noweb-expansion
				  (while (re-search-forward rx nil t)
				    (let* ((i (org-babel-get-src-block-info 'light))
					   (body (org-babel-expand-noweb-references i))
					   (sep (or (cdr (assoc :noweb-sep (nth 2 i)))
						    "\n"))
					   (full (if comment
						     ((lambda (cs)
							(concat (funcall c-wrap (car cs)) "\n"
								body "\n"
								(funcall c-wrap (cadr cs))))
						      (org-babel-tangle-comment-links i))
						   body)))
				      (setq expansion (cons sep (cons full expansion)))))
				(org-babel-map-src-blocks nil
				  (let ((i (org-babel-get-src-block-info 'light)))
				    (when (equal (or (cdr (assoc :noweb-ref (nth 2 i)))
						     (nth 4 i))
						 source-name)
				      (let* ((body (org-babel-expand-noweb-references i))
					     (sep (or (cdr (assoc :noweb-sep (nth 2 i)))
						      "\n"))
					     (full (if comment
						       ((lambda (cs)
							  (concat (funcall c-wrap (car cs)) "\n"
								  body "\n"
								  (funcall c-wrap (cadr cs))))
							(org-babel-tangle-comment-links i))
						     body)))
					(setq expansion
					      (cons sep (cons full expansion)))))))))
			    (and expansion
				 (mapconcat #'identity (nreverse (cdr expansion)) "")))
			  ;; possibly raise an error if named block doesn't exist
			  (if (member lang org-babel-noweb-error-langs)
			      (error "%s" (concat
					   (org-babel-noweb-wrap source-name)
					   "could not be resolved (see "
					   "`org-babel-noweb-error-langs')"))
			    "")))
		       "[\n\r]") (concat "\n" prefix))))))
      (funcall nb-add (buffer-substring index (point-max))))
    new-body))

(defun org-babel-script-escape (str &optional force)
  "Safely convert tables into elisp lists."
  (let (in-single in-double out)
    ((lambda (escaped) (condition-case nil (org-babel-read escaped) (error escaped)))
     (if (or force
	     (and (stringp str)
		  (> (length str) 2)
		  (or (and (string-equal "[" (substring str 0 1))
			   (string-equal "]" (substring str -1)))
		      (and (string-equal "{" (substring str 0 1))
			   (string-equal "}" (substring str -1)))
		      (and (string-equal "(" (substring str 0 1))
			   (string-equal ")" (substring str -1))))))
	 (org-babel-read
	  (concat
	   "'"
	   (progn
	     (mapc
	      (lambda (ch)
		(setq
		 out
		 (case ch
		   (91 (if (or in-double in-single) ; [
			   (cons 91 out)
			 (cons 40 out)))
		   (93 (if (or in-double in-single) ; ]
			   (cons 93 out)
			 (cons 41 out)))
		   (123 (if (or in-double in-single) ; {
			    (cons 123 out)
			  (cons 40 out)))
		   (125 (if (or in-double in-single) ; }
			    (cons 125 out)
			  (cons 41 out)))
		   (44 (if (or in-double in-single) ; ,
			   (cons 44 out) (cons 32 out)))
		   (39 (if in-double	; '
			   (cons 39 out)
			 (setq in-single (not in-single)) (cons 34 out)))
		   (34 (if in-single	; "
			   (append (list 34 32) out)
			 (setq in-double (not in-double)) (cons 34 out)))
		   (t  (cons ch out)))))
	      (string-to-list str))
	     (apply #'string (reverse out)))))
       str))))

(defun org-babel-read (cell &optional inhibit-lisp-eval)
  "Convert the string value of CELL to a number if appropriate.
Otherwise if cell looks like lisp (meaning it starts with a
\"(\", \"'\", \"`\" or a \"[\") then read it as lisp, otherwise
return it unmodified as a string.  Optional argument NO-LISP-EVAL
inhibits lisp evaluation for situations in which is it not
appropriate."
  (if (and (stringp cell) (not (equal cell "")))
      (or (org-babel-number-p cell)
          (if (and (not inhibit-lisp-eval)
		   (member (substring cell 0 1) '("(" "'" "`" "[")))
              (eval (read cell))
            (if (string= (substring cell 0 1) "\"")
		(read cell)
	      (progn (set-text-properties 0 (length cell) nil cell) cell))))
    cell))

(defun org-babel-number-p (string)
  "If STRING represents a number return its value."
  (if (and (string-match "^-?[0-9]*\\.?[0-9]*$" string)
           (= (length (substring string (match-beginning 0)
				 (match-end 0)))
	      (length string)))
      (string-to-number string)))

(defun org-babel-import-elisp-from-file (file-name &optional separator)
  "Read the results located at FILE-NAME into an elisp table.
If the table is trivial, then return it as a scalar."
  (let (result)
    (save-window-excursion
      (with-temp-buffer
	(condition-case err
	    (progn
	      (org-table-import file-name separator)
	      (delete-file file-name)
	      (setq result (mapcar (lambda (row)
				     (mapcar #'org-babel-string-read row))
				   (org-table-to-lisp))))
	  (error (message "Error reading results: %s" err) nil)))
      (if (null (cdr result)) ;; if result is trivial vector, then scalarize it
	  (if (consp (car result))
	      (if (null (cdr (car result)))
		  (caar result)
		result)
	    (car result))
	result))))

(defun org-babel-string-read (cell)
  "Strip nested \"s from around strings."
  (org-babel-read (or (and (stringp cell)
                           (string-match "\\\"\\(.+\\)\\\"" cell)
                           (match-string 1 cell))
                      cell) t))

(defun org-babel-reverse-string (string)
  "Return the reverse of STRING."
  (apply 'string (reverse (string-to-list string))))

(defun org-babel-chomp (string &optional regexp)
  "Strip trailing spaces and carriage returns from STRING.
Default regexp used is \"[ \f\t\n\r\v]\" but can be
overwritten by specifying a regexp as a second argument."
  (let ((regexp (or regexp "[ \f\t\n\r\v]")))
    (while (and (> (length string) 0)
                (string-match regexp (substring string -1)))
      (setq string (substring string 0 -1)))
    string))

(defun org-babel-trim (string &optional regexp)
  "Strip leading and trailing spaces and carriage returns from STRING.
Like `org-babel-chomp' only it runs on both the front and back
of the string."
  (org-babel-chomp (org-babel-reverse-string
                    (org-babel-chomp (org-babel-reverse-string string) regexp))
                   regexp))

(defvar org-babel-org-babel-call-process-region-original nil)
(defun org-babel-tramp-handle-call-process-region
  (start end program &optional delete buffer display &rest args)
  "Use Tramp to handle `call-process-region'.
Fixes a bug in `tramp-handle-call-process-region'."
  (if (and (featurep 'tramp) (file-remote-p default-directory))
      (let ((tmpfile (tramp-compat-make-temp-file "")))
	(write-region start end tmpfile)
	(when delete (delete-region start end))
	(unwind-protect
	    ;;	(apply 'call-process program tmpfile buffer display args)
            ;; bug in tramp
	    (apply 'process-file program tmpfile buffer display args)
	  (delete-file tmpfile)))
    ;; org-babel-call-process-region-original is the original emacs
    ;; definition.  It is in scope from the let binding in
    ;; org-babel-execute-src-block
    (apply org-babel-call-process-region-original
           start end program delete buffer display args)))

(defun org-babel-local-file-name (file)
  "Return the local name component of FILE."
  (if (file-remote-p file)
      (let (localname)
	(with-parsed-tramp-file-name file nil
				     localname))
    file))

(defun org-babel-process-file-name (name &optional no-quote-p)
  "Prepare NAME to be used in an external process.
If NAME specifies a remote location, the remote portion of the
name is removed, since in that case the process will be executing
remotely.  The file name is then processed by `expand-file-name'.
Unless second argument NO-QUOTE-P is non-nil, the file name is
additionally processed by `shell-quote-argument'"
  ((lambda (f) (if no-quote-p f (shell-quote-argument f)))
   (expand-file-name (org-babel-local-file-name name))))

(defvar org-babel-temporary-directory)
(unless (or noninteractive (boundp 'org-babel-temporary-directory))
  (defvar org-babel-temporary-directory
    (or (and (boundp 'org-babel-temporary-directory)
	     (file-exists-p org-babel-temporary-directory)
	     org-babel-temporary-directory)
	(make-temp-file "babel-" t))
    "Directory to hold temporary files created to execute code blocks.
Used by `org-babel-temp-file'.  This directory will be removed on
Emacs shutdown."))

(defmacro org-babel-result-cond (result-params scalar-form &rest table-forms)
  "Call the code to parse raw string results according to RESULT-PARAMS."
  (declare (indent 1))
  `(unless (member "none" ,result-params)
     (if (or (member "scalar" ,result-params)
	     (member "verbatim" ,result-params)
	     (member "html" ,result-params)
	     (member "code" ,result-params)
	     (member "pp" ,result-params)
	     (and (member "output" ,result-params)
		  (not (member "table" ,result-params))))
	 ,scalar-form
       ,@table-forms)))

(defun org-babel-temp-file (prefix &optional suffix)
  "Create a temporary file in the `org-babel-temporary-directory'.
Passes PREFIX and SUFFIX directly to `make-temp-file' with the
value of `temporary-file-directory' temporarily set to the value
of `org-babel-temporary-directory'."
  (if (file-remote-p default-directory)
      (make-temp-file
       (concat (file-remote-p default-directory)
	       (expand-file-name
		prefix temporary-file-directory)
	       nil suffix))
    (let ((temporary-file-directory
	   (or (and (boundp 'org-babel-temporary-directory)
		    (file-exists-p org-babel-temporary-directory)
		    org-babel-temporary-directory)
	       temporary-file-directory)))
      (make-temp-file prefix nil suffix))))

(defun org-babel-remove-temporary-directory ()
  "Remove `org-babel-temporary-directory' on Emacs shutdown."
  (when (and (boundp 'org-babel-temporary-directory)
	     (file-exists-p org-babel-temporary-directory))
    ;; taken from `delete-directory' in files.el
    (condition-case nil
	(progn
	  (mapc (lambda (file)
		  ;; This test is equivalent to
		  ;; (and (file-directory-p fn) (not (file-symlink-p fn)))
		  ;; but more efficient
		  (if (eq t (car (file-attributes file)))
		      (delete-directory file)
		    (delete-file file)))
		;; We do not want to delete "." and "..".
		(directory-files org-babel-temporary-directory 'full
				 "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*"))
	  (delete-directory org-babel-temporary-directory))
      (error
       (message "Failed to remove temporary Org-babel directory %s"
		(if (boundp 'org-babel-temporary-directory)
		    org-babel-temporary-directory
		  "[directory not defined]"))))))

(add-hook 'kill-emacs-hook 'org-babel-remove-temporary-directory)

;;; ob-lob.el

(declare-function org-babel-in-example-or-verbatim "ob-exp" nil)

(defvar org-babel-library-of-babel nil
  "Library of source-code blocks.
This is an association list.  Populate the library by adding
files to `org-babel-lob-files'.")

(defcustom org-babel-lob-files '()
  "Files used to populate the `org-babel-library-of-babel'.
To add files to this list use the `org-babel-lob-ingest' command."
  :group 'org-babel
  :version "24.1"
  :type 'list)

(defvar org-babel-default-lob-header-args '((:exports . "results"))
  "Default header arguments to use when exporting #+lob/call lines.")

(defun org-babel-lob-ingest (&optional file)
  "Add all named source-blocks defined in FILE to
`org-babel-library-of-babel'."
  (interactive "fFile: ")
  (let ((lob-ingest-count 0))
    (org-babel-map-src-blocks file
      (let* ((info (org-babel-get-src-block-info 'light))
	     (source-name (nth 4 info)))
	(when source-name
	  (setq source-name (intern source-name)
		org-babel-library-of-babel
		(cons (cons source-name info)
		      (assq-delete-all source-name org-babel-library-of-babel))
		lob-ingest-count (1+ lob-ingest-count)))))
    (message "%d src block%s added to Library of Babel"
	     lob-ingest-count (if (> lob-ingest-count 1) "s" ""))
    lob-ingest-count))

(defconst org-babel-block-lob-one-liner-regexp
  (concat
   "^\\([ \t]*?\\)#\\+call:[ \t]+\\([^\(\)\n]+?\\)\\(\\[\\(.*\\)\\]\\|\\(\\)\\)"
   "\(\\([^\n]*?\\)\)\\(\\[.+\\]\\|\\)[ \t]*\\(\\([^\n]*\\)\\)?")
  "Regexp to match non-inline calls to predefined source block functions.")

(defconst org-babel-inline-lob-one-liner-regexp
  (concat
   "\\([^\n]*?\\)call_\\([^\(\)\n]+?\\)\\(\\[\\(.*?\\)\\]\\|\\(\\)\\)"
   "\(\\([^\n]*?\\)\)\\(\\[\\(.*?\\)\\]\\)?")
  "Regexp to match inline calls to predefined source block functions.")

(defconst org-babel-lob-one-liner-regexp
  (concat "\\(" org-babel-block-lob-one-liner-regexp
	  "\\|" org-babel-inline-lob-one-liner-regexp "\\)")
  "Regexp to match calls to predefined source block functions.")

;; functions for executing lob one-liners

;;;###autoload
(defun org-babel-lob-execute-maybe ()
  "Execute a Library of Babel source block, if appropriate.
Detect if this is context for a Library Of Babel source block and
if so then run the appropriate source block from the Library."
  (interactive)
  (let ((info (org-babel-lob-get-info)))
    (if (and (nth 0 info) (not (org-babel-in-example-or-verbatim)))
	(progn (org-babel-lob-execute info) t)
      nil)))

;;;###autoload
(defun org-babel-lob-get-info ()
  "Return a Library of Babel function call as a string."
  (let ((case-fold-search t)
	(nonempty (lambda (a b)
		    (let ((it (match-string a)))
		      (if (= (length it) 0) (match-string b) it)))))
    (save-excursion
      (beginning-of-line 1)
      (when (looking-at org-babel-lob-one-liner-regexp)
	(append
	 (mapcar #'org-no-properties
		 (list
		  (format "%s%s(%s)%s"
			  (funcall nonempty 3 12)
			  (if (not (= 0 (length (funcall nonempty 5 14))))
			      (concat "[" (funcall nonempty 5 14) "]") "")
			  (or (funcall nonempty 7 16) "")
			  (or (funcall nonempty 8 19) ""))
		  (funcall nonempty 9 18)))
	 (list (length (if (= (length (match-string 12)) 0)
			   (match-string 2) (match-string 11)))))))))

(defun org-babel-lob-execute (info)
  "Execute the lob call specified by INFO."
  (let* ((mkinfo (lambda (p) (list "emacs-lisp" "results" p nil nil (nth 2 info))))
	 (pre-params (org-babel-merge-params
		      org-babel-default-header-args
		      (org-babel-params-from-properties)
		      (org-babel-parse-header-arguments
		       (org-no-properties
			(concat ":var results="
				(mapconcat #'identity (butlast info) " "))))))
	 (pre-info (funcall mkinfo pre-params))
	 (cache? (and (cdr (assoc :cache pre-params))
		      (string= "yes" (cdr (assoc :cache pre-params)))))
	 (new-hash (when cache? (org-babel-sha1-hash pre-info)))
	 (old-hash (when cache? (org-babel-current-result-hash))))
    (if (and cache? (equal new-hash old-hash))
	(save-excursion (goto-char (org-babel-where-is-src-block-result))
			(forward-line 1)
			(message "%S" (org-babel-read-result)))
      (prog1 (org-babel-execute-src-block
	      nil (funcall mkinfo (org-babel-process-params pre-params)))
	;; update the hash
	(when new-hash (org-babel-set-current-result-hash new-hash))))))

(declare-function org-link-escape "org" (text &optional table))
(declare-function org-heading-components "org" ())
(declare-function org-back-to-heading "org" (invisible-ok))
(declare-function org-fill-template "org" (template alist))
(declare-function org-babel-update-block-body "org" (new-body))
(declare-function make-directory "files" (dir &optional parents))

(defcustom org-babel-tangle-lang-exts
  '(("emacs-lisp" . "el"))
  "Alist mapping languages to their file extensions.
The key is the language name, the value is the string that should
be inserted as the extension commonly used to identify files
written in this language.  If no entry is found in this list,
then the name of the language is used."
  :group 'org-babel-tangle
  :version "24.1"
  :type '(repeat
	  (cons
	   (string "Language name")
	   (string "File Extension"))))

(defcustom org-babel-post-tangle-hook nil
  "Hook run in code files tangled by `org-babel-tangle'."
  :group 'org-babel
  :version "24.1"
  :type 'hook)

(defcustom org-babel-pre-tangle-hook '(save-buffer)
  "Hook run at the beginning of `org-babel-tangle'."
  :group 'org-babel
  :version "24.1"
  :type 'hook)

(defcustom org-babel-tangle-body-hook nil
  "Hook run over the contents of each code block body."
  :group 'org-babel
  :version "24.1"
  :type 'hook)

(defcustom org-babel-tangle-comment-format-beg "[[%link][%source-name]]"
  "Format of inserted comments in tangled code files.
The following format strings can be used to insert special
information into the output using `org-fill-template'.
%start-line --- the line number at the start of the code block
%file --------- the file from which the code block was tangled
%link --------- Org-mode style link to the code block
%source-name -- name of the code block

Whether or not comments are inserted during tangling is
controlled by the :comments header argument."
  :group 'org-babel
  :version "24.1"
  :type 'string)

(defcustom org-babel-tangle-comment-format-end "%source-name ends here"
  "Format of inserted comments in tangled code files.
The following format strings can be used to insert special
information into the output using `org-fill-template'.
%start-line --- the line number at the start of the code block
%file --------- the file from which the code block was tangled
%link --------- Org-mode style link to the code block
%source-name -- name of the code block

Whether or not comments are inserted during tangling is
controlled by the :comments header argument."
  :group 'org-babel
  :version "24.1"
  :type 'string)

(defcustom org-babel-process-comment-text #'org-babel-trim
  "Function called to process raw Org-mode text collected to be
inserted as comments in tangled source-code files.  The function
should take a single string argument and return a string
result.  The default value is `org-babel-trim'."
  :group 'org-babel
  :version "24.1"
  :type 'function)

(defun org-babel-find-file-noselect-refresh (file)
  "Find file ensuring that the latest changes on disk are
represented in the file."
  (find-file-noselect file)
  (with-current-buffer (get-file-buffer file)
    (revert-buffer t t t)))

(defmacro org-babel-with-temp-filebuffer (file &rest body)
  "Open FILE into a temporary buffer execute BODY there like
`progn', then kill the FILE buffer returning the result of
evaluating BODY."
  (declare (indent 1))
  (let ((temp-path (make-symbol "temp-path"))
	(temp-result (make-symbol "temp-result"))
	(temp-file (make-symbol "temp-file"))
	(visited-p (make-symbol "visited-p")))
    `(let* ((,temp-path ,file)
	    (,visited-p (get-file-buffer ,temp-path))
	    ,temp-result ,temp-file)
       (org-babel-find-file-noselect-refresh ,temp-path)
       (setf ,temp-file (get-file-buffer ,temp-path))
       (with-current-buffer ,temp-file
	 (setf ,temp-result (progn ,@body)))
       (unless ,visited-p (kill-buffer ,temp-file))
       ,temp-result)))
(def-edebug-spec org-babel-with-temp-filebuffer (form body))

;;;###autoload
(defun org-babel-load-file (file &optional compile)
  "Load Emacs Lisp source code blocks in the Org-mode FILE.
This function exports the source code using `org-babel-tangle'
and then loads the resulting file using `load-file'.  With prefix
arg (noninteractively: 2nd arg) COMPILE the tangled Emacs Lisp
file to byte-code before it is loaded."
  (interactive "fFile to load: \nP")
  (let* ((age (lambda (file)
		(float-time
		 (time-subtract (current-time)
				(nth 5 (or (file-attributes (file-truename file))
					   (file-attributes file)))))))
	 (base-name (file-name-sans-extension file))
	 (exported-file (concat base-name ".el")))
    ;; tangle if the org-mode file is newer than the elisp file
    (unless (and (file-exists-p exported-file)
		 (> (funcall age file) (funcall age exported-file)))
      (org-babel-tangle-file file exported-file "emacs-lisp"))
    (message "%s %s"
	     (if compile
		 (progn (byte-compile-file exported-file 'load)
			"Compiled and loaded")
	       (progn (load-file exported-file) "Loaded"))
	     exported-file)))

;;;###autoload
(defun org-babel-tangle-file (file &optional target-file lang)
  "Extract the bodies of source code blocks in FILE.
Source code blocks are extracted with `org-babel-tangle'.
Optional argument TARGET-FILE can be used to specify a default
export file for all source blocks.  Optional argument LANG can be
used to limit the exported source code blocks by language."
  (interactive "fFile to tangle: \nP")
  (let ((visited-p (get-file-buffer (expand-file-name file)))
	to-be-removed)
    (save-window-excursion
      (find-file file)
      (setq to-be-removed (current-buffer))
      (org-babel-tangle nil target-file lang))
    (unless visited-p
      (kill-buffer to-be-removed))))

(defun org-babel-tangle-publish (_ filename pub-dir)
  "Tangle FILENAME and place the results in PUB-DIR."
  (mapc (lambda (el) (copy-file el pub-dir t)) (org-babel-tangle-file filename)))

;;;###autoload
(defun org-babel-tangle (&optional only-this-block target-file lang)
  "Write code blocks to source-specific files.
Extract the bodies of all source code blocks from the current
file into their own source-specific files.  Optional argument
TARGET-FILE can be used to specify a default export file for all
source blocks.  Optional argument LANG can be used to limit the
exported source code blocks by language."
  (interactive "P")
  (run-hooks 'org-babel-pre-tangle-hook)
  ;; possibly restrict the buffer to the current code block
  (save-restriction
    (when only-this-block
      (unless (org-babel-where-is-src-block-head)
	(error "Point is not currently inside of a code block"))
      (save-match-data
	(unless (or (cdr (assoc :tangle (nth 2 (org-babel-get-src-block-info))))
		    target-file)
	  (setq target-file
		(read-from-minibuffer "Tangle to: " (buffer-file-name)))))
      (narrow-to-region (match-beginning 0) (match-end 0)))
    (save-excursion
      (let ((block-counter 0)
	    (org-babel-default-header-args
	     (if target-file
		 (org-babel-merge-params org-babel-default-header-args
					 (list (cons :tangle target-file)))
	       org-babel-default-header-args))
	    path-collector)
	(mapc ;; map over all languages
	 (lambda (by-lang)
	   (let* ((lang (car by-lang))
		  (specs (cdr by-lang))
		  (ext (or (cdr (assoc lang org-babel-tangle-lang-exts)) lang))
		  (lang-f (intern
			   (concat
			    (or (and (cdr (assoc lang org-src-lang-modes))
				     (symbol-name
				      (cdr (assoc lang org-src-lang-modes))))
				lang)
			    "-mode")))
		  she-banged)
	     (mapc
	      (lambda (spec)
		(let ((get-spec (lambda (name) (cdr (assoc name (nth 4 spec))))))
		  (let* ((tangle (funcall get-spec :tangle))
			 (she-bang ((lambda (sheb) (when (> (length sheb) 0) sheb))
				    (funcall get-spec :shebang)))
			 (base-name (cond
				     ((string= "yes" tangle)
				      (file-name-sans-extension
				       (buffer-file-name)))
				     ((string= "no" tangle) nil)
				     ((> (length tangle) 0) tangle)))
			 (file-name (when base-name
				      ;; decide if we want to add ext to base-name
				      (if (and ext (string= "yes" tangle))
					  (concat base-name "." ext) base-name))))
		    (when file-name
		      ;; possibly create the parent directories for file
		      (when ((lambda (m) (and m (not (string= m "no"))))
			     (funcall get-spec :mkdirp))
			(make-directory (file-name-directory file-name) 'parents))
		      ;; delete any old versions of file
		      (when (and (file-exists-p file-name)
				 (not (member file-name path-collector)))
			(delete-file file-name))
		      ;; drop source-block to file
		      (with-temp-buffer
			(when (fboundp lang-f) (ignore-errors (funcall lang-f)))
			(when (and she-bang (not (member file-name she-banged)))
			  (insert (concat she-bang "\n"))
			  (setq she-banged (cons file-name she-banged)))
			(org-babel-spec-to-string spec)
			;; We avoid append-to-file as it does not work with tramp.
			(let ((content (buffer-string)))
			  (with-temp-buffer
			    (if (file-exists-p file-name)
				(insert-file-contents file-name))
			    (goto-char (point-max))
			    (insert content)
			    (write-region nil nil file-name))))
		      (set-file-modes
		       file-name
		       ;; never writable (don't accidentally edit tangled files)
		       (if she-bang
			   #o555 ;; files with she-bangs should be executable
			 #o444)) ;; those without should not
		      ;; update counter
		      (setq block-counter (+ 1 block-counter))
		      (add-to-list 'path-collector file-name)))))
	      specs)))
	 (org-babel-tangle-collect-blocks lang))
	(message "Tangled %d code block%s from %s" block-counter
		 (if (= block-counter 1) "" "s")
		 (file-name-nondirectory
		  (buffer-file-name (or (buffer-base-buffer) (current-buffer)))))
	;; run `org-babel-post-tangle-hook' in all tangled files
	(when org-babel-post-tangle-hook
	  (mapc
	   (lambda (file)
	     (org-babel-with-temp-filebuffer file
	       (run-hooks 'org-babel-post-tangle-hook)))
	   path-collector))
	path-collector))))

(defun org-babel-tangle-clean ()
  "Remove comments inserted by `org-babel-tangle'.
Call this function inside of a source-code file generated by
`org-babel-tangle' to remove all comments inserted automatically
by `org-babel-tangle'.  Warning, this comment removes any lines
containing constructs which resemble org-mode file links or noweb
references."
  (interactive)
  (goto-char (point-min))
  (while (or (re-search-forward "\\[\\[file:.*\\]\\[.*\\]\\]" nil t)
             (re-search-forward (org-babel-noweb-wrap) nil t))
    (delete-region (save-excursion (beginning-of-line 1) (point))
                   (save-excursion (end-of-line 1) (forward-char 1) (point)))))

(defvar org-stored-links)
(defvar org-bracket-link-regexp)
(defun org-babel-spec-to-string (spec)
  "Insert SPEC into the current file.
Insert the source-code specified by SPEC into the current
source code file.  This function uses `comment-region' which
assumes that the appropriate major-mode is set.  SPEC has the
form

  (start-line file link source-name params body comment)"
  (let* ((start-line (nth 0 spec))
	 (file (nth 1 spec))
	 (link (nth 2 spec))
	 (source-name (nth 3 spec))
	 (body (nth 5 spec))
	 (comment (nth 6 spec))
	 (comments (cdr (assoc :comments (nth 4 spec))))
	 (padline (not (string= "no" (cdr (assoc :padline (nth 4 spec))))))
	 (link-p (or (string= comments "both") (string= comments "link")
		     (string= comments "yes") (string= comments "noweb")))
	 (link-data (mapcar (lambda (el)
			      (cons (symbol-name el)
				    ((lambda (le)
				       (if (stringp le) le (format "%S" le)))
				     (eval el))))
			    '(start-line file link source-name)))
	 (insert-comment (lambda (text)
			   (when (and comments (not (string= comments "no"))
				      (> (length text) 0))
			     (when padline (insert "\n"))
			     (comment-region (point) (progn (insert text) (point)))
			     (end-of-line nil) (insert "\n")))))
    (when comment (funcall insert-comment comment))
    (when link-p
      (funcall
       insert-comment
       (org-fill-template org-babel-tangle-comment-format-beg link-data)))
    (when padline (insert "\n"))
    (insert
     (format
      "%s\n"
      (replace-regexp-in-string
       "^," ""
       (org-babel-trim body (if org-src-preserve-indentation "[\f\n\r\v]")))))
    (when link-p
      (funcall
       insert-comment
       (org-fill-template org-babel-tangle-comment-format-end link-data)))))

(defun org-babel-tangle-collect-blocks (&optional language)
  "Collect source blocks in the current Org-mode file.
Return an association list of source-code block specifications of
the form used by `org-babel-spec-to-string' grouped by language.
Optional argument LANG can be used to limit the collected source
code blocks by language."
  (let ((block-counter 1) (current-heading "") blocks)
    (org-babel-map-src-blocks (buffer-file-name)
      ((lambda (new-heading)
	 (if (not (string= new-heading current-heading))
	     (progn
	       (setq block-counter 1)
	       (setq current-heading new-heading))
	   (setq block-counter (+ 1 block-counter))))
       (replace-regexp-in-string "[ \t]" "-"
				 (condition-case nil
				     (or (nth 4 (org-heading-components))
					 "(dummy for heading without text)")
				   (error (buffer-file-name)))))
      (let* ((start-line (save-restriction (widen)
					   (+ 1 (line-number-at-pos (point)))))
	     (file (buffer-file-name))
	     (info (org-babel-get-src-block-info 'light))
	     (src-lang (nth 0 info)))
        (unless (string= (cdr (assoc :tangle (nth 2 info))) "no")
          (unless (and language (not (string= language src-lang)))
	    (let* ((info (org-babel-get-src-block-info))
		   (params (nth 2 info))
		   (link ((lambda (link)
			    (and (string-match org-bracket-link-regexp link)
				 (match-string 1 link)))
			  (org-no-properties
			   (org-store-link nil))))
		   (source-name
		    (intern (or (nth 4 info)
				(format "%s:%d"
					current-heading block-counter))))
		   (expand-cmd
		    (intern (concat "org-babel-expand-body:" src-lang)))
		   (assignments-cmd
		    (intern (concat "org-babel-variable-assignments:" src-lang)))
		   (body
		    ((lambda (body) ;; run the tangle-body-hook
		       (with-temp-buffer
			 (insert body)
			 (run-hooks 'org-babel-tangle-body-hook)
			 (buffer-string)))
		     ((lambda (body) ;; expand the body in language specific manner
			(if (assoc :no-expand params)
			    body
			  (if (fboundp expand-cmd)
			      (funcall expand-cmd body params)
			    (org-babel-expand-body:generic
			     body params
			     (and (fboundp assignments-cmd)
				  (funcall assignments-cmd params))))))
		      (if (org-babel-noweb-p params :tangle)
			  (org-babel-expand-noweb-references info)
			(nth 1 info)))))
		   (comment
		    (when (or (string= "both" (cdr (assoc :comments params)))
			      (string= "org" (cdr (assoc :comments params))))
		      ;; from the previous heading or code-block end
		      (funcall
		       org-babel-process-comment-text
		       (buffer-substring
			(max (condition-case nil
				 (save-excursion
				   (org-back-to-heading t)  ; sets match data
				   (match-end 0))
			       (error (point-min)))
			     (save-excursion
			       (if (re-search-backward
				    org-babel-src-block-regexp nil t)
				   (match-end 0)
				 (point-min))))
			(point)))))
		   by-lang)
	      ;; add the spec for this block to blocks under it's language
	      (setq by-lang (cdr (assoc src-lang blocks)))
	      (setq blocks (delq (assoc src-lang blocks) blocks))
	      (setq blocks (cons
			    (cons src-lang
				  (cons (list start-line file link
					      source-name params body comment)
					by-lang)) blocks)))))))
    ;; ensure blocks in the correct order
    (setq blocks
          (mapcar
	   (lambda (by-lang) (cons (car by-lang) (reverse (cdr by-lang))))
	   blocks))
    blocks))

(defun org-babel-tangle-comment-links ( &optional info)
  "Return a list of begin and end link comments for the code block at point."
  (let* ((start-line (org-babel-where-is-src-block-head))
	 (file (buffer-file-name))
	 (link (org-link-escape (progn (call-interactively 'org-store-link)
				       (org-no-properties
					(car (pop org-stored-links))))))
	 (source-name (nth 4 (or info (org-babel-get-src-block-info 'light))))
	 (link-data (mapcar (lambda (el)
			      (cons (symbol-name el)
				    ((lambda (le)
				       (if (stringp le) le (format "%S" le)))
				     (eval el))))
			    '(start-line file link source-name))))
    (list (org-fill-template org-babel-tangle-comment-format-beg link-data)
	  (org-fill-template org-babel-tangle-comment-format-end link-data))))

;; de-tangling functions
(defvar org-bracket-link-analytic-regexp)
(defun org-babel-detangle (&optional source-code-file)
  "Propagate changes in source file back original to Org-mode file.
This requires that code blocks were tangled with link comments
which enable the original code blocks to be found."
  (interactive)
  (save-excursion
    (when source-code-file (find-file source-code-file))
    (goto-char (point-min))
    (let ((counter 0) new-body end)
      (while (re-search-forward org-bracket-link-analytic-regexp nil t)
        (when (re-search-forward
	       (concat " " (regexp-quote (match-string 5)) " ends here"))
          (setq end (match-end 0))
          (forward-line -1)
          (save-excursion
	    (when (setq new-body (org-babel-tangle-jump-to-org))
	      (org-babel-update-block-body new-body)))
          (setq counter (+ 1 counter)))
        (goto-char end))
      (prog1 counter (message "Detangled %d code blocks" counter)))))

(defun org-babel-tangle-jump-to-org ()
  "Jump from a tangled code file to the related Org-mode file."
  (interactive)
  (let ((mid (point))
	start end done
        target-buffer target-char link path block-name body)
    (save-window-excursion
      (save-excursion
	(while (and (re-search-backward org-bracket-link-analytic-regexp nil t)
		    (not ; ever wider searches until matching block comments
		     (and (setq start (point-at-eol))
			  (setq link (match-string 0))
			  (setq path (match-string 3))
			  (setq block-name (match-string 5))
			  (save-excursion
			    (save-match-data
			      (re-search-forward
			       (concat " " (regexp-quote block-name)
				       " ends here") nil t)
			      (setq end (point-at-bol))))))))
	(unless (and start (< start mid) (< mid end))
	  (error "Not in tangled code"))
        (setq body (org-babel-trim (buffer-substring start end))))
      (when (string-match "::" path)
        (setq path (substring path 0 (match-beginning 0))))
      (find-file path) (setq target-buffer (current-buffer))
      (goto-char start) (org-open-link-from-string link)
      (if (string-match "[^ \t\n\r]:\\([[:digit:]]+\\)" block-name)
          (org-babel-next-src-block
           (string-to-number (match-string 1 block-name)))
        (org-babel-goto-named-src-block block-name))
      (setq target-char (point)))
    (pop-to-buffer target-buffer)
    (prog1 body (goto-char target-char))))

;;; ob-comint.el

(declare-function with-parsed-tramp-file-name "tramp" (filename var &rest body))
(declare-function tramp-flush-directory-property "tramp" (vec directory))

(defun org-babel-comint-buffer-livep (buffer)
  "Check if BUFFER is a comint buffer with a live process."
  (let ((buffer (if buffer (get-buffer buffer))))
    (and buffer (buffer-live-p buffer) (get-buffer-process buffer) buffer)))

(defmacro org-babel-comint-in-buffer (buffer &rest body)
  "Check BUFFER and execute BODY.
BUFFER is checked with `org-babel-comint-buffer-livep'.  BODY is
executed inside the protection of `save-excursion' and
`save-match-data'."
  (declare (indent 1))
  `(save-excursion
     (save-match-data
       (unless (org-babel-comint-buffer-livep ,buffer)
         (error "Buffer %s does not exist or has no process" ,buffer))
       (set-buffer ,buffer)
       ,@body)))
(def-edebug-spec org-babel-comint-in-buffer (form body))

(defmacro org-babel-comint-with-output (meta &rest body)
  "Evaluate BODY in BUFFER and return process output.
Will wait until EOE-INDICATOR appears in the output, then return
all process output.  If REMOVE-ECHO and FULL-BODY are present and
non-nil, then strip echo'd body from the returned output.  META
should be a list containing the following where the last two
elements are optional.

 (BUFFER EOE-INDICATOR REMOVE-ECHO FULL-BODY)

This macro ensures that the filter is removed in case of an error
or user `keyboard-quit' during execution of body."
  (declare (indent 1))
  (let ((buffer (car meta))
	(eoe-indicator (cadr meta))
	(remove-echo (cadr (cdr meta)))
	(full-body (cadr (cdr (cdr meta)))))
    `(org-babel-comint-in-buffer ,buffer
       (let ((string-buffer "") dangling-text raw)
	 ;; setup filter
	 (setq comint-output-filter-functions
	       (cons (lambda (text) (setq string-buffer (concat string-buffer text)))
		     comint-output-filter-functions))
	 (unwind-protect
	     (progn
	       ;; got located, and save dangling text
	       (goto-char (process-mark (get-buffer-process (current-buffer))))
	       (let ((start (point))
		     (end (point-max)))
		 (setq dangling-text (buffer-substring start end))
		 (delete-region start end))
	       ;; pass FULL-BODY to process
	       ,@body
	       ;; wait for end-of-evaluation indicator
	       (while (progn
			(goto-char comint-last-input-end)
			(not (save-excursion
			       (and (re-search-forward
				     (regexp-quote ,eoe-indicator) nil t)
				    (re-search-forward
				     comint-prompt-regexp nil t)))))
		 (accept-process-output (get-buffer-process (current-buffer)))
		 ;; thought the following this would allow async
		 ;; background running, but I was wrong...
		 ;; (run-with-timer .5 .5 'accept-process-output
		 ;; 		 (get-buffer-process (current-buffer)))
		 )
	       ;; replace cut dangling text
	       (goto-char (process-mark (get-buffer-process (current-buffer))))
	       (insert dangling-text))
	   ;; remove filter
	   (setq comint-output-filter-functions
		 (cdr comint-output-filter-functions)))
	 ;; remove echo'd FULL-BODY from input
	 (if (and ,remove-echo ,full-body
		  (string-match
		   (replace-regexp-in-string
		    "\n" "[\r\n]+" (regexp-quote (or ,full-body "")))
		   string-buffer))
	     (setq raw (substring string-buffer (match-end 0))))
	 (split-string string-buffer comint-prompt-regexp)))))
(def-edebug-spec org-babel-comint-with-output (form body))

(defun org-babel-comint-input-command (buffer cmd)
  "Pass CMD to BUFFER.
The input will not be echoed."
  (org-babel-comint-in-buffer buffer
    (goto-char (process-mark (get-buffer-process buffer)))
    (insert cmd)
    (comint-send-input)
    (org-babel-comint-wait-for-output buffer)))

(defun org-babel-comint-wait-for-output (buffer)
  "Wait until output arrives from BUFFER.
Note: this is only safe when waiting for the result of a single
statement (not large blocks of code)."
  (org-babel-comint-in-buffer buffer
    (while (progn
             (goto-char comint-last-input-end)
             (not (and (re-search-forward comint-prompt-regexp nil t)
                       (goto-char (match-beginning 0))
                       (string= (face-name (face-at-point))
                                "comint-highlight-prompt"))))
      (accept-process-output (get-buffer-process buffer)))))

(defun org-babel-comint-eval-invisibly-and-wait-for-file
  (buffer file string &optional period)
  "Evaluate STRING in BUFFER invisibly.
Don't return until FILE exists.  Code in STRING must ensure that
FILE exists at end of evaluation."
  (unless (org-babel-comint-buffer-livep buffer)
    (error "Buffer %s does not exist or has no process" buffer))
  (if (file-exists-p file) (delete-file file))
  (process-send-string
   (get-buffer-process buffer)
   (if (string-match "\n$" string) string (concat string "\n")))
  ;; From Tramp 2.1.19 the following cache flush is not necessary
  (if (file-remote-p default-directory)
      (let (v)
	(with-parsed-tramp-file-name default-directory nil
				     (tramp-flush-directory-property v ""))))
  (while (not (file-exists-p file)) (sit-for (or period 0.25))))

;;; ob-ref

(declare-function org-remove-if-not "org" (predicate seq))
(declare-function org-at-table-p "org" (&optional table-type))
(declare-function org-count "org" (CL-ITEM CL-SEQ))
(declare-function org-at-item-p "org-list" ())
(declare-function org-narrow-to-subtree "org" ())
(declare-function org-id-find-id-in-file "org-id" (id file &optional markerp))
(declare-function org-id-find-id-file "org-id" (id))
(declare-function org-show-context "org" (&optional key))
(declare-function org-pop-to-buffer-same-window
		  "org-compat" (&optional buffer-or-name norecord label))

(defvar org-babel-ref-split-regexp
  "[ \f\t\n\r\v]*\\(.+?\\)[ \f\t\n\r\v]*=[ \f\t\n\r\v]*\\(.+\\)[ \f\t\n\r\v]*")

(defvar org-babel-update-intermediate nil
  "Update the in-buffer results of code blocks executed to resolve references.")

(defun org-babel-ref-parse (assignment)
  "Parse a variable ASSIGNMENT in a header argument.
If the right hand side of the assignment has a literal value
return that value, otherwise interpret as a reference to an
external resource and find its value using
`org-babel-ref-resolve'.  Return a list with two elements.  The
first element of the list will be the name of the variable, and
the second will be an emacs-lisp representation of the value of
the variable."
  (when (string-match org-babel-ref-split-regexp assignment)
    (let ((var (match-string 1 assignment))
	  (ref (match-string 2 assignment)))
      (cons (intern var)
	    (let ((out (org-babel-read ref)))
	      (if (equal out ref)
		  (if (string-match "^\".*\"$" ref)
		      (read ref)
		    (org-babel-ref-resolve ref))
		out))))))

(defun org-babel-ref-goto-headline-id (id)
  (goto-char (point-min))
  (let ((rx (regexp-quote id)))
    (or (re-search-forward
	 (concat "^[ \t]*:CUSTOM_ID:[ \t]+" rx "[ \t]*$") nil t)
	(let* ((file (org-id-find-id-file id))
	       (m (when file (org-id-find-id-in-file id file 'marker))))
	  (when (and file m)
	    (message "file:%S" file)
	    (org-pop-to-buffer-same-window (marker-buffer m))
	    (goto-char m)
	    (move-marker m nil)
	    (org-show-context)
	    t)))))

(defun org-babel-ref-headline-body ()
  (save-restriction
    (org-narrow-to-subtree)
    (buffer-substring
     (save-excursion (goto-char (point-min))
		     (forward-line 1)
		     (when (looking-at "[ \t]*:PROPERTIES:")
		       (re-search-forward ":END:" nil)
		       (forward-char))
		     (point))
     (point-max))))

(defvar org-babel-library-of-babel)
(defun org-babel-ref-resolve (ref)
  "Resolve the reference REF and return its value."
  (save-window-excursion
    (save-excursion
      (let ((case-fold-search t)
	    type args new-refere new-header-args new-referent result
	    lob-info split-file split-ref index index-row index-col id)
	;; if ref is indexed grab the indices -- beware nested indices
	(when (and (string-match "\\[\\([^\\[]+\\)\\]$" ref)
		   (let ((str (substring ref 0 (match-beginning 0))))
		     (= (org-count ?( str) (org-count ?) str))))
	  (setq index (match-string 1 ref))
	  (setq ref (substring ref 0 (match-beginning 0))))
	;; assign any arguments to pass to source block
	(when (string-match
	       "^\\(.+?\\)\\(\\[\\(.*\\)\\]\\|\\(\\)\\)\(\\(.*\\)\)$" ref)
	  (setq new-refere      (match-string 1 ref))
	  (setq new-header-args (match-string 3 ref))
	  (setq new-referent    (match-string 5 ref))
	  (when (> (length new-refere) 0)
	    (when (> (length new-referent) 0)
	      (setq args (mapcar (lambda (ref) (cons :var ref))
				 (org-babel-ref-split-args new-referent))))
	    (when (> (length new-header-args) 0)
	      (setq args (append (org-babel-parse-header-arguments
				  new-header-args) args)))
	    (setq ref new-refere)))
	(when (string-match "^\\(.+\\):\\(.+\\)$" ref)
	  (setq split-file (match-string 1 ref))
	  (setq split-ref (match-string 2 ref))
	  (find-file split-file) (setq ref split-ref))
	(save-restriction
	  (widen)
	  (goto-char (point-min))
	  (if (let ((src-rx (org-babel-named-src-block-regexp-for-name ref))
		    (res-rx (org-babel-named-data-regexp-for-name ref)))
		;; goto ref in the current buffer
		(or
		 ;; check for code blocks
		 (re-search-forward src-rx nil t)
		 ;; check for named data
		 (re-search-forward res-rx nil t)
		 ;; check for local or global headlines by id
		 (setq id (org-babel-ref-goto-headline-id ref))
		 ;; check the Library of Babel
		 (setq lob-info (cdr (assoc (intern ref)
					    org-babel-library-of-babel)))))
	      (unless (or lob-info id) (goto-char (match-beginning 0)))
	    ;; ;; TODO: allow searching for names in other buffers
	    ;; (setq id-loc (org-id-find ref 'marker)
	    ;;       buffer (marker-buffer id-loc)
	    ;;       loc (marker-position id-loc))
	    ;; (move-marker id-loc nil)
	    (error "Reference '%s' not found in this buffer" ref))
	  (cond
	   (lob-info (setq type 'lob))
	   (id (setq type 'id))
	   ((and (looking-at org-babel-src-name-regexp)
		 (save-excursion
		   (forward-line 1)
		   (or (looking-at org-babel-src-block-regexp)
		       (looking-at org-babel-multi-line-header-regexp))))
	    (setq type 'source-block))
	   (t (while (not (setq type (org-babel-ref-at-ref-p)))
		(forward-line 1)
		(beginning-of-line)
		(if (or (= (point) (point-min)) (= (point) (point-max)))
		    (error "Reference not found")))))
	  (let ((params (append args '((:results . "silent")))))
	    (setq result
		  (case type
		    (results-line (org-babel-read-result))
		    (table        (org-babel-read-table))
		    (list         (org-babel-read-list))
		    (file         (org-babel-read-link))
		    (source-block (org-babel-execute-src-block
				   nil nil (if org-babel-update-intermediate
					       nil params)))
		    (lob          (org-babel-execute-src-block
				   nil lob-info params))
		    (id           (org-babel-ref-headline-body)))))
	  (if (symbolp result)
	      (format "%S" result)
	    (if (and index (listp result))
		(org-babel-ref-index-list index result)
	      result)))))))

(defun org-babel-ref-index-list (index lis)
  "Return the subset of LIS indexed by INDEX.

Indices are 0 based and negative indices count from the end of
LIS, so 0 references the first element of LIS and -1 references
the last.  If INDEX is separated by \",\"s then each \"portion\"
is assumed to index into the next deepest nesting or dimension.

A valid \"portion\" can consist of either an integer index, two
integers separated by a \":\" in which case the entire range is
returned, or an empty string or \"*\" both of which are
interpreted to mean the entire range and as such are equivalent
to \"0:-1\"."
  (if (and (> (length index) 0) (string-match "^\\([^,]*\\),?" index))
      (let* ((ind-re "\\(\\([-[:digit:]]+\\):\\([-[:digit:]]+\\)\\|\*\\)")
	     (lgth (length lis))
	     (portion (match-string 1 index))
	     (remainder (substring index (match-end 0)))
	     (wrap (lambda (num) (if (< num 0) (+ lgth num) num)))
	     (open (lambda (ls) (if (and (listp ls) (= (length ls) 1)) (car ls) ls))))
	(funcall
	 open
	 (mapcar
	  (lambda (sub-lis)
	    (if (listp sub-lis)
		(org-babel-ref-index-list remainder sub-lis)
	      sub-lis))
	  (if (or (= 0 (length portion)) (string-match ind-re portion))
	      (mapcar
	       (lambda (n) (nth n lis))
	       (apply 'org-number-sequence
		      (if (and (> (length portion) 0) (match-string 2 portion))
			  (list
			   (funcall wrap (string-to-number (match-string 2 portion)))
			   (funcall wrap (string-to-number (match-string 3 portion))))
			(list (funcall wrap 0) (funcall wrap -1)))))
	    (list (nth (funcall wrap (string-to-number portion)) lis))))))
    lis))

(defun org-babel-ref-split-args (arg-string)
  "Split ARG-STRING into top-level arguments of balanced parenthesis."
  (mapcar #'org-babel-trim (org-babel-balanced-split arg-string 44)))

(defvar org-bracket-link-regexp)
(defun org-babel-ref-at-ref-p ()
  "Return the type of reference located at point.
Return nil if none of the supported reference types are found.
Supported reference types are tables and source blocks."
  (cond ((org-at-table-p) 'table)
	((org-at-item-p) 'list)
        ((looking-at "^[ \t]*#\\+BEGIN_SRC") 'source-block)
        ((looking-at org-bracket-link-regexp) 'file)
        ((looking-at org-babel-result-regexp) 'results-line)))

(provide 'ob)

;; Local variables:
;; generated-autoload-file: "org-loaddefs.el"
;; End:

;;; ob.el ends here