[PATCH 0/2] spawning-related cleanups

[PATCH 0/2] spawning-related cleanups

[Eric Wong]

Eric Wong (2):
  spawn_pp: cleanup, error check and more descriptive errors
  test_common: avoid needless fcntl in start_script

 lib/PublicInbox/SpawnPP.pm    | 32 +++++++++++---------------------
 lib/PublicInbox/TestCommon.pm | 13 +++----------
 2 files changed, 14 insertions(+), 31 deletions(-)

[PATCH 1/2] spawn_pp: cleanup, error checks and descriptive errors

[Eric Wong]

The pipe(2) call needs to be checked for failure.  While we're
at it, none of this is affected by unicode_strings, so Perl v5.12
is safe to use and gets rid of the strict.pm overhead.

We can also `die' directly since it's pure Perl and not contort
our Perl code to the assumptions of the Inline::C version.

`die' already implies a failure, so follow existing conventions
of just having the failing function or op name.

We can also rely on the grep op for filtering out non-system
signals to avoid writing a loop ourselves.

Finally, drop a needless `undef' on the read side of the pipe
since it's already closed immediately in the child.
---
 lib/PublicInbox/SpawnPP.pm | 32 +++++++++++---------------------
 1 file changed, 11 insertions(+), 21 deletions(-)

diff --git a/lib/PublicInbox/SpawnPP.pm b/lib/PublicInbox/SpawnPP.pm
index 6d7e2c34..7a5793f6 100644
--- a/lib/PublicInbox/SpawnPP.pm
+++ b/lib/PublicInbox/SpawnPP.pm
@@ -1,11 +1,10 @@
-# Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
+# Copyright (C) all contributors <meta@public-inbox.org>
 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
 
 # Pure-Perl implementation of "spawn".  This can't take advantage
 # of vfork, so no speedups under Linux for spawning from large processes.
 package PublicInbox::SpawnPP;
-use strict;
-use v5.10.1;
+use v5.12;
 use POSIX qw(dup2 _exit setpgid :signal_h);
 
 # Pure Perl implementation for folks that do not use Inline::C
@@ -13,15 +12,11 @@ sub pi_fork_exec ($$$$$$$) {
 	my ($redir, $f, $cmd, $env, $rlim, $cd, $pgid) = @_;
 	my $old = POSIX::SigSet->new();
 	my $set = POSIX::SigSet->new();
-	$set->fillset or die "fillset failed: $!";
-	sigprocmask(SIG_SETMASK, $set, $old) or die "can't block signals: $!";
+	$set->fillset or die "sigfillset: $!";
+	sigprocmask(SIG_SETMASK, $set, $old) or die "SIG_SETMASK(set): $!";
 	my $syserr;
-	pipe(my ($r, $w));
-	my $pid = fork;
-	unless (defined $pid) { # compat with Inline::C version
-		$syserr = $!;
-		$pid = -1;
-	}
+	pipe(my ($r, $w)) or die "pipe: $!";
+	my $pid = fork // die "fork (+exec) @$cmd: $!\n";
 	if ($pid == 0) {
 		close $r;
 		$SIG{__DIE__} = sub {
@@ -38,9 +33,7 @@ sub pi_fork_exec ($$$$$$$) {
 		if ($pgid >= 0 && !defined(setpgid(0, $pgid))) {
 			die "setpgid(0, $pgid): $!";
 		}
-		for (keys %SIG) {
-			$SIG{$_} = 'DEFAULT' if substr($_, 0, 1) ne '_';
-		}
+		$SIG{$_} = 'DEFAULT' for grep(!/\A__/, keys %SIG);
 		if ($cd ne '') {
 			chdir $cd or die "chdir $cd: $!";
 		}
@@ -49,25 +42,22 @@ sub pi_fork_exec ($$$$$$$) {
 			BSD::Resource::setrlimit($r, $soft, $hard) or
 				die "setrlimit($r=[$soft,$hard]: $!)";
 		}
-		$old->delset(POSIX::SIGCHLD) or die "delset SIGCHLD: $!";
-		sigprocmask(SIG_SETMASK, $old) or die "SETMASK: ~SIGCHLD: $!";
+		$old->delset(POSIX::SIGCHLD) or die "sigdelset CHLD: $!";
+		sigprocmask(SIG_SETMASK, $old) or die "SIG_SETMASK ~CHLD: $!";
 		$cmd->[0] = $f;
 		if ($ENV{MOD_PERL}) {
 			@$cmd = (which('env'), '-i', @$env, @$cmd);
 		} else {
 			%ENV = map { split(/=/, $_, 2) } @$env;
 		}
-		undef $r;
 		exec { $f } @$cmd;
 		die "exec @$cmd failed: $!";
 	}
 	close $w;
-	sigprocmask(SIG_SETMASK, $old) or die "can't unblock signals: $!";
+	sigprocmask(SIG_SETMASK, $old) or die "SIG_SETMASK(old): $!";
 	if (my $cerrnum = do { local $/, <$r> }) {
-		$pid = -1;
 		$! = $cerrnum;
-	} else {
-		$! = $syserr;
+		die "forked child $@: $!";
 	}
 	$pid;
 }

[PATCH 2/2] test_common: avoid needless fcntl in start_script

[Eric Wong]

POSIX::dup2 does not do anything in addition to dup2(2) and is
thus immune to Perl automatically setting FD_CLOEXEC on FDs it
makes into IO objects/globs.
---
 lib/PublicInbox/TestCommon.pm | 13 +++----------
 1 file changed, 3 insertions(+), 10 deletions(-)

diff --git a/lib/PublicInbox/TestCommon.pm b/lib/PublicInbox/TestCommon.pm
index 888c1f1e..179f8bae 100644
--- a/lib/PublicInbox/TestCommon.pm
+++ b/lib/PublicInbox/TestCommon.pm
@@ -479,16 +479,9 @@ sub start_script {
 		# pretend to be systemd (cf. sd_listen_fds(3))
 		# 3 == SD_LISTEN_FDS_START
 		my $fd;
-		for ($fd = 0; 1; $fd++) {
-			my $s = $opt->{$fd};
-			last if $fd >= 3 && !defined($s);
-			next unless $s;
-			my $fl = fcntl($s, F_GETFD, 0);
-			if (($fl & FD_CLOEXEC) != FD_CLOEXEC) {
-				warn "got FD:".fileno($s)." w/o CLOEXEC\n";
-			}
-			fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
-			dup2(fileno($s), $fd) or die "dup2 failed: $!\n";
+		for ($fd = 0; $fd < 3 || defined($opt->{$fd}); $fd++) {
+			my $io = $opt->{$fd} // next;
+			dup2(fileno($io), $fd) or die "dup2($io, $fd): $!";
 		}
 		%ENV = (%ENV, %$env) if $env;
 		my $fds = $fd - 3;

[PATCH v2 2/2] test_common: avoid needless fcntl in start_script

[Eric Wong]

POSIX::dup2 does not do anything in addition to dup2(2) and is
thus immune to Perl automatically setting FD_CLOEXEC on FDs it
makes into IO objects/globs.  We only need to account for the
case when both args for dup2 are identical, in which case the
kernel treats it as a no-op and then thus we need to clear
FD_CLOEXEC ourselves.
---
  v2 now accounts for oldfd == newfd for dup2(2).

Interdiff:
  diff --git a/lib/PublicInbox/TestCommon.pm b/lib/PublicInbox/TestCommon.pm
  index 179f8bae..b36c71a6 100644
  --- a/lib/PublicInbox/TestCommon.pm
  +++ b/lib/PublicInbox/TestCommon.pm
  @@ -6,7 +6,7 @@ package PublicInbox::TestCommon;
   use strict;
   use parent qw(Exporter);
   use v5.10.1;
  -use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD :seek);
  +use Fcntl qw(F_SETFD :seek);
   use POSIX qw(dup2);
   use IO::Socket::INET;
   use File::Spec;
  @@ -481,7 +481,12 @@ sub start_script {
   		my $fd;
   		for ($fd = 0; $fd < 3 || defined($opt->{$fd}); $fd++) {
   			my $io = $opt->{$fd} // next;
  -			dup2(fileno($io), $fd) or die "dup2($io, $fd): $!";
  +			my $old = fileno($io);
  +			if ($old == $fd) {
  +				fcntl($io, F_SETFD, 0) // die "F_SETFD: $!";
  +			} else {
  +				dup2($old, $fd) // die "dup2($old, $fd): $!";
  +			}
   		}
   		%ENV = (%ENV, %$env) if $env;
   		my $fds = $fd - 3;

 lib/PublicInbox/TestCommon.pm | 18 ++++++++----------
 1 file changed, 8 insertions(+), 10 deletions(-)

diff --git a/lib/PublicInbox/TestCommon.pm b/lib/PublicInbox/TestCommon.pm
index 888c1f1e..b36c71a6 100644
--- a/lib/PublicInbox/TestCommon.pm
+++ b/lib/PublicInbox/TestCommon.pm
@@ -6,7 +6,7 @@ package PublicInbox::TestCommon;
 use strict;
 use parent qw(Exporter);
 use v5.10.1;
-use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD :seek);
+use Fcntl qw(F_SETFD :seek);
 use POSIX qw(dup2);
 use IO::Socket::INET;
 use File::Spec;
@@ -479,16 +479,14 @@ sub start_script {
 		# pretend to be systemd (cf. sd_listen_fds(3))
 		# 3 == SD_LISTEN_FDS_START
 		my $fd;
-		for ($fd = 0; 1; $fd++) {
-			my $s = $opt->{$fd};
-			last if $fd >= 3 && !defined($s);
-			next unless $s;
-			my $fl = fcntl($s, F_GETFD, 0);
-			if (($fl & FD_CLOEXEC) != FD_CLOEXEC) {
-				warn "got FD:".fileno($s)." w/o CLOEXEC\n";
+		for ($fd = 0; $fd < 3 || defined($opt->{$fd}); $fd++) {
+			my $io = $opt->{$fd} // next;
+			my $old = fileno($io);
+			if ($old == $fd) {
+				fcntl($io, F_SETFD, 0) // die "F_SETFD: $!";
+			} else {
+				dup2($old, $fd) // die "dup2($old, $fd): $!";
 			}
-			fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
-			dup2(fileno($s), $fd) or die "dup2 failed: $!\n";
 		}
 		%ENV = (%ENV, %$env) if $env;
 		my $fds = $fd - 3;