;;; test-ox-latex.el --- tests for ox-latex.el       -*- lexical-binding: t; -*-

;; Copyright (C) 2023  Ihor Radchenko

;; Author: Ihor Radchenko <yantar92@posteo.net>

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; Tests checking validity of Org ASCII export output.

;;; Code:

(require 'ox-ascii nil t)
(unless (featurep 'ox-ascii)
  (signal 'missing-test-dependency "org-export-ascii"))

(defun test-ox-ascii--restore-syntax ()
  (org-link-make-regexps)
  (when (featurep 'org-element) (org-element-update-syntax)))

(defun test-ox-ascii--link-export-inline (path desc backend info)
  (and (org-export-derived-backend-p backend 'ascii)
       (let ((description (and (org-string-nw-p desc) (org-trim desc)))
             (target (format "(|tststr:%s|)" path)))
         (if description
             (format "[|%s|] %s" description target)
           target))))

(ert-deftest test-ox-ascii/link-custom-protocol-fallback ()
  "Test link custom protocol fallback."
  (unwind-protect
      (let ((org-link-parameters))
        (org-link-set-parameters "tstdflt")
        ;; As notes.
        (let ((org-ascii-links-to-notes t))
          (should ; With description.
           (string-equal
            (org-export-string-as
             "Link [[tstdflt:path-descr][with description]] as note."
             'ascii t)
            "Link [with description] as note.
\n
[with description] <tstdflt:path-descr>\n"))
          (should ; No description.
           (string-equal
            (org-export-string-as
             "Link [[tstdflt:path-no-descr]] without description (note)."
             'ascii t)
            "Link <tstdflt:path-no-descr> without description (note).\n")))
        ;; Inline.
        (let ((org-ascii-links-to-notes nil))
          (should ; With description.
           (string-equal
            (org-export-string-as
             "Inline link [[tstdflt:path-descr][with description]]."
             'ascii t)
            "Inline link [with description] (<tstdflt:path-descr>).\n"))
          (should ; No description.
           (string-equal
            (org-export-string-as
             "Inline link [[tstdflt:path-no-descr]] without description."
             'ascii t)
            "Inline link <tstdflt:path-no-descr> without description.\n"))))
    (test-ox-ascii--restore-syntax)))

(ert-deftest test-ox-ascii/link-custom-protocol-string ()
  "Test link custom protocol forced inline (string return value)."
  (unwind-protect
      (let ((org-link-parameters))
        (org-link-set-parameters "tststr"
                                 :export #'test-ox-ascii--link-export-inline)
        ;; Inline despite as notes is requested.
        (let ((org-ascii-links-to-notes t))
          (should ; With description.
           (string-equal
            (org-export-string-as
             "Link [[tststr:path-descr][with description]] as string (opt note)."
             'ascii t)
            "Link [|with description|] (|tststr:path-descr|) as string (opt note).\n"))
          (should ; No description.
           (string-equal
            (org-export-string-as
             "Link [[tststr:path-no-descr]] without description as string (opt note)."
             'ascii t)
            "Link (|tststr:path-no-descr|) without description as string (opt note).\n")))
        ;; Inline.
        (let ((org-ascii-links-to-notes nil))
          (should ; With description.
           (string-equal
            (org-export-string-as
             "Link [[tststr:path-descr][with description]] as string (opt inline)."
             'ascii t)
            "Link [|with description|] (|tststr:path-descr|) as string (opt inline).\n"))
          (should ; No description.
           (string-equal
            (org-export-string-as
             "Link <tststr:path-no-descr> without description as string (opt inline)."
             'ascii t)
            "Link (|tststr:path-no-descr|) without description as string (opt
inline).\n"))))
  (test-ox-ascii--restore-syntax)))

(ert-deftest test-ox-ascii/list ()
  "Test lists."
  ;; Number counter.
  (org-test-with-exported-text
      'ascii
      "1. [@3] foo"
    (goto-char (point-min))
    (should
     (search-forward
      "3. foo")))
  ;; Number counter.  Start from 1.
  (org-test-with-exported-text
      'ascii
      "3. foo"
    (goto-char (point-min))
    (should
     (search-forward
      "1. foo")))
  ;; Alphanumeric counter.
  (let ((org-list-allow-alphabetical t))
    (org-test-with-exported-text
        'ascii
        "m. [@k] baz"
      (goto-char (point-min))
      (should
       (search-forward
        "11. baz"))))
  ;; Start from 1.
  (let ((org-list-allow-alphabetical t))
    (org-test-with-exported-text
        'ascii
        "m. bar"
      (goto-char (point-min))
      (should
       (search-forward
        "1. bar")))))

(provide 'test-ox-ascii)
;;; test-ox-ascii.el ends here