From: Austin Clements <amdragon@MIT.EDU>
To: notmuch@notmuchmail.org
Subject: [PATCH 1/7] emacs: Centralize notmuch command error handling
Date: Sat, 15 Dec 2012 00:15:07 -0500 [thread overview]
Message-ID: <1355548513-10085-2-git-send-email-amdragon@mit.edu> (raw)
In-Reply-To: <1355548513-10085-1-git-send-email-amdragon@mit.edu>
This provides library functions for unified handling of errors from
the notmuch CLI. Follow-up patches will convert some scattered error
handling to use this and add error handling where we currently ignore
errors.
---
emacs/notmuch-lib.el | 53 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 53 insertions(+)
diff --git a/emacs/notmuch-lib.el b/emacs/notmuch-lib.el
index 9c4ee71..851098f 100644
--- a/emacs/notmuch-lib.el
+++ b/emacs/notmuch-lib.el
@@ -316,6 +316,59 @@ string), a property list of face attributes, or a list of these."
(put-text-property pos next 'face (cons face cur))
(setq pos next)))))
+(defun notmuch-pop-up-error (msg)
+ "Pop up an error buffer displaying MSG.
+
+This will accumulate error messages in the errors buffer until
+the user dismisses it."
+
+ (let ((buf (get-buffer-create "*Notmuch errors*")))
+ (with-current-buffer buf
+ (view-mode-enter nil #'kill-buffer)
+ (let ((inhibit-read-only t))
+ (insert msg)
+ (unless (bolp)
+ (insert "\n"))
+ (goto-char (point-min))))
+ (pop-to-buffer buf)))
+
+(defun notmuch-check-exit-status (exit-status command &optional output err-file)
+ "If EXIT-STATUS is non-zero, pop up an error buffer and signal an error.
+
+If EXIT-STATUS is non-zero, pop up a notmuch error buffer
+describing the error and signal an Elisp error. EXIT-STATUS must
+be a number indicating the exit status code of a process or a
+string describing the signal that terminated the process (such as
+returned by `call-process'). COMMAND must be a list giving the
+command and its arguments. OUTPUT, if provided, is a string
+giving the output of command. ERR-FILE, if provided, is the name
+of a file containing the error output of command. OUTPUT and the
+contents of ERR-FILE will be included in the error message."
+
+ ;; This is implemented as a cond to make it easy to expand.
+ (cond
+ ((eq exit-status 0) t)
+ (t
+ (notmuch-pop-up-error
+ (concat
+ (format "Error invoking notmuch. %s exited with %s%s.\n"
+ (mapconcat #'identity command " ")
+ ;; Signal strings look like "Terminated", hence the
+ ;; colon.
+ (if (integerp exit-status) "status " "signal: ")
+ exit-status)
+ (when err-file
+ (concat "Error:\n"
+ (with-temp-buffer
+ (insert-file-contents err-file)
+ (if (eobp)
+ "(no error output)\n"
+ (buffer-string)))))
+ (when (and output (not (equal output "")))
+ (format "Output:\n%s" output))))
+ ;; Mimic `process-lines'
+ (error "%s exited with status %s" (car command) exit-status))))
+
;; Compatibility functions for versions of emacs before emacs 23.
;;
;; Both functions here were copied from emacs 23 with the following copyright:
--
1.7.10.4
next prev parent reply other threads:[~2012-12-15 5:15 UTC|newest]
Thread overview: 15+ messages / expand[flat|nested] mbox.gz Atom feed top
2012-12-15 5:15 [PATCH 0/7] Improve Emacs CLI error handling Austin Clements
2012-12-15 5:15 ` Austin Clements [this message]
2012-12-15 16:20 ` [PATCH 1/7] emacs: Centralize notmuch command " Tomi Ollila
2012-12-15 19:45 ` Austin Clements
2012-12-15 5:15 ` [PATCH 2/7] emacs: Use unified error handling in notmuch-call-notmuch-process Austin Clements
2012-12-15 9:30 ` Mark Walters
2012-12-15 19:51 ` Austin Clements
2012-12-15 5:15 ` [PATCH 3/7] emacs: Factor out synchronous notmuch JSON invocations Austin Clements
2012-12-15 5:15 ` [PATCH 4/7] emacs: Improve error handling for notmuch-call-notmuch-json Austin Clements
2012-12-15 5:15 ` [PATCH 5/7] test: Test show's handling of subprocess errors Austin Clements
2012-12-15 5:15 ` [PATCH 6/7] emacs: Use unified error handling in search Austin Clements
2012-12-15 9:33 ` Mark Walters
2012-12-15 19:52 ` Austin Clements
2012-12-15 5:15 ` [PATCH 7/7] test: Test search's handling of subprocess errors Austin Clements
2012-12-15 9:48 ` Mark Walters
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://notmuchmail.org/
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1355548513-10085-2-git-send-email-amdragon@mit.edu \
--to=amdragon@mit.edu \
--cc=notmuch@notmuchmail.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://yhetil.org/notmuch.git/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).