unofficial mirror of notmuch@notmuchmail.org
 help / color / mirror / code / Atom feed
blob d820525b3f0240a3afe0e41a5faa82b85cd16cd2 4921 bytes (raw)
name: emacs/coolj.el 	 # note: path name is non-authoritative(*)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
 
;;; coolj.el --- automatically wrap long lines  -*- lexical-binding: t; coding: utf-8 -*-

;; Copyright (C) 2000, 2001, 2004-2009 Free Software Foundation, Inc.

;; Authors:    Kai Grossjohann <Kai.Grossjohann@CS.Uni-Dortmund.DE>
;;             Alex Schroeder <alex@gnu.org>
;;             Chong Yidong <cyd@stupidchicken.com>
;; Maintainer: David Edmondson <dme@dme.org>
;; Keywords: convenience, wp

;; This file is not part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; This is a simple derivative of some functionality from
;; `longlines.el'. The key difference is that this version will
;; insert a prefix at the head of each wrapped line. The prefix is
;; calculated from the originating long line.

;; No minor-mode is provided, the caller is expected to call
;; `coolj-wrap-region' to wrap the region of interest.

;;; Code:

(defgroup coolj nil
  "Wrapping of long lines with prefix."
  :group 'fill)

(defcustom coolj-wrap-follows-window-size t
  "Non-nil means wrap text to the window size.
Otherwise respect `fill-column'."
  :group 'coolj
  :type 'boolean)

(defcustom coolj-line-prefix-regexp "^\\(>+ \\)*"
  "Regular expression that matches line prefixes."
  :group 'coolj
  :type 'regexp)

(defvar-local coolj-wrap-point nil)

(defun coolj-determine-prefix ()
  "Determine the prefix for the current line."
  (save-excursion
    (beginning-of-line)
    (if (re-search-forward coolj-line-prefix-regexp nil t)
	(buffer-substring (match-beginning 0) (match-end 0))
      "")))

(defun coolj-wrap-buffer ()
  "Wrap the current buffer."
  (coolj-wrap-region (point-min) (point-max)))

(defun coolj-wrap-region (beg end)
  "Wrap each successive line, starting with the line before BEG.
Stop when we reach lines after END that don't need wrapping, or the
end of the buffer."
  (setq fill-column (if coolj-wrap-follows-window-size
			(window-width)
		      fill-column))
  (let ((mod (buffer-modified-p)))
    (setq coolj-wrap-point (point))
    (goto-char beg)
    (forward-line -1)
    ;; Two successful coolj-wrap-line's in a row mean successive
    ;; lines don't need wrapping.
    (while (null (and (coolj-wrap-line)
		      (or (eobp)
			  (and (>= (point) end)
			       (coolj-wrap-line))))))
    (goto-char coolj-wrap-point)
    (set-buffer-modified-p mod)))

(defun coolj-wrap-line ()
  "If the current line needs to be wrapped, wrap it and return nil.
If wrapping is performed, point remains on the line.  If the line does
not need to be wrapped, move point to the next line and return t."
  (let ((prefix (coolj-determine-prefix)))
    (if (coolj-set-breakpoint prefix)
	(progn
	  (insert-before-markers ?\n)
	  (backward-char 1)
	  (delete-char -1)
	  (forward-char 1)
	  (insert-before-markers prefix)
	  nil)
      (forward-line 1)
      t)))

(defun coolj-set-breakpoint (prefix)
  "Place point where we should break the current line, and return t.
If the line should not be broken, return nil; point remains on the
line."
  (move-to-column fill-column)
  (and (re-search-forward "[^ ]" (line-end-position) 1)
       (> (current-column) fill-column)
       ;; This line is too long.  Can we break it?
       (or (coolj-find-break-backward prefix)
	   (progn (move-to-column fill-column)
		  (coolj-find-break-forward)))))

(defun coolj-find-break-backward (prefix)
  "Move point backward to the first available breakpoint and return t.
If no breakpoint is found, return nil."
  (let ((end-of-prefix (+ (line-beginning-position) (length prefix))))
    (and (search-backward " " end-of-prefix 1)
	 (save-excursion
	   (skip-chars-backward " " end-of-prefix)
	   (null (bolp)))
	 (progn (forward-char 1)
		(if (and fill-nobreak-predicate
			 (run-hook-with-args-until-success
			  'fill-nobreak-predicate))
		    (progn (skip-chars-backward " " end-of-prefix)
			   (coolj-find-break-backward prefix))
		  t)))))

(defun coolj-find-break-forward ()
  "Move point forward to the first available breakpoint and return t.
If no break point is found, return nil."
  (and (search-forward " " (line-end-position) 1)
       (progn (skip-chars-forward " " (line-end-position))
	      (null (eolp)))
       (if (and fill-nobreak-predicate
		(run-hook-with-args-until-success
		 'fill-nobreak-predicate))
	   (coolj-find-break-forward)
	 t)))

(provide 'coolj)

;;; coolj.el ends here

debug log:

solving d820525b ...
found d820525b in https://yhetil.org/notmuch.git/

(*) Git path names are given by the tree(s) the blob belongs to.
    Blobs themselves have no identifier aside from the hash of its contents.^

Code repositories for project(s) associated with this public inbox

	https://yhetil.org/notmuch.git/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).