;;; ox-publish.el --- Publish Related Org Mode Files as a Website -*- lexical-binding: t; -*-
;; Copyright (C) 2006-2016 Free Software Foundation, Inc.

;; Author: David O'Toole <dto@gnu.org>
;; Maintainer: Carsten Dominik <carsten DOT dominik AT gmail DOT com>
;; Keywords: hypermedia, outlines, wp

;; This file is part of GNU Emacs.
;;
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; This program allow configurable publishing of related sets of
;; Org mode files as a complete website.
;;
;; ox-publish.el can do the following:
;;
;; + Publish all one's Org files to a given export back-end
;; + Upload HTML, images, attachments and other files to a web server
;; + Exclude selected private pages from publishing
;; + Publish a clickable sitemap of pages
;; + Manage local timestamps for publishing only changed files
;; + Accept plugin functions to extend range of publishable content
;;
;; Documentation for publishing is in the manual.

;;; Code:

(require 'cl-lib)
(require 'format-spec)
(require 'ox)


\f
;;; Variables

(defvar org-publish-temp-files nil
  "Temporary list of files to be published.")

;; Here, so you find the variable right before it's used the first time:
(defvar org-publish-cache nil
  "This will cache timestamps and titles for files in publishing projects.
Blocks could hash sha1 values here.")

(defvar org-publish-after-publishing-hook nil
  "Hook run each time a file is published.
Every function in this hook will be called with two arguments:
the name of the original file and the name of the file
produced.")

(defgroup org-publish nil
  "Options for publishing a set of Org-mode and related files."
  :tag "Org Publishing"
  :group 'org)

(defcustom org-publish-project-alist nil
  "Association list to control publishing behavior.
Each element of the alist is a publishing project.  The CAR of
each element is a string, uniquely identifying the project.  The
CDR of each element is in one of the following forms:

1. A well-formed property list with an even number of elements,
   alternating keys and values, specifying parameters for the
   publishing process.

     (:property value :property value ... )

2. A meta-project definition, specifying of a list of
   sub-projects:

     (:components (\"project-1\" \"project-2\" ...))

When the CDR of an element of org-publish-project-alist is in
this second form, the elements of the list after `:components'
are taken to be components of the project, which group together
files requiring different publishing options.  When you publish
such a project with \\[org-publish], the components all publish.

When a property is given a value in `org-publish-project-alist',
its setting overrides the value of the corresponding user
variable (if any) during publishing.  However, options set within
a file override everything.

Most properties are optional, but some should always be set:

  `:base-directory'

    Directory containing publishing source files.

  `:base-extension'

    Extension (without the dot!) of source files.  This can be
    a regular expression.  If not given, \"org\" will be used as
    default extension.

  `:publishing-directory'

    Directory (possibly remote) where output files will be
    published.

If `:recursive' is non-nil files in sub-directories of
`:base-directory' are considered.

The `:exclude' property may be used to prevent certain files from
being published.  Its value may be a string or regexp matching
file names you don't want to be published.

The `:include' property may be used to include extra files.  Its
value may be a list of filenames to include.  The filenames are
considered relative to the base directory.

When both `:include' and `:exclude' properties are given values,
the exclusion step happens first.

One special property controls which back-end function to use for
publishing files in the project.  This can be used to extend the
set of file types publishable by `org-publish', as well as the
set of output formats.

  `:publishing-function'

    Function to publish file.  Each back-end may define its
    own (i.e. `org-latex-publish-to-pdf',
    `org-html-publish-to-html').  May be a list of functions, in
    which case each function in the list is invoked in turn.

Another property allows you to insert code that prepares
a project for publishing.  For example, you could call GNU Make
on a certain makefile, to ensure published files are built up to
date.

  `:preparation-function'

    Function to be called before publishing this project.  This
    may also be a list of functions.

  `:completion-function'

    Function to be called after publishing this project.  This
    may also be a list of functions.

Some properties control details of the Org publishing process,
and are equivalent to the corresponding user variables listed in
the right column.  Back-end specific properties may also be
included.  See the back-end documentation for more information.

  :author                   `user-full-name'
  :creator                  `org-export-creator-string'
  :email                    `user-mail-address'
  :exclude-tags             `org-export-exclude-tags'
  :headline-levels          `org-export-headline-levels'
  :language                 `org-export-default-language'
  :preserve-breaks          `org-export-preserve-breaks'
  :section-numbers          `org-export-with-section-numbers'
  :select-tags              `org-export-select-tags'
  :time-stamp-file          `org-export-time-stamp-file'
  :with-archived-trees      `org-export-with-archived-trees'
  :with-author              `org-export-with-author'
  :with-creator             `org-export-with-creator'
  :with-date                `org-export-with-date'
  :with-drawers             `org-export-with-drawers'
  :with-email               `org-export-with-email'
  :with-emphasize           `org-export-with-emphasize'
  :with-entities            `org-export-with-entities'
  :with-fixed-width         `org-export-with-fixed-width'
  :with-footnotes           `org-export-with-footnotes'
  :with-inlinetasks         `org-export-with-inlinetasks'
  :with-latex               `org-export-with-latex'
  :with-planning            `org-export-with-planning'
  :with-priority            `org-export-with-priority'
  :with-properties          `org-export-with-properties'
  :with-smart-quotes        `org-export-with-smart-quotes'
  :with-special-strings     `org-export-with-special-strings'
  :with-statistics-cookies' `org-export-with-statistics-cookies'
  :with-sub-superscript     `org-export-with-sub-superscripts'
  :with-toc                 `org-export-with-toc'
  :with-tables              `org-export-with-tables'
  :with-tags                `org-export-with-tags'
  :with-tasks               `org-export-with-tasks'
  :with-timestamps          `org-export-with-timestamps'
  :with-title               `org-export-with-title'
  :with-todo-keywords       `org-export-with-todo-keywords'

The following properties may be used to control publishing of
a site-map of files or summary page for a given project.

  `:auto-sitemap'

    Whether to publish a site-map during
    `org-publish-current-project' or `org-publish-all'.

  `:sitemap-filename'

    Filename for output of sitemap.  Defaults to \"sitemap.org\".

  `:sitemap-title'

    Title of site-map page.  Defaults to name of file.

  `:sitemap-function'

    Plugin function to use for generation of site-map.  Defaults
    to `org-publish-org-sitemap', which generates a plain list of
    links to all files in the project.

  `:sitemap-style'

    By default `list' (site-map is a list of files) or
    `tree' (the directory structure of the source files is
    reflected in the site-map).  Defaults to `tree'.  Files are
    formatted according to `:sitemap-file-entry-format',
    directories according to `:sitemap-dir-entry-format'.  To add
    new styles STYLE define a new function
    `org-publish-org-sitemap-as-STYLE' that takes a list of files
    and project-plist as arguments (assuming `:sitemap-function'
    is `org-publish-org-sitemap').

  `:sitemap-sans-extension'

    Remove extension from site-map's file-names.  Useful to have
    cool URIs (see http://www.w3.org/Provider/Style/URI).
    Defaults to nil.

  `:sitemap-file-entry-format'
  `:sitemap-dir-entry-format'

    Format of filenames and directories included in the sitemap.
    See `org-publish-sitemap-file-entry-format' for details.

  `:sitemap-preamble'
  `:sitemap-postamble'

    Preamble and postamble for sitemap.  Useful for inserting
    #+OPTIONS: keywords, footers etc.  See
    `org-publish-sitemap-preamble' for details.


If you create a site-map file, adjust the sorting like this:

  `:sitemap-sort-folders'

    Where folders should appear in the site-map.  Set this to
    `first' (default) or `last' to display folders first or last,
    respectively.  Any other value will mix files and folders.

  `:sitemap-sort-files'

    The site map is normally sorted alphabetically.  You can
    change this behavior setting this to `anti-chronologically',
    `chronologically', or nil.

  `:sitemap-ignore-case'

    Should sorting be case-sensitive?  Default nil.

The following property control the creation of a concept index.

  `:makeindex'

    Create a concept index.  The file containing the index has to
    be called \"theindex.org\".  If it doesn't exist in the
    project, it will be generated.  Contents of the index are
    stored in the file \"theindex.inc\", which can be included in
    \"theindex.org\".

Other properties affecting publication.

  `:body-only'

    Set this to t to publish only the body of the documents."
  :group 'org-export-publish
  :type 'alist)

(defcustom org-publish-use-timestamps-flag t
  "Non-nil means use timestamp checking to publish only changed files.
When nil, do no timestamp checking and always publish all files."
  :group 'org-export-publish
  :type 'boolean)

(defcustom org-publish-timestamp-directory
  (convert-standard-filename "~/.org-timestamps/")
  "Name of directory in which to store publishing timestamps."
  :group 'org-export-publish
  :type 'directory)

(defcustom org-publish-list-skipped-files t
  "Non-nil means show message about files *not* published."
  :group 'org-export-publish
  :type 'boolean)

(defcustom org-publish-sitemap-sort-files 'alphabetically
  "Method to sort files in site-maps.
Possible values are `alphabetically', `chronologically',
`anti-chronologically' and nil.

If `alphabetically', files will be sorted alphabetically.  If
`chronologically', files will be sorted with older modification
time first.  If `anti-chronologically', files will be sorted with
newer modification time first.  nil won't sort files.

You can overwrite this default per project in your
`org-publish-project-alist', using `:sitemap-sort-files'."
  :group 'org-export-publish
  :type 'symbol)

(defcustom org-publish-sitemap-sort-folders 'first
  "A symbol, denoting if folders are sorted first in sitemaps.
Possible values are `first', `last', and nil.
If `first', folders will be sorted before files.
If `last', folders are sorted to the end after the files.
Any other value will not mix files and folders.

You can overwrite this default per project in your
`org-publish-project-alist', using `:sitemap-sort-folders'."
  :group 'org-export-publish
  :type 'symbol)

(defcustom org-publish-sitemap-sort-ignore-case nil
  "Non-nil when site-map sorting should ignore case.

You can overwrite this default per project in your
`org-publish-project-alist', using `:sitemap-ignore-case'."
  :group 'org-export-publish
  :type 'boolean)

(defcustom org-publish-sitemap-date-format "%Y-%m-%d"
  "Format for printing a date in the sitemap.
See `format-time-string' for allowed formatters."
  :group 'org-export-publish
  :type 'string)

(defcustom org-publish-sitemap-file-entry-format "%- [[file:%link][%TITLE]]"
  "Format string for site-map file entry.

Most keywords can be accessed using a the name of the keyword
prefixed with \"%\", e.g. \"%TITLE\" or \"%KEYWORDS\".  In
addition, the following keywords are defined.

  %fullpath
    The full path of the file.

  %relpath
    The relative path of the file.

  %filename
  %f
    The filename.

  %link
  %l
    The link.

  %*
    Leveled headline relative to the base directory.

  %*
    Leveled item relative to the base directory.

  %author
    The author of the document, the project, or `user-full-name'.

  %date
     Date formatted using `org-publish-sitemap-date-format'.

See also `org-publish-sitemap-dir-entry-format'."
  :group 'org-export-publish
  :type 'string
  :version "25.2"
  :package-version '(Org . "9.0"))

(defcustom org-publish-sitemap-dir-entry-format "%- %f"
  "Format string for site-map file entry.

The following keywords are defined.

  %fullpath
    The full path of the file.

  %relpath
    The relative path of the file.

  %filename
  %f
    The filename.

  %link
  %l
    The link.

  %*
    Leveled headline relative to the base directory.

  %*
    Leveled item relative to the base directory.

  %author
    The author of the document, the project, or `user-full-name'.

  %date
     Date formatted using `org-publish-sitemap-date-format'.

See also `org-publish-sitemap-file-entry-format'."
  :group 'org-export-publish
  :type 'string
  :version "25.2"
  :package-version '(Org . "9.0"))

(defcustom org-publish-sitemap-preamble nil
  "Sitemap preamble.

Can be either a string, a list of strings, or a function that
takes a project-plist as an argument and return a string."
  :group 'org-export-publish
  :type '(choice
	  (const :tag "None" nil)
	  (string :tag "String")
	  (repeat :tag "List of strings"
		  (string :tag "String"))
	  (function :tag "Function"))
  :version "25.2"
  :package-version '(Org . "9.0"))

(defcustom org-publish-sitemap-postamble nil
  "Sitemap postamble.

Can be either a string, a list of strings, or a function that
takes a project-plist as an argument and return a string."
  :group 'org-export-publish
  :type '(choice
	  (const :tag "None" nil)
	  (string :tag "String")
	  (repeat :tag "List of strings"
		  (string :tag "String"))
	  (function :tag "Function"))
  :version "25.2"
  :package-version '(Org . "9.0"))


\f
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Timestamp-related functions

(defun org-publish-timestamp-filename (filename &optional pub-dir pub-func)
  "Return path to timestamp file for filename FILENAME."
  (setq filename (concat filename "::" (or pub-dir "") "::"
                         (format "%s" (or pub-func ""))))
  (concat "X" (if (fboundp 'sha1) (sha1 filename) (md5 filename))))

(defun org-publish-needed-p
  (filename &optional pub-dir pub-func _true-pub-dir base-dir)
  "Non-nil if FILENAME should be published in PUB-DIR using PUB-FUNC.
TRUE-PUB-DIR is where the file will truly end up.  Currently we
are not using this - maybe it can eventually be used to check if
the file is present at the target location, and how old it is.
Right now we cannot do this, because we do not know under what
file name the file will be stored - the publishing function can
still decide about that independently."
  (let ((rtn (if (not org-publish-use-timestamps-flag) t
               (org-publish-cache-file-needs-publishing
                filename pub-dir pub-func base-dir))))
    (if rtn (message "Publishing file %s using `%s'" filename pub-func)
      (when org-publish-list-skipped-files
        (message   "Skipping unmodified file %s" filename)))
    rtn))

(defun org-publish-update-timestamp
  (filename &optional pub-dir pub-func _base-dir)
  "Update publishing timestamp for file FILENAME.
If there is no timestamp, create one."
  (let ((key (org-publish-timestamp-filename filename pub-dir pub-func))
        (stamp (org-publish-cache-ctime-of-src filename)))
    (org-publish-cache-set key stamp)))

(defun org-publish-remove-all-timestamps ()
  "Remove all files in the timestamp directory."
  (let ((dir org-publish-timestamp-directory))
    (when (and (file-exists-p dir) (file-directory-p dir))
      (mapc #'delete-file (directory-files dir 'full "[^.]\\'"))
      (org-publish-reset-cache))))


\f
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Getting project information out of `org-publish-project-alist'

(defun org-publish-expand-projects (projects-alist)
  "Expand projects in PROJECTS-ALIST.
This splices all the components into the list."
  (let ((rest projects-alist) rtn p components)
    (while (setq p (pop rest))
      (if (setq components (plist-get (cdr p) :components))
          (setq rest (append
                      (mapcar (lambda (x) (assoc x org-publish-project-alist))
                              components)
                      rest))
        (push p rtn)))
    (nreverse (delete-dups (delq nil rtn)))))

(defvar org-publish-sitemap-sort-files)
(defvar org-publish-sitemap-sort-folders)
(defvar org-publish-sitemap-ignore-case)
(defvar org-publish-sitemap-requested)
(defvar org-publish-sitemap-date-format)
(defvar org-publish-sitemap-file-entry-format)
(defun org-publish-compare-directory-files (a b)
  "Predicate for `sort', that sorts folders and files for sitemap."
  (let ((retval t))
    (when (or org-publish-sitemap-sort-files org-publish-sitemap-sort-folders)
      ;; First we sort files:
      (when org-publish-sitemap-sort-files
        (pcase org-publish-sitemap-sort-files
          (`alphabetically
           (let* ((adir (file-directory-p a))
                  (aorg (and (string-match "\\.org$" a) (not adir)))
                  (bdir (file-directory-p b))
                  (borg (and (string-match "\\.org$" b) (not bdir)))
                  (A (if aorg (concat (file-name-directory a)
                                      (org-publish-find-title a)) a))
                  (B (if borg (concat (file-name-directory b)
                                      (org-publish-find-title b)) b)))
             (setq retval (if org-publish-sitemap-ignore-case
                              (not (string-lessp (upcase B) (upcase A)))
                            (not (string-lessp B A))))))
          ((or `anti-chronologically `chronologically)
           (let* ((adate (org-publish-find-date a))
                  (bdate (org-publish-find-date b))
                  (A (+ (lsh (car adate) 16) (cadr adate)))
                  (B (+ (lsh (car bdate) 16) (cadr bdate))))
             (setq retval
                   (if (eq org-publish-sitemap-sort-files 'chronologically)
                       (<= A B)
                     (>= A B)))))))
      ;; Directory-wise wins:
      (when org-publish-sitemap-sort-folders
        ;; a is directory, b not:
        (cond
         ((and (file-directory-p a) (not (file-directory-p b)))
          (setq retval (equal org-publish-sitemap-sort-folders 'first)))
         ;; a is not a directory, but b is:
         ((and (not (file-directory-p a)) (file-directory-p b))
          (setq retval (equal org-publish-sitemap-sort-folders 'last))))))
    retval))

(defun org-publish-get-base-files-1
    (base-dir &optional recurse match skip-file skip-dir include-dirs)
  "Set `org-publish-temp-files' with files from BASE-DIR directory.
If RECURSE is non-nil, check BASE-DIR recursively.  If MATCH is
non-nil, restrict this list to the files matching the regexp
MATCH.  If SKIP-FILE is non-nil, skip file matching the regexp
SKIP-FILE.  If SKIP-DIR is non-nil, don't check directories
matching the regexp SKIP-DIR when recursing through BASE-DIR.
If INCLUDE-DIRS is non-nil include directories"
  (let ((all-files (if (not recurse) (directory-files base-dir t match)
                     ;; If RECURSE is non-nil, we want all files
                     ;; matching MATCH and sub-directories.
                     (cl-remove-if-not
                      (lambda (file)
                        (or (file-directory-p file)
                            (and match (string-match-p match file))))
                      (directory-files base-dir t)))))
    (dolist (f (if (not org-publish-sitemap-requested) all-files
                 (sort all-files #'org-publish-compare-directory-files)))
      (let ((fd-p (file-directory-p f))
            (fnd (file-name-nondirectory f)))
        (if (and fd-p recurse
                 (not (string-match "^\\.+$" fnd))
                 (if skip-dir (not (string-match skip-dir fnd)) t))
            (progn
              (and include-dirs
                   (cl-pushnew f org-publish-temp-files :test #'file-equal-p))
              (org-publish-get-base-files-1
               f recurse match skip-file skip-dir include-dirs))
          (unless (or fd-p		; This is a directory.
                      (and skip-file (string-match skip-file fnd))
                      (not (file-exists-p (file-truename f)))
                      (not (string-match match fnd)))
            (cl-pushnew f org-publish-temp-files :test #'file-equal-p)))))))

(defun org-publish-get-base-files (project &optional exclude-regexp include-dirs)
  "Return a list of all files in PROJECT.
If EXCLUDE-REGEXP is set, this will be used to filter out
matching filenames."
  (let* ((project-plist (cdr project))
         (base-dir (file-name-as-directory
                    (plist-get project-plist :base-directory)))
         (include-list (plist-get project-plist :include))
         (recurse (plist-get project-plist :recursive))
         (extension (or (plist-get project-plist :base-extension) "org"))
         ;; sitemap-... variables are dynamically scoped for
         ;; org-publish-compare-directory-files:
         (org-publish-sitemap-requested
          (plist-get project-plist :auto-sitemap))
         (sitemap-filename
          (or (plist-get project-plist :sitemap-filename) "sitemap.org"))
         (org-publish-sitemap-sort-folders
          (if (plist-member project-plist :sitemap-sort-folders)
              (plist-get project-plist :sitemap-sort-folders)
            org-publish-sitemap-sort-folders))
         (org-publish-sitemap-sort-files
          (cond ((plist-member project-plist :sitemap-sort-files)
                 (plist-get project-plist :sitemap-sort-files))
                ;; For backward compatibility:
                ((plist-member project-plist :sitemap-alphabetically)
                 (if (plist-get project-plist :sitemap-alphabetically)
                     'alphabetically nil))
                (t org-publish-sitemap-sort-files)))
         (org-publish-sitemap-ignore-case
          (if (plist-member project-plist :sitemap-ignore-case)
              (plist-get project-plist :sitemap-ignore-case)
            org-publish-sitemap-sort-ignore-case))
         (match (if (eq extension 'any) "^[^\\.]"
                  (concat "^[^\\.].*\\.\\(" extension "\\)$"))))
    ;; Make sure `org-publish-sitemap-sort-folders' has an accepted
    ;; value.
    (unless (memq org-publish-sitemap-sort-folders '(first last))
      (setq org-publish-sitemap-sort-folders nil))

    (setq org-publish-temp-files nil)
    (when org-publish-sitemap-requested
      (cl-pushnew (expand-file-name (concat base-dir sitemap-filename))
                  org-publish-temp-files :test #'file-equal-p))
    (org-publish-get-base-files-1 base-dir recurse match
                                  ;; FIXME distinguish exclude regexp
                                  ;; for skip-file and skip-dir?
                                  exclude-regexp exclude-regexp include-dirs)
    (dolist (f include-list org-publish-temp-files)
      (cl-pushnew (expand-file-name (concat base-dir f))
                  org-publish-temp-files :test #'file-equal-p))
    ;; Remove directories from `org-publish-temp-files' that do not
    ;; hold project files.
    (when include-dirs
      (let* ((dirs (cl-remove-if-not 'file-directory-p org-publish-temp-files))
	     (file-dirs (mapcar 'file-name-directory
				(cl-remove-if 'file-directory-p org-publish-temp-files))))
	(setq org-publish-temp-files
	      (cl-set-difference org-publish-temp-files
				 (cl-set-difference dirs file-dirs :test #'file-equal-p)
				 :test #'file-equal-p))))))

(defun org-publish-get-project-from-filename (filename &optional up)
  "Return the project that FILENAME belongs to."
  (let* ((filename (expand-file-name filename))
         project-name)

    (catch 'p-found
      (dolist (prj org-publish-project-alist)
        (unless (plist-get (cdr prj) :components)
          ;; [[info:org:Selecting%20files]] shows how this is supposed to work:
          (let* ((r (plist-get (cdr prj) :recursive))
                 (b (expand-file-name (file-name-as-directory
                                       (plist-get (cdr prj) :base-directory))))
                 (x (or (plist-get (cdr prj) :base-extension) "org"))
                 (e (plist-get (cdr prj) :exclude))
                 (i (plist-get (cdr prj) :include))
                 (xm (concat "^" b (if r ".+" "[^/]+") "\\.\\(" x "\\)$")))
            (when
                (or (and i
                         (member filename
                                 (dolist (file i) (expand-file-name file b))))
                    (and (not (and e (string-match e filename)))
                         (string-match xm filename)))
              (setq project-name (car prj))
              (throw 'p-found project-name))))))
    (when up
      (dolist (prj org-publish-project-alist)
        (if (member project-name (plist-get (cdr prj) :components))
            (setq project-name (car prj)))))
    (assoc project-name org-publish-project-alist)))


\f
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Tools for publishing functions in back-ends

(defun org-publish-org-to (backend filename extension plist &optional pub-dir)
  "Publish an Org file to a specified back-end.

BACKEND is a symbol representing the back-end used for
transcoding.  FILENAME is the filename of the Org file to be
published.  EXTENSION is the extension used for the output
string, with the leading dot.  PLIST is the property list for the
given project.

Optional argument PUB-DIR, when non-nil is the publishing
directory.

Return output file name."
  (unless (or (not pub-dir) (file-exists-p pub-dir)) (make-directory pub-dir t))
  ;; Check if a buffer visiting FILENAME is already open.
  (let* ((org-inhibit-startup t)
         (visiting (find-buffer-visiting filename))
         (work-buffer (or visiting (find-file-noselect filename))))
    (unwind-protect
        (with-current-buffer work-buffer
          (let ((output (org-export-output-file-name extension nil pub-dir)))
            (org-export-to-file backend output
              nil nil nil (plist-get plist :body-only)
              ;; Add `org-publish--store-crossrefs' and
              ;; `org-publish-collect-index' to final output filters.
              ;; The latter isn't dependent on `:makeindex', since we
              ;; want to keep it up-to-date in cache anyway.
              (org-combine-plists
               plist
               `(:crossrefs
                 ,(org-publish-cache-get-file-property
                   (expand-file-name filename) :crossrefs nil t)
                 :filter-final-output
                 (org-publish--store-crossrefs
                  org-publish-collect-index
                  ,@(plist-get plist :filter-final-output)))))))
      ;; Remove opened buffer in the process.
      (unless visiting (kill-buffer work-buffer)))))

(defun org-publish-attachment (_plist filename pub-dir)
  "Publish a file with no transformation of any kind.

FILENAME is the filename of the Org file to be published.  PLIST
is the property list for the given project.  PUB-DIR is the
publishing directory.

Return output file name."
  (unless (file-directory-p pub-dir)
    (make-directory pub-dir t))
  (let ((output (expand-file-name (file-name-nondirectory filename) pub-dir)))
    (or (equal (expand-file-name (file-name-directory filename))
               (file-name-as-directory (expand-file-name pub-dir)))
        (copy-file filename output t))
    ;; Return file name.
    output))


\f
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Publishing files, sets of files, and indices

(defun org-publish-file (filename &optional project no-cache)
  "Publish file FILENAME from PROJECT.
If NO-CACHE is not nil, do not initialize `org-publish-cache'.
This is needed, since this function is used to publish single
files, when entire projects are published (see
`org-publish-projects')."
  (let* ((project
          (or project
              (or (org-publish-get-project-from-filename filename)
                  (error "File %s not part of any known project"
                         (abbreviate-file-name filename)))))
         (project-plist (cdr project))
         (ftname (expand-file-name filename))
         (publishing-function
          (let ((fun (plist-get project-plist :publishing-function)))
            (cond ((null fun) (error "No publishing function chosen"))
                  ((listp fun) fun)
                  (t (list fun)))))
         (base-dir
          (file-name-as-directory
           (expand-file-name
            (or (plist-get project-plist :base-directory)
                (error "Project %s does not have :base-directory defined"
                       (car project))))))
         (pub-dir
          (file-name-as-directory
           (file-truename
            (or (eval (plist-get project-plist :publishing-directory))
                (error "Project %s does not have :publishing-directory defined"
                       (car project))))))
         tmp-pub-dir)

    (unless no-cache (org-publish-initialize-cache (car project)))

    (setq tmp-pub-dir
          (file-name-directory
           (concat pub-dir
                   (and (string-match (regexp-quote base-dir) ftname)
                        (substring ftname (match-end 0))))))
    ;; Allow chain of publishing functions.
    (dolist (f publishing-function)
      (when (org-publish-needed-p filename pub-dir f tmp-pub-dir base-dir)
        (let ((output (funcall f project-plist filename tmp-pub-dir)))
          (org-publish-update-timestamp filename pub-dir f base-dir)
          (run-hook-with-args 'org-publish-after-publishing-hook
                              filename
                              output))))
    ;; Make sure to write cache to file after successfully publishing
    ;; a file, so as to minimize impact of a publishing failure.
    (org-publish-write-cache-file)))

(defun org-publish-projects (projects)
  "Publish all files belonging to the PROJECTS alist.
If `:auto-sitemap' is set, publish the sitemap too.  If
`:makeindex' is set, also produce a file \"theindex.org\"."
  (dolist (project (org-publish-expand-projects projects))
    (let ((project-plist (cdr project)))
      (let ((f (plist-get project-plist :preparation-function)))
        (cond ((consp f) (mapc #'funcall f))
              ((functionp f) (funcall f))))
      ;; Each project uses its own cache file.
      (org-publish-initialize-cache (car project))
      (when  (plist-get project-plist :auto-sitemap)
	(let ((sitemap-filename
	       (or (plist-get project-plist :sitemap-filename)
		   "sitemap.org"))
	      (sitemap-function
	       (or (plist-get project-plist :sitemap-function)
		   #'org-publish-org-sitemap))
	      (org-publish-sitemap-date-format
	       (or (plist-get project-plist :sitemap-date-format)
		   org-publish-sitemap-date-format))
	      (org-publish-sitemap-file-entry-format
	       (or (plist-get project-plist :sitemap-file-entry-format)
		   org-publish-sitemap-file-entry-format))
	      (org-publish-sitemap-dir-entry-format
	       (or (plist-get project-plist :sitemap-dir-entry-format)
		   org-publish-sitemap-dir-entry-format))
	      (org-publish-sitemap-preamble
	       (or (plist-get project-plist :sitemap-preamble)
		   org-publish-sitemap-preamble))
	      (org-publish-sitemap-postamble
	       (or (plist-get project-plist :sitemap-postamble)
		   org-publish-sitemap-postamble)))
	  (funcall sitemap-function project sitemap-filename)))
      ;; Publish all files from PROJECT excepted "theindex.org".  Its
      ;; publishing will be deferred until "theindex.inc" is
      ;; populated.
      (let ((theindex
             (expand-file-name "theindex.org"
                               (plist-get project-plist :base-directory)))
            (exclude-regexp (plist-get project-plist :exclude)))
        (dolist (file (org-publish-get-base-files project exclude-regexp))
          (unless (equal file theindex) (org-publish-file file project t)))
        ;; Populate "theindex.inc", if needed, and publish
        ;; "theindex.org".
        (when (plist-get project-plist :makeindex)
          (org-publish-index-generate-theindex
           project (plist-get project-plist :base-directory))
          (org-publish-file theindex project t)))
      (let ((f (plist-get project-plist :completion-function)))
        (cond ((consp f) (mapc #'funcall f))
              ((functionp f) (funcall f))))
      (org-publish-write-cache-file))))

(defun org-publish-org-sitemap (project &optional sitemap-filename)
  "Create a sitemap of pages in set defined by PROJECT.
Optionally set the filename of the sitemap with SITEMAP-FILENAME.
Default for SITEMAP-FILENAME is `sitemap.org'."
  (let* ((project-plist (cdr project))
	 (dir (file-name-as-directory
	       (plist-get project-plist :base-directory)))
	 (sitemap-filename (concat dir (or sitemap-filename "sitemap.org")))
	 (files (nreverse
		 ;; Sitemap shouldn't list itself.
		 (cl-remove sitemap-filename
			    (org-publish-get-base-files
			     project
			     (plist-get project-plist :exclude) t)
			    :test #'equal)))
	 (sitemap-title (or (plist-get project-plist :sitemap-title)
			    (concat "Sitemap for project " (car project))))
	 (prepare-pre-or-postamble (lambda (pre-or-postamble)
				     (cond ((not pre-or-postamble) nil)
					   ((stringp pre-or-postamble) pre-or-postamble)
					   ((listp pre-or-postamble)
					    (mapconcat 'identity preamble "\n"))
					   ((functionp pre-or-postamble)
					    (funcall pre-or-postamble project-plist))
					   (t (error (concat "unknown `:sitemap-preamble' or "
							     "`:sitemap-postamble' format")))))))
    (with-temp-file sitemap-filename
      (insert
       (mapconcat
	'identity
	(list
	 (format "#+TITLE: %s" sitemap-title)
	 ;; Insert sitemap-preamble.
	 (funcall prepare-pre-or-postamble
		  (plist-get project-plist :sitemap-preamble))
	 ;; Call function to build sitemap based on files and the project-plist.
	 (let* ((style (or (plist-get project-plist :sitemap-style) 'tree))
		(fun (intern (format "org-publish-org-sitemap-as-%s" style))))
	   (unless (functionp fun)
	     (error "Unknown function %s for :sitemap-style %s."
		    fun style))
	   (funcall fun files project-plist))
	 ;; Insert sitemap-postamble.
	 (funcall prepare-pre-or-postamble
		  (plist-get project-plist :sitemap-postamble)))
        "\n")))))

(defun org-publish-org-sitemap-as-list (files project-plist)
  "Insert FILES as simple list separated by newlines.
PROJECT-PLIST holds the project information."
  (mapconcat
   (lambda (file)
     (org-publish-format-file-entry
      org-publish-sitemap-file-entry-format file project-plist))
   (cl-delete-if 'file-directory-p files) "\n"))

(defun org-publish-org-sitemap-as-tree (files project-plist)
  "Insert FILES as a tree.
PROJECT-PLIST holds the project information."
  (mapconcat (lambda (elm)
               (org-publish-format-file-entry
                (cond
                 ((file-directory-p elm) org-publish-sitemap-dir-entry-format)
                 (t org-publish-sitemap-file-entry-format))
                elm project-plist))
             (cl-remove (plist-get project-plist :base-directory)
                        files :test #'file-equal-p)
             "\n"))

(defun org-publish-format-file-entry (fmt file project-plist)
  "Format FILE according to the format-string FMT.
PROJECT-PLIST is a plist holding project options.
See also `org-publish-sitemap-file-entry-format'.
"
  (let* ((basedir (file-truename (plist-get project-plist :base-directory)))
         (filename (file-relative-name file basedir))
         (dirname (file-name-directory filename))
         (dirp (file-directory-p file))
         (depth (if (or (eq 'list (plist-get project-plist :sitemap-style))
                        (not dirname))
                    1
                  (+ (if (not (directory-name-p filename)) 1 0)
                     (length (split-string (file-name-directory filename) "/" t)))))
         (link (funcall (if (plist-get project-plist :sitemap-sans-extension)
                            #'file-name-sans-extension
                          #'identity)
                        filename))
         (relfilepath (if (file-equal-p file basedir) ""
                        (directory-file-name
                         (if dirp
                             (file-relative-name
                              filename (file-name-directory (directory-file-name filename)))
                           (file-relative-name filename dirname)))))
         (date (unless dirp
                 (format-time-string
                  (or (plist-get project-plist :sitemap-date-format)
                      org-publish-sitemap-date-format)
                  (org-publish-find-date file))))
         (info (list (list "fullpath" file)
                     (list "relpath" filename)
                     (list "filename" relfilepath)
                     (list "f" relfilepath)
                     (list "l" link)
                     (list "link" link)
                     (list "*" (concat (make-string depth ?*)))
                     (list "-" (concat (make-string (* 2 depth) ?\s) "-"))
                     (list "date" (format-time-string
                                   (or (plist-get project-plist :sitemap-date-format)
                                       org-publish-sitemap-date-format)
                                   (org-publish-find-date file)))
                     (list "author" (or (unless dirp (org-publish-find-property file :author t))
                                        (plist-get project-plist :author)
                                        user-full-name))
                     ;; TODO: Insert legacy values here...
                     )))
    (with-temp-buffer
      (save-excursion (insert fmt))
      (while (re-search-forward "%\\([a-zA-Z-*]+\\>?\\)" nil t)
        (save-excursion
          (replace-match (or (cadr (assoc-string (match-string 1) info t))
                             (save-match-data (org-publish-find-property file (match-string 1) t))
                             (error "Could not expand \"%s\" while formatting sitemap entry for \"%s\""
                                    (match-string 1) file)))))
      (buffer-string))))

(defun org-publish-find-property (file property &optional reset)
  "Find the PROPERTY of FILE in project.
PROPERTY can be a string or a symbol-property."
  (unless (or (file-directory-p file) (directory-name-p file))
    (let ((prop (cond ((stringp property)
                       (intern (downcase (format ":%s" property))))
                      (t property))))
      (and (not reset) (org-publish-cache-get-file-property file prop nil t))
      (let* ((org-inhibit-startup t)
             (visiting (find-buffer-visiting file))
             (buffer (or visiting (find-file-noselect file)))
             (case-fold-search t))
        (with-current-buffer buffer
          ;; protect local variables in open buffers
          (org-export-with-buffer-copy
           (let* ((backends (append (list nil)
                                    (mapcar 'org-export-backend-name
                                            org-export-registered-backends)))
                  (value (cl-loop for backend in backends
                                  when (org-no-properties
                                        (org-element-interpret-data
                                         (plist-get (org-export-get-environment backend)
                                                    prop)))
                                  return it)))
             (unless visiting (kill-buffer buffer))
             (org-publish-cache-set-file-property file prop value)
             value)))))))

(defun org-publish-find-title (file &optional reset)
  "Find the title of FILE in project."
  (org-publish-find-property file :title reset))

(defun org-publish-find-date (file)
  "Find the date of FILE in project.
This function assumes FILE is either a directory or an Org file.
If FILE is an Org file and provides a DATE keyword use it.  In
any other case use the file system's modification time.  Return
time in `current-time' format."
  (if (file-directory-p file) (nth 5 (file-attributes file))
    (let* ((date (org-publish-find-property file :date t)))
      ;; DATE is a secondary string.  If it contains a timestamp,
      ;; convert it to internal format.  Otherwise, use FILE
      ;; modification time.
      (cond ((let ((ts (and (consp date) (assq 'timestamp date))))
               (and ts
                    (let ((value (org-element-interpret-data ts)))
                      (and (org-string-nw-p value)
                           (org-time-string-to-time value))))))
            ((file-exists-p file) (nth 5 (file-attributes file)))
            (t (error "No such file: \"%s\"" file))))))


\f
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; Interactive publishing functions

;;;###autoload
(defalias 'org-publish-project 'org-publish)

;;;###autoload
(defun org-publish (project &optional force async)
  "Publish PROJECT.

PROJECT is either a project name, as a string, or a project
alist (see `org-publish-project-alist' variable).

When optional argument FORCE is non-nil, force publishing all
files in PROJECT.  With a non-nil optional argument ASYNC,
publishing will be done asynchronously, in another process."
  (interactive
   (list (assoc (completing-read "Publish project: "
                                 org-publish-project-alist nil t)
                org-publish-project-alist)
         current-prefix-arg))
  (let ((project (if (not (stringp project)) project
                   ;; If this function is called in batch mode,
                   ;; PROJECT is still a string here.
                   (assoc project org-publish-project-alist))))
    (cond
     ((not project))
     (async
      (org-export-async-start (lambda (_) nil)
        `(let ((org-publish-use-timestamps-flag
                ,(and (not force) org-publish-use-timestamps-flag)))
           ;; Expand components right now as external process may not
           ;; be aware of complete `org-publish-project-alist'.
           (org-publish-projects
            ',(org-publish-expand-projects (list project))))))
     (t (save-window-excursion
          (let ((org-publish-use-timestamps-flag
                 (and (not force) org-publish-use-timestamps-flag)))
            (org-publish-projects (list project))))))))

;;;###autoload
(defun org-publish-all (&optional force async)
  "Publish all projects.
With prefix argument FORCE, remove all files in the timestamp
directory and force publishing all projects.  With a non-nil
optional argument ASYNC, publishing will be done asynchronously,
in another process."
  (interactive "P")
  (if async
      (org-export-async-start (lambda (_) nil)
        `(progn
           (when ',force (org-publish-remove-all-timestamps))
           (let ((org-publish-use-timestamps-flag
                  (if ',force nil ,org-publish-use-timestamps-flag)))
             (org-publish-projects ',org-publish-project-alist))))
    (when force (org-publish-remove-all-timestamps))
    (save-window-excursion
      (let ((org-publish-use-timestamps-flag
             (if force nil org-publish-use-timestamps-flag)))
        (org-publish-projects org-publish-project-alist)))))


;;;###autoload
(defun org-publish-current-file (&optional force async)
  "Publish the current file.
With prefix argument FORCE, force publish the file.  When
optional argument ASYNC is non-nil, publishing will be done
asynchronously, in another process."
  (interactive "P")
  (let ((file (buffer-file-name (buffer-base-buffer))))
    (if async
        (org-export-async-start (lambda (_) nil)
          `(let ((org-publish-use-timestamps-flag
                  (if ',force nil ,org-publish-use-timestamps-flag)))
             (org-publish-file ,file)))
      (save-window-excursion
        (let ((org-publish-use-timestamps-flag
               (if force nil org-publish-use-timestamps-flag)))
          (org-publish-file file))))))

;;;###autoload
(defun org-publish-current-project (&optional force async)
  "Publish the project associated with the current file.
With a prefix argument, force publishing of all files in
the project."
  (interactive "P")
  (save-window-excursion
    (let ((project (org-publish-get-project-from-filename
                    (buffer-file-name (buffer-base-buffer)) 'up)))
      (if project (org-publish project force async)
        (error "File %s is not part of any known project"
               (buffer-file-name (buffer-base-buffer)))))))


\f
;;; Index generation

(defun org-publish-collect-index (output _backend info)
  "Update index for a file in cache.

OUTPUT is the output from transcoding current file.  BACKEND is
the back-end that was used for transcoding.  INFO is a plist
containing publishing and export options.

The index relative to current file is stored as an alist.  An
association has the following shape: (TERM FILE-NAME PARENT),
where TERM is the indexed term, as a string, FILE-NAME is the
original full path of the file where the term in encountered, and
PARENT is a reference to the headline, if any, containing the
original index keyword.  When non-nil, this reference is a cons
cell.  Its CAR is a symbol among `id', `custom-id' and `name' and
its CDR is a string."
  (let ((file (plist-get info :input-file)))
    (org-publish-cache-set-file-property
     file :index
     (delete-dups
      (org-element-map (plist-get info :parse-tree) 'keyword
        (lambda (k)
          (when (equal (org-element-property :key k) "INDEX")
            (let ((parent (org-export-get-parent-headline k)))
              (list (org-element-property :value k)
                    file
                    (cond
                     ((not parent) nil)
                     ((let ((id (org-element-property :ID parent)))
                        (and id (cons 'id id))))
                     ((let ((id (org-element-property :CUSTOM_ID parent)))
                        (and id (cons 'custom-id id))))
                     (t (cons 'name
                              ;; Remove statistics cookie.
                              (replace-regexp-in-string
                               "\\[[0-9]+%\\]\\|\\[[0-9]+/[0-9]+\\]" ""
                               (org-element-property :raw-value parent)))))))))
        info))))
  ;; Return output unchanged.
  output)

(defun org-publish-index-generate-theindex (project directory)
  "Retrieve full index from cache and build \"theindex.org\".
PROJECT is the project the index relates to.  DIRECTORY is the
publishing directory."
  (let ((all-files (org-publish-get-base-files
                    project (plist-get (cdr project) :exclude)))
        full-index)
    ;; Compile full index and sort it alphabetically.
    (dolist (file all-files
                  (setq full-index
                        (sort (nreverse full-index)
                              (lambda (a b) (string< (downcase (car a))
                                                (downcase (car b)))))))
      (let ((index (org-publish-cache-get-file-property file :index)))
        (dolist (term index)
          (unless (member term full-index) (push term full-index)))))
    ;; Write "theindex.inc" in DIRECTORY.
    (with-temp-file (expand-file-name "theindex.inc" directory)
      (let ((current-letter nil) (last-entry nil))
        (dolist (idx full-index)
          (let* ((entry (org-split-string (car idx) "!"))
                 (letter (upcase (substring (car entry) 0 1)))
                 ;; Transform file into a path relative to publishing
                 ;; directory.
                 (file (file-relative-name
                        (nth 1 idx)
                        (plist-get (cdr project) :base-directory))))
            ;; Check if another letter has to be inserted.
            (unless (string= letter current-letter)
              (insert (format "* %s\n" letter)))
            ;; Compute the first difference between last entry and
            ;; current one: it tells the level at which new items
            ;; should be added.
            (let* ((rank
                    (if (equal entry last-entry) (1- (length entry))
                      (cl-loop for n from 0 to (length entry)
                               unless (equal (nth n entry) (nth n last-entry))
                               return n)))
                   (len (length (nthcdr rank entry))))
              ;; For each term after the first difference, create
              ;; a new sub-list with the term as body.  Moreover,
              ;; linkify the last term.
              (dotimes (n len)
                (insert
                 (concat
                  (make-string (* (+ rank n) 2) ? ) "  - "
                  (if (not (= (1- len) n)) (nth (+ rank n) entry)
                    ;; Last term: Link it to TARGET, if possible.
                    (let ((target (nth 2 idx)))
                      (format
                       "[[%s][%s]]"
                       ;; Destination.
                       (pcase (car target)
                         (`nil (format "file:%s" file))
                         (`id (format "id:%s" (cdr target)))
                         (`custom-id (format "file:%s::#%s" file (cdr target)))
                         (_ (format "file:%s::*%s" file (cdr target))))
                       ;; Description.
                       (car (last entry)))))
                  "\n"))))
            (setq current-letter letter last-entry entry))))
      ;; Create "theindex.org", if it doesn't exist yet, and provide
      ;; a default index file.
      (let ((index.org (expand-file-name "theindex.org" directory)))
        (unless (file-exists-p index.org)
          (with-temp-file index.org
            (insert "#+TITLE: Index\n\n#+INCLUDE: \"theindex.inc\"\n\n")))))))


\f
;;; External Fuzzy Links Resolution
;;
;; This part implements tools to resolve [[file.org::*Some headline]]
;; links, where "file.org" belongs to the current project.

(defun org-publish--store-crossrefs (output _backend info)
  "Store cross-references for current published file.

OUPUT is the produced output, as a string.  BACKEND is the export
back-end used, as a symbol.  INFO is the final export state, as
a plist.

This function is meant to be used as a final output filter.  See
`org-publish-org-to'."
  (org-publish-cache-set-file-property
   (plist-get info :input-file) :crossrefs
   ;; Update `:crossrefs' so as to remove unused references and search
   ;; cells.  Actually used references are extracted from
   ;; `:internal-references', with references as strings removed.  See
   ;; `org-export-get-reference' for details.
   (cl-remove-if (lambda (pair) (stringp (car pair)))
                 (plist-get info :internal-references)))
  ;; Return output unchanged.
  output)

(defun org-publish-resolve-external-link (search file)
  "Return reference for element matching string SEARCH in FILE.

Return value is an internal reference, as a string.

This function allows resolving external links with a search
option, e.g.,

  [[file.org::*heading][description]]
  [[file.org::#custom-id][description]]
  [[file.org::fuzzy][description]]

It only makes sense to use this if export back-end builds
references with `org-export-get-reference'."
  (if (not org-publish-cache)
      (progn
        (message "Reference %S in file %S cannot be resolved without publishing"
                 search
                 file)
        "MissingReference")
    (let* ((filename (expand-file-name file))
           (crossrefs
            (org-publish-cache-get-file-property filename :crossrefs nil t))
           (cells (org-export-string-to-search-cell search)))
      (or
       ;; Look for reference associated to search cells triggered by
       ;; LINK.  It can match when targeted file has been published
       ;; already.
       (let ((known (cdr (cl-some (lambda (c) (assoc c crossrefs)) cells))))
         (and known (org-export-format-reference known)))
       ;; Search cell is unknown so far.  Generate a new internal
       ;; reference that will be used when the targeted file will be
       ;; published.
       (let ((new (org-export-new-reference crossrefs)))
         (dolist (cell cells) (push (cons cell new) crossrefs))
         (org-publish-cache-set-file-property filename :crossrefs crossrefs)
         (org-export-format-reference new))))))


\f
;;; Caching functions

(defun org-publish-write-cache-file (&optional free-cache)
  "Write `org-publish-cache' to file.
If FREE-CACHE, empty the cache."
  (unless org-publish-cache
    (error "`org-publish-write-cache-file' called, but no cache present"))

  (let ((cache-file (org-publish-cache-get ":cache-file:")))
    (unless cache-file
      (error "Cannot find cache-file name in `org-publish-write-cache-file'"))
    (with-temp-file cache-file
      (let (print-level print-length)
        (insert "(setq org-publish-cache \
\(make-hash-table :test 'equal :weakness nil :size 100))\n")
        (maphash (lambda (k v)
                   (insert
                    (format "(puthash %S %s%S org-publish-cache)\n"
                            k (if (or (listp v) (symbolp v)) "'" "") v)))
                 org-publish-cache)))
    (when free-cache (org-publish-reset-cache))))

(defun org-publish-initialize-cache (project-name)
  "Initialize the projects cache if not initialized yet and return it."

  (unless project-name
    (error "Cannot initialize `org-publish-cache' without projects name in \
`org-publish-initialize-cache'"))

  (unless (file-exists-p org-publish-timestamp-directory)
    (make-directory org-publish-timestamp-directory t))
  (unless (file-directory-p org-publish-timestamp-directory)
    (error "Org publish timestamp: %s is not a directory"
           org-publish-timestamp-directory))

  (unless (and org-publish-cache
               (string= (org-publish-cache-get ":project:") project-name))
    (let* ((cache-file
            (concat
             (expand-file-name org-publish-timestamp-directory)
             project-name ".cache"))
           (cexists (file-exists-p cache-file)))

      (when org-publish-cache (org-publish-reset-cache))

      (if cexists (load-file cache-file)
        (setq org-publish-cache
              (make-hash-table :test #'equal :weakness nil :size 100))
        (org-publish-cache-set ":project:" project-name)
        (org-publish-cache-set ":cache-file:" cache-file))
      (unless cexists (org-publish-write-cache-file nil))))
  org-publish-cache)

(defun org-publish-reset-cache ()
  "Empty org-publish-cache and reset it nil."
  (message "%s" "Resetting org-publish-cache")
  (when (hash-table-p org-publish-cache)
    (clrhash org-publish-cache))
  (setq org-publish-cache nil))

(defun org-publish-cache-file-needs-publishing
    (filename &optional pub-dir pub-func _base-dir)
  "Check the timestamp of the last publishing of FILENAME.
Return non-nil if the file needs publishing.  Also check if
any included files have been more recently published, so that
the file including them will be republished as well."
  (unless org-publish-cache
    (error
     "`org-publish-cache-file-needs-publishing' called, but no cache present"))
  (let* ((case-fold-search t)
         (key (org-publish-timestamp-filename filename pub-dir pub-func))
         (pstamp (org-publish-cache-get key))
         (org-inhibit-startup t)
         (visiting (find-buffer-visiting filename))
         included-files-ctime buf)
    (when (equal (file-name-extension filename) "org")
      (setq buf (find-file (expand-file-name filename)))
      (with-current-buffer buf
        (goto-char (point-min))
        (while (re-search-forward "^[ \t]*#\\+INCLUDE:" nil t)
          (let* ((element (org-element-at-point))
                 (included-file
                  (and (eq (org-element-type element) 'keyword)
                       (let ((value (org-element-property :value element)))
                         (and value
                              (string-match
                               "\\`\\(\".+?\"\\|\\S-+\\)\\(?:\\s-+\\|$\\)"
                               value)
                              (let ((m (match-string 1 value)))
                                (org-remove-double-quotes
                                 ;; Ignore search suffix.
                                 (if (string-match "\\(::\\(.*?\\)\\)\"?\\'" m)
                                     (substring m 0 (match-beginning 0))
                                   m))))))))
            (when included-file
              (push (org-publish-cache-ctime-of-src
                     (expand-file-name included-file))
                    included-files-ctime)))))
      (unless visiting (kill-buffer buf)))
    (or (null pstamp)
        (let ((ctime (org-publish-cache-ctime-of-src filename)))
          (or (< pstamp ctime)
              (cl-some (lambda (ct) (< ctime ct)) included-files-ctime))))))

(defun org-publish-cache-set-file-property
  (filename property value &optional project-name)
  "Set the VALUE for a PROPERTY of file FILENAME in publishing cache to VALUE.
Use cache file of PROJECT-NAME.  If the entry does not exist, it
will be created.  Return VALUE."
  ;; Evtl. load the requested cache file:
  (if project-name (org-publish-initialize-cache project-name))
  (let ((pl (org-publish-cache-get filename)))
    (if pl (progn (plist-put pl property value) value)
      (org-publish-cache-get-file-property
       filename property value nil project-name))))

(defun org-publish-cache-get-file-property
  (filename property &optional default no-create project-name)
  "Return the value for a PROPERTY of file FILENAME in publishing cache.
Use cache file of PROJECT-NAME. Return the value of that PROPERTY
or DEFAULT, if the value does not yet exist.  If the entry will
be created, unless NO-CREATE is not nil."
  ;; Evtl. load the requested cache file:
  (if project-name (org-publish-initialize-cache project-name))
  (let ((pl (org-publish-cache-get filename)) retval)
    (if pl
        (if (plist-member pl property)
            (setq retval (plist-get pl property))
          (setq retval default))
      ;; no pl yet:
      (unless no-create
        (org-publish-cache-set filename (list property default)))
      (setq retval default))
    retval))

(defun org-publish-cache-get (key)
  "Return the value stored in `org-publish-cache' for key KEY.
Returns nil, if no value or nil is found, or the cache does not
exist."
  (unless org-publish-cache
    (error "`org-publish-cache-get' called, but no cache present"))
  (gethash key org-publish-cache))

(defun org-publish-cache-set (key value)
  "Store KEY VALUE pair in `org-publish-cache'.
Returns value on success, else nil."
  (unless org-publish-cache
    (error "`org-publish-cache-set' called, but no cache present"))
  (puthash key value org-publish-cache))

(defun org-publish-cache-ctime-of-src (file)
  "Get the ctime of FILE as an integer."
  (let ((attr (file-attributes
               (expand-file-name (or (file-symlink-p file) file)
                                 (file-name-directory file)))))
    (if (not attr) (error "No such file: \"%s\"" file)
      (+ (lsh (car (nth 5 attr)) 16)
         (cadr (nth 5 attr))))))


(provide 'ox-publish)

;; Local variables:
;; generated-autoload-file: "org-loaddefs.el"
;; End:

;;; ox-publish.el ends here