handling unquoted utf8 in the headers

handling unquoted utf8 in the headers

[Konstantin Ryabitsev]

Hello:

There's a bit of inconsistency handling messages with utf8 content in the
headers:

https://lore.kernel.org/b4-sent/20221122-gud-shadow-plane-v1-0-9de3afa3383e@tronnes.org/

You can see that the name in the From: line is mangled, but in the thread
overview it is displayed correctly.

I know older SMTP standards still require 7bit escaping in the headers, but
with SMTPUTF8 being very widely available, it should be possible to store and
properly display messages with 8bit unicode in the headers.

-K

[PATCH] eml: header_raw converts octets to Perl UTF-8

[Eric Wong]

Konstantin Ryabitsev <konstantin@linuxfoundation.org> wrote:
> Hello:
> 
> There's a bit of inconsistency handling messages with utf8 content in the
> headers:
> 
> https://lore.kernel.org/b4-sent/20221122-gud-shadow-plane-v1-0-9de3afa3383e@tronnes.org/
> 
> You can see that the name in the From: line is mangled, but in the thread
> overview it is displayed correctly.

Thanks, the overview and Xapian/SQLite DBs were correct because
PublicInbox::Smsg->populate had a special case.

The below case generalizes it to all HTML displays and removes
the special case.

> I know older SMTP standards still require 7bit escaping in the headers, but
> with SMTPUTF8 being very widely available, it should be possible to store and
> properly display messages with 8bit unicode in the headers.

Oops, I barely knew about it :x

Anyways, the below should fix it and I've deployed it to:
https://yhbt.net/lore/b4-sent/20221122-gud-shadow-plane-v1-0-9de3afa3383e@tronnes.org/

I'm pretty sure it's safe, but my HW is problematic and I'm not
sure if it can finish a full reindex.

---------8<--------
Subject: [PATCH] eml: header_raw converts octets to Perl UTF-8

This fixes the display of raw (non-RFC 2047) names and subjects
in HTML message views.

SMTPUTF8 (RFC 6531) allows raw UTF-8 in headers without RFC 2047
encoding, so let Perl handle it as a character sequence for the
rest of our consumers.  Thus, the old special case in
PublicInbox::Smsg->populate is no longer necessary and gone.

The one regression notice so far (and fixed here) is compressed
IMAP envelope responses still needs raw bytes since the zlib
wrapper is designed for octets, Perl UTF-8 bytes.  Thus we
reverse utf8::decode with utf8::encode in PublicInbox::IMAP::_esc.

->header_set also forces encoding to bytes, since all existing
callers would either be dealing with ->header_raw results or
be RFC-2047-encoded anyways.

Reindexing is not necessary with this change due to the prior
PublicInbox::Smsg->populate special case.

Reported-by: Konstantin Ryabitsev <konstantin@linuxfoundation.org>
Link: https://public-inbox.org/meta/20221124153715.3nenjpjzj43vqxr2@meerkat.local/
---
 lib/PublicInbox/Eml.pm  |  8 +++++---
 lib/PublicInbox/IMAP.pm |  2 ++
 lib/PublicInbox/Smsg.pm |  3 ---
 t/imapd.t               | 28 ++++++++++++++++++++++++++++
 t/psgi_search.t         |  7 ++++++-
 5 files changed, 41 insertions(+), 7 deletions(-)

diff --git a/lib/PublicInbox/Eml.pm b/lib/PublicInbox/Eml.pm
index 485f637a..8b999e1a 100644
--- a/lib/PublicInbox/Eml.pm
+++ b/lib/PublicInbox/Eml.pm
@@ -1,4 +1,4 @@
-# Copyright (C) 2020-2021 all contributors <meta@public-inbox.org>
+# Copyright (C) all contributors <meta@public-inbox.org>
 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
 #
 # Lazy MIME parser, it still slurps the full message but keeps short
@@ -144,6 +144,7 @@ sub header_raw {
 	my $re = re_memo($_[1]);
 	my @v = (${ $_[0]->{hdr} } =~ /$re/g);
 	for (@v) {
+		utf8::decode($_); # SMTPUTF8
 		# for compatibility w/ Email::Simple::Header,
 		s/\s+\z//s;
 		s/\A\s+//s;
@@ -359,14 +360,15 @@ sub header_set {
 	$pfx .= ': ';
 	my $len = 78 - length($pfx);
 	@vals = map {;
+		utf8::encode(my $v = $_); # to bytes, support SMTPUTF8
 		# folding differs from Email::Simple::Header,
 		# we favor tabs for visibility (and space savings :P)
 		if (length($_) >= $len && (/\n[^ \t]/s || !/\n/s)) {
 			local $Text::Wrap::columns = $len;
 			local $Text::Wrap::huge = 'overflow';
-			$pfx . wrap('', "\t", $_) . $self->{crlf};
+			$pfx . wrap('', "\t", $v) . $self->{crlf};
 		} else {
-			$pfx . $_ . $self->{crlf};
+			$pfx . $v . $self->{crlf};
 		}
 	} @vals;
 	$$hdr =~ s!$re!shift(@vals) // ''!ge; # replace current headers, first
diff --git a/lib/PublicInbox/IMAP.pm b/lib/PublicInbox/IMAP.pm
index 1f65aa65..37317948 100644
--- a/lib/PublicInbox/IMAP.pm
+++ b/lib/PublicInbox/IMAP.pm
@@ -426,8 +426,10 @@ sub _esc ($) {
 	if (!defined($v)) {
 		'NIL';
 	} elsif ($v =~ /[{"\r\n%*\\\[]/) { # literal string
+		utf8::encode($v);
 		'{' . length($v) . "}\r\n" . $v;
 	} else { # quoted string
+		utf8::encode($v);
 		qq{"$v"}
 	}
 }
diff --git a/lib/PublicInbox/Smsg.pm b/lib/PublicInbox/Smsg.pm
index 2026c7d9..b132381b 100644
--- a/lib/PublicInbox/Smsg.pm
+++ b/lib/PublicInbox/Smsg.pm
@@ -99,9 +99,6 @@ sub populate {
 		# to protect git and NNTP clients
 		$val =~ tr/\0\t\n/   /;
 
-		# rare: in case headers have wide chars (not RFC2047-encoded)
-		utf8::decode($val);
-
 		# lower-case fields for read-only stuff
 		$self->{lc($f)} = $val;
 
diff --git a/t/imapd.t b/t/imapd.t
index 3c74aefd..cbd6c1b9 100644
--- a/t/imapd.t
+++ b/t/imapd.t
@@ -534,6 +534,34 @@ SKIP: {
 	}
 }
 
+{
+	ok(my $ic = $imap_client->new(%mic_opt), 'logged in');
+	my $mb = "$ibx[0]->{newsgroup}.$first_range";
+	ok($ic->examine($mb), "EXAMINE $mb");
+	my $uidnext = $ic->uidnext($mb); # we'll fetch BODYSTRUCTURE on this
+	my $im = $ibx[0]->importer(0);
+	$im->add(PublicInbox::Eml->new(<<EOF)) or BAIL_OUT;
+Subject: test Ævar
+Message-ID: <smtputf8-delivered-mess\@age>
+From: Ævar Arnfjörð Bjarmason <avarab\@example>
+To: git\@vger.kernel.org
+
+EOF
+	$im->done;
+	my $envl = $ic->get_envelope($uidnext);
+	is($envl->{subject}, 'test Ævar', 'UTF-8 subject');
+	is($envl->{sender}->[0]->{personalname}, 'Ævar Arnfjörð Bjarmason',
+		'UTF-8 sender[0].personalname');
+	SKIP: {
+		skip 'need compress for comparisons', 1 if !$can_compress;
+		ok($ic = $imap_client->new(%mic_opt), 'uncompressed logged in');
+		ok($ic && $ic->compress, 'compress enabled');
+		ok($ic->examine($mb), "EXAMINE $mb");
+		my $raw = $ic->get_envelope($uidnext);
+		is_deeply($envl, $raw, 'raw and compressed match');
+	}
+}
+
 $td->kill;
 $td->join;
 is($?, 0, 'no error in exited process') if !$ENV{TEST_KILL_IMAPD};
diff --git a/t/psgi_search.t b/t/psgi_search.t
index 3da93eda..8868f67e 100644
--- a/t/psgi_search.t
+++ b/t/psgi_search.t
@@ -1,5 +1,5 @@
 #!perl -w
-# Copyright (C) 2017-2021 all contributors <meta@public-inbox.org>
+# Copyright (C) all contributors <meta@public-inbox.org>
 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
 use strict;
 use v5.10.1;
@@ -103,6 +103,11 @@ test_psgi(sub { $www->call(@_) }, sub {
 		like($res->content, $mid_re, 'found mid in response');
 		chop($digits);
 	}
+	$res = $cb->(GET("/test/$mid/"));
+	$html = $res->content;
+	like($html, qr/\bFrom: &#198;var /,
+		"displayed Ævar's name properly in permalink From:");
+	unlike($html, qr/&#195;/, 'no raw octets in permalink HTML');
 
 	$res = $cb->(GET('/test/'));
 	$html = $res->content;
-- 
[1] getting weird SATA errors and disconnects and SMART is not
    telling me anything useful.  I suspect a wrong BIOS setting
    after replacing a CMOS battery, but so many knobs and it
    takes hours/days to reproduce :<

Re: [PATCH] eml: header_raw converts octets to Perl UTF-8

[Konstantin Ryabitsev]

On Thu, Nov 24, 2022 at 09:31:55PM +0000, Eric Wong wrote:
> The below case generalizes it to all HTML displays and removes
> the special case.

It looks good to me in some cursory tests, thank you!

-K

Re: [PATCH] eml: header_raw converts octets to Perl UTF-8

[Eric Wong]

Eric Wong <e@80x24.org> wrote:
> IMAP envelope responses still needs raw bytes since the zlib
> wrapper is designed for octets, Perl UTF-8 bytes.

That should say:
   wrapper is designed for octets, not Perl UTF-8 chars.

Fixed and pushed.  Thanks for testing.

[PATCH] content_hash: handle References as octets

[Eric Wong]

Konstantin Ryabitsev <konstantin@linuxfoundation.org> wrote:
> On Thu, Nov 24, 2022 at 09:31:55PM +0000, Eric Wong wrote:
> > The below case generalizes it to all HTML displays and removes
> > the special case.
> 
> It looks good to me in some cursory tests, thank you!

I just noticed this so far:
-------8<------
Subject: [PATCH] content_hash: handle References as octets

The alsa-devel archives on lore has some UTF-8 References:
headers, so we need to treat them as octets, again, otherwise
(re)indexing triggers cascading failures.

Fixes: 5198c976ce8b "eml: header_raw converts octets to Perl UTF-8"
---
 lib/PublicInbox/ContentHash.pm |  7 ++++---
 t/v2writable.t                 | 16 ++++++++++++++++
 2 files changed, 20 insertions(+), 3 deletions(-)

diff --git a/lib/PublicInbox/ContentHash.pm b/lib/PublicInbox/ContentHash.pm
index bacc9cdd..1afbb413 100644
--- a/lib/PublicInbox/ContentHash.pm
+++ b/lib/PublicInbox/ContentHash.pm
@@ -1,4 +1,4 @@
-# Copyright (C) 2018-2021 all contributors <meta@public-inbox.org>
+# Copyright (C) all contributors <meta@public-inbox.org>
 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
 
 # Unstable internal API.
@@ -63,8 +63,9 @@ sub content_digest ($;$) {
 	# do NOT consider the Message-ID as part of the content_hash
 	# if we got here, we've already got Message-ID reuse
 	my %seen = map { $_ => 1 } @{mids($eml)};
-	foreach my $mid (@{references($eml)}) {
-		$dig->add("ref\0$mid\0") unless $seen{$mid}++;
+	for (grep { !$seen{$_}++ } @{references($eml)}) {
+		utf8::encode($_);
+		$dig->add("ref\0$_\0");
 	}
 
 	# Only use Sender: if From is not present
diff --git a/t/v2writable.t b/t/v2writable.t
index ad946338..0d102204 100644
--- a/t/v2writable.t
+++ b/t/v2writable.t
@@ -283,6 +283,22 @@ EOF
 	is($msgs->[1]->{mid}, 'y'x244, 'stored truncated mid(2)');
 }
 
+if ('UTF-8 References') {
+	my @w;
+	local $SIG{__WARN__} = sub { push @w, @_ };
+	my $msg = <<EOM;
+From: a\@example.com
+Subject: b
+Message-ID: <horrible\@example>
+References: <\xc4\x80\@example>
+
+EOM
+	ok($im->add(PublicInbox::Eml->new($msg."a\n")), 'UTF-8 References 1');
+	ok($im->add(PublicInbox::Eml->new($msg."b\n")), 'UTF-8 References 2');
+	$im->done;
+	ok(!grep(/Wide character/, @w), 'no wide characters') or xbail(\@w);
+}
+
 my $tmp = {
 	inboxdir => "$inboxdir/non-existent/subdir",
 	name => 'nope',