[PATCH 1/2] emacs: Use pcase in notmuch-search-insert-field

[PATCH 1/2] emacs: Use pcase in notmuch-search-insert-field

[David Edmondson]

Rather than lots of string-equal calls, use the pcase macro.
---
 emacs/notmuch.el | 44 +++++++++++++++++++++++---------------------
 1 file changed, 23 insertions(+), 21 deletions(-)

diff --git a/emacs/notmuch.el b/emacs/notmuch.el
index 83bcee57..efbf5bd0 100644
--- a/emacs/notmuch.el
+++ b/emacs/notmuch.el
@@ -65,7 +65,9 @@
 
 ;;; Code:
 
-(eval-when-compile (require 'cl-lib))
+(eval-when-compile
+  (require 'cl-lib)
+  (require 'pcase))
 
 (require 'mm-view)
 (require 'message)
@@ -822,26 +824,26 @@ non-authors is found, assume that all of the authors match."
       (insert padding))))
 
 (defun notmuch-search-insert-field (field format-string result)
-  (cond
-   ((string-equal field "date")
-    (insert (propertize (format format-string (plist-get result :date_relative))
-			'face 'notmuch-search-date)))
-   ((string-equal field "count")
-    (insert (propertize (format format-string
-				(format "[%s/%s]" (plist-get result :matched)
-					(plist-get result :total)))
-			'face 'notmuch-search-count)))
-   ((string-equal field "subject")
-    (insert (propertize (format format-string
-				(notmuch-sanitize (plist-get result :subject)))
-			'face 'notmuch-search-subject)))
-   ((string-equal field "authors")
-    (notmuch-search-insert-authors
-     format-string (notmuch-sanitize (plist-get result :authors))))
-   ((string-equal field "tags")
-    (let ((tags (plist-get result :tags))
-	  (orig-tags (plist-get result :orig-tags)))
-      (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))
+  (pcase field
+    ("date"
+     (insert (propertize (format format-string (plist-get result :date_relative))
+			 'face 'notmuch-search-date)))
+    ("count"
+     (insert (propertize (format format-string
+				 (format "[%s/%s]" (plist-get result :matched)
+					 (plist-get result :total)))
+			 'face 'notmuch-search-count)))
+    ("subject"
+     (insert (propertize (format format-string
+				 (notmuch-sanitize (plist-get result :subject)))
+			 'face 'notmuch-search-subject)))
+    ("authors"
+     (notmuch-search-insert-authors format-string
+				    (notmuch-sanitize (plist-get result :authors))))
+    ("tags"
+     (let ((tags (plist-get result :tags))
+	   (orig-tags (plist-get result :orig-tags)))
+       (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))
 
 (defun notmuch-search-show-result (result pos)
   "Insert RESULT at POS."
-- 
2.29.2

[PATCH 2/2] emacs: Allow functions in notmuch-search-result-format

[David Edmondson]

If the car of an element in notmuch-search-result-format is a
function, insert the result of calling the function into the buffer.

This allows a user to generate custom fields in the output of a search
result. For example, with:

(defun -notmuch-result-flags (format-string result)
  (let ((tags-to-letters '(("flagged" . "!")
			   ("unread" . "u")
			   ("mine" . "m")
			   ("sent" . "s")
			   ("replied" . "r")))
	(tags (plist-get result :tags)))

    (format format-string
	    (mapconcat (lambda (t2l)
			 (if (member (car t2l) tags)
			     (cdr t2l)
			   " "))
		       tags-to-letters ""))))

(setq notmuch-search-result-format '((-notmuch-result-flags . "%s ")
				     ("date" . "%12s ")
				     ("count" . "%9s ")
				     ("authors" . "%-30s ")
				     ("subject" . "%s ")
				     ("tags" . "(%s)")))

The first few characters on each line of the search result are used to
show information about some significant tags associated with the
thread.
---
 emacs/notmuch.el | 45 +++++++++++++++++++++++++--------------------
 1 file changed, 25 insertions(+), 20 deletions(-)

diff --git a/emacs/notmuch.el b/emacs/notmuch.el
index efbf5bd0..92cb5202 100644
--- a/emacs/notmuch.el
+++ b/emacs/notmuch.el
@@ -824,26 +824,31 @@ non-authors is found, assume that all of the authors match."
       (insert padding))))
 
 (defun notmuch-search-insert-field (field format-string result)
-  (pcase field
-    ("date"
-     (insert (propertize (format format-string (plist-get result :date_relative))
-			 'face 'notmuch-search-date)))
-    ("count"
-     (insert (propertize (format format-string
-				 (format "[%s/%s]" (plist-get result :matched)
-					 (plist-get result :total)))
-			 'face 'notmuch-search-count)))
-    ("subject"
-     (insert (propertize (format format-string
-				 (notmuch-sanitize (plist-get result :subject)))
-			 'face 'notmuch-search-subject)))
-    ("authors"
-     (notmuch-search-insert-authors format-string
-				    (notmuch-sanitize (plist-get result :authors))))
-    ("tags"
-     (let ((tags (plist-get result :tags))
-	   (orig-tags (plist-get result :orig-tags)))
-       (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))
+  (cond
+   ((functionp field)
+    (insert (funcall field format-string result)))
+
+   ((stringp field)
+    (pcase field
+      ("date"
+       (insert (propertize (format format-string (plist-get result :date_relative))
+			   'face 'notmuch-search-date)))
+      ("count"
+       (insert (propertize (format format-string
+				   (format "[%s/%s]" (plist-get result :matched)
+					   (plist-get result :total)))
+			   'face 'notmuch-search-count)))
+      ("subject"
+       (insert (propertize (format format-string
+				   (notmuch-sanitize (plist-get result :subject)))
+			   'face 'notmuch-search-subject)))
+      ("authors"
+       (notmuch-search-insert-authors format-string
+				      (notmuch-sanitize (plist-get result :authors))))
+      ("tags"
+       (let ((tags (plist-get result :tags))
+	     (orig-tags (plist-get result :orig-tags)))
+	 (insert (format format-string (notmuch-tag-format-tags tags orig-tags)))))))))
 
 (defun notmuch-search-show-result (result pos)
   "Insert RESULT at POS."
-- 
2.29.2