* [PATCH v3 0/4] Retrieve GPG keys asynchronously.
@ 2018-10-01 16:06 David Edmondson
2018-10-01 16:06 ` [PATCH v3 1/4] emacs: Asynchronous retrieval of GPG keys David Edmondson
` (4 more replies)
0 siblings, 5 replies; 10+ messages in thread
From: David Edmondson @ 2018-10-01 16:06 UTC (permalink / raw)
To: notmuch
Retrieve GPG keys asynchronously.
v2:
- Update the label on buttons when they are used to request
asyncronous key retrieval.
- Always update the buffer when key retrieval completes, even if the
retrieval failed, so that the label is properly re-generated.
v3:
- Code review comments from bremner:
- Fix spelling.
- Fix button label.
- Update docstring to describe the redisplay conditions.
David Edmondson (4):
emacs: Asynchronous retrieval of GPG keys
emacs: Minor refactoring of crypto code
emacs: Add notmuch-crypto-gpg-program and use it
emacs: Improve the reporting of key activity
emacs/notmuch-crypto.el | 195 ++++++++++++++++++++++++++++------------
1 file changed, 138 insertions(+), 57 deletions(-)
--
2.19.0
^ permalink raw reply [flat|nested] 10+ messages in thread
* [PATCH v3 1/4] emacs: Asynchronous retrieval of GPG keys
2018-10-01 16:06 [PATCH v3 0/4] Retrieve GPG keys asynchronously David Edmondson
@ 2018-10-01 16:06 ` David Edmondson
2019-01-15 2:08 ` David Bremner
2018-10-01 16:06 ` [PATCH v3 2/4] emacs: Minor refactoring of crypto code David Edmondson
` (3 subsequent siblings)
4 siblings, 1 reply; 10+ messages in thread
From: David Edmondson @ 2018-10-01 16:06 UTC (permalink / raw)
To: notmuch
Rather than blocking emacs while gpg does its' thing, by default run
key retrieval asynchronously, possibly updating the display of the
message on successful completion.
---
emacs/notmuch-crypto.el | 85 +++++++++++++++++++++++++++++++++++------
1 file changed, 74 insertions(+), 11 deletions(-)
diff --git a/emacs/notmuch-crypto.el b/emacs/notmuch-crypto.el
index fc2b5301..c20fd4f8 100644
--- a/emacs/notmuch-crypto.el
+++ b/emacs/notmuch-crypto.el
@@ -43,6 +43,11 @@ mode."
:package-version '(notmuch . "0.25")
:group 'notmuch-crypto)
+(defcustom notmuch-crypto-get-keys-asynchronously t
+ "Retrieve gpg keys asynchronously."
+ :type 'boolean
+ :group 'notmuch-crypto)
+
(defface notmuch-crypto-part-header
'((((class color)
(background dark))
@@ -113,7 +118,7 @@ mode."
(let ((keyid (concat "0x" (plist-get sigstatus :keyid))))
(setq label (concat "Unknown key ID " keyid " or unsupported algorithm"))
(setq button-action 'notmuch-crypto-sigstatus-error-callback)
- (setq help-msg (concat "Click to retrieve key ID " keyid " from keyserver and redisplay."))))
+ (setq help-msg (concat "Click to retrieve key ID " keyid " from keyserver."))))
((string= status "bad")
(let ((keyid (concat "0x" (plist-get sigstatus :keyid))))
(setq label (concat "Bad signature (claimed key ID " keyid ")"))
@@ -145,19 +150,77 @@ mode."
(call-process epg-gpg-program nil t t "--list-keys" fingerprint))
(recenter -1))))
+(defun notmuch-crypto--async-key-sentinel (process event)
+ "When the user asks for a GPG key to be retrieved
+asynchronously, handle completion of that task.
+
+If the retrieval is successful, the thread where the retrieval
+was initiated is still displayed and the cursor has not moved,
+redisplay the thread."
+ (let ((status (process-status process))
+ (exit-status (process-exit-status process))
+ (keyid (process-get process :gpg-key-id)))
+ (when (memq status '(exit signal))
+ (message "Getting the GPG key %s asynchronously...%s."
+ keyid
+ (if (= exit-status 0)
+ "completed"
+ "failed"))
+ ;; If the original buffer is still alive and point didn't move
+ ;; (i.e. the user didn't move on or away), refresh the buffer to
+ ;; show the updated signature status.
+ (let ((show-buffer (process-get process :notmuch-show-buffer))
+ (show-point (process-get process :notmuch-show-point)))
+ (when (and (bufferp show-buffer)
+ (buffer-live-p show-buffer)
+ (= show-point
+ (with-current-buffer show-buffer
+ (point))))
+ (with-current-buffer show-buffer
+ (notmuch-show-refresh-view)))))))
+
+(defun notmuch-crypto--set-button-label (button label)
+ "Set the text displayed in BUTTON to LABEL."
+ (save-excursion
+ (let ((inhibit-read-only t))
+ ;; This knows rather too much about how we typically format
+ ;; buttons.
+ (goto-char (button-start button))
+ (forward-char 2)
+ (delete-region (point) (- (button-end button) 2))
+ (insert label))))
+
(defun notmuch-crypto-sigstatus-error-callback (button)
(let* ((sigstatus (button-get button :notmuch-sigstatus))
(keyid (concat "0x" (plist-get sigstatus :keyid)))
- (buffer (get-buffer-create "*notmuch-crypto-gpg-out*"))
- (window (display-buffer buffer t nil)))
- (with-selected-window window
- (with-current-buffer buffer
- (goto-char (point-max))
- (call-process epg-gpg-program nil t t "--recv-keys" keyid)
- (insert "\n")
- (call-process epg-gpg-program nil t t "--list-keys" keyid))
- (recenter -1))
- (notmuch-show-refresh-view)))
+ (buffer (get-buffer-create "*notmuch-crypto-gpg-out*")))
+ (if notmuch-crypto-get-keys-asynchronously
+ (progn
+ (notmuch-crypto--set-button-label
+ button (format "Retrieving key %s asynchronously..." keyid))
+ (let ((p (make-process :name "notmuch GPG key retrieval"
+ :buffer buffer
+ :command (list epg-gpg-program "--recv-keys" keyid)
+ :connection-type 'pipe
+ :sentinel #'notmuch-crypto--async-key-sentinel
+ ;; Create the process stopped so that
+ ;; we have time to store the key id,
+ ;; etc. on it.
+ :stop t)))
+ (process-put p :gpg-key-id keyid)
+ (process-put p :notmuch-show-buffer (current-buffer))
+ (process-put p :notmuch-show-point (point))
+ (message "Getting the GPG key %s asynchronously..." keyid)
+ (continue-process p)))
+ (let ((window (display-buffer buffer t nil)))
+ (with-selected-window window
+ (with-current-buffer buffer
+ (goto-char (point-max))
+ (call-process epg-gpg-program nil t t "--recv-keys" keyid)
+ (insert "\n")
+ (call-process epg-gpg-program nil t t "--list-keys" keyid))
+ (recenter -1))
+ (notmuch-show-refresh-view)))))
(defun notmuch-crypto-insert-encstatus-button (encstatus)
(let* ((status (plist-get encstatus :status))
--
2.19.0
^ permalink raw reply related [flat|nested] 10+ messages in thread
* [PATCH v3 2/4] emacs: Minor refactoring of crypto code
2018-10-01 16:06 [PATCH v3 0/4] Retrieve GPG keys asynchronously David Edmondson
2018-10-01 16:06 ` [PATCH v3 1/4] emacs: Asynchronous retrieval of GPG keys David Edmondson
@ 2018-10-01 16:06 ` David Edmondson
2018-10-01 16:06 ` [PATCH v3 3/4] emacs: Add notmuch-crypto-gpg-program and use it David Edmondson
` (2 subsequent siblings)
4 siblings, 0 replies; 10+ messages in thread
From: David Edmondson @ 2018-10-01 16:06 UTC (permalink / raw)
To: notmuch
---
emacs/notmuch-crypto.el | 96 +++++++++++++++++++++--------------------
1 file changed, 50 insertions(+), 46 deletions(-)
diff --git a/emacs/notmuch-crypto.el b/emacs/notmuch-crypto.el
index c20fd4f8..f128f30e 100644
--- a/emacs/notmuch-crypto.el
+++ b/emacs/notmuch-crypto.el
@@ -96,36 +96,40 @@ mode."
:supertype 'notmuch-button-type)
(defun notmuch-crypto-insert-sigstatus-button (sigstatus from)
+ "Insert a button describing the signature status SIGSTATUS sent
+by user FROM."
(let* ((status (plist-get sigstatus :status))
- (help-msg nil)
- (label "Signature not processed")
(face 'notmuch-crypto-signature-unknown)
- (button-action (lambda (button) (message (button-get button 'help-echo)))))
+ (button-action (lambda (button) (message (button-get button 'help-echo))))
+ (keyid (concat "0x" (plist-get sigstatus :keyid)))
+ label help-msg)
(cond
((string= status "good")
- (let ((fingerprint (concat "0x" (plist-get sigstatus :fingerprint))))
- ;; if userid present, userid has full or greater validity
- (if (plist-member sigstatus :userid)
- (let ((userid (plist-get sigstatus :userid)))
- (setq label (concat "Good signature by: " userid))
- (setq face 'notmuch-crypto-signature-good))
- (progn
- (setq label (concat "Good signature by key: " fingerprint))
- (setq face 'notmuch-crypto-signature-good-key)))
- (setq button-action 'notmuch-crypto-sigstatus-good-callback)
- (setq help-msg (concat "Click to list key ID 0x" fingerprint "."))))
+ (let ((fingerprint (concat "0x" (plist-get sigstatus :fingerprint)))
+ (userid (plist-get sigstatus :userid)))
+ ;; If userid is present it has full or greater validity.
+ (if userid
+ (setq label (concat "Good signature by: " userid)
+ face 'notmuch-crypto-signature-good)
+ (setq label (concat "Good signature by key: " fingerprint)
+ face 'notmuch-crypto-signature-good-key))
+ (setq button-action 'notmuch-crypto-sigstatus-good-callback
+ help-msg (concat "Click to list key ID 0x" fingerprint "."))))
+
((string= status "error")
- (let ((keyid (concat "0x" (plist-get sigstatus :keyid))))
- (setq label (concat "Unknown key ID " keyid " or unsupported algorithm"))
- (setq button-action 'notmuch-crypto-sigstatus-error-callback)
- (setq help-msg (concat "Click to retrieve key ID " keyid " from keyserver."))))
+ (setq label (concat "Unknown key ID " keyid " or unsupported algorithm")
+ button-action 'notmuch-crypto-sigstatus-error-callback
+ help-msg (concat "Click to retrieve key ID " keyid
+ " from keyserver.")))
+
((string= status "bad")
- (let ((keyid (concat "0x" (plist-get sigstatus :keyid))))
- (setq label (concat "Bad signature (claimed key ID " keyid ")"))
- (setq face 'notmuch-crypto-signature-bad)))
+ (setq label (concat "Bad signature (claimed key ID " keyid ")")
+ face 'notmuch-crypto-signature-bad))
+
(t
(setq label (concat "Unknown signature status"
(if status (concat ": " status))))))
+
(insert-button
(concat "[ " label " ]")
:type 'notmuch-crypto-status-button-type
@@ -134,22 +138,22 @@ mode."
'mouse-face face
'action button-action
:notmuch-sigstatus sigstatus
- :notmuch-from from)
- (insert "\n")))
-
-(declare-function notmuch-show-refresh-view "notmuch-show" (&optional reset-state))
+ :notmuch-from from))
+ (insert "\n"))
(defun notmuch-crypto-sigstatus-good-callback (button)
(let* ((sigstatus (button-get button :notmuch-sigstatus))
(fingerprint (concat "0x" (plist-get sigstatus :fingerprint)))
(buffer (get-buffer-create "*notmuch-crypto-gpg-out*"))
- (window (display-buffer buffer t nil)))
+ (window (display-buffer buffer)))
(with-selected-window window
(with-current-buffer buffer
(goto-char (point-max))
(call-process epg-gpg-program nil t t "--list-keys" fingerprint))
(recenter -1))))
+(declare-function notmuch-show-refresh-view "notmuch-show" (&optional reset-state))
+
(defun notmuch-crypto--async-key-sentinel (process event)
"When the user asks for a GPG key to be retrieved
asynchronously, handle completion of that task.
@@ -191,6 +195,8 @@ redisplay the thread."
(insert label))))
(defun notmuch-crypto-sigstatus-error-callback (button)
+ "When signature validation has failed, try to retrieve the
+corresponding key when the status button is pressed."
(let* ((sigstatus (button-get button :notmuch-sigstatus))
(keyid (concat "0x" (plist-get sigstatus :keyid)))
(buffer (get-buffer-create "*notmuch-crypto-gpg-out*")))
@@ -212,7 +218,7 @@ redisplay the thread."
(process-put p :notmuch-show-point (point))
(message "Getting the GPG key %s asynchronously..." keyid)
(continue-process p)))
- (let ((window (display-buffer buffer t nil)))
+ (let ((window (display-buffer buffer)))
(with-selected-window window
(with-current-buffer buffer
(goto-char (point-max))
@@ -223,25 +229,23 @@ redisplay the thread."
(notmuch-show-refresh-view)))))
(defun notmuch-crypto-insert-encstatus-button (encstatus)
- (let* ((status (plist-get encstatus :status))
- (help-msg nil)
- (label "Decryption not attempted")
- (face 'notmuch-crypto-decryption))
- (cond
- ((string= status "good")
- (setq label "Decryption successful"))
- ((string= status "bad")
- (setq label "Decryption error"))
- (t
- (setq label (concat "Unknown encryption status"
- (if status (concat ": " status))))))
- (insert-button
- (concat "[ " label " ]")
- :type 'notmuch-crypto-status-button-type
- 'help-echo help-msg
- 'face face
- 'mouse-face face)
- (insert "\n")))
+ "Insert a button describing the encryption status ENCSTATUS."
+ (insert-button
+ (concat "[ "
+ (let ((status (plist-get encstatus :status)))
+ (cond
+ ((string= status "good")
+ "Decryption successful")
+ ((string= status "bad")
+ "Decryption error")
+ (t
+ (concat "Unknown encryption status"
+ (if status (concat ": " status))))))
+ " ]")
+ :type 'notmuch-crypto-status-button-type
+ 'face 'notmuch-crypto-decryption
+ 'mouse-face 'notmuch-crypto-decryption)
+ (insert "\n"))
;;
--
2.19.0
^ permalink raw reply related [flat|nested] 10+ messages in thread
* [PATCH v3 3/4] emacs: Add notmuch-crypto-gpg-program and use it
2018-10-01 16:06 [PATCH v3 0/4] Retrieve GPG keys asynchronously David Edmondson
2018-10-01 16:06 ` [PATCH v3 1/4] emacs: Asynchronous retrieval of GPG keys David Edmondson
2018-10-01 16:06 ` [PATCH v3 2/4] emacs: Minor refactoring of crypto code David Edmondson
@ 2018-10-01 16:06 ` David Edmondson
2018-10-01 16:06 ` [PATCH v3 4/4] emacs: Improve the reporting of key activity David Edmondson
2019-09-03 23:49 ` [PATCH v3 0/4] Retrieve GPG keys asynchronously David Bremner
4 siblings, 0 replies; 10+ messages in thread
From: David Edmondson @ 2018-10-01 16:06 UTC (permalink / raw)
To: notmuch
Allow the user to specify the gpg program to use when retrieving keys,
etc., defaulting to the value of `epg-gpg-program'.
---
emacs/notmuch-crypto.el | 14 ++++++++++----
1 file changed, 10 insertions(+), 4 deletions(-)
diff --git a/emacs/notmuch-crypto.el b/emacs/notmuch-crypto.el
index f128f30e..99087d0b 100644
--- a/emacs/notmuch-crypto.el
+++ b/emacs/notmuch-crypto.el
@@ -48,6 +48,11 @@ mode."
:type 'boolean
:group 'notmuch-crypto)
+(defcustom notmuch-crypto-gpg-program epg-gpg-program
+ "The gpg executable."
+ :type 'string
+ :group 'notmuch-crypto)
+
(defface notmuch-crypto-part-header
'((((class color)
(background dark))
@@ -149,7 +154,7 @@ by user FROM."
(with-selected-window window
(with-current-buffer buffer
(goto-char (point-max))
- (call-process epg-gpg-program nil t t "--list-keys" fingerprint))
+ (call-process notmuch-crypto-gpg-program nil t t "--list-keys" fingerprint))
(recenter -1))))
(declare-function notmuch-show-refresh-view "notmuch-show" (&optional reset-state))
@@ -206,7 +211,7 @@ corresponding key when the status button is pressed."
button (format "Retrieving key %s asynchronously..." keyid))
(let ((p (make-process :name "notmuch GPG key retrieval"
:buffer buffer
- :command (list epg-gpg-program "--recv-keys" keyid)
+ :command (list notmuch-crypto-gpg-program "--recv-keys" keyid)
:connection-type 'pipe
:sentinel #'notmuch-crypto--async-key-sentinel
;; Create the process stopped so that
@@ -218,13 +223,14 @@ corresponding key when the status button is pressed."
(process-put p :notmuch-show-point (point))
(message "Getting the GPG key %s asynchronously..." keyid)
(continue-process p)))
+
(let ((window (display-buffer buffer)))
(with-selected-window window
(with-current-buffer buffer
(goto-char (point-max))
- (call-process epg-gpg-program nil t t "--recv-keys" keyid)
+ (call-process notmuch-crypto-gpg-program nil t t "--recv-keys" keyid)
(insert "\n")
- (call-process epg-gpg-program nil t t "--list-keys" keyid))
+ (call-process notmuch-crypto-gpg-program nil t t "--list-keys" keyid))
(recenter -1))
(notmuch-show-refresh-view)))))
--
2.19.0
^ permalink raw reply related [flat|nested] 10+ messages in thread
* [PATCH v3 4/4] emacs: Improve the reporting of key activity
2018-10-01 16:06 [PATCH v3 0/4] Retrieve GPG keys asynchronously David Edmondson
` (2 preceding siblings ...)
2018-10-01 16:06 ` [PATCH v3 3/4] emacs: Add notmuch-crypto-gpg-program and use it David Edmondson
@ 2018-10-01 16:06 ` David Edmondson
2019-09-03 23:49 ` [PATCH v3 0/4] Retrieve GPG keys asynchronously David Bremner
4 siblings, 0 replies; 10+ messages in thread
From: David Edmondson @ 2018-10-01 16:06 UTC (permalink / raw)
To: notmuch
Improve the information provided about key retrieval and key validity.
---
emacs/notmuch-crypto.el | 12 ++++++++++--
1 file changed, 10 insertions(+), 2 deletions(-)
diff --git a/emacs/notmuch-crypto.el b/emacs/notmuch-crypto.el
index 99087d0b..553ddca8 100644
--- a/emacs/notmuch-crypto.el
+++ b/emacs/notmuch-crypto.el
@@ -147,13 +147,16 @@ by user FROM."
(insert "\n"))
(defun notmuch-crypto-sigstatus-good-callback (button)
- (let* ((sigstatus (button-get button :notmuch-sigstatus))
+ (let* ((id (notmuch-show-get-message-id))
+ (sigstatus (button-get button :notmuch-sigstatus))
(fingerprint (concat "0x" (plist-get sigstatus :fingerprint)))
(buffer (get-buffer-create "*notmuch-crypto-gpg-out*"))
(window (display-buffer buffer)))
(with-selected-window window
(with-current-buffer buffer
(goto-char (point-max))
+ (insert (format "-- Key %s in message %s:\n"
+ fingerprint id))
(call-process notmuch-crypto-gpg-program nil t t "--list-keys" fingerprint))
(recenter -1))))
@@ -209,10 +212,14 @@ corresponding key when the status button is pressed."
(progn
(notmuch-crypto--set-button-label
button (format "Retrieving key %s asynchronously..." keyid))
+ (with-current-buffer buffer
+ (goto-char (point-max))
+ (insert (format "--- Retrieving key %s:\n" keyid)))
(let ((p (make-process :name "notmuch GPG key retrieval"
+ :connection-type 'pipe
:buffer buffer
+ :stderr buffer
:command (list notmuch-crypto-gpg-program "--recv-keys" keyid)
- :connection-type 'pipe
:sentinel #'notmuch-crypto--async-key-sentinel
;; Create the process stopped so that
;; we have time to store the key id,
@@ -228,6 +235,7 @@ corresponding key when the status button is pressed."
(with-selected-window window
(with-current-buffer buffer
(goto-char (point-max))
+ (insert (format "--- Retrieving key %s:\n" keyid))
(call-process notmuch-crypto-gpg-program nil t t "--recv-keys" keyid)
(insert "\n")
(call-process notmuch-crypto-gpg-program nil t t "--list-keys" keyid))
--
2.19.0
^ permalink raw reply related [flat|nested] 10+ messages in thread
* Re: [PATCH v3 1/4] emacs: Asynchronous retrieval of GPG keys
2018-10-01 16:06 ` [PATCH v3 1/4] emacs: Asynchronous retrieval of GPG keys David Edmondson
@ 2019-01-15 2:08 ` David Bremner
2019-01-19 11:15 ` David Edmondson
0 siblings, 1 reply; 10+ messages in thread
From: David Bremner @ 2019-01-15 2:08 UTC (permalink / raw)
To: David Edmondson, notmuch
David Edmondson <dme@dme.org> writes:
> Rather than blocking emacs while gpg does its' thing, by default run
> key retrieval asynchronously, possibly updating the display of the
> message on successful completion.
> ---
> emacs/notmuch-crypto.el | 85 +++++++++++++++++++++++++++++++++++------
> 1 file changed, 74 insertions(+), 11 deletions(-)
>
> diff --git a/emacs/notmuch-crypto.el b/emacs/notmuch-crypto.el
> index fc2b5301..c20fd4f8 100644
> --- a/emacs/notmuch-crypto.el
> +++ b/emacs/notmuch-crypto.el
> @@ -43,6 +43,11 @@ mode."
> :package-version '(notmuch . "0.25")
> :group 'notmuch-crypto)
>
> +(defcustom notmuch-crypto-get-keys-asynchronously t
> + "Retrieve gpg keys asynchronously."
> + :type 'boolean
> + :group 'notmuch-crypto)
> +
Sorry for the long delay. Should this have a :package-version key like
the defcustom right about it?
> + (buffer (get-buffer-create "*notmuch-crypto-gpg-out*")))
> + (if notmuch-crypto-get-keys-asynchronously
> + (progn
> + (notmuch-crypto--set-button-label
> + button (format "Retrieving key %s asynchronously..." keyid))
> + (let ((p (make-process :name "notmuch GPG key retrieval"
> + :buffer buffer
> + :command (list epg-gpg-program "--recv-keys" keyid)
> + :connection-type 'pipe
> + :sentinel #'notmuch-crypto--async-key-sentinel
> + ;; Create the process stopped so that
> + ;; we have time to store the key id,
> + ;; etc. on it.
> + :stop t)))
Using make-process unconditionally seems to require emacs 25. I think
we're still trying to support Emacs 24. That can always change, but I
still haven't merged Tomi's patch officially deprecating emacs 23.
^ permalink raw reply [flat|nested] 10+ messages in thread
* Re: [PATCH v3 1/4] emacs: Asynchronous retrieval of GPG keys
2019-01-15 2:08 ` David Bremner
@ 2019-01-19 11:15 ` David Edmondson
2019-01-19 12:47 ` David Bremner
0 siblings, 1 reply; 10+ messages in thread
From: David Edmondson @ 2019-01-19 11:15 UTC (permalink / raw)
To: David Bremner, notmuch
On Monday, 2019-01-14 at 22:08:14 -04, David Bremner wrote:
> David Edmondson <dme@dme.org> writes:
>
>> Rather than blocking emacs while gpg does its' thing, by default run
>> key retrieval asynchronously, possibly updating the display of the
>> message on successful completion.
>> ---
>> emacs/notmuch-crypto.el | 85 +++++++++++++++++++++++++++++++++++------
>> 1 file changed, 74 insertions(+), 11 deletions(-)
>>
>> diff --git a/emacs/notmuch-crypto.el b/emacs/notmuch-crypto.el
>> index fc2b5301..c20fd4f8 100644
>> --- a/emacs/notmuch-crypto.el
>> +++ b/emacs/notmuch-crypto.el
>> @@ -43,6 +43,11 @@ mode."
>> :package-version '(notmuch . "0.25")
>> :group 'notmuch-crypto)
>>
>> +(defcustom notmuch-crypto-get-keys-asynchronously t
>> + "Retrieve gpg keys asynchronously."
>> + :type 'boolean
>> + :group 'notmuch-crypto)
>> +
>
> Sorry for the long delay. Should this have a :package-version key like
> the defcustom right about it?
Okay.
>> + (buffer (get-buffer-create "*notmuch-crypto-gpg-out*")))
>> + (if notmuch-crypto-get-keys-asynchronously
>> + (progn
>> + (notmuch-crypto--set-button-label
>> + button (format "Retrieving key %s asynchronously..." keyid))
>> + (let ((p (make-process :name "notmuch GPG key retrieval"
>> + :buffer buffer
>> + :command (list epg-gpg-program "--recv-keys" keyid)
>> + :connection-type 'pipe
>> + :sentinel #'notmuch-crypto--async-key-sentinel
>> + ;; Create the process stopped so that
>> + ;; we have time to store the key id,
>> + ;; etc. on it.
>> + :stop t)))
>
> Using make-process unconditionally seems to require emacs 25. I think
> we're still trying to support Emacs 24. That can always change, but I
> still haven't merged Tomi's patch officially deprecating emacs 23.
Would you accept something like:
(defcustom notmuch-crypto-get-keys-asynchronously (functionp 'make-process)
...)
?
dme.
--
I had my eyes closed in the dark.
^ permalink raw reply [flat|nested] 10+ messages in thread
* Re: [PATCH v3 1/4] emacs: Asynchronous retrieval of GPG keys
2019-01-19 11:15 ` David Edmondson
@ 2019-01-19 12:47 ` David Bremner
0 siblings, 0 replies; 10+ messages in thread
From: David Bremner @ 2019-01-19 12:47 UTC (permalink / raw)
To: David Edmondson, notmuch
David Edmondson <dme@dme.org> writes:
> Would you accept something like:
>
> (defcustom notmuch-crypto-get-keys-asynchronously (functionp 'make-process)
> ...)
>
Yes, assuming it means what I think, namely turn off
notmuch-crypto-get-keys-asynchronously if make-process is not
present. It would be good to have (part of) a docstring explaining that
the feature is only available in emacs >= 25.1 (according to NEWS.25).
d
^ permalink raw reply [flat|nested] 10+ messages in thread
* Re: [PATCH v3 0/4] Retrieve GPG keys asynchronously.
2018-10-01 16:06 [PATCH v3 0/4] Retrieve GPG keys asynchronously David Edmondson
` (3 preceding siblings ...)
2018-10-01 16:06 ` [PATCH v3 4/4] emacs: Improve the reporting of key activity David Edmondson
@ 2019-09-03 23:49 ` David Bremner
2019-09-12 1:33 ` Daniel Kahn Gillmor
4 siblings, 1 reply; 10+ messages in thread
From: David Bremner @ 2019-09-03 23:49 UTC (permalink / raw)
To: David Edmondson, notmuch; +Cc: Daniel Kahn Gillmor
David Edmondson <dme@dme.org> writes:
> Retrieve GPG keys asynchronously.
>
> v2:
> - Update the label on buttons when they are used to request
> asyncronous key retrieval.
> - Always update the buffer when key retrieval completes, even if the
> retrieval failed, so that the label is properly re-generated.
>
> v3:
> - Code review comments from bremner:
> - Fix spelling.
> - Fix button label.
> - Update docstring to describe the redisplay conditions.
>
I went back to this series to try and do the last minor things my self,
but unfortunately I got lost in trying to do the rebase. I think it
collides with a couple of dkg's fixes (9300defd6 and 3c752b855f). If
either of you has (or can make) a version of this series that applies
cleanly to master, I'd like to get it merged (perhaps with one or two
minor tweaks that I could take care of).
d
^ permalink raw reply [flat|nested] 10+ messages in thread
* Re: [PATCH v3 0/4] Retrieve GPG keys asynchronously.
2019-09-03 23:49 ` [PATCH v3 0/4] Retrieve GPG keys asynchronously David Bremner
@ 2019-09-12 1:33 ` Daniel Kahn Gillmor
0 siblings, 0 replies; 10+ messages in thread
From: Daniel Kahn Gillmor @ 2019-09-12 1:33 UTC (permalink / raw)
To: David Bremner, David Edmondson, notmuch
[-- Attachment #1: Type: text/plain, Size: 815 bytes --]
On Tue 2019-09-03 20:49:13 -0300, David Bremner wrote:
> David Edmondson <dme@dme.org> writes:
>
>> Retrieve GPG keys asynchronously.
[…]
> I went back to this series to try and do the last minor things my self,
> but unfortunately I got lost in trying to do the rebase. I think it
> collides with a couple of dkg's fixes (9300defd6 and 3c752b855f). If
> either of you has (or can make) a version of this series that applies
> cleanly to master, I'd like to get it merged (perhaps with one or two
> minor tweaks that I could take care of).
In id:87blw1rldy.fsf@tethera.net, I've just sent v4 of this series,
revised based on the two fixes from me thatyou've rightly identified as
having stepped on its toes.
I believe it does what dme expects it to do, and v4 applies to master.
--dkg
[-- Attachment #2: signature.asc --]
[-- Type: application/pgp-signature, Size: 227 bytes --]
^ permalink raw reply [flat|nested] 10+ messages in thread
end of thread, other threads:[~2019-09-12 1:33 UTC | newest]
Thread overview: 10+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2018-10-01 16:06 [PATCH v3 0/4] Retrieve GPG keys asynchronously David Edmondson
2018-10-01 16:06 ` [PATCH v3 1/4] emacs: Asynchronous retrieval of GPG keys David Edmondson
2019-01-15 2:08 ` David Bremner
2019-01-19 11:15 ` David Edmondson
2019-01-19 12:47 ` David Bremner
2018-10-01 16:06 ` [PATCH v3 2/4] emacs: Minor refactoring of crypto code David Edmondson
2018-10-01 16:06 ` [PATCH v3 3/4] emacs: Add notmuch-crypto-gpg-program and use it David Edmondson
2018-10-01 16:06 ` [PATCH v3 4/4] emacs: Improve the reporting of key activity David Edmondson
2019-09-03 23:49 ` [PATCH v3 0/4] Retrieve GPG keys asynchronously David Bremner
2019-09-12 1:33 ` Daniel Kahn Gillmor
Code repositories for project(s) associated with this public inbox
https://yhetil.org/notmuch.git/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).