From: "Eric Wong (Contractor, The Linux Foundation)" <e@80x24.org>
To: meta@public-inbox.org
Subject: [PATCH 12/34] v2writable: inject new Message-IDs on true duplicates
Date: Tue, 6 Mar 2018 08:42:20 +0000 [thread overview]
Message-ID: <20180306084242.19988-13-e@80x24.org> (raw)
In-Reply-To: <20180306084242.19988-1-e@80x24.org>
Since we'll need to support multiple Message-IDs anyways,
inject a new one if we hit a duplicate (or don't get one at
all).
Try to use a deterministic Message-Id for consistency, but give
up determinism and use a random Message-Id if an "attacker"
wants to prevent their message from being archived.
---
MANIFEST | 1 +
lib/PublicInbox/V2Writable.pm | 88 +++++++++++++++++++++++++++++++++----------
t/v2writable.t | 84 +++++++++++++++++++++++++++++++++++++++++
3 files changed, 154 insertions(+), 19 deletions(-)
create mode 100644 t/v2writable.t
diff --git a/MANIFEST b/MANIFEST
index 1aaf8ff..7366aa0 100644
--- a/MANIFEST
+++ b/MANIFEST
@@ -177,5 +177,6 @@ t/spawn.t
t/thread-all.t
t/thread-cycle.t
t/utf8.mbox
+t/v2writable.t
t/view.t
t/watch_maildir.t
diff --git a/lib/PublicInbox/V2Writable.pm b/lib/PublicInbox/V2Writable.pm
index 57cb7d3..6d73827 100644
--- a/lib/PublicInbox/V2Writable.pm
+++ b/lib/PublicInbox/V2Writable.pm
@@ -11,8 +11,8 @@ use PublicInbox::SearchIdxSkeleton;
use PublicInbox::MIME;
use PublicInbox::Git;
use PublicInbox::Import;
-use PublicInbox::MID qw(mid_clean mid_mime);
-use PublicInbox::ContentId qw(content_id);
+use PublicInbox::MID qw(mids);
+use PublicInbox::ContentId qw(content_id content_digest);
use PublicInbox::Inbox;
# an estimate of the post-packed size to the raw uncompressed size
@@ -62,21 +62,8 @@ sub add {
# leaking FDs to it...
$self->idx_init;
- my $mid = mid_clean(mid_mime($mime));
- my $num = $self->{skel}->{mm}->mid_insert($mid);
- if (!defined($num)) { # mid is already known
- $self->done; # ensure all subprocesses are done writing
-
- my $existing = $self->lookup_content($mime);
- warn "<$mid> resent\n" if $existing;
- return if $existing; # easy, don't store duplicates
-
- # reuse NNTP article number?
- warn "<$mid> reused for mismatched content\n";
- $self->idx_init;
- $num = $self->{skel}->{mm}->num_for($mid);
- }
-
+ my $num = num_for($self, $mime);
+ defined $num or return; # duplicate
my $im = $self->importer;
my $cmt = $im->add($mime);
$cmt = $im->get_mark($cmt);
@@ -95,6 +82,70 @@ sub add {
$mime;
}
+sub num_for {
+ my ($self, $mime) = @_;
+ my $mids = mids($mime->header_obj);
+ if (@$mids) {
+ my $mid = $mids->[0];
+ my $num = $self->{skel}->{mm}->mid_insert($mid);
+ return $num if defined($num); # common case
+
+ # crap, Message-ID is already known, hope somebody just resent:
+ $self->done; # write barrier, clears $self->{skel}
+ foreach my $m (@$mids) {
+ # read-only lookup now safe to do after above barrier
+ my $existing = $self->lookup_content($mime, $m);
+ if ($existing) {
+ warn "<$m> resent\n";
+ return; # easy, don't store duplicates
+ }
+ }
+
+ # very unlikely:
+ warn "<$mid> reused for mismatched content\n";
+ $self->idx_init;
+
+ # try the rest of the mids
+ foreach my $i (1..$#$mids) {
+ my $m = $mids->[$i];
+ $num = $self->{skel}->{mm}->mid_insert($m);
+ if (defined $num) {
+ warn "alternative <$m> for <$mid> found\n";
+ return $num;
+ }
+ }
+ }
+ # none of the existing Message-IDs are good, generate a new one:
+ num_for_harder($self, $mime);
+}
+
+sub num_for_harder {
+ my ($self, $mime) = @_;
+
+ my $hdr = $mime->header_obj;
+ my $dig = content_digest($mime);
+ my $mid = $dig->clone->hexdigest . '@localhost';
+ my $num = $self->{skel}->{mm}->mid_insert($mid);
+ unless (defined $num) {
+ # it's hard to spoof the last Received: header
+ my @recvd = $hdr->header_raw('Received');
+ $dig->add("Received: $_") foreach (@recvd);
+ $mid = $dig->clone->hexdigest . '@localhost';
+ $num = $self->{skel}->{mm}->mid_insert($mid);
+
+ # fall back to a random Message-ID and give up determinism:
+ until (defined($num)) {
+ $dig->add(rand);
+ $mid = $dig->clone->hexdigest . '@localhost';
+ warn "using random Message-ID <$mid> as fallback\n";
+ $num = $self->{skel}->{mm}->mid_insert($mid);
+ }
+ }
+ my @cur = $hdr->header_raw('Message-Id');
+ $hdr->header_set('Message-Id', @cur, "<$mid>");
+ $num;
+}
+
sub idx_part {
my ($self, $part) = @_;
$self->{idx_parts}->[$part];
@@ -268,13 +319,12 @@ sub import_init {
}
sub lookup_content {
- my ($self, $mime) = @_;
+ my ($self, $mime, $mid) = @_;
my $ibx = $self->{-inbox};
my $srch = $ibx->search;
my $cid = content_id($mime);
my $found;
- my $mid = mid_mime($mime);
$srch->each_smsg_by_mid($mid, sub {
my ($smsg) = @_;
$smsg->load_expand;
diff --git a/t/v2writable.t b/t/v2writable.t
new file mode 100644
index 0000000..bc2437a
--- /dev/null
+++ b/t/v2writable.t
@@ -0,0 +1,84 @@
+# Copyright (C) 2018 all contributors <meta@public-inbox.org>
+# License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
+use strict;
+use warnings;
+use Test::More;
+use PublicInbox::MIME;
+use PublicInbox::ContentId qw(content_digest);
+use File::Temp qw/tempdir/;
+foreach my $mod (qw(DBD::SQLite Search::Xapian)) {
+ eval "require $mod";
+ plan skip_all => "$mod missing for nntpd.t" if $@;
+}
+use_ok 'PublicInbox::V2Writable';
+my $mainrepo = tempdir('pi-v2writable-XXXXXX', TMPDIR => 1, CLEANUP => 1);
+my $ibx = {
+ mainrepo => $mainrepo,
+ name => 'test-v2writable',
+ version => 2,
+ -primary_address => 'test@example.com',
+};
+$ibx = PublicInbox::Inbox->new($ibx);
+my $mime = PublicInbox::MIME->create(
+ header => [
+ From => 'a@example.com',
+ To => 'test@example.com',
+ Subject => 'this is a subject',
+ 'Message-ID' => '<a-mid@b>',
+ Date => 'Fri, 02 Oct 1993 00:00:00 +0000',
+ ],
+ body => "hello world\n",
+);
+
+my $im = PublicInbox::V2Writable->new($ibx, 1);
+ok($im->add($mime), 'ordinary message added');
+{
+ my @warn;
+ local $SIG{__WARN__} = sub { push @warn, @_ };
+ is(undef, $im->add($mime), 'obvious duplicate rejected');
+ like(join(' ', @warn), qr/resent/, 'warned about resent message');
+
+ @warn = ();
+ $mime->header_set('Message-Id', '<a-mid@b>', '<c@d>');
+ ok($im->add($mime), 'secondary MID used');
+ like(join(' ', @warn), qr/mismatched/, 'warned about mismatch');
+ like(join(' ', @warn), qr/alternative/, 'warned about alternative');
+ is_deeply([ '<a-mid@b>', '<c@d>' ],
+ [ $mime->header_obj->header_raw('Message-Id') ],
+ 'no new Message-Id added');
+
+ @warn = ();
+ $mime->header_set('Message-Id', '<a-mid@b>');
+ $mime->body_set('different');
+ ok($im->add($mime), 'reused mid ok');
+ like(join(' ', @warn), qr/reused/, 'warned about reused MID');
+ my @mids = $mime->header_obj->header_raw('Message-Id');
+ is($mids[0], '<a-mid@b>', 'original mid not changed');
+ like($mids[1], qr/\A<\w+\@localhost>\z/, 'new MID added');
+ is(scalar(@mids), 2, 'only one new MID added');
+
+ @warn = ();
+ $mime->header_set('Message-Id', '<a-mid@b>');
+ $mime->body_set('this one needs a random mid');
+ my $gen = content_digest($mime)->hexdigest . '@localhost';
+ my $fake = PublicInbox::MIME->new($mime->as_string);
+ $fake->header_set('Message-Id', $gen);
+ ok($im->add($fake), 'fake added easily');
+ is_deeply(\@warn, [], 'no warnings from a faker');
+ ok($im->add($mime), 'random MID made');
+ like(join(' ', @warn), qr/using random/, 'warned about using random');
+ @mids = $mime->header_obj->header_raw('Message-Id');
+ is($mids[0], '<a-mid@b>', 'original mid not changed');
+ like($mids[1], qr/\A<\w+\@localhost>\z/, 'new MID added');
+ is(scalar(@mids), 2, 'only one new MID added');
+
+ @warn = ();
+ $mime->header_set('Message-Id');
+ ok($im->add($mime), 'random MID made for MID free message');
+ @mids = $mime->header_obj->header_raw('Message-Id');
+ like($mids[0], qr/\A<\w+\@localhost>\z/, 'mid was generated');
+ is(scalar(@mids), 1, 'new generated');
+}
+
+$im->done;
+done_testing();
--
EW
next prev parent reply other threads:[~2018-03-06 8:42 UTC|newest]
Thread overview: 36+ messages / expand[flat|nested] mbox.gz Atom feed top
2018-03-06 8:42 [v2 PATCH 00/34] duplicate handling, smaller Xapian DBs, date fixes Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 01/34] v2writable: delete ::Import obj when ->done Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 02/34] search: remove informational "warning" message Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 03/34] searchidx: add PID to error message when die-ing Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 04/34] content_id: special treatment for Message-Id headers Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 05/34] evcleanup: disable outside of daemon Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 06/34] v2writable: deduplicate detection on add Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 07/34] evcleanup: do not create event loop if nothing was registered Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 08/34] mid: add `mids' and `references' methods for extraction Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 09/34] content_id: use `mids' and `references' for MID extraction Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 10/34] searchidx: use new `references' method for parsing References Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 11/34] content_id: no need to be human-friendly Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` Eric Wong (Contractor, The Linux Foundation) [this message]
2018-03-06 8:42 ` [PATCH 13/34] search: revert to using 'Q' as a uniQue id per-Xapian conventions Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 14/34] searchidx: support indexing multiple MIDs Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 15/34] mid: be strict with References, but loose on Message-Id Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 16/34] searchidx: avoid excessive XNQ indexing with diffs Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 17/34] searchidxskeleton: add a note about locking Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 18/34] v2writable: generated Message-ID goes first Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 19/34] searchidx: use add_boolean_term for internal terms Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 20/34] searchidx: add NNTP article number as a searchable term Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 21/34] mid: truncate excessively long MIDs early Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 22/34] nntp: use NNTP article numbers for lookups Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 23/34] nntp: fix NEWNEWS command Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 24/34] searchidx: store the primary MID in doc data for NNTP Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 25/34] import: consolidate object info for v2 imports Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 26/34] v2: avoid redundant/repeated configs for git partition repos Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 27/34] INSTALL: document more optional dependencies Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 28/34] search: favor skeleton DB for lookup_mail Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 29/34] search: each_smsg_by_mid uses skeleton if available Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 30/34] v2writable: remove unnecessary skeleton commit Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 31/34] favor Received: date over Date: header globally Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 32/34] import: fall back to Sender for extracting name and email Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 33/34] scripts/import_vger_from_mbox: perform mboxrd or mboxo escaping Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:42 ` [PATCH 34/34] v2writable: detect and use previous partition count Eric Wong (Contractor, The Linux Foundation)
2018-03-06 8:53 ` [v2 PATCH 00/34] duplicate handling, smaller Xapian DBs, date fixes Eric Wong
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
List information: https://public-inbox.org/README
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20180306084242.19988-13-e@80x24.org \
--to=e@80x24.org \
--cc=meta@public-inbox.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for read-only IMAP folder(s) and NNTP newsgroup(s).