;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2022 Pierre Langlois <pierre.langlois@gmx.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (guix build-system tree-sitter)
  #:use-module (guix store)
  #:use-module (guix utils)
  #:use-module (guix packages)
  #:use-module (guix gexp)
  #:use-module (guix monads)
  #:use-module (guix search-paths)
  #:use-module (guix build-system)
  #:use-module (guix build-system gnu)
  #:use-module (guix build-system node)
  #:use-module (ice-9 match)
  #:export (%tree-sitter-build-system-modules
            tree-sitter-build
            tree-sitter-build-system))

(define %tree-sitter-build-system-modules
  ;; Build-side modules imported by default.
  `((guix build tree-sitter-build-system)
    ;; (guix build json)
    ,@%node-build-system-modules))

(define* (lower name
                #:key source inputs native-inputs outputs system target
                #:allow-other-keys
                #:rest arguments)
  ""
  (define private-keywords
    '(#:target #:inputs #:native-inputs #:outputs))

  (and (not target)                    ;XXX: no cross-compilation
       (bag
         (name name)
         (system system)
         (host-inputs `(,@(if source
                              `(("source" ,source))
                              '())
                        ,@(map (match-lambda
                                 ((name package)
                                  `(,name ,package "js")))
                               inputs)
                        ;; Keep the standard inputs of 'gnu-build-system'.
                        ,@(standard-packages)))
         (build-inputs `(("node" ,(module-ref (resolve-interface '(gnu packages node))
                                              'node-lts))
                         ("tree-sitter" ,(module-ref (resolve-interface '(gnu packages tree-sitter))
                                                     'tree-sitter))
                         ("tree-sitter-cli" ,(module-ref (resolve-interface '(gnu packages tree-sitter))
                                                         'tree-sitter-cli))
                         ,@native-inputs))
         (outputs (match outputs
                    (("out") (cons "js" outputs))
                    (_ outputs)))
         (build tree-sitter-build)
         (arguments (strip-keyword-arguments private-keywords arguments)))))

(define* (tree-sitter-build name inputs
                            #:key
                            source
                            (phases '%standard-phases)
                            (outputs '("out" "js"))
                            (search-paths '())
                            (system (%current-system))
                            (guile #f)
                            (imported-modules %tree-sitter-build-system-modules)
                            (modules '((guix build utils)
                                       (guix build tree-sitter-build-system))))
  (define builder
    (with-imported-modules imported-modules
      #~(begin
          (use-modules #$@(sexp->gexp modules))
          (tree-sitter-build #:name #$name
                             #:source #+source
                             #:system #$system
                             #:phases #$phases
                             #:outputs #$(outputs->gexp outputs)
                             #:search-paths '#$(sexp->gexp
                                                (map search-path-specification->sexp
                                                     search-paths))
                             #:inputs #$(input-tuples->gexp inputs)))))

  (mlet %store-monad ((guile (package->derivation (or guile (default-guile))
                                                  system #:graft? #f)))
    (gexp->derivation name builder
                      #:system system
                      #:guile-for-build guile)))

(define tree-sitter-build-system
  (build-system
    (name 'tree-sitter)
    (description "")
    (lower lower)))