[PATCH v4 0/2] Check for misplaced secure mml tags

[PATCH v4 0/2] Check for misplaced secure mml tags

[Mark Walters]

This is a new version of 
id:1475417131-24915-1-git-send-email-markwalters1009@gmail.com

It fixes bremner's comment that the warning message presented to the
user was wrong.

Also, I think the logic is a little simpler, and I think the general
layout extends to any other checks we wish to do before sending.

Best wishes

Mark

Mark Walters (2):
  emacs: mua: extract a common message-send function.
  emacs: mua: check for misplaced secure mml tags

 emacs/notmuch-mua.el | 57 ++++++++++++++++++++++++++++++++++++++++++++++++----
 1 file changed, 53 insertions(+), 4 deletions(-)

-- 
2.1.4

[PATCH v4 1/2] emacs: mua: extract a common message-send function.

[Mark Walters]

This commit adds a common message-send function for message-send and
message-send-and-exit. At the moment the overlap is small, but the
message-send function will get more complex.
---
 emacs/notmuch-mua.el | 13 +++++++++----
 1 file changed, 9 insertions(+), 4 deletions(-)

diff --git a/emacs/notmuch-mua.el b/emacs/notmuch-mua.el
index 55bc267..72fb770 100644
--- a/emacs/notmuch-mua.el
+++ b/emacs/notmuch-mua.el
@@ -490,15 +490,20 @@ will be addressed to all recipients of the source message."
     (notmuch-mua-reply query-string sender reply-all)
     (deactivate-mark)))
 
+(defun notmuch-mua-send-common (arg &optional exit)
+  (interactive "P")
+  (letf (((symbol-function 'message-do-fcc) #'notmuch-maildir-message-do-fcc))
+	(if exit
+	    (message-send-and-exit arg)
+	  (message-send arg))))
+
 (defun notmuch-mua-send-and-exit (&optional arg)
   (interactive "P")
-  (letf (((symbol-function 'message-do-fcc) #'notmuch-maildir-message-do-fcc))
-	(message-send-and-exit arg)))
+  (notmuch-mua-send-common arg 't))
 
 (defun notmuch-mua-send (&optional arg)
   (interactive "P")
-  (letf (((symbol-function 'message-do-fcc) #'notmuch-maildir-message-do-fcc))
-	(message-send arg)))
+  (notmuch-mua-send-common arg))
 
 (defun notmuch-mua-kill-buffer ()
   (interactive)
-- 
2.1.4

[PATCH v4 2/2] emacs: mua: check for misplaced secure mml tags

[Mark Walters]

Emacs message-send seems to ignore a secure mml tag anywhere except at
the start of the body, and it must be followed by a newline. Since
this is almost certainly not desired we check for it, and require user
confirmation before sending.

As the setup before message-send or message-send-and-exit is getting
more complicated it is convenient to unify the two correspoinding
notmuch functions.
---
 emacs/notmuch-mua.el | 52 ++++++++++++++++++++++++++++++++++++++++++++++++----
 1 file changed, 48 insertions(+), 4 deletions(-)

diff --git a/emacs/notmuch-mua.el b/emacs/notmuch-mua.el
index 72fb770..c567173 100644
--- a/emacs/notmuch-mua.el
+++ b/emacs/notmuch-mua.el
@@ -490,12 +490,56 @@ will be addressed to all recipients of the source message."
     (notmuch-mua-reply query-string sender reply-all)
     (deactivate-mark)))
 
+(defun notmuch-mua-check-no-misplaced-secure-tag ()
+  "Query user if there is a misplaced secure mml tag.
+
+Emacs message-send will (probably) ignore a secure mml tag unless
+it is at the start of the body. Returns t if there is no such
+tag, or the user confirms they mean it."
+  (save-excursion
+    (let ((body-start (progn (message-goto-body) (point))))
+      (goto-char (point-max))
+      (or
+       ;; We are always fine if there is no secure tag.
+       (not (search-backward "<#secure" nil 't))
+       ;; There is a secure tag, so it must be at the start of the
+       ;; body, with no secure tag earlier (i.e., in the headers).
+       (and (= (point) body-start)
+	    (not (search-backward "<#secure" nil 't)))
+       ;; The user confirms they means it.
+       (yes-or-no-p "\
+There is a <#secure> tag not at the start of the body. It is
+likely that the message will be sent unsigned and unencrypted.
+Really send? ")))))
+
+(defun notmuch-mua-check-secure-tag-has-newline ()
+  "Query if the secure mml tag has a newline following it.
+
+Emacs message-send will (probably) ignore a correctly placed
+secure mml tag unless it is followed by a newline. Returns t if
+any secure tag is followed by a newline, or the user confirms
+they mean it."
+  (save-excursion
+    (message-goto-body)
+    (or
+     ;; There is no (correctly placed) secure tag.
+     (not (looking-at "<#secure"))
+     ;; The secure tag is followed by a newline.
+     (looking-at "<#secure[^\n>]*>\n")
+     ;; The user confirms they means it.
+     (yes-or-no-p "\
+The <#secure> tag at the start of the body is not followed by a
+newline. It is likely that the message will be sent unsigned and
+unencrypted.  Really send? "))))
+
 (defun notmuch-mua-send-common (arg &optional exit)
   (interactive "P")
-  (letf (((symbol-function 'message-do-fcc) #'notmuch-maildir-message-do-fcc))
-	(if exit
-	    (message-send-and-exit arg)
-	  (message-send arg))))
+  (when (and (notmuch-mua-check-no-misplaced-secure-tag)
+	     (notmuch-mua-check-secure-tag-has-newline))
+    (letf (((symbol-function 'message-do-fcc) #'notmuch-maildir-message-do-fcc))
+	  (if exit
+	      (message-send-and-exit arg)
+	    (message-send arg)))))
 
 (defun notmuch-mua-send-and-exit (&optional arg)
   (interactive "P")
-- 
2.1.4

Re: [PATCH v4 2/2] emacs: mua: check for misplaced secure mml tags

[David Bremner]

Mark Walters <markwalters1009@gmail.com> writes:
>
> As the setup before message-send or message-send-and-exit is getting
> more complicated it is convenient to unify the two correspoinding
> notmuch functions.

Is this paragraph leftover from when this series was one patch?
If so, I can amend it away.

Re: [PATCH v4 2/2] emacs: mua: check for misplaced secure mml tags

[Mark Walters]

On Sat, 08 Oct 2016, David Bremner <david@tethera.net> wrote:
> Mark Walters <markwalters1009@gmail.com> writes:
>>
>> As the setup before message-send or message-send-and-exit is getting
>> more complicated it is convenient to unify the two correspoinding
>> notmuch functions.
>
> Is this paragraph leftover from when this series was one patch?
> If so, I can amend it away.

Yes it is. Sorry about that.

Best wishes

Mark

Re: [PATCH v4 0/2] Check for misplaced secure mml tags

[David Bremner]

Mark Walters <markwalters1009@gmail.com> writes:

> This is a new version of 
> id:1475417131-24915-1-git-send-email-markwalters1009@gmail.com
>
> It fixes bremner's comment that the warning message presented to the
> user was wrong.
>

series pushed,

d

Re: [PATCH v4 0/2] Check for misplaced secure mml tags

[David Bremner]

David Bremner <david@tethera.net> writes:

> Mark Walters <markwalters1009@gmail.com> writes:
>
>> This is a new version of 
>> id:1475417131-24915-1-git-send-email-markwalters1009@gmail.com
>>
>> It fixes bremner's comment that the warning message presented to the
>> user was wrong.
>>
>
> series pushed,
>
> d

damnit, I forgot to amend the commit message, sorry.

d