From: Mark Walters <markwalters1009@gmail.com>
To: notmuch@notmuchmail.org
Subject: [PATCH v3] emacs: address completion, allow sender/recipient and filters
Date: Mon, 16 May 2016 08:36:51 +0100 [thread overview]
Message-ID: <1463384211-13086-1-git-send-email-markwalters1009@gmail.com> (raw)
In-Reply-To: <87h9e11vq1.fsf@steelpick.2x.cz>
This commit lets the user customize the address completion.
The first change controls whether to build the address completion list
based on messages you have sent or you have received (the latter is
much faster).
The second change add a possible filter query to limit the messages
used -- for example, setting this to date:1y.. would limit the
address completions to addresses used in the last year. This speeds up
the address harvest and may also make the search less cluttered as old
addresses may well no longer be valid.
---
This version uses the docstrings suggested my Michal (which are much
better than mine), and renames some variables, as he suggested, to
make the code clearer.
I wondered about allowing the user to specify completion based on
message "sent or received", rather than either sent, or received, but
think that is adding too much mess. We could also allow completion
based on any messages in the database, which would the include
completion based on messages received via mailing lists or
distribution lists.
I also note that if the user enters a bad query into the filter query
box (eg 6M.. rather than date:6M..) they may get an obscure error as
notmuch/xapian fails. I don't see a goo way round that so have left
that as a "don't do that" case.
Best wishes
Mark
emacs/notmuch-address.el | 119 ++++++++++++++++++++++++++++++++---------------
emacs/notmuch-company.el | 2 +-
2 files changed, 82 insertions(+), 39 deletions(-)
diff --git a/emacs/notmuch-address.el b/emacs/notmuch-address.el
index aafbe5f..3dc5da9 100644
--- a/emacs/notmuch-address.el
+++ b/emacs/notmuch-address.el
@@ -28,15 +28,51 @@
;;
(declare-function company-manual-begin "company")
-(defcustom notmuch-address-command 'internal
- "The command which generates possible addresses. It must take a
-single argument and output a list of possible matches, one per
-line. The default value of `internal' uses built-in address
-completion."
+(defvar notmuch-address-last-harvest 0
+ "Time of last address harvest")
+
+(defvar notmuch-address-completions (make-hash-table :test 'equal)
+ "Hash of email addresses for completion during email composition.
+ This variable is set by calling `notmuch-address-harvest'.")
+
+(defvar notmuch-address-full-harvest-finished nil
+ "t indicates that full completion address harvesting has been
+finished")
+
+(defcustom notmuch-address-command '(sent nil)
+ "Determines how to generate address completion candidates.
+
+If it is a string then that string should be an external program
+which must take a single argument (searched string) and output a
+list of completion candidates, one per line.
+
+Alternatively, it can be a (non-nil) list, in which case internal
+completion is used; in this case the list should have form
+'(DIRECTION FILTER), where DIRECTION is either sent or received
+and specifies whether the candidates are searched in messages
+sent by the user or received by the user (note received by is
+much faster), and FILTER is either nil or a filter-string, such
+as \"date:1y..\" to append to the query.
+
+If this variable is nil then address completion is disabled."
:type '(radio
- (const :tag "Use internal address completion" internal)
+ (list :tag "Use internal address completion"
+ (radio
+ :tag "Base completion on messages you have"
+ :value sent
+ (const :tag "sent" sent)
+ (const :tag "received" received))
+ (radio :tag "Filter messages used for completion"
+ (const :tag "Use all messages" nil)
+ (string :tag "Filter query")))
(const :tag "Disable address completion" nil)
- (string :tag "Use external completion command" "notmuch-addresses"))
+ (string :tag "Use external completion command"))
+ ;; We override set so that we can clear the cache when this changes
+ :set (lambda (symbol value)
+ (set-default symbol value)
+ (setq notmuch-address-last-harvest 0)
+ (setq notmuch-address-completions (clrhash notmuch-address-completions))
+ (setq notmuch-address-full-harvest-finished nil))
:group 'notmuch-send
:group 'notmuch-external)
@@ -51,17 +87,6 @@ to know how address selection is made by default."
:group 'notmuch-send
:group 'notmuch-external)
-(defvar notmuch-address-last-harvest 0
- "Time of last address harvest")
-
-(defvar notmuch-address-completions (make-hash-table :test 'equal)
- "Hash of email addresses for completion during email composition.
- This variable is set by calling `notmuch-address-harvest'.")
-
-(defvar notmuch-address-full-harvest-finished nil
- "t indicates that full completion address harvesting has been
-finished")
-
(defun notmuch-address-selection-function (prompt collection initial-input)
"Call (`completing-read'
PROMPT COLLECTION nil nil INITIAL-INPUT 'notmuch-address-history)"
@@ -83,7 +108,8 @@ finished")
(defun notmuch-address-setup ()
(let* ((use-company (and notmuch-address-use-company
- (eq notmuch-address-command 'internal)
+ notmuch-address-command
+ (listp notmuch-address-command)
(require 'company nil t)))
(pair (cons notmuch-address-completion-headers-regexp
(if use-company
@@ -111,11 +137,11 @@ The candidates are taken from `notmuch-address-completions'."
elisp-based implementation or older implementation requiring
external commands."
(cond
- ((eq notmuch-address-command 'internal)
+ ((and notmuch-address-command (listp notmuch-address-command))
(when (not notmuch-address-full-harvest-finished)
;; First, run quick synchronous harvest based on what the user
;; entered so far
- (notmuch-address-harvest (format "to:%s*" original) t))
+ (notmuch-address-harvest original t))
(prog1 (notmuch-address-matching original)
;; Then start the (potentially long-running) full asynchronous harvest if necessary
(notmuch-address-harvest-trigger)))
@@ -191,32 +217,49 @@ external commands."
The car is a partial harvest, and the cdr is a full harvest")
-(defun notmuch-address-harvest (&optional filter-query synchronous callback)
- "Collect addresses completion candidates. It queries the
-notmuch database for all messages sent by the user optionally
-matching FILTER-QUERY (if not nil). It collects the destination
-addresses from those messages and stores them in
-`notmuch-address-completions'. Address harvesting may take some
-time so the address collection runs asynchronously unless
-SYNCHRONOUS is t. In case of asynchronous execution, CALLBACK is
-called when harvesting finishes."
- (let* ((from-me-query (mapconcat (lambda (x) (concat "from:" x)) (notmuch-user-emails) " or "))
- (query (if filter-query
- (format "(%s) and (%s)" from-me-query filter-query)
- from-me-query))
+(defun notmuch-address-harvest (&optional addr-prefix synchronous callback)
+ "Collect addresses completion candidates.
+
+It queries the notmuch database for messages sent/received (as
+configured with `notmuch-address-command`) by the user, collects
+destination/source addresses from those messages and stores them
+in `notmuch-address-completions'.
+
+If ADDR-PREFIX is not nil, only messages with to/from addresses
+matching ADDR-PREFIX*' are queried.
+
+Address harvesting may take some time so the address collection runs
+asynchronously unless SYNCHRONOUS is t. In case of asynchronous
+execution, CALLBACK is called when harvesting finishes."
+
+ (let* ((sent (eq (car notmuch-address-command) 'sent))
+ (config-query (cadr notmuch-address-command))
+ (prefix-query (when addr-prefix
+ (format "%s:%s*" (if sent "to" "from") addr-prefix)))
+ (from-or-to-me-query
+ (mapconcat (lambda (x)
+ (concat (if sent "from:" "to:") x))
+ (notmuch-user-emails) " or "))
+ (query (if (or prefix-query config-query)
+ (concat (format "(%s)" from-or-to-me-query)
+ (when prefix-query
+ (format " and (%s)" prefix-query))
+ (when config-query
+ (format " and (%s)" config-query)))
+ from-or-to-me-query))
(args `("address" "--format=sexp" "--format-version=2"
- "--output=recipients"
+ ,(if sent "--output=recipients" "--output=sender")
"--deduplicate=address"
,query)))
(if synchronous
(mapc #'notmuch-address-harvest-addr
(apply 'notmuch-call-notmuch-sexp args))
;; Asynchronous
- (let* ((current-proc (if filter-query
+ (let* ((current-proc (if addr-prefix
(car notmuch-address-harvest-procs)
(cdr notmuch-address-harvest-procs)))
(proc-name (format "notmuch-address-%s-harvest"
- (if filter-query "partial" "full")))
+ (if addr-prefix "partial" "full")))
(proc-buf (concat " *" proc-name "*")))
;; Kill any existing process
(when current-proc
@@ -228,7 +271,7 @@ called when harvesting finishes."
args))
(set-process-filter current-proc 'notmuch-address-harvest-filter)
(set-process-query-on-exit-flag current-proc nil)
- (if filter-query
+ (if addr-prefix
(setcar notmuch-address-harvest-procs current-proc)
(setcdr notmuch-address-harvest-procs current-proc)))))
;; return value
diff --git a/emacs/notmuch-company.el b/emacs/notmuch-company.el
index b881d6d..dcb59cd 100644
--- a/emacs/notmuch-company.el
+++ b/emacs/notmuch-company.el
@@ -72,7 +72,7 @@
(lambda (callback)
;; First run quick asynchronous harvest based on what the user entered so far
(notmuch-address-harvest
- (format "to:%s*" arg) nil
+ arg nil
(lambda (_proc _event)
(funcall callback (notmuch-address-matching arg))
;; Then start the (potentially long-running) full asynchronous harvest if necessary
--
2.1.4
next prev parent reply other threads:[~2016-05-16 7:37 UTC|newest]
Thread overview: 9+ messages / expand[flat|nested] mbox.gz Atom feed top
2015-12-20 9:07 [PATCH] emacs: address completion, allow sender/recipient and filters Mark Walters
2015-12-28 11:50 ` Michal Sojka
2016-05-13 15:28 ` [PATCH v2] " Mark Walters
2016-05-13 21:41 ` Michal Sojka
2016-05-16 7:36 ` Mark Walters [this message]
2016-05-17 11:53 ` [PATCH v3] " Michal Sojka
2016-05-18 8:06 ` [PATCH] " Mark Walters
2016-05-18 12:29 ` Michal Sojka
2016-05-19 14:45 ` Tomi Ollila
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://notmuchmail.org/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1463384211-13086-1-git-send-email-markwalters1009@gmail.com \
--to=markwalters1009@gmail.com \
--cc=notmuch@notmuchmail.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://yhetil.org/notmuch.git/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).